[mirror_ubuntu-zesty-kernel.git] / arch / x86 / entry / entry_64_compat.S

/*
 * Compatibility mode system call entry point for x86-64.
 *
 * Copyright 2000-2002 Andi Kleen, SuSE Labs.
 */
#include "calling.h"
#include <asm/asm-offsets.h>
#include <asm/current.h>
#include <asm/errno.h>
#include <asm/ia32_unistd.h>
#include <asm/thread_info.h>
#include <asm/segment.h>
#include <asm/irqflags.h>
#include <asm/asm.h>
#include <asm/smap.h>
#include <linux/linkage.h>
#include <linux/err.h>

	.section .entry.text, "ax"

/*
 * 32-bit SYSENTER instruction entry.
 *
 * SYSENTER loads ss, rsp, cs, and rip from previously programmed MSRs.
 * IF and VM in rflags are cleared (IOW: interrupts are off).
 * SYSENTER does not save anything on the stack,
 * and does not save old rip (!!!) and rflags.
 *
 * Arguments:
 * eax  system call number
 * ebx  arg1
 * ecx  arg2
 * edx  arg3
 * esi  arg4
 * edi  arg5
 * ebp  user stack
 * 0(%ebp) arg6
 *
 * This is purely a fast path. For anything complicated we use the int 0x80
 * path below. We set up a complete hardware stack frame to share code
 * with the int 0x80 path.
 */
ENTRY(entry_SYSENTER_compat)
	/* Interrupts are off on entry. */
	SWAPGS_UNSAFE_STACK
	movq	PER_CPU_VAR(cpu_current_top_of_stack), %rsp

	/*
	 * User tracing code (ptrace or signal handlers) might assume that
	 * the saved RAX contains a 32-bit number when we're invoking a 32-bit
	 * syscall.  Just in case the high bits are nonzero, zero-extend
	 * the syscall number.  (This could almost certainly be deleted
	 * with no ill effects.)
	 */
	movl	%eax, %eax

	/* Construct struct pt_regs on stack */
	pushq	$__USER32_DS		/* pt_regs->ss */
	pushq	%rbp			/* pt_regs->sp (stashed in bp) */

	/*
	 * Push flags.  This is nasty.  First, interrupts are currently
	 * off, but we need pt_regs->flags to have IF set.  Second, even
	 * if TF was set when SYSENTER started, it's clear by now.  We fix
	 * that later using TIF_SINGLESTEP.
	 */
	pushfq				/* pt_regs->flags (except IF = 0) */
	orl	$X86_EFLAGS_IF, (%rsp)	/* Fix saved flags */
	pushq	$__USER32_CS		/* pt_regs->cs */
	xorq    %r8,%r8
	pushq	%r8			/* pt_regs->ip = 0 (placeholder) */
	pushq	%rax			/* pt_regs->orig_ax */
	pushq	%rdi			/* pt_regs->di */
	pushq	%rsi			/* pt_regs->si */
	pushq	%rdx			/* pt_regs->dx */
	pushq	%rcx			/* pt_regs->cx */
	pushq	$-ENOSYS		/* pt_regs->ax */
	pushq   %r8                     /* pt_regs->r8  = 0 */
	pushq   %r8                     /* pt_regs->r9  = 0 */
	pushq   %r8                     /* pt_regs->r10 = 0 */
	pushq   %r8                     /* pt_regs->r11 = 0 */
	pushq   %rbx                    /* pt_regs->rbx */
	pushq   %rbp                    /* pt_regs->rbp (will be overwritten) */
	pushq   %r8                     /* pt_regs->r12 = 0 */
	pushq   %r8                     /* pt_regs->r13 = 0 */
	pushq   %r8                     /* pt_regs->r14 = 0 */
	pushq   %r8                     /* pt_regs->r15 = 0 */
	cld

	/*
	 * SYSENTER doesn't filter flags, so we need to clear NT and AC
	 * ourselves.  To save a few cycles, we can check whether
	 * either was set instead of doing an unconditional popfq.
	 * This needs to happen before enabling interrupts so that
	 * we don't get preempted with NT set.
	 *
	 * If TF is set, we will single-step all the way to here -- do_debug
	 * will ignore all the traps.  (Yes, this is slow, but so is
	 * single-stepping in general.  This allows us to avoid having
	 * a more complicated code to handle the case where a user program
	 * forces us to single-step through the SYSENTER entry code.)
	 *
	 * NB.: .Lsysenter_fix_flags is a label with the code under it moved
	 * out-of-line as an optimization: NT is unlikely to be set in the
	 * majority of the cases and instead of polluting the I$ unnecessarily,
	 * we're keeping that code behind a branch which will predict as
	 * not-taken and therefore its instructions won't be fetched.
	 */
	testl	$X86_EFLAGS_NT|X86_EFLAGS_AC|X86_EFLAGS_TF, EFLAGS(%rsp)
	jnz	.Lsysenter_fix_flags
