ceph/src/seastar/doc/CMakeLists.txt

   1 find_program (Seastar_DOXYGEN_EXECUTABLE doxygen)
   2
   3 configure_file (
   4   ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in
   5   ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
   6   @ONLY)
   7
   8 configure_file (
   9   ${CMAKE_CURRENT_SOURCE_DIR}/DoxygenLayout.xml
  10   ${CMAKE_CURRENT_BINARY_DIR}/DoxygenLayout.xml
  11   COPYONLY)
  12
  13 add_custom_target (doc_api
  14   COMMAND ${Seastar_DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile)
  15
  16 add_custom_command (
  17   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/html/tutorial.html
  18   DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tutorial.md
  19   COMMAND
  20     ${CMAKE_CURRENT_SOURCE_DIR}/md2html
  21     ${CMAKE_CURRENT_SOURCE_DIR}/tutorial.md
  22     ${CMAKE_CURRENT_BINARY_DIR}/html/tutorial.html)
  23
  24 add_custom_target (doc_tutorial_html
  25   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/html/tutorial.html)
  26
  27 add_custom_command (
  28   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/html/split
  29   DEPENDS
  30     # Necessary because file-level dependencies are not propagated for custom targets.
  31     ${CMAKE_CURRENT_BINARY_DIR}/html/tutorial.html
  32     doc_tutorial_html
  33   COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/html/split
  34   COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/htmlsplit.py
  35     --input ${CMAKE_CURRENT_BINARY_DIR}/html/tutorial.html
  36     --output-dir ${CMAKE_CURRENT_BINARY_DIR}/html/split)
  37
  38 add_custom_target (doc_tutorial_html_split
  39   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/html/split)
  40
  41 add_custom_command (
  42   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/tutorial.pdf
  43   DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tutorial.md
  44   COMMAND
  45     ${CMAKE_CURRENT_SOURCE_DIR}/md2pdf
  46     ${CMAKE_CURRENT_SOURCE_DIR}/tutorial.md
  47     ${CMAKE_CURRENT_BINARY_DIR}/tutorial.pdf)
  48
  49 add_custom_target (doc_tutorial_pdf
  50   DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/tutorial.pdf)
  51
  52 # Logical target for all documentation.
  53 add_custom_target (docs
  54   DEPENDS
  55     doc_api
  56     doc_tutorial_html
  57     doc_tutorial_html_split
  58     doc_tutorial_pdf)