acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 17; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.17.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIB=-lintel_dpdk
 174
 175     ovs_save_CFLAGS="$CFLAGS"
 176     ovs_save_LDFLAGS="$LDFLAGS"
 177     LDFLAGS="$LDFLAGS -L$DPDK_LIB_DIR"
 178     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 179
 180     # On some systems we have to add -ldl to link with dpdk
 181     #
 182     # This code, at first, tries to link without -ldl (""),
 183     # then adds it and tries again.
 184     # Before each attempt the search cache must be unset,
 185     # otherwise autoconf will stick with the old result
 186
 187     found=false
 188     save_LIBS=$LIBS
 189     for extras in "" "-ldl"; do
 190         LIBS="$DPDK_LIB $extras $save_LIBS"
 191         AC_LINK_IFELSE(
 192            [AC_LANG_PROGRAM([#include <rte_config.h>
 193                              #include <rte_eal.h>],
 194                             [int rte_argc; char ** rte_argv;
 195                              rte_eal_init(rte_argc, rte_argv);])],
 196            [found=true])
 197         if $found; then
 198             break
 199         fi
 200     done
 201     if $found; then :; else
 202         AC_MSG_ERROR([cannot link with dpdk])
 203     fi
 204     CFLAGS="$ovs_save_CFLAGS"
 205     LDFLAGS="$ovs_save_LDFLAGS"
 206     OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 207     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 208
 209     # DPDK 1.7.0 pmd drivers are not linked unless --whole-archive is used.
 210     #
 211     # This happens because the rest of the DPDK code doesn't use any symbol in
 212     # the pmd driver objects, and the drivers register themselves using an
 213     # __attribute__((constructor)) function.
 214     #
 215     # These options are specified inside a single -Wl directive to prevent
 216     # autotools from reordering them.
 217     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 218     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 219     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 220   else
 221     RTE_SDK=
 222   fi
 223
 224   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 225 ])
 226
 227 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 228 dnl
 229 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 230 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 231 dnl <REGEX> translated to uppercase.
 232 AC_DEFUN([OVS_GREP_IFELSE], [
 233   AC_MSG_CHECKING([whether $2 matches in $1])
 234   if test -f $1; then
 235     grep '$2' $1 >/dev/null 2>&1
 236     status=$?
 237     case $status in
 238       0)
 239         AC_MSG_RESULT([yes])
 240         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 241         ;;
 242       1)
 243         AC_MSG_RESULT([no])
 244         $4
 245         ;;
 246       *)
 247         AC_MSG_ERROR([grep exited with status $status])
 248         ;;
 249     esac
 250   else
 251     AC_MSG_RESULT([file not found])
 252     $4
 253   fi
 254 ])
 255
 256 dnl OVS_DEFINE(NAME)
 257 dnl
 258 dnl Defines NAME to 1 in kcompat.h.
 259 AC_DEFUN([OVS_DEFINE], [
 260   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 261 ])
 262
 263 AC_DEFUN([OVS_CHECK_LOG2_H], [
 264   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 265   if test -e $KSRC/include/linux/log2.h; then
 266     AC_MSG_RESULT([yes])
 267     OVS_DEFINE([HAVE_LOG2_H])
 268   else
 269     AC_MSG_RESULT([no])
 270   fi
 271 ])
 272
 273 dnl OVS_CHECK_LINUX_COMPAT
 274 dnl
 275 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 276 dnl the directory in $KBUILD.
 277 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 278   rm -f datapath/linux/kcompat.h.new
 279   mkdir -p datapath/linux
 280   : > datapath/linux/kcompat.h.new
 281
 282   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 283                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 284
 285   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 286   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 287   OVS_GREP_IFELSE([$KSRC/include/linux/hash.h], [fast_hash_ops])
 288
 289   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 291
 292   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 293
 294   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 295   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 296                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 297
 298   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 299   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 301   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 302   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 303   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 304   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 305
 306   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 307
 308   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 309                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 310                                    [rcu_read_lock_held])])
 311   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 312
 313   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 314   # is necessary because some versions of this header remove the
 315   # member but retain the kerneldoc comment that describes it (which
 316   # starts with @).  The brackets must be doubled because of m4
 317   # quoting rules.
 318   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 319                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 320   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 321   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 322                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 324                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 326                   [skb_copy_from_linear_data_offset])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 328                   [skb_reset_tail_pointer])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 331                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 333                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 335                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 337   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 338   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 339   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 341   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 342   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 343   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 344   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 345   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 346                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 347   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 348
 349   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 350                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 351   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 352                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 353   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 354                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 355
 356   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 357   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 358
 359   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 360   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 361   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 362   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 363   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 364   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 365   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [iptunnel_xmit.*net],
 366                   [OVS_DEFINE([HAVE_IPTUNNEL_XMIT_NET])])
 367   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 368   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 369   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 370   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 371   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 372
 373   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 374
 375   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 376                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 377
 378   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 379
 380   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 381                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 382   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_xmit_skb])
 383   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [bool xnet],
 384                   [OVS_DEFINE([HAVE_VXLAN_XMIT_SKB_XNET_ARG])])
 385   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 386                   [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])
 387   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df:1],
 388                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 389   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 390                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 391
 392   OVS_CHECK_LOG2_H
 393
 394   if cmp -s datapath/linux/kcompat.h.new \
 395             datapath/linux/kcompat.h >/dev/null 2>&1; then
 396     rm datapath/linux/kcompat.h.new
 397   else
 398     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 399   fi
 400 ])
 401
 402 dnl Checks for net/if_packet.h.
 403 AC_DEFUN([OVS_CHECK_IF_PACKET],
 404   [AC_CHECK_HEADER([net/if_packet.h],
 405                    [HAVE_IF_PACKET=yes],
 406                    [HAVE_IF_PACKET=no])
 407    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 408    if test "$HAVE_IF_PACKET" = yes; then
 409       AC_DEFINE([HAVE_IF_PACKET], [1],
 410                 [Define to 1 if net/if_packet.h is available.])
 411    fi])
 412
 413 dnl Checks for net/if_dl.h.
 414 dnl
 415 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 416 dnl or NetBSD.)
 417 AC_DEFUN([OVS_CHECK_IF_DL],
 418   [AC_CHECK_HEADER([net/if_dl.h],
 419                    [HAVE_IF_DL=yes],
 420                    [HAVE_IF_DL=no])
 421    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 422    if test "$HAVE_IF_DL" = yes; then
 423       AC_DEFINE([HAVE_IF_DL], [1],
 424                 [Define to 1 if net/if_dl.h is available.])
 425
 426       # On these platforms we use libpcap to access network devices.
 427       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 428    fi])
 429
 430 dnl Checks for buggy strtok_r.
 431 dnl
 432 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 433 dnl with optimization that can cause segfaults:
 434 dnl
 435 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 436 AC_DEFUN([OVS_CHECK_STRTOK_R],
 437   [AC_CACHE_CHECK(
 438      [whether strtok_r macro segfaults on some inputs],
 439      [ovs_cv_strtok_r_bug],
 440      [AC_RUN_IFELSE(
 441         [AC_LANG_PROGRAM([#include <stdio.h>
 442                           #include <string.h>
 443                          ],
 444                          [[char string[] = ":::";
 445                            char *save_ptr = (char *) 0xc0ffee;
 446                            char *token1, *token2;
 447                            token1 = strtok_r(string, ":", &save_ptr);
 448                            token2 = strtok_r(NULL, ":", &save_ptr);
 449                            freopen ("/dev/null", "w", stdout);
 450                            printf ("%s %s\n", token1, token2);
 451                            return 0;
 452                           ]])],
 453         [ovs_cv_strtok_r_bug=no],
 454         [ovs_cv_strtok_r_bug=yes],
 455         [ovs_cv_strtok_r_bug=yes])])
 456    if test $ovs_cv_strtok_r_bug = yes; then
 457      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 458                [Define if strtok_r macro segfaults on some inputs])
 459    fi
 460 ])
 461
 462 dnl ----------------------------------------------------------------------
 463 dnl These macros are from GNU PSPP, with the following original license:
 464 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 465 dnl This file is free software; the Free Software Foundation
 466 dnl gives unlimited permission to copy and/or distribute it,
 467 dnl with or without modifications, as long as this notice is preserved.
 468
 469 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 470   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 471   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 472     [ovs_save_CFLAGS="$CFLAGS"
 473      dnl Include -Werror in the compiler options, because without -Werror
 474      dnl clang's GCC-compatible compiler driver does not return a failure
 475      dnl exit status even though it complains about options it does not
 476      dnl understand.
 477      CFLAGS="$CFLAGS $WERROR $1"
 478      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 479      CFLAGS="$ovs_save_CFLAGS"])
 480   if test $ovs_cv_name = yes; then
 481     m4_if([$2], [], [:], [$2])
 482   else
 483     m4_if([$3], [], [:], [$3])
 484   fi
 485 ])
 486
 487 dnl OVS_CHECK_WERROR
 488 dnl
 489 dnl Check whether the C compiler accepts -Werror.
 490 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 491 AC_DEFUN([OVS_CHECK_WERROR],
 492   [WERROR=
 493    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 494
 495 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 496 dnl Check whether the given C compiler OPTION is accepted.
 497 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 498 AC_DEFUN([OVS_CHECK_CC_OPTION],
 499   [AC_REQUIRE([OVS_CHECK_WERROR])
 500    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 501
 502 dnl OVS_ENABLE_OPTION([OPTION])
 503 dnl Check whether the given C compiler OPTION is accepted.
 504 dnl If so, add it to WARNING_FLAGS.
 505 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 506 AC_DEFUN([OVS_ENABLE_OPTION],
 507   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 508    AC_SUBST([WARNING_FLAGS])])
 509
 510 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 511 dnl Check whether the given C compiler OPTION is accepted.
 512 dnl If so, enable the given Automake CONDITIONAL.
 513
 514 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 515 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 516   [OVS_CHECK_CC_OPTION(
 517     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 518    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 519 dnl ----------------------------------------------------------------------
 520
 521 dnl Check for too-old XenServer.
 522 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 523   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 524     [if test -e /etc/redhat-release; then
 525        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 526      fi
 527      if test -z "$ovs_cv_xsversion"; then
 528        ovs_cv_xsversion=none
 529      fi])
 530   case $ovs_cv_xsversion in
 531     none)
 532       ;;
 533
 534     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 535     [[6-9]]* |                           dnl XenServer 6 or later
 536     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 537     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 538     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 539     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 540       ;;
 541
 542     *)
 543       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 544       ;;
 545   esac])
 546
 547 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 548 dnl
 549 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 550 dnl Runs 'if-true' if so, 'if-false' otherwise.
 551 AC_DEFUN([OVS_CHECK_MAKE_IF],
 552   [AC_CACHE_CHECK(
 553      [whether ${MAKE-make} has GNU make \$(if) extension],
 554      [ovs_cv_gnu_make_if],
 555      [cat <<'EOF' > conftest.mk
 556 conftest.out:
 557         echo $(if x,y,z) > conftest.out
 558 .PHONY: all
 559 EOF
 560       rm -f conftest.out
 561       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 562       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 563       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 564       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 565       result=`cat conftest.out`
 566       rm -f conftest.mk conftest.out
 567       if test "X$result" = "Xy"; then
 568         ovs_cv_gnu_make_if=yes
 569       else
 570         ovs_cv_gnu_make_if=no
 571       fi])])
 572
 573 dnl OVS_CHECK_GNU_MAKE
 574 dnl
 575 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 576 dnl only work with GNU make).
 577 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 578   [AC_CACHE_CHECK(
 579      [whether ${MAKE-make} is GNU make],
 580      [ovs_cv_gnu_make],
 581      [rm -f conftest.out
 582       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 583       ${MAKE-make} --version >conftest.out 2>&1
 584       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 585       result=`cat conftest.out`
 586       rm -f conftest.mk conftest.out
 587
 588       case $result in # (
 589         GNU*) ovs_cv_gnu_make=yes ;; # (
 590         *) ovs_cv_gnu_make=no ;;
 591       esac])
 592    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 593
 594 dnl OVS_CHECK_SPARSE_TARGET
 595 dnl
 596 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 597 dnl target for which the code is being built.  This helps it out.
 598 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 599   [AC_CACHE_CHECK(
 600     [target hint for cgcc],
 601     [ac_cv_sparse_target],
 602     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 603        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 604        [x86_64-*], [ac_cv_sparse_target=x86_64],
 605        [ac_cv_sparse_target=other])])
 606    AS_CASE([$ac_cv_sparse_target],
 607      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 608      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 609      [SPARSEFLAGS= CGCCFLAGS=])
 610    AC_SUBST([SPARSEFLAGS])
 611    AC_SUBST([CGCCFLAGS])])
 612
 613 dnl OVS_SPARSE_EXTRA_INCLUDES
 614 dnl
 615 dnl The cgcc script from "sparse" does not search gcc's default
 616 dnl search path. Get the default search path from GCC and pass
 617 dnl them to sparse.
 618 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 619     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 620            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 621
 622 dnl OVS_ENABLE_SPARSE
 623 AC_DEFUN([OVS_ENABLE_SPARSE],
 624   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 625    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 626    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 627    : ${SPARSE=sparse}
 628    AC_SUBST([SPARSE])
 629    AC_CONFIG_COMMANDS_PRE(
 630      [if test $ovs_cv_gnu_make_if = yes; then
 631         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 632       fi])])
 633
 634 dnl OVS_PTHREAD_SET_NAME
 635 dnl
 636 dnl This checks for three known variants of pthreads functions for setting
 637 dnl the name of the current thread:
 638 dnl
 639 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 640 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 641 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 642 dnl
 643 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 644 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 645 dnl provide to it.
 646 dnl
 647 dnl This macro defines:
 648 dnl
 649 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 650 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 651 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 652 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 653   [AC_CHECK_FUNCS([pthread_set_name_np])
 654    if test $ac_cv_func_pthread_set_name_np != yes; then
 655      AC_CACHE_CHECK(
 656        [for pthread_setname_np() variant],
 657        [ovs_cv_pthread_setname_np],
 658        [AC_LINK_IFELSE(
 659          [AC_LANG_PROGRAM([#include <pthread.h>
 660   ], [pthread_setname_np(pthread_self(), "name");])],
 661          [ovs_cv_pthread_setname_np=glibc],
 662          [AC_LINK_IFELSE(
 663            [AC_LANG_PROGRAM([#include <pthread.h>
 664 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 665            [ovs_cv_pthread_setname_np=netbsd],
 666            [ovs_cv_pthread_setname_np=none])])])
 667      case $ovs_cv_pthread_setname_np in # (
 668        glibc)
 669           AC_DEFINE(
 670             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 671             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 672           ;; # (
 673        netbsd)
 674           AC_DEFINE(
 675             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 676             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 677           ;;
 678      esac
 679    fi])
 680
 681 dnl OVS_CHECK_LINUX_HOST.
 682 dnl
 683 dnl Checks whether we're building for a Linux host, based on the presence of
 684 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 685 dnl LINUX based on the result.
 686 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 687   [AC_CACHE_CHECK(
 688      [whether __linux__ is defined],
 689      [ovs_cv_linux],
 690      [AC_COMPILE_IFELSE(
 691         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 692         [ovs_cv_linux=true],
 693         [ovs_cv_linux=false])])
 694    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])