.Lsysenter_flags_fixed:

	/*
	 * User mode is traced as though IRQs are on, and SYSENTER
	 * turned them off.
	 */
	TRACE_IRQS_OFF

	movq	%rsp, %rdi
	call	do_fast_syscall_32
	/* XEN PV guests always use IRET path */
	ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
		    "jmp .Lsyscall_32_done", X86_FEATURE_XENPV
	jmp	sysret32_from_system_call

.Lsysenter_fix_flags:
	pushq	$X86_EFLAGS_FIXED
	popfq
	jmp	.Lsysenter_flags_fixed
GLOBAL(__end_entry_SYSENTER_compat)
ENDPROC(entry_SYSENTER_compat)

/*
 * 32-bit SYSCALL instruction entry.
 *
 * 32-bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
 * then loads new ss, cs, and rip from previously programmed MSRs.
 * rflags gets masked by a value from another MSR (so CLD and CLAC
 * are not needed). SYSCALL does not save anything on the stack
 * and does not change rsp.
 *
 * Note: rflags saving+masking-with-MSR happens only in Long mode
 * (in legacy 32-bit mode, IF, RF and VM bits are cleared and that's it).
 * Don't get confused: rflags saving+masking depends on Long Mode Active bit
 * (EFER.LMA=1), NOT on bitness of userspace where SYSCALL executes
 * or target CS descriptor's L bit (SYSCALL does not read segment descriptors).
 *
 * Arguments:
 * eax  system call number
 * ecx  return address
 * ebx  arg1
 * ebp  arg2	(note: not saved in the stack frame, should not be touched)
 * edx  arg3
 * esi  arg4
 * edi  arg5
 * esp  user stack
 * 0(%esp) arg6
 */
ENTRY(entry_SYSCALL_compat)
	/* Interrupts are off on entry. */
	SWAPGS_UNSAFE_STACK

	/* Stash user ESP and switch to the kernel stack. */
	movl	%esp, %r8d
	movq	PER_CPU_VAR(cpu_current_top_of_stack), %rsp

	/* Zero-extending 32-bit regs, do not remove */
	movl	%eax, %eax

	/* Construct struct pt_regs on stack */
	pushq	$__USER32_DS		/* pt_regs->ss */
	pushq	%r8			/* pt_regs->sp */
	pushq	%r11			/* pt_regs->flags */
	pushq	$__USER32_CS		/* pt_regs->cs */
	pushq	%rcx			/* pt_regs->ip */
	pushq	%rax			/* pt_regs->orig_ax */
	pushq	%rdi			/* pt_regs->di */
	pushq	%rsi			/* pt_regs->si */
	pushq	%rdx			/* pt_regs->dx */
	pushq	%rbp			/* pt_regs->cx (stashed in bp) */
	pushq	$-ENOSYS		/* pt_regs->ax */
	xorq    %r8,%r8
	pushq   %r8                     /* pt_regs->r8  = 0 */
	pushq   %r8                     /* pt_regs->r9  = 0 */
	pushq   %r8                     /* pt_regs->r10 = 0 */
	pushq   %r8                     /* pt_regs->r11 = 0 */
	pushq   %rbx                    /* pt_regs->rbx */
	pushq   %rbp                    /* pt_regs->rbp (will be overwritten) */
	pushq   %r8                     /* pt_regs->r12 = 0 */
	pushq   %r8                     /* pt_regs->r13 = 0 */
	pushq   %r8                     /* pt_regs->r14 = 0 */
	pushq   %r8                     /* pt_regs->r15 = 0 */

	/*
	 * User mode is traced as though IRQs are on, and SYSENTER
	 * turned them off.
	 */
	TRACE_IRQS_OFF

	movq	%rsp, %rdi
	call	do_fast_syscall_32
	/* XEN PV guests always use IRET path */
	ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
		    "jmp .Lsyscall_32_done", X86_FEATURE_XENPV

	/* Opportunistic SYSRET */
