]>
Commit | Line | Data |
---|---|---|
ef53dae8 SR |
1 | /* |
2 | * Helper macros to support writing architecture specific | |
3 | * linker scripts. | |
4 | * | |
5 | * A minimal linker scripts has following content: | |
6 | * [This is a sample, architectures may have special requiriements] | |
7 | * | |
8 | * OUTPUT_FORMAT(...) | |
9 | * OUTPUT_ARCH(...) | |
10 | * ENTRY(...) | |
11 | * SECTIONS | |
12 | * { | |
13 | * . = START; | |
14 | * __init_begin = .; | |
7923f90f | 15 | * HEAD_TEXT_SECTION |
ef53dae8 SR |
16 | * INIT_TEXT_SECTION(PAGE_SIZE) |
17 | * INIT_DATA_SECTION(...) | |
0415b00d | 18 | * PERCPU_SECTION(CACHELINE_SIZE) |
ef53dae8 SR |
19 | * __init_end = .; |
20 | * | |
21 | * _stext = .; | |
22 | * TEXT_SECTION = 0 | |
23 | * _etext = .; | |
24 | * | |
25 | * _sdata = .; | |
26 | * RO_DATA_SECTION(PAGE_SIZE) | |
27 | * RW_DATA_SECTION(...) | |
28 | * _edata = .; | |
29 | * | |
30 | * EXCEPTION_TABLE(...) | |
31 | * NOTES | |
32 | * | |
04e448d9 | 33 | * BSS_SECTION(0, 0, 0) |
ef53dae8 SR |
34 | * _end = .; |
35 | * | |
ef53dae8 SR |
36 | * STABS_DEBUG |
37 | * DWARF_DEBUG | |
023bf6f1 TH |
38 | * |
39 | * DISCARDS // must be the last | |
ef53dae8 SR |
40 | * } |
41 | * | |
42 | * [__init_begin, __init_end] is the init section that may be freed after init | |
43 | * [_stext, _etext] is the text section | |
44 | * [_sdata, _edata] is the data section | |
45 | * | |
46 | * Some of the included output section have their own set of constants. | |
47 | * Examples are: [__initramfs_start, __initramfs_end] for initramfs and | |
48 | * [__nosave_begin, __nosave_end] for the nosave data | |
49 | */ | |
c80d471a | 50 | |
1da177e4 LT |
51 | #ifndef LOAD_OFFSET |
52 | #define LOAD_OFFSET 0 | |
53 | #endif | |
54 | ||
b92021b0 | 55 | #include <linux/export.h> |
1da177e4 | 56 | |
6d30e3a8 SR |
57 | /* Align . to a 8 byte boundary equals to maximum function alignment. */ |
58 | #define ALIGN_FUNCTION() . = ALIGN(8) | |
59 | ||
07fca0e5 SR |
60 | /* |
61 | * Align to a 32 byte boundary equal to the | |
62 | * alignment gcc 4.5 uses for a struct | |
63 | */ | |
aab94339 DB |
64 | #define STRUCT_ALIGNMENT 32 |
65 | #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT) | |
07fca0e5 | 66 | |
eb8f6890 SR |
67 | /* The actual configuration determine if the init/exit sections |
68 | * are handled as text/data or they can be discarded (which | |
69 | * often happens at runtime) | |
70 | */ | |
eb8f6890 SR |
71 | #ifdef CONFIG_HOTPLUG_CPU |
72 | #define CPU_KEEP(sec) *(.cpu##sec) | |
73 | #define CPU_DISCARD(sec) | |
74 | #else | |
75 | #define CPU_KEEP(sec) | |
76 | #define CPU_DISCARD(sec) *(.cpu##sec) | |
77 | #endif | |
78 | ||
1a3fb6d4 | 79 | #if defined(CONFIG_MEMORY_HOTPLUG) |
eb8f6890 SR |
80 | #define MEM_KEEP(sec) *(.mem##sec) |
81 | #define MEM_DISCARD(sec) | |
82 | #else | |
83 | #define MEM_KEEP(sec) | |
84 | #define MEM_DISCARD(sec) *(.mem##sec) | |
85 | #endif | |
86 | ||
8da3821b | 87 | #ifdef CONFIG_FTRACE_MCOUNT_RECORD |
4b3b4c5e JR |
88 | #define MCOUNT_REC() . = ALIGN(8); \ |
89 | VMLINUX_SYMBOL(__start_mcount_loc) = .; \ | |
8da3821b SR |
90 | *(__mcount_loc) \ |
91 | VMLINUX_SYMBOL(__stop_mcount_loc) = .; | |
92 | #else | |
93 | #define MCOUNT_REC() | |
94 | #endif | |
eb8f6890 | 95 | |
2ed84eeb | 96 | #ifdef CONFIG_TRACE_BRANCH_PROFILING |
45b79749 SR |
97 | #define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \ |
98 | *(_ftrace_annotated_branch) \ | |
99 | VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .; | |
1f0d69a9 SR |
100 | #else |
101 | #define LIKELY_PROFILE() | |
102 | #endif | |
103 | ||
2bcd521a SR |
104 | #ifdef CONFIG_PROFILE_ALL_BRANCHES |
105 | #define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \ | |
106 | *(_ftrace_branch) \ | |
107 | VMLINUX_SYMBOL(__stop_branch_profile) = .; | |
108 | #else | |
109 | #define BRANCH_PROFILE() | |
110 | #endif | |
111 | ||
5f77a88b | 112 | #ifdef CONFIG_EVENT_TRACING |
e4a9ea5e SR |
113 | #define FTRACE_EVENTS() . = ALIGN(8); \ |
114 | VMLINUX_SYMBOL(__start_ftrace_events) = .; \ | |
b77e38aa SR |
115 | *(_ftrace_events) \ |
116 | VMLINUX_SYMBOL(__stop_ftrace_events) = .; | |
117 | #else | |
118 | #define FTRACE_EVENTS() | |
119 | #endif | |
120 | ||
1ba28e02 LJ |
121 | #ifdef CONFIG_TRACING |
122 | #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \ | |
123 | *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \ | |
124 | VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .; | |
102c9323 SRRH |
125 | #define TRACEPOINT_STR() VMLINUX_SYMBOL(__start___tracepoint_str) = .; \ |
126 | *(__tracepoint_str) /* Trace_printk fmt' pointer */ \ | |
127 | VMLINUX_SYMBOL(__stop___tracepoint_str) = .; | |
1ba28e02 LJ |
128 | #else |
129 | #define TRACE_PRINTKS() | |
102c9323 | 130 | #define TRACEPOINT_STR() |
1ba28e02 LJ |
131 | #endif |
132 | ||
bed1ffca | 133 | #ifdef CONFIG_FTRACE_SYSCALLS |
3d56e331 SR |
134 | #define TRACE_SYSCALLS() . = ALIGN(8); \ |
135 | VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \ | |
bed1ffca FW |
136 | *(__syscalls_metadata) \ |
137 | VMLINUX_SYMBOL(__stop_syscalls_metadata) = .; | |
138 | #else | |
139 | #define TRACE_SYSCALLS() | |
140 | #endif | |
141 | ||
aab94339 | 142 | |
06309288 RH |
143 | #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name) |
144 | #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name) | |
145 | #define OF_TABLE(cfg, name) __OF_TABLE(config_enabled(cfg), name) | |
146 | #define _OF_TABLE_0(name) | |
147 | #define _OF_TABLE_1(name) \ | |
f6e916b8 | 148 | . = ALIGN(8); \ |
06309288 RH |
149 | VMLINUX_SYMBOL(__##name##_of_table) = .; \ |
150 | *(__##name##_of_table) \ | |
151 | *(__##name##_of_table_end) | |
152 | ||
153 | #define CLKSRC_OF_TABLES() OF_TABLE(CONFIG_CLKSRC_OF, clksrc) | |
154 | #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip) | |
155 | #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk) | |
156 | #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem) | |
157 | #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method) | |
6c3ff8b1 | 158 | |
aab94339 DB |
159 | #define KERNEL_DTB() \ |
160 | STRUCT_ALIGN(); \ | |
161 | VMLINUX_SYMBOL(__dtb_start) = .; \ | |
162 | *(.dtb.init.rodata) \ | |
163 | VMLINUX_SYMBOL(__dtb_end) = .; | |
164 | ||
ca967258 SR |
165 | /* .data section */ |
166 | #define DATA_DATA \ | |
0e0d314e | 167 | *(.data) \ |
312b1485 | 168 | *(.ref.data) \ |
d356c0b6 | 169 | *(.data..shared_aligned) /* percpu related */ \ |
eb8f6890 SR |
170 | MEM_KEEP(init.data) \ |
171 | MEM_KEEP(exit.data) \ | |
7ccaba53 | 172 | *(.data.unlikely) \ |
65498646 | 173 | STRUCT_ALIGN(); \ |
97e1c18e | 174 | *(__tracepoints) \ |
e9d376f0 | 175 | /* implement dynamic printk debug */ \ |
d430d3d7 JB |
176 | . = ALIGN(8); \ |
177 | VMLINUX_SYMBOL(__start___jump_table) = .; \ | |
178 | *(__jump_table) \ | |
179 | VMLINUX_SYMBOL(__stop___jump_table) = .; \ | |
e9d376f0 JB |
180 | . = ALIGN(8); \ |
181 | VMLINUX_SYMBOL(__start___verbose) = .; \ | |
182 | *(__verbose) \ | |
183 | VMLINUX_SYMBOL(__stop___verbose) = .; \ | |
2bcd521a | 184 | LIKELY_PROFILE() \ |
b77e38aa | 185 | BRANCH_PROFILE() \ |
102c9323 SRRH |
186 | TRACE_PRINTKS() \ |
187 | TRACEPOINT_STR() | |
ca967258 | 188 | |
ef53dae8 SR |
189 | /* |
190 | * Data section helpers | |
191 | */ | |
192 | #define NOSAVE_DATA \ | |
193 | . = ALIGN(PAGE_SIZE); \ | |
194 | VMLINUX_SYMBOL(__nosave_begin) = .; \ | |
07b3bb1e | 195 | *(.data..nosave) \ |
ef53dae8 SR |
196 | . = ALIGN(PAGE_SIZE); \ |
197 | VMLINUX_SYMBOL(__nosave_end) = .; | |
198 | ||
199 | #define PAGE_ALIGNED_DATA(page_align) \ | |
200 | . = ALIGN(page_align); \ | |
75b13483 | 201 | *(.data..page_aligned) |
ef53dae8 SR |
202 | |
203 | #define READ_MOSTLY_DATA(align) \ | |
204 | . = ALIGN(align); \ | |
8369744f SL |
205 | *(.data..read_mostly) \ |
206 | . = ALIGN(align); | |
ef53dae8 SR |
207 | |
208 | #define CACHELINE_ALIGNED_DATA(align) \ | |
209 | . = ALIGN(align); \ | |
4af57b78 | 210 | *(.data..cacheline_aligned) |
ef53dae8 | 211 | |
39a449d9 | 212 | #define INIT_TASK_DATA(align) \ |
ef53dae8 | 213 | . = ALIGN(align); \ |
2af7687f | 214 | *(.data..init_task) |
ef53dae8 SR |
215 | |
216 | /* | |
217 | * Read only Data | |
218 | */ | |
219 | #define RO_DATA_SECTION(align) \ | |
4096b46f | 220 | . = ALIGN((align)); \ |
1da177e4 | 221 | .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \ |
6569580d | 222 | VMLINUX_SYMBOL(__start_rodata) = .; \ |
1da177e4 LT |
223 | *(.rodata) *(.rodata.*) \ |
224 | *(__vermagic) /* Kernel version magic */ \ | |
65498646 MD |
225 | . = ALIGN(8); \ |
226 | VMLINUX_SYMBOL(__start___tracepoints_ptrs) = .; \ | |
227 | *(__tracepoints_ptrs) /* Tracepoints: pointer array */\ | |
228 | VMLINUX_SYMBOL(__stop___tracepoints_ptrs) = .; \ | |
97e1c18e | 229 | *(__tracepoints_strings)/* Tracepoints: strings */ \ |
1da177e4 LT |
230 | } \ |
231 | \ | |
232 | .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \ | |
233 | *(.rodata1) \ | |
234 | } \ | |
235 | \ | |
6360b1fb JB |
236 | BUG_TABLE \ |
237 | \ | |
1da177e4 LT |
238 | /* PCI quirks */ \ |
239 | .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \ | |
240 | VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \ | |
241 | *(.pci_fixup_early) \ | |
242 | VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \ | |
243 | VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \ | |
244 | *(.pci_fixup_header) \ | |
245 | VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \ | |
246 | VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \ | |
247 | *(.pci_fixup_final) \ | |
248 | VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \ | |
249 | VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \ | |
250 | *(.pci_fixup_enable) \ | |
251 | VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \ | |
1597cacb AC |
252 | VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \ |
253 | *(.pci_fixup_resume) \ | |
254 | VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \ | |
e1a2a51e RW |
255 | VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \ |
256 | *(.pci_fixup_resume_early) \ | |
257 | VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \ | |
258 | VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \ | |
259 | *(.pci_fixup_suspend) \ | |
260 | VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \ | |
1da177e4 LT |
261 | } \ |
262 | \ | |
5658c769 DW |
263 | /* Built-in firmware blobs */ \ |
264 | .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \ | |
265 | VMLINUX_SYMBOL(__start_builtin_fw) = .; \ | |
266 | *(.builtin_fw) \ | |
267 | VMLINUX_SYMBOL(__end_builtin_fw) = .; \ | |
268 | } \ | |
269 | \ | |
63687a52 JB |
270 | TRACEDATA \ |
271 | \ | |
1da177e4 LT |
272 | /* Kernel symbol table: Normal symbols */ \ |
273 | __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \ | |
274 | VMLINUX_SYMBOL(__start___ksymtab) = .; \ | |
f02e8a65 | 275 | *(SORT(___ksymtab+*)) \ |
1da177e4 LT |
276 | VMLINUX_SYMBOL(__stop___ksymtab) = .; \ |
277 | } \ | |
278 | \ | |
279 | /* Kernel symbol table: GPL-only symbols */ \ | |
280 | __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \ | |
281 | VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \ | |
f02e8a65 | 282 | *(SORT(___ksymtab_gpl+*)) \ |
1da177e4 LT |
283 | VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \ |
284 | } \ | |
285 | \ | |
f71d20e9 AV |
286 | /* Kernel symbol table: Normal unused symbols */ \ |
287 | __ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \ | |
288 | VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \ | |
f02e8a65 | 289 | *(SORT(___ksymtab_unused+*)) \ |
f71d20e9 AV |
290 | VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \ |
291 | } \ | |
292 | \ | |
293 | /* Kernel symbol table: GPL-only unused symbols */ \ | |
294 | __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \ | |
295 | VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \ | |
f02e8a65 | 296 | *(SORT(___ksymtab_unused_gpl+*)) \ |
f71d20e9 AV |
297 | VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \ |
298 | } \ | |
299 | \ | |
9f28bb7e GKH |
300 | /* Kernel symbol table: GPL-future-only symbols */ \ |
301 | __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \ | |
302 | VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \ | |
f02e8a65 | 303 | *(SORT(___ksymtab_gpl_future+*)) \ |
9f28bb7e GKH |
304 | VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \ |
305 | } \ | |
306 | \ | |
1da177e4 LT |
307 | /* Kernel symbol table: Normal symbols */ \ |
308 | __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \ | |
309 | VMLINUX_SYMBOL(__start___kcrctab) = .; \ | |
f02e8a65 | 310 | *(SORT(___kcrctab+*)) \ |
1da177e4 LT |
311 | VMLINUX_SYMBOL(__stop___kcrctab) = .; \ |
312 | } \ | |
313 | \ | |
314 | /* Kernel symbol table: GPL-only symbols */ \ | |
315 | __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \ | |
316 | VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \ | |
f02e8a65 | 317 | *(SORT(___kcrctab_gpl+*)) \ |
1da177e4 LT |
318 | VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \ |
319 | } \ | |
320 | \ | |
f71d20e9 AV |
321 | /* Kernel symbol table: Normal unused symbols */ \ |
322 | __kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \ | |
323 | VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \ | |
f02e8a65 | 324 | *(SORT(___kcrctab_unused+*)) \ |
f71d20e9 AV |
325 | VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \ |
326 | } \ | |
327 | \ | |
328 | /* Kernel symbol table: GPL-only unused symbols */ \ | |
329 | __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \ | |
330 | VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \ | |
f02e8a65 | 331 | *(SORT(___kcrctab_unused_gpl+*)) \ |
f71d20e9 AV |
332 | VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \ |
333 | } \ | |
334 | \ | |
9f28bb7e GKH |
335 | /* Kernel symbol table: GPL-future-only symbols */ \ |
336 | __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \ | |
337 | VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \ | |
f02e8a65 | 338 | *(SORT(___kcrctab_gpl_future+*)) \ |
9f28bb7e GKH |
339 | VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \ |
340 | } \ | |
341 | \ | |
1da177e4 LT |
342 | /* Kernel symbol table: strings */ \ |
343 | __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \ | |
344 | *(__ksymtab_strings) \ | |
345 | } \ | |
346 | \ | |
eb8f6890 SR |
347 | /* __*init sections */ \ |
348 | __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \ | |
312b1485 | 349 | *(.ref.rodata) \ |
eb8f6890 SR |
350 | MEM_KEEP(init.rodata) \ |
351 | MEM_KEEP(exit.rodata) \ | |
352 | } \ | |
353 | \ | |
1da177e4 LT |
354 | /* Built-in module parameters. */ \ |
355 | __param : AT(ADDR(__param) - LOAD_OFFSET) { \ | |
356 | VMLINUX_SYMBOL(__start___param) = .; \ | |
357 | *(__param) \ | |
358 | VMLINUX_SYMBOL(__stop___param) = .; \ | |
e94965ed DT |
359 | } \ |
360 | \ | |
361 | /* Built-in module versions. */ \ | |
362 | __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \ | |
363 | VMLINUX_SYMBOL(__start___modver) = .; \ | |
364 | *(__modver) \ | |
365 | VMLINUX_SYMBOL(__stop___modver) = .; \ | |
edeed305 | 366 | . = ALIGN((align)); \ |
6569580d | 367 | VMLINUX_SYMBOL(__end_rodata) = .; \ |
7583ddfd | 368 | } \ |
4096b46f SR |
369 | . = ALIGN((align)); |
370 | ||
ef53dae8 | 371 | /* RODATA & RO_DATA provided for backward compatibility. |
4096b46f | 372 | * All archs are supposed to use RO_DATA() */ |
ef53dae8 SR |
373 | #define RODATA RO_DATA_SECTION(4096) |
374 | #define RO_DATA(align) RO_DATA_SECTION(align) | |
1da177e4 LT |
375 | |
376 | #define SECURITY_INIT \ | |
60bad7fa | 377 | .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \ |
1da177e4 LT |
378 | VMLINUX_SYMBOL(__security_initcall_start) = .; \ |
379 | *(.security_initcall.init) \ | |
380 | VMLINUX_SYMBOL(__security_initcall_end) = .; \ | |
381 | } | |
382 | ||
7664709b SR |
383 | /* .text section. Map to function alignment to avoid address changes |
384 | * during second ld run in second ld pass when generating System.map */ | |
385 | #define TEXT_TEXT \ | |
386 | ALIGN_FUNCTION(); \ | |
fb5e2b37 | 387 | *(.text.hot) \ |
0e0d314e | 388 | *(.text) \ |
312b1485 | 389 | *(.ref.text) \ |
eb8f6890 | 390 | MEM_KEEP(init.text) \ |
fb5e2b37 JB |
391 | MEM_KEEP(exit.text) \ |
392 | *(.text.unlikely) | |
eb8f6890 | 393 | |
7664709b | 394 | |
6d30e3a8 SR |
395 | /* sched.text is aling to function alignment to secure we have same |
396 | * address even at second ld pass when generating System.map */ | |
1da177e4 | 397 | #define SCHED_TEXT \ |
6d30e3a8 | 398 | ALIGN_FUNCTION(); \ |
1da177e4 LT |
399 | VMLINUX_SYMBOL(__sched_text_start) = .; \ |
400 | *(.sched.text) \ | |
401 | VMLINUX_SYMBOL(__sched_text_end) = .; | |
402 | ||
6d30e3a8 SR |
403 | /* spinlock.text is aling to function alignment to secure we have same |
404 | * address even at second ld pass when generating System.map */ | |
1da177e4 | 405 | #define LOCK_TEXT \ |
6d30e3a8 | 406 | ALIGN_FUNCTION(); \ |
1da177e4 LT |
407 | VMLINUX_SYMBOL(__lock_text_start) = .; \ |
408 | *(.spinlock.text) \ | |
409 | VMLINUX_SYMBOL(__lock_text_end) = .; | |
d0aaff97 PP |
410 | |
411 | #define KPROBES_TEXT \ | |
412 | ALIGN_FUNCTION(); \ | |
413 | VMLINUX_SYMBOL(__kprobes_text_start) = .; \ | |
414 | *(.kprobes.text) \ | |
415 | VMLINUX_SYMBOL(__kprobes_text_end) = .; | |
a7d0c210 | 416 | |
ea714547 JO |
417 | #define ENTRY_TEXT \ |
418 | ALIGN_FUNCTION(); \ | |
419 | VMLINUX_SYMBOL(__entry_text_start) = .; \ | |
420 | *(.entry.text) \ | |
421 | VMLINUX_SYMBOL(__entry_text_end) = .; | |
422 | ||
a0343e82 FW |
423 | #ifdef CONFIG_FUNCTION_GRAPH_TRACER |
424 | #define IRQENTRY_TEXT \ | |
425 | ALIGN_FUNCTION(); \ | |
426 | VMLINUX_SYMBOL(__irqentry_text_start) = .; \ | |
427 | *(.irqentry.text) \ | |
428 | VMLINUX_SYMBOL(__irqentry_text_end) = .; | |
429 | #else | |
430 | #define IRQENTRY_TEXT | |
431 | #endif | |
432 | ||
37c514e3 | 433 | /* Section used for early init (in .S files) */ |
7923f90f | 434 | #define HEAD_TEXT *(.head.text) |
37c514e3 | 435 | |
7923f90f | 436 | #define HEAD_TEXT_SECTION \ |
ef53dae8 SR |
437 | .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \ |
438 | HEAD_TEXT \ | |
439 | } | |
440 | ||
441 | /* | |
442 | * Exception table | |
443 | */ | |
444 | #define EXCEPTION_TABLE(align) \ | |
445 | . = ALIGN(align); \ | |
446 | __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \ | |
447 | VMLINUX_SYMBOL(__start___ex_table) = .; \ | |
448 | *(__ex_table) \ | |
449 | VMLINUX_SYMBOL(__stop___ex_table) = .; \ | |
450 | } | |
451 | ||
452 | /* | |
453 | * Init task | |
454 | */ | |
39a449d9 | 455 | #define INIT_TASK_DATA_SECTION(align) \ |
ef53dae8 | 456 | . = ALIGN(align); \ |
da5e37ef | 457 | .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \ |
39a449d9 | 458 | INIT_TASK_DATA(align) \ |
ef53dae8 | 459 | } |
37c514e3 | 460 | |
b99b87f7 | 461 | #ifdef CONFIG_CONSTRUCTORS |
2a2325e6 HC |
462 | #define KERNEL_CTORS() . = ALIGN(8); \ |
463 | VMLINUX_SYMBOL(__ctors_start) = .; \ | |
b99b87f7 | 464 | *(.ctors) \ |
eb3057df | 465 | *(.init_array) \ |
b99b87f7 PO |
466 | VMLINUX_SYMBOL(__ctors_end) = .; |
467 | #else | |
468 | #define KERNEL_CTORS() | |
469 | #endif | |
470 | ||
01ba2bdc | 471 | /* init and exit section handling */ |
eb8f6890 SR |
472 | #define INIT_DATA \ |
473 | *(.init.data) \ | |
eb8f6890 | 474 | MEM_DISCARD(init.data) \ |
b99b87f7 | 475 | KERNEL_CTORS() \ |
4b3b4c5e | 476 | MCOUNT_REC() \ |
9fd49328 | 477 | *(.init.rodata) \ |
e4a9ea5e | 478 | FTRACE_EVENTS() \ |
3d56e331 | 479 | TRACE_SYSCALLS() \ |
aab94339 | 480 | MEM_DISCARD(init.rodata) \ |
f2f6c255 | 481 | CLK_OF_TABLES() \ |
f618c470 | 482 | RESERVEDMEM_OF_TABLES() \ |
ae278a93 | 483 | CLKSRC_OF_TABLES() \ |
6c3ff8b1 | 484 | CPU_METHOD_OF_TABLES() \ |
f6e916b8 TP |
485 | KERNEL_DTB() \ |
486 | IRQCHIP_OF_MATCH_TABLE() | |
eb8f6890 SR |
487 | |
488 | #define INIT_TEXT \ | |
489 | *(.init.text) \ | |
eb8f6890 SR |
490 | MEM_DISCARD(init.text) |
491 | ||
492 | #define EXIT_DATA \ | |
493 | *(.exit.data) \ | |
eb8f6890 SR |
494 | MEM_DISCARD(exit.data) \ |
495 | MEM_DISCARD(exit.rodata) | |
01ba2bdc | 496 | |
eb8f6890 SR |
497 | #define EXIT_TEXT \ |
498 | *(.exit.text) \ | |
eb8f6890 | 499 | MEM_DISCARD(exit.text) |
01ba2bdc | 500 | |
7923f90f SR |
501 | #define EXIT_CALL \ |
502 | *(.exitcall.exit) | |
503 | ||
ef53dae8 SR |
504 | /* |
505 | * bss (Block Started by Symbol) - uninitialized data | |
506 | * zeroed during startup | |
507 | */ | |
04e448d9 TA |
508 | #define SBSS(sbss_align) \ |
509 | . = ALIGN(sbss_align); \ | |
ef53dae8 SR |
510 | .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \ |
511 | *(.sbss) \ | |
512 | *(.scommon) \ | |
513 | } | |
514 | ||
c87728ca DD |
515 | /* |
516 | * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra | |
517 | * sections to the front of bss. | |
518 | */ | |
519 | #ifndef BSS_FIRST_SECTIONS | |
520 | #define BSS_FIRST_SECTIONS | |
521 | #endif | |
522 | ||
ef53dae8 SR |
523 | #define BSS(bss_align) \ |
524 | . = ALIGN(bss_align); \ | |
525 | .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \ | |
c87728ca | 526 | BSS_FIRST_SECTIONS \ |
7c74df07 | 527 | *(.bss..page_aligned) \ |
ef53dae8 SR |
528 | *(.dynbss) \ |
529 | *(.bss) \ | |
530 | *(COMMON) \ | |
ef53dae8 SR |
531 | } |
532 | ||
533 | /* | |
534 | * DWARF debug sections. | |
535 | * Symbols in the DWARF debugging sections are relative to | |
536 | * the beginning of the section so we begin them at 0. | |
537 | */ | |
a7d0c210 PBG |
538 | #define DWARF_DEBUG \ |
539 | /* DWARF 1 */ \ | |
540 | .debug 0 : { *(.debug) } \ | |
541 | .line 0 : { *(.line) } \ | |
542 | /* GNU DWARF 1 extensions */ \ | |
543 | .debug_srcinfo 0 : { *(.debug_srcinfo) } \ | |
544 | .debug_sfnames 0 : { *(.debug_sfnames) } \ | |
545 | /* DWARF 1.1 and DWARF 2 */ \ | |
546 | .debug_aranges 0 : { *(.debug_aranges) } \ | |
547 | .debug_pubnames 0 : { *(.debug_pubnames) } \ | |
548 | /* DWARF 2 */ \ | |
549 | .debug_info 0 : { *(.debug_info \ | |
550 | .gnu.linkonce.wi.*) } \ | |
551 | .debug_abbrev 0 : { *(.debug_abbrev) } \ | |
552 | .debug_line 0 : { *(.debug_line) } \ | |
553 | .debug_frame 0 : { *(.debug_frame) } \ | |
554 | .debug_str 0 : { *(.debug_str) } \ | |
555 | .debug_loc 0 : { *(.debug_loc) } \ | |
556 | .debug_macinfo 0 : { *(.debug_macinfo) } \ | |
557 | /* SGI/MIPS DWARF 2 extensions */ \ | |
558 | .debug_weaknames 0 : { *(.debug_weaknames) } \ | |
559 | .debug_funcnames 0 : { *(.debug_funcnames) } \ | |
560 | .debug_typenames 0 : { *(.debug_typenames) } \ | |
561 | .debug_varnames 0 : { *(.debug_varnames) } \ | |
562 | ||
563 | /* Stabs debugging sections. */ | |
564 | #define STABS_DEBUG \ | |
565 | .stab 0 : { *(.stab) } \ | |
566 | .stabstr 0 : { *(.stabstr) } \ | |
567 | .stab.excl 0 : { *(.stab.excl) } \ | |
568 | .stab.exclstr 0 : { *(.stab.exclstr) } \ | |
569 | .stab.index 0 : { *(.stab.index) } \ | |
570 | .stab.indexstr 0 : { *(.stab.indexstr) } \ | |
571 | .comment 0 : { *(.comment) } | |
9c9b8b38 | 572 | |
6360b1fb | 573 | #ifdef CONFIG_GENERIC_BUG |
7664c5a1 JF |
574 | #define BUG_TABLE \ |
575 | . = ALIGN(8); \ | |
576 | __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \ | |
c6de0026 | 577 | VMLINUX_SYMBOL(__start___bug_table) = .; \ |
7664c5a1 | 578 | *(__bug_table) \ |
c6de0026 | 579 | VMLINUX_SYMBOL(__stop___bug_table) = .; \ |
7664c5a1 | 580 | } |
6360b1fb JB |
581 | #else |
582 | #define BUG_TABLE | |
583 | #endif | |
7664c5a1 | 584 | |
63687a52 JB |
585 | #ifdef CONFIG_PM_TRACE |
586 | #define TRACEDATA \ | |
587 | . = ALIGN(4); \ | |
588 | .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \ | |
c6de0026 | 589 | VMLINUX_SYMBOL(__tracedata_start) = .; \ |
63687a52 | 590 | *(.tracedata) \ |
c6de0026 | 591 | VMLINUX_SYMBOL(__tracedata_end) = .; \ |
63687a52 JB |
592 | } |
593 | #else | |
594 | #define TRACEDATA | |
595 | #endif | |
596 | ||
9c9b8b38 | 597 | #define NOTES \ |
cbe87121 RM |
598 | .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \ |
599 | VMLINUX_SYMBOL(__start_notes) = .; \ | |
600 | *(.note.*) \ | |
601 | VMLINUX_SYMBOL(__stop_notes) = .; \ | |
602 | } | |
61ce1efe | 603 | |
ef53dae8 SR |
604 | #define INIT_SETUP(initsetup_align) \ |
605 | . = ALIGN(initsetup_align); \ | |
606 | VMLINUX_SYMBOL(__setup_start) = .; \ | |
607 | *(.init.setup) \ | |
608 | VMLINUX_SYMBOL(__setup_end) = .; | |
609 | ||
026cee00 PM |
610 | #define INIT_CALLS_LEVEL(level) \ |
611 | VMLINUX_SYMBOL(__initcall##level##_start) = .; \ | |
612 | *(.initcall##level##.init) \ | |
613 | *(.initcall##level##s.init) \ | |
61ce1efe | 614 | |
ef53dae8 SR |
615 | #define INIT_CALLS \ |
616 | VMLINUX_SYMBOL(__initcall_start) = .; \ | |
026cee00 PM |
617 | *(.initcallearly.init) \ |
618 | INIT_CALLS_LEVEL(0) \ | |
619 | INIT_CALLS_LEVEL(1) \ | |
620 | INIT_CALLS_LEVEL(2) \ | |
621 | INIT_CALLS_LEVEL(3) \ | |
622 | INIT_CALLS_LEVEL(4) \ | |
623 | INIT_CALLS_LEVEL(5) \ | |
624 | INIT_CALLS_LEVEL(rootfs) \ | |
625 | INIT_CALLS_LEVEL(6) \ | |
626 | INIT_CALLS_LEVEL(7) \ | |
ef53dae8 SR |
627 | VMLINUX_SYMBOL(__initcall_end) = .; |
628 | ||
629 | #define CON_INITCALL \ | |
630 | VMLINUX_SYMBOL(__con_initcall_start) = .; \ | |
631 | *(.con_initcall.init) \ | |
632 | VMLINUX_SYMBOL(__con_initcall_end) = .; | |
633 | ||
634 | #define SECURITY_INITCALL \ | |
635 | VMLINUX_SYMBOL(__security_initcall_start) = .; \ | |
636 | *(.security_initcall.init) \ | |
637 | VMLINUX_SYMBOL(__security_initcall_end) = .; | |
638 | ||
639 | #ifdef CONFIG_BLK_DEV_INITRD | |
640 | #define INIT_RAM_FS \ | |
d8826262 | 641 | . = ALIGN(4); \ |
ef53dae8 SR |
642 | VMLINUX_SYMBOL(__initramfs_start) = .; \ |
643 | *(.init.ramfs) \ | |
ffe8018c HB |
644 | . = ALIGN(8); \ |
645 | *(.init.ramfs.info) | |
ef53dae8 | 646 | #else |
eadfe219 | 647 | #define INIT_RAM_FS |
ef53dae8 SR |
648 | #endif |
649 | ||
023bf6f1 TH |
650 | /* |
651 | * Default discarded sections. | |
652 | * | |
653 | * Some archs want to discard exit text/data at runtime rather than | |
654 | * link time due to cross-section references such as alt instructions, | |
655 | * bug table, eh_frame, etc. DISCARDS must be the last of output | |
656 | * section definitions so that such archs put those in earlier section | |
657 | * definitions. | |
658 | */ | |
405d967d TH |
659 | #define DISCARDS \ |
660 | /DISCARD/ : { \ | |
661 | EXIT_TEXT \ | |
662 | EXIT_DATA \ | |
023bf6f1 | 663 | EXIT_CALL \ |
405d967d | 664 | *(.discard) \ |
c7f52cdc | 665 | *(.discard.*) \ |
405d967d TH |
666 | } |
667 | ||
6ea0c34d MF |
668 | /** |
669 | * PERCPU_INPUT - the percpu input sections | |
670 | * @cacheline: cacheline size | |
671 | * | |
672 | * The core percpu section names and core symbols which do not rely | |
673 | * directly upon load addresses. | |
674 | * | |
675 | * @cacheline is used to align subsections to avoid false cacheline | |
676 | * sharing between subsections for different purposes. | |
677 | */ | |
678 | #define PERCPU_INPUT(cacheline) \ | |
679 | VMLINUX_SYMBOL(__per_cpu_start) = .; \ | |
680 | *(.data..percpu..first) \ | |
681 | . = ALIGN(PAGE_SIZE); \ | |
682 | *(.data..percpu..page_aligned) \ | |
683 | . = ALIGN(cacheline); \ | |
684 | *(.data..percpu..readmostly) \ | |
685 | . = ALIGN(cacheline); \ | |
686 | *(.data..percpu) \ | |
687 | *(.data..percpu..shared_aligned) \ | |
688 | VMLINUX_SYMBOL(__per_cpu_end) = .; | |
689 | ||
3e5d8f97 | 690 | /** |
6b7c38d5 | 691 | * PERCPU_VADDR - define output section for percpu area |
19df0c2f | 692 | * @cacheline: cacheline size |
3e5d8f97 TH |
693 | * @vaddr: explicit base address (optional) |
694 | * @phdr: destination PHDR (optional) | |
695 | * | |
19df0c2f TH |
696 | * Macro which expands to output section for percpu area. |
697 | * | |
698 | * @cacheline is used to align subsections to avoid false cacheline | |
699 | * sharing between subsections for different purposes. | |
700 | * | |
701 | * If @vaddr is not blank, it specifies explicit base address and all | |
702 | * percpu symbols will be offset from the given address. If blank, | |
703 | * @vaddr always equals @laddr + LOAD_OFFSET. | |
3e5d8f97 TH |
704 | * |
705 | * @phdr defines the output PHDR to use if not blank. Be warned that | |
706 | * output PHDR is sticky. If @phdr is specified, the next output | |
707 | * section in the linker script will go there too. @phdr should have | |
708 | * a leading colon. | |
709 | * | |
3ac6cffe TH |
710 | * Note that this macros defines __per_cpu_load as an absolute symbol. |
711 | * If there is no need to put the percpu section at a predetermined | |
0415b00d | 712 | * address, use PERCPU_SECTION. |
3e5d8f97 | 713 | */ |
19df0c2f | 714 | #define PERCPU_VADDR(cacheline, vaddr, phdr) \ |
dba3d36b | 715 | VMLINUX_SYMBOL(__per_cpu_load) = .; \ |
3d9a854c | 716 | .data..percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \ |
6b7c38d5 | 717 | - LOAD_OFFSET) { \ |
6ea0c34d | 718 | PERCPU_INPUT(cacheline) \ |
6b7c38d5 | 719 | } phdr \ |
3d9a854c | 720 | . = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data..percpu); |
3e5d8f97 TH |
721 | |
722 | /** | |
0415b00d | 723 | * PERCPU_SECTION - define output section for percpu area, simple version |
19df0c2f | 724 | * @cacheline: cacheline size |
3e5d8f97 | 725 | * |
0415b00d TH |
726 | * Align to PAGE_SIZE and outputs output section for percpu area. This |
727 | * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and | |
3e5d8f97 | 728 | * __per_cpu_start will be identical. |
3ac6cffe | 729 | * |
0415b00d | 730 | * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,) |
19df0c2f TH |
731 | * except that __per_cpu_load is defined as a relative symbol against |
732 | * .data..percpu which is required for relocatable x86_32 configuration. | |
3e5d8f97 | 733 | */ |
0415b00d TH |
734 | #define PERCPU_SECTION(cacheline) \ |
735 | . = ALIGN(PAGE_SIZE); \ | |
3d9a854c | 736 | .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \ |
3ac6cffe | 737 | VMLINUX_SYMBOL(__per_cpu_load) = .; \ |
6ea0c34d | 738 | PERCPU_INPUT(cacheline) \ |
3ac6cffe | 739 | } |
ef53dae8 SR |
740 | |
741 | ||
742 | /* | |
743 | * Definition of the high level *_SECTION macros | |
744 | * They will fit only a subset of the architectures | |
745 | */ | |
746 | ||
747 | ||
748 | /* | |
749 | * Writeable data. | |
750 | * All sections are combined in a single .data section. | |
751 | * The sections following CONSTRUCTORS are arranged so their | |
752 | * typical alignment matches. | |
753 | * A cacheline is typical/always less than a PAGE_SIZE so | |
754 | * the sections that has this restriction (or similar) | |
755 | * is located before the ones requiring PAGE_SIZE alignment. | |
756 | * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which | |
25985edc | 757 | * matches the requirement of PAGE_ALIGNED_DATA. |
ef53dae8 | 758 | * |
7923f90f | 759 | * use 0 as page_align if page_aligned data is not used */ |
73f1d939 | 760 | #define RW_DATA_SECTION(cacheline, pagealigned, inittask) \ |
ef53dae8 SR |
761 | . = ALIGN(PAGE_SIZE); \ |
762 | .data : AT(ADDR(.data) - LOAD_OFFSET) { \ | |
39a449d9 | 763 | INIT_TASK_DATA(inittask) \ |
1b208622 TA |
764 | NOSAVE_DATA \ |
765 | PAGE_ALIGNED_DATA(pagealigned) \ | |
ef53dae8 SR |
766 | CACHELINE_ALIGNED_DATA(cacheline) \ |
767 | READ_MOSTLY_DATA(cacheline) \ | |
768 | DATA_DATA \ | |
769 | CONSTRUCTORS \ | |
ef53dae8 SR |
770 | } |
771 | ||
772 | #define INIT_TEXT_SECTION(inittext_align) \ | |
773 | . = ALIGN(inittext_align); \ | |
774 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \ | |
775 | VMLINUX_SYMBOL(_sinittext) = .; \ | |
776 | INIT_TEXT \ | |
777 | VMLINUX_SYMBOL(_einittext) = .; \ | |
778 | } | |
779 | ||
780 | #define INIT_DATA_SECTION(initsetup_align) \ | |
781 | .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \ | |
782 | INIT_DATA \ | |
783 | INIT_SETUP(initsetup_align) \ | |
784 | INIT_CALLS \ | |
785 | CON_INITCALL \ | |
786 | SECURITY_INITCALL \ | |
787 | INIT_RAM_FS \ | |
788 | } | |
789 | ||
04e448d9 TA |
790 | #define BSS_SECTION(sbss_align, bss_align, stop_align) \ |
791 | . = ALIGN(sbss_align); \ | |
792 | VMLINUX_SYMBOL(__bss_start) = .; \ | |
793 | SBSS(sbss_align) \ | |
ef53dae8 | 794 | BSS(bss_align) \ |
04e448d9 TA |
795 | . = ALIGN(stop_align); \ |
796 | VMLINUX_SYMBOL(__bss_stop) = .; |