ceph/src/boost/libs/system/test/CMakeLists.txt

   1 # Copyright 2018-2020 Peter Dimov
   2 # Distributed under the Boost Software License, Version 1.0.
   3 # See accompanying file LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt
   4
   5 include(BoostTest OPTIONAL RESULT_VARIABLE HAVE_BOOST_TEST)
   6
   7 if(NOT HAVE_BOOST_TEST)
   8   return()
   9 endif()
  10
  11 macro(system_run s1)
  12
  13   string(MAKE_C_IDENTIFIER ${s1} n1)
  14
  15   boost_test(SOURCES ${s1} ${ARGN})
  16   boost_test(SOURCES ${s1} ${ARGN} COMPILE_DEFINITIONS BOOST_NO_ANSI_APIS NAME ${n1}_no_ansi)
  17   boost_test(SOURCES ${s1} ${ARGN} COMPILE_DEFINITIONS BOOST_SYSTEM_USE_UTF8 NAME ${n1}_utf8)
  18
  19 endmacro()
  20
  21 macro(lib name macro)
  22
  23   add_library(${name} EXCLUDE_FROM_ALL ${ARGN})
  24   target_compile_definitions(${name} PRIVATE $<$<BOOL:BUILD_SHARED_LIBS>:${macro}=1>)
  25   target_link_libraries(${name} PRIVATE Boost::system Boost::config)
  26
  27 endmacro()
  28
  29 set(BOOST_TEST_LINK_LIBRARIES Boost::system Boost::core Boost::static_assert)
  30
  31 boost_test(SOURCES quick.cpp)
  32
  33 system_run(error_code_test.cpp)
  34 system_run(error_code_user_test.cpp)
  35 system_run(system_error_test.cpp)
  36
  37 lib(boost_system_throw_test THROW_DYN_LINK throw_test.cpp)
  38 boost_test(SOURCES dynamic_link_test.cpp LINK_LIBRARIES boost_system_throw_test)
  39
  40 system_run(initialization_test.cpp)
  41 system_run(header_only_test.cpp)
  42
  43 boost_test(SOURCES config_test.cpp)
  44
  45 system_run(std_interop_test.cpp)
  46 system_run(std_mismatch_test.cpp)
  47
  48 lib(boost_system_single_instance_lib1 SINGLE_INSTANCE_DYN_LINK single_instance_1.cpp)
  49 lib(boost_system_single_instance_lib2 SINGLE_INSTANCE_DYN_LINK single_instance_2.cpp)
  50
  51 system_run(single_instance_test.cpp single_instance_1.cpp single_instance_2.cpp)
  52 boost_test(SOURCES single_instance_test.cpp NAME single_instance_test_lib LINK_LIBRARIES boost_system_single_instance_lib1 boost_system_single_instance_lib2)
  53
  54 system_run(before_main_test.cpp)
  55 system_run(constexpr_test.cpp)
  56 system_run(win32_hresult_test.cpp)
  57
  58 system_run(error_category_test.cpp)
  59 system_run(generic_category_test.cpp)
  60 system_run(system_category_test.cpp)
  61 system_run(after_main_test.cpp)
  62 system_run(failed_test.cpp)
  63 system_run(failed_constexpr_test.cpp)
  64
  65 boost_test(SOURCES warnings_test.cpp COMPILE_OPTIONS -Wall -Werror)
  66
  67 lib(boost_system_std_single_instance_lib1 STD_SINGLE_INSTANCE_DYN_LINK std_single_instance_1.cpp)
  68 lib(boost_system_std_single_instance_lib2 STD_SINGLE_INSTANCE_DYN_LINK std_single_instance_2.cpp)
  69
  70 system_run(std_single_instance_test.cpp std_single_instance_1.cpp std_single_instance_2.cpp)
  71 boost_test(SOURCES std_single_instance_test.cpp NAME std_single_instance_test_lib LINK_LIBRARIES boost_system_std_single_instance_lib1 boost_system_std_single_instance_lib2)