sysret32_from_system_call:
	TRACE_IRQS_ON			/* User mode traces as IRQs on. */
	movq	RBX(%rsp), %rbx		/* pt_regs->rbx */
	movq	RBP(%rsp), %rbp		/* pt_regs->rbp */
	movq	EFLAGS(%rsp), %r11	/* pt_regs->flags (in r11) */
	movq	RIP(%rsp), %rcx		/* pt_regs->ip (in rcx) */
	addq	$RAX, %rsp		/* Skip r8-r15 */
	popq	%rax			/* pt_regs->rax */
	popq	%rdx			/* Skip pt_regs->cx */
	popq	%rdx			/* pt_regs->dx */
	popq	%rsi			/* pt_regs->si */
	popq	%rdi			/* pt_regs->di */

        /*
         * USERGS_SYSRET32 does:
         *  GSBASE = user's GS base
         *  EIP = ECX
         *  RFLAGS = R11
         *  CS = __USER32_CS
         *  SS = __USER_DS
         *
	 * ECX will not match pt_regs->cx, but we're returning to a vDSO
	 * trampoline that will fix up RCX, so this is okay.
	 *
	 * R12-R15 are callee-saved, so they contain whatever was in them
	 * when the system call started, which is already known to user
	 * code.  We zero R8-R10 to avoid info leaks.
         */
	xorq	%r8, %r8
	xorq	%r9, %r9
	xorq	%r10, %r10
	movq	RSP-ORIG_RAX(%rsp), %rsp
	swapgs
	sysretl
END(entry_SYSCALL_compat)

/*
 * Emulated IA32 system calls via int 0x80.
 *
 * Arguments:
 * eax  system call number
 * ebx  arg1
 * ecx  arg2
 * edx  arg3
 * esi  arg4
 * edi  arg5
 * ebp  arg6	(note: not saved in the stack frame, should not be touched)
 *
 * Notes:
 * Uses the same stack frame as the x86-64 version.
 * All registers except eax must be saved (but ptrace may violate that).
 * Arguments are zero extended. For system calls that want sign extension and
 * take long arguments a wrapper is needed. Most calls can just be called
 * directly.
 * Assumes it is only called from user space and entered with interrupts off.
 */

