arch/arm64/kvm/hyp-init.S

   1 /*
   2  * Copyright (C) 2012,2013 - ARM Ltd
   3  * Author: Marc Zyngier <marc.zyngier@arm.com>
   4  *
   5  * This program is free software; you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License, version 2, as
   7  * published by the Free Software Foundation.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16  */
  17
  18 #include <linux/linkage.h>
  19
  20 #include <asm/assembler.h>
  21 #include <asm/kvm_arm.h>
  22 #include <asm/kvm_mmu.h>
  23 #include <asm/pgtable-hwdef.h>
  24 #include <asm/sysreg.h>
  25
  26         .text
  27         .pushsection    .hyp.idmap.text, "ax"
  28
  29         .align  11
  30
  31 ENTRY(__kvm_hyp_init)
  32         ventry  __invalid               // Synchronous EL2t
  33         ventry  __invalid               // IRQ EL2t
  34         ventry  __invalid               // FIQ EL2t
  35         ventry  __invalid               // Error EL2t
  36
  37         ventry  __invalid               // Synchronous EL2h
  38         ventry  __invalid               // IRQ EL2h
  39         ventry  __invalid               // FIQ EL2h
  40         ventry  __invalid               // Error EL2h
  41
  42         ventry  __do_hyp_init           // Synchronous 64-bit EL1
  43         ventry  __invalid               // IRQ 64-bit EL1
  44         ventry  __invalid               // FIQ 64-bit EL1
  45         ventry  __invalid               // Error 64-bit EL1
  46
  47         ventry  __invalid               // Synchronous 32-bit EL1
  48         ventry  __invalid               // IRQ 32-bit EL1
  49         ventry  __invalid               // FIQ 32-bit EL1
  50         ventry  __invalid               // Error 32-bit EL1
  51
  52 __invalid:
  53         b       .
  54
  55         /*
  56          * x0: HYP pgd
  57          * x1: HYP stack
  58          * x2: HYP vectors
  59          */
  60 __do_hyp_init:
  61
  62         msr     ttbr0_el2, x0
  63
  64         mrs     x4, tcr_el1
  65         ldr     x5, =TCR_EL2_MASK
  66         and     x4, x4, x5
  67         mov     x5, #TCR_EL2_RES1
  68         orr     x4, x4, x5
  69
  70 #ifndef CONFIG_ARM64_VA_BITS_48
  71         /*
  72          * If we are running with VA_BITS < 48, we may be running with an extra
  73          * level of translation in the ID map. This is only the case if system
  74          * RAM is out of range for the currently configured page size and number
  75          * of translation levels, in which case we will also need the extra
  76          * level for the HYP ID map, or we won't be able to enable the EL2 MMU.
  77          *
  78          * However, at EL2, there is only one TTBR register, and we can't switch
  79          * between translation tables *and* update TCR_EL2.T0SZ at the same
  80          * time. Bottom line: we need the extra level in *both* our translation
  81          * tables.
  82          *
  83          * So use the same T0SZ value we use for the ID map.
  84          */
  85         ldr_l   x5, idmap_t0sz
  86         bfi     x4, x5, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH
  87 #endif
  88         /*
  89          * Read the PARange bits from ID_AA64MMFR0_EL1 and set the PS bits in
  90          * TCR_EL2.
  91          */
  92         mrs     x5, ID_AA64MMFR0_EL1
  93         bfi     x4, x5, #16, #3
  94
  95         msr     tcr_el2, x4
  96
  97         mrs     x4, mair_el1
  98         msr     mair_el2, x4
  99         isb
 100
 101         /* Invalidate the stale TLBs from Bootloader */
 102         tlbi    alle2
 103         dsb     sy
 104
 105         mrs     x4, sctlr_el2
 106         and     x4, x4, #SCTLR_ELx_EE   // preserve endianness of EL2
 107         ldr     x5, =SCTLR_ELx_FLAGS
 108         orr     x4, x4, x5
 109         msr     sctlr_el2, x4
 110         isb
 111
 112         /* Set the stack and new vectors */
 113         kern_hyp_va     x1
 114         mov     sp, x1
 115         kern_hyp_va     x2
 116         msr     vbar_el2, x2
 117
 118         /* Hello, World! */
 119         eret
 120 ENDPROC(__kvm_hyp_init)
 121
 122         /*
 123          * Reset kvm back to the hyp stub.
 124          */
 125 ENTRY(__kvm_hyp_reset)
 126         /* We're now in idmap, disable MMU */
 127         mrs     x0, sctlr_el2
 128         ldr     x1, =SCTLR_ELx_FLAGS
 129         bic     x0, x0, x1              // Clear SCTL_M and etc
 130         msr     sctlr_el2, x0
 131         isb
 132
 133         /* Install stub vectors */
 134         adr_l   x0, __hyp_stub_vectors
 135         msr     vbar_el2, x0
 136
 137         eret
 138 ENDPROC(__kvm_hyp_reset)
 139
 140         .ltorg
 141
 142         .popsection