ENTRY(entry_INT80_compat)
	/*
	 * Interrupts are off on entry.
	 */
	PARAVIRT_ADJUST_EXCEPTION_FRAME
	ASM_CLAC			/* Do this early to minimize exposure */
	SWAPGS

	/*
	 * User tracing code (ptrace or signal handlers) might assume that
	 * the saved RAX contains a 32-bit number when we're invoking a 32-bit
	 * syscall.  Just in case the high bits are nonzero, zero-extend
	 * the syscall number.  (This could almost certainly be deleted
	 * with no ill effects.)
	 */
	movl	%eax, %eax

	/* Construct struct pt_regs on stack (iret frame is already on stack) */
	pushq	%rax			/* pt_regs->orig_ax */
	pushq	%rdi			/* pt_regs->di */
	pushq	%rsi			/* pt_regs->si */
	pushq	%rdx			/* pt_regs->dx */
	pushq	%rcx			/* pt_regs->cx */
	pushq	$-ENOSYS		/* pt_regs->ax */
	xorq    %r8,%r8
	pushq   %r8                     /* pt_regs->r8  = 0 */
	pushq   %r8                     /* pt_regs->r9  = 0 */
	pushq   %r8                     /* pt_regs->r10 = 0 */
	pushq   %r8                     /* pt_regs->r11 = 0 */
	pushq   %rbx                    /* pt_regs->rbx */
	pushq   %rbp                    /* pt_regs->rbp */
	pushq   %r12                    /* pt_regs->r12 */
	pushq   %r13                    /* pt_regs->r13 */
	pushq   %r14                    /* pt_regs->r14 */
	pushq   %r15                    /* pt_regs->r15 */
	cld

	/*
	 * User mode is traced as though IRQs are on, and the interrupt
	 * gate turned them off.
	 */
	TRACE_IRQS_OFF

	movq	%rsp, %rdi
	call	do_syscall_32_irqs_off
.Lsyscall_32_done:

	/* Go back to user mode. */
	TRACE_IRQS_ON
	SWAPGS
	jmp	restore_regs_and_iret
END(entry_INT80_compat)

	ALIGN
GLOBAL(stub32_clone)
	/*
	 * The 32-bit clone ABI is: clone(..., int tls_val, int *child_tidptr).
	 * The 64-bit clone ABI is: clone(..., int *child_tidptr, int tls_val).
	 *
	 * The native 64-bit kernel's sys_clone() implements the latter,
	 * so we need to swap arguments here before calling it:
	 */
	xchg	%r8, %rcx
	jmp	sys_clone
Commit	Line	Data
1da177e4	1	/*
54ad726c IM	2	* Compatibility mode system call entry point for x86-64.
54ad726c IM	3	*
1da177e4	4	* Copyright 2000-2002 Andi Kleen, SuSE Labs.
54ad726c	5	*/
d36f9479	6	#include "calling.h"
e2d5df93	7	#include <asm/asm-offsets.h>
1da177e4 LT	8	#include <asm/current.h>
1da177e4 LT	9	#include <asm/errno.h>
54ad726c IM	10	#include <asm/ia32_unistd.h>
54ad726c IM	11	#include <asm/thread_info.h>
1da177e4	12	#include <asm/segment.h>
2601e64d	13	#include <asm/irqflags.h>
1ce6f868	14	#include <asm/asm.h>
63bcff2a	15	#include <asm/smap.h>
1da177e4	16	#include <linux/linkage.h>
d7e7528b	17	#include <linux/err.h>
1da177e4	18
ea714547 JO	19	.section .entry.text, "ax"
ea714547 JO	20
1da177e4	21	/*
54ad726c	22	* 32-bit SYSENTER instruction entry.
1da177e4	23	*
b87cf63e DV	24	* SYSENTER loads ss, rsp, cs, and rip from previously programmed MSRs.
	25	* IF and VM in rflags are cleared (IOW: interrupts are off).
	26	* SYSENTER does not save anything on the stack,
	27	* and does not save old rip (!!!) and rflags.
	28	*
1da177e4	29	* Arguments:
b87cf63e DV	30	* eax system call number
	31	* ebx arg1
	32	* ecx arg2
	33	* edx arg3
	34	* esi arg4
	35	* edi arg5
	36	* ebp user stack
	37	* 0(%ebp) arg6
	38	*
1da177e4	39	* This is purely a fast path. For anything complicated we use the int 0x80
b87cf63e	40	* path below. We set up a complete hardware stack frame to share code
1da177e4	41	* with the int 0x80 path.
b87cf63e	42	*/
4c8cd0c5	43	ENTRY(entry_SYSENTER_compat)
b611acf4	44	/* Interrupts are off on entry. */
a232e3d5	45	SWAPGS_UNSAFE_STACK
3a23208e	46	movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
a232e3d5	47
a474e67c AL	48	/*
	49	* User tracing code (ptrace or signal handlers) might assume that
	50	* the saved RAX contains a 32-bit number when we're invoking a 32-bit
	51	* syscall. Just in case the high bits are nonzero, zero-extend
	52	* the syscall number. (This could almost certainly be deleted
	53	* with no ill effects.)
	54	*/
4ee8ec17 DV	55	movl %eax, %eax
4ee8ec17 DV	56
4c9c0e91	57	/* Construct struct pt_regs on stack */
131484c8	58	pushq $__USER32_DS /* pt_regs->ss */
30bfa7b3	59	pushq %rbp /* pt_regs->sp (stashed in bp) */
b611acf4 AL	60
	61	/*
	62	* Push flags. This is nasty. First, interrupts are currently
	63	* off, but we need pt_regs->flags to have IF set. Second, even
	64	* if TF was set when SYSENTER started, it's clear by now. We fix
	65	* that later using TIF_SINGLESTEP.
	66	*/
	67	pushfq /* pt_regs->flags (except IF = 0) */
	68	orl $X86_EFLAGS_IF, (%rsp) /* Fix saved flags */
131484c8	69	pushq $__USER32_CS /* pt_regs->cs */
a474e67c AL	70	xorq %r8,%r8
a474e67c AL	71	pushq %r8 /* pt_regs->ip = 0 (placeholder) */
131484c8 IM	72	pushq %rax /* pt_regs->orig_ax */
	73	pushq %rdi /* pt_regs->di */
	74	pushq %rsi /* pt_regs->si */
	75	pushq %rdx /* pt_regs->dx */
30bfa7b3	76	pushq %rcx /* pt_regs->cx */
131484c8	77	pushq $-ENOSYS /* pt_regs->ax */
a474e67c AL	78	pushq %r8 /* pt_regs->r8 = 0 */
	79	pushq %r8 /* pt_regs->r9 = 0 */
	80	pushq %r8 /* pt_regs->r10 = 0 */
	81	pushq %r8 /* pt_regs->r11 = 0 */
	82	pushq %rbx /* pt_regs->rbx */
30bfa7b3	83	pushq %rbp /* pt_regs->rbp (will be overwritten) */
a474e67c AL	84	pushq %r8 /* pt_regs->r12 = 0 */
	85	pushq %r8 /* pt_regs->r13 = 0 */
	86	pushq %r8 /* pt_regs->r14 = 0 */
	87	pushq %r8 /* pt_regs->r15 = 0 */
1da177e4	88	cld
4c9c0e91	89
8c7aa698	90	/*
e7860411	91	* SYSENTER doesn't filter flags, so we need to clear NT and AC
8c7aa698	92	* ourselves. To save a few cycles, we can check whether
e7860411	93	* either was set instead of doing an unconditional popfq.
b611acf4 AL	94	* This needs to happen before enabling interrupts so that
b611acf4 AL	95	* we don't get preempted with NT set.
374a3a39	96	*
f2b37575 AL	97	* If TF is set, we will single-step all the way to here -- do_debug
	98	* will ignore all the traps. (Yes, this is slow, but so is
	99	* single-stepping in general. This allows us to avoid having
	100	* a more complicated code to handle the case where a user program
	101	* forces us to single-step through the SYSENTER entry code.)
	102	*
f74acf0e	103	* NB.: .Lsysenter_fix_flags is a label with the code under it moved
374a3a39 BP	104	* out-of-line as an optimization: NT is unlikely to be set in the
	105	* majority of the cases and instead of polluting the I$ unnecessarily,
	106	* we're keeping that code behind a branch which will predict as
	107	* not-taken and therefore its instructions won't be fetched.
8c7aa698	108	*/
f2b37575	109	testl $X86_EFLAGS_NT\|X86_EFLAGS_AC\|X86_EFLAGS_TF, EFLAGS(%rsp)
f74acf0e BP	110	jnz .Lsysenter_fix_flags
f74acf0e BP	111	.Lsysenter_flags_fixed:
8c7aa698	112
a474e67c AL	113	/*
	114	* User mode is traced as though IRQs are on, and SYSENTER
	115	* turned them off.
	116	*/
	117	TRACE_IRQS_OFF
e62a254a	118
a474e67c AL	119	movq %rsp, %rdi
a474e67c AL	120	call do_fast_syscall_32
91e2eea9 BO	121	/* XEN PV guests always use IRET path */
	122	ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
	123	"jmp .Lsyscall_32_done", X86_FEATURE_XENPV
7841b408	124	jmp sysret32_from_system_call
1da177e4	125
f74acf0e	126	.Lsysenter_fix_flags:
b611acf4	127	pushq $X86_EFLAGS_FIXED
131484c8	128	popfq
f74acf0e	129	jmp .Lsysenter_flags_fixed
f2b37575	130	GLOBAL(__end_entry_SYSENTER_compat)
4c8cd0c5	131	ENDPROC(entry_SYSENTER_compat)
1da177e4 LT	132
1da177e4 LT	133	/*
54ad726c	134	* 32-bit SYSCALL instruction entry.
1da177e4	135	*
54ad726c	136	* 32-bit SYSCALL saves rip to rcx, clears rflags.RF, then saves rflags to r11,
b87cf63e DV	137	* then loads new ss, cs, and rip from previously programmed MSRs.
	138	* rflags gets masked by a value from another MSR (so CLD and CLAC
	139	* are not needed). SYSCALL does not save anything on the stack
	140	* and does not change rsp.
	141	*
	142	* Note: rflags saving+masking-with-MSR happens only in Long mode
54ad726c	143	* (in legacy 32-bit mode, IF, RF and VM bits are cleared and that's it).
b87cf63e DV	144	* Don't get confused: rflags saving+masking depends on Long Mode Active bit
	145	* (EFER.LMA=1), NOT on bitness of userspace where SYSCALL executes
	146	* or target CS descriptor's L bit (SYSCALL does not read segment descriptors).
	147	*
1da177e4	148	* Arguments:
b87cf63e DV	149	* eax system call number
	150	* ecx return address
	151	* ebx arg1
	152	* ebp arg2 (note: not saved in the stack frame, should not be touched)
	153	* edx arg3
	154	* esi arg4
	155	* edi arg5
	156	* esp user stack
	157	* 0(%esp) arg6
b87cf63e	158	*/
2cd23553	159	ENTRY(entry_SYSCALL_compat)
a474e67c	160	/* Interrupts are off on entry. */
457da70e	161	SWAPGS_UNSAFE_STACK
e62a254a	162
a474e67c	163	/* Stash user ESP and switch to the kernel stack. */
54ad726c IM	164	movl %esp, %r8d
54ad726c IM	165	movq PER_CPU_VAR(cpu_current_top_of_stack), %rsp
a232e3d5	166
4ee8ec17	167	/* Zero-extending 32-bit regs, do not remove */
54ad726c	168	movl %eax, %eax
4ee8ec17	169
4c9c0e91	170	/* Construct struct pt_regs on stack */
131484c8 IM	171	pushq $__USER32_DS /* pt_regs->ss */
	172	pushq %r8 /* pt_regs->sp */
	173	pushq %r11 /* pt_regs->flags */
	174	pushq $__USER32_CS /* pt_regs->cs */
	175	pushq %rcx /* pt_regs->ip */
	176	pushq %rax /* pt_regs->orig_ax */
	177	pushq %rdi /* pt_regs->di */
	178	pushq %rsi /* pt_regs->si */
	179	pushq %rdx /* pt_regs->dx */
30bfa7b3	180	pushq %rbp /* pt_regs->cx (stashed in bp) */
131484c8	181	pushq $-ENOSYS /* pt_regs->ax */
a474e67c AL	182	xorq %r8,%r8
	183	pushq %r8 /* pt_regs->r8 = 0 */
	184	pushq %r8 /* pt_regs->r9 = 0 */
	185	pushq %r8 /* pt_regs->r10 = 0 */
	186	pushq %r8 /* pt_regs->r11 = 0 */
	187	pushq %rbx /* pt_regs->rbx */
30bfa7b3	188	pushq %rbp /* pt_regs->rbp (will be overwritten) */
a474e67c AL	189	pushq %r8 /* pt_regs->r12 = 0 */
	190	pushq %r8 /* pt_regs->r13 = 0 */
	191	pushq %r8 /* pt_regs->r14 = 0 */
	192	pushq %r8 /* pt_regs->r15 = 0 */
4c9c0e91	193
a474e67c AL	194	/*
	195	* User mode is traced as though IRQs are on, and SYSENTER
	196	* turned them off.
	197	*/
	198	TRACE_IRQS_OFF
	199
	200	movq %rsp, %rdi
	201	call do_fast_syscall_32
91e2eea9 BO	202	/* XEN PV guests always use IRET path */
	203	ALTERNATIVE "testl %eax, %eax; jz .Lsyscall_32_done", \
	204	"jmp .Lsyscall_32_done", X86_FEATURE_XENPV
7841b408 AL	205
	206	/* Opportunistic SYSRET */
	207	sysret32_from_system_call:
	208	TRACE_IRQS_ON /* User mode traces as IRQs on. */
	209	movq RBX(%rsp), %rbx /* pt_regs->rbx */
	210	movq RBP(%rsp), %rbp /* pt_regs->rbp */
	211	movq EFLAGS(%rsp), %r11 /* pt_regs->flags (in r11) */
	212	movq RIP(%rsp), %rcx /* pt_regs->ip (in rcx) */
	213	addq $RAX, %rsp /* Skip r8-r15 */
	214	popq %rax /* pt_regs->rax */
	215	popq %rdx /* Skip pt_regs->cx */
	216	popq %rdx /* pt_regs->dx */
	217	popq %rsi /* pt_regs->si */
	218	popq %rdi /* pt_regs->di */
	219
	220	/*
	221	* USERGS_SYSRET32 does:
	222	* GSBASE = user's GS base
	223	* EIP = ECX
	224	* RFLAGS = R11
	225	* CS = __USER32_CS
	226	* SS = __USER_DS
	227	*
	228	* ECX will not match pt_regs->cx, but we're returning to a vDSO
	229	* trampoline that will fix up RCX, so this is okay.
	230	*
	231	* R12-R15 are callee-saved, so they contain whatever was in them
	232	* when the system call started, which is already known to user
	233	* code. We zero R8-R10 to avoid info leaks.
	234	*/
	235	xorq %r8, %r8
	236	xorq %r9, %r9
	237	xorq %r10, %r10
	238	movq RSP-ORIG_RAX(%rsp), %rsp
75ef8219 BO	239	swapgs
75ef8219 BO	240	sysretl
2cd23553	241	END(entry_SYSCALL_compat)
54ad726c	242
b87cf63e DV	243	/*
b87cf63e DV	244	* Emulated IA32 system calls via int 0x80.
1da177e4	245	*
b87cf63e DV	246	* Arguments:
	247	* eax system call number
	248	* ebx arg1
	249	* ecx arg2
	250	* edx arg3
	251	* esi arg4
	252	* edi arg5
	253	* ebp arg6 (note: not saved in the stack frame, should not be touched)
1da177e4 LT	254	*
1da177e4 LT	255	* Notes:
b87cf63e DV	256	* Uses the same stack frame as the x86-64 version.
b87cf63e DV	257	* All registers except eax must be saved (but ptrace may violate that).
1da177e4 LT	258	* Arguments are zero extended. For system calls that want sign extension and
	259	* take long arguments a wrapper is needed. Most calls can just be called
	260	* directly.
b87cf63e DV	261	* Assumes it is only called from user space and entered with interrupts off.
b87cf63e DV	262	*/
1da177e4	263
2cd23553	264	ENTRY(entry_INT80_compat)
2601e64d	265	/*
a232e3d5	266	* Interrupts are off on entry.
2601e64d	267	*/
a232e3d5	268	PARAVIRT_ADJUST_EXCEPTION_FRAME
3d44d51b	269	ASM_CLAC /* Do this early to minimize exposure */
a232e3d5	270	SWAPGS
a232e3d5	271
ee08c6bd AL	272	/*
	273	* User tracing code (ptrace or signal handlers) might assume that
	274	* the saved RAX contains a 32-bit number when we're invoking a 32-bit
	275	* syscall. Just in case the high bits are nonzero, zero-extend
	276	* the syscall number. (This could almost certainly be deleted
	277	* with no ill effects.)
	278	*/
54ad726c	279	movl %eax, %eax
4ee8ec17	280
4c9c0e91	281	/* Construct struct pt_regs on stack (iret frame is already on stack) */
131484c8 IM	282	pushq %rax /* pt_regs->orig_ax */
	283	pushq %rdi /* pt_regs->di */
	284	pushq %rsi /* pt_regs->si */
	285	pushq %rdx /* pt_regs->dx */
	286	pushq %rcx /* pt_regs->cx */
	287	pushq $-ENOSYS /* pt_regs->ax */
8169aff6 AL	288	xorq %r8,%r8
	289	pushq %r8 /* pt_regs->r8 = 0 */
	290	pushq %r8 /* pt_regs->r9 = 0 */
	291	pushq %r8 /* pt_regs->r10 = 0 */
	292	pushq %r8 /* pt_regs->r11 = 0 */
	293	pushq %rbx /* pt_regs->rbx */
	294	pushq %rbp /* pt_regs->rbp */
	295	pushq %r12 /* pt_regs->r12 */
	296	pushq %r13 /* pt_regs->r13 */
	297	pushq %r14 /* pt_regs->r14 */
	298	pushq %r15 /* pt_regs->r15 */
1da177e4	299	cld
54ad726c	300
73cbf687	301	/*
ee08c6bd AL	302	* User mode is traced as though IRQs are on, and the interrupt
ee08c6bd AL	303	* gate turned them off.
73cbf687	304	*/
ee08c6bd AL	305	TRACE_IRQS_OFF
	306
	307	movq %rsp, %rdi
657c1eea	308	call do_syscall_32_irqs_off
a474e67c	309	.Lsyscall_32_done:
ee08c6bd AL	310
	311	/* Go back to user mode. */
	312	TRACE_IRQS_ON
	313	SWAPGS
	314	jmp restore_regs_and_iret
2cd23553	315	END(entry_INT80_compat)
1da177e4	316
1d4b4b29 AV	317	ALIGN
1d4b4b29 AV	318	GLOBAL(stub32_clone)
5cdc683b	319	/*
7a5a9824 DV	320	* The 32-bit clone ABI is: clone(..., int tls_val, int *child_tidptr).
	321	* The 64-bit clone ABI is: clone(..., int *child_tidptr, int tls_val).
	322	*
	323	* The native 64-bit kernel's sys_clone() implements the latter,
	324	* so we need to swap arguments here before calling it:
5cdc683b	325	*/
7a5a9824	326	xchg %r8, %rcx
8169aff6	327	jmp sys_clone