config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_QAT
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  12         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  13         ZFS_AC_KERNEL_SUPER_USER_NS
  14         ZFS_AC_KERNEL_SUBMIT_BIO
  15         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  16         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  17         ZFS_AC_KERNEL_TYPE_FMODE_T
  18         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  19         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  20         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  21         ZFS_AC_KERNEL_LOOKUP_BDEV
  22         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  23         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  24         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  25         ZFS_AC_KERNEL_BIO_BVEC_ITER
  26         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  27         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  28         ZFS_AC_KERNEL_REQ_OP_DISCARD
  29         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  30         ZFS_AC_KERNEL_REQ_OP_FLUSH
  31         ZFS_AC_KERNEL_BIO_BI_OPF
  32         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  33         ZFS_AC_KERNEL_BIO_BI_STATUS
  34         ZFS_AC_KERNEL_BIO_RW_BARRIER
  35         ZFS_AC_KERNEL_BIO_RW_DISCARD
  36         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  37         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  38         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  39         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  40         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  41         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  42         ZFS_AC_KERNEL_GET_DISK_RO
  43         ZFS_AC_KERNEL_GET_GENDISK
  44         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  45         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  46         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  47         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  48         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  49         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  50         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  51         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  52         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  53         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  54         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  55         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  56         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  57         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  58         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  63         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  64         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  65         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  66         ZFS_AC_KERNEL_INODE_SET_FLAGS
  67         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  68         ZFS_AC_KERNEL_SHOW_OPTIONS
  69         ZFS_AC_KERNEL_FILE_INODE
  70         ZFS_AC_KERNEL_FILE_DENTRY
  71         ZFS_AC_KERNEL_FSYNC
  72         ZFS_AC_KERNEL_EVICT_INODE
  73         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  74         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  75         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  76         ZFS_AC_KERNEL_FALLOCATE
  77         ZFS_AC_KERNEL_AIO_FSYNC
  78         ZFS_AC_KERNEL_MKDIR_UMODE_T
  79         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  80         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  81         ZFS_AC_KERNEL_GET_LINK
  82         ZFS_AC_KERNEL_PUT_LINK
  83         ZFS_AC_KERNEL_TMPFILE
  84         ZFS_AC_KERNEL_TRUNCATE_RANGE
  85         ZFS_AC_KERNEL_AUTOMOUNT
  86         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  87         ZFS_AC_KERNEL_COMMIT_METADATA
  88         ZFS_AC_KERNEL_CLEAR_INODE
  89         ZFS_AC_KERNEL_SETATTR_PREPARE
  90         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  91         ZFS_AC_KERNEL_D_MAKE_ROOT
  92         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  93         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  94         ZFS_AC_KERNEL_D_SET_D_OP
  95         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  96         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  97         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  98         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  99         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 100         ZFS_AC_KERNEL_MOUNT_NODEV
 101         ZFS_AC_KERNEL_SHRINK
 102         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 103         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 104         ZFS_AC_KERNEL_S_D_OP
 105         ZFS_AC_KERNEL_BDI
 106         ZFS_AC_KERNEL_SET_NLINK
 107         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 108         ZFS_AC_KERNEL_5ARG_SGET
 109         ZFS_AC_KERNEL_LSEEK_EXECUTE
 110         ZFS_AC_KERNEL_VFS_ITERATE
 111         ZFS_AC_KERNEL_VFS_RW_ITERATE
 112         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 113         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 114         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 115         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 116         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 117         ZFS_AC_KERNEL_FPU
 118         ZFS_AC_KERNEL_KUID_HELPERS
 119         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 120         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 121         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 122         ZFS_AC_KERNEL_CURRENT_TIME
 123         ZFS_AC_KERNEL_VM_NODE_STAT
 124
 125         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 126                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 127         ])
 128         AC_SUBST(KERNELMAKE_PARAMS)
 129
 130
 131         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 132         dnl # compiler options are added by the kernel build system.
 133         KERNELCPPFLAGS="$KERNELCPPFLAGS -std=gnu99"
 134         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wno-declaration-after-statement"
 135         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 136         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 137         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 138         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 139
 140         AC_SUBST(KERNELCPPFLAGS)
 141 ])
 142
 143 dnl #
 144 dnl # Detect name used for Module.symvers file in kernel
 145 dnl #
 146 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 147         modpost=$LINUX/scripts/Makefile.modpost
 148         AC_MSG_CHECKING([kernel file name for module symbols])
 149         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 150                 AS_IF([grep -q Modules.symvers $modpost], [
 151                         LINUX_SYMBOLS=Modules.symvers
 152                 ], [
 153                         LINUX_SYMBOLS=Module.symvers
 154                 ])
 155
 156                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 157                         AC_MSG_ERROR([
 158         *** Please make sure the kernel devel package for your distribution
 159         *** is installed.  If you are building with a custom kernel, make sure the
 160         *** kernel is configured, built, and the '--with-linux=PATH' configure
 161         *** option refers to the location of the kernel source.])
 162                 ])
 163         ], [
 164                 LINUX_SYMBOLS=NONE
 165         ])
 166         AC_MSG_RESULT($LINUX_SYMBOLS)
 167         AC_SUBST(LINUX_SYMBOLS)
 168 ])
 169
 170 dnl #
 171 dnl # Detect the kernel to be built against
 172 dnl #
 173 AC_DEFUN([ZFS_AC_KERNEL], [
 174         AC_ARG_WITH([linux],
 175                 AS_HELP_STRING([--with-linux=PATH],
 176                 [Path to kernel source]),
 177                 [kernelsrc="$withval"])
 178
 179         AC_ARG_WITH(linux-obj,
 180                 AS_HELP_STRING([--with-linux-obj=PATH],
 181                 [Path to kernel build objects]),
 182                 [kernelbuild="$withval"])
 183
 184         AC_MSG_CHECKING([kernel source directory])
 185         AS_IF([test -z "$kernelsrc"], [
 186                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 187                         headersdir="/lib/modules/$(uname -r)/source"
 188                         sourcelink=$(readlink -f "$headersdir")
 189                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 190                         headersdir="/lib/modules/$(uname -r)/build"
 191                         sourcelink=$(readlink -f "$headersdir")
 192                 ], [
 193                         sourcelink=$(ls -1d /usr/src/kernels/* \
 194                                      /usr/src/linux-* \
 195                                      2>/dev/null | grep -v obj | tail -1)
 196                 ])
 197
 198                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 199                         kernelsrc=`readlink -f ${sourcelink}`
 200                 ], [
 201                         kernelsrc="[Not found]"
 202                 ])
 203         ], [
 204                 AS_IF([test "$kernelsrc" = "NONE"], [
 205                         kernsrcver=NONE
 206                 ])
 207                 withlinux=yes
 208         ])
 209
 210         AC_MSG_RESULT([$kernelsrc])
 211         AS_IF([test ! -d "$kernelsrc"], [
 212                 AC_MSG_ERROR([
 213         *** Please make sure the kernel devel package for your distribution
 214         *** is installed and then try again.  If that fails, you can specify the
 215         *** location of the kernel source with the '--with-linux=PATH' option.])
 216         ])
 217
 218         AC_MSG_CHECKING([kernel build directory])
 219         AS_IF([test -z "$kernelbuild"], [
 220                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 221                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 222                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 223                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 224                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 225                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 226                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 227                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 228                 ], [
 229                         kernelbuild=${kernelsrc}
 230                 ])
 231         ])
 232         AC_MSG_RESULT([$kernelbuild])
 233
 234         AC_MSG_CHECKING([kernel source version])
 235         utsrelease1=$kernelbuild/include/linux/version.h
 236         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 237         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 238         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 239                 utsrelease=linux/version.h
 240         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 241                 utsrelease=linux/utsrelease.h
 242         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 243                 utsrelease=generated/utsrelease.h
 244         ])
 245
 246         AS_IF([test "$utsrelease"], [
 247                 kernsrcver=`(echo "#include <$utsrelease>";
 248                              echo "kernsrcver=UTS_RELEASE") |
 249                              cpp -I $kernelbuild/include |
 250                              grep "^kernsrcver=" | cut -d \" -f 2`
 251
 252                 AS_IF([test -z "$kernsrcver"], [
 253                         AC_MSG_RESULT([Not found])
 254                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 255                 ])
 256         ], [
 257                 AC_MSG_RESULT([Not found])
 258                 if test "x$enable_linux_builtin" != xyes; then
 259                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 260                 else
 261                         AC_MSG_ERROR([
 262         *** Cannot find UTS_RELEASE definition.
 263         *** Please run 'make prepare' inside the kernel source tree.])
 264                 fi
 265         ])
 266
 267         AC_MSG_RESULT([$kernsrcver])
 268
 269         LINUX=${kernelsrc}
 270         LINUX_OBJ=${kernelbuild}
 271         LINUX_VERSION=${kernsrcver}
 272
 273         AC_SUBST(LINUX)
 274         AC_SUBST(LINUX_OBJ)
 275         AC_SUBST(LINUX_VERSION)
 276
 277         ZFS_AC_MODULE_SYMVERS
 278 ])
 279
 280
 281 dnl #
 282 dnl # Detect the SPL module to be built against
 283 dnl #
 284 AC_DEFUN([ZFS_AC_SPL], [
 285         AC_ARG_WITH([spl],
 286                 AS_HELP_STRING([--with-spl=PATH],
 287                 [Path to spl source]),
 288                 AS_IF([test "$withval" = "yes"],
 289                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 290                         [splsrc="$withval"]))
 291
 292         AC_ARG_WITH([spl-obj],
 293                 AS_HELP_STRING([--with-spl-obj=PATH],
 294                 [Path to spl build objects]),
 295                 [splbuild="$withval"])
 296
 297         AC_ARG_WITH([spl-timeout],
 298                 AS_HELP_STRING([--with-spl-timeout=SECS],
 299                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 300                 [timeout="$withval"], [timeout=0])
 301
 302         dnl #
 303         dnl # The existence of spl.release.in is used to identify a valid
 304         dnl # source directory.  In order of preference:
 305         dnl #
 306         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 307         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 308         splsrc2="/usr/local/src/spl-${VERSION}"
 309         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 310         splsrc4="/usr/src/spl-${VERSION}"
 311         splsrc5="../spl/"
 312         splsrc6="$LINUX"
 313
 314         AC_MSG_CHECKING([spl source directory])
 315         AS_IF([test -z "${splsrc}"], [
 316                 [all_spl_sources="
 317                 ${splsrc0}
 318                 ${splsrc1}
 319                 ${splsrc2}
 320                 ${splsrc3}
 321                 ${splsrc4}
 322                 ${splsrc5}
 323                 ${splsrc6}"],
 324                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 325                         splsrc=${splsrc0}
 326                 ], [ test -e "${splsrc1}/spl.release.in"], [
 327                         splsrc=${splsrc1}
 328                 ], [ test -e "${splsrc2}/spl.release.in"], [
 329                         splsrc=${splsrc2}
 330                 ], [ test -e "${splsrc3}/spl.release.in"], [
 331                         splsrc=$(readlink -f "${splsrc3}")
 332                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 333                         splsrc=${splsrc4}
 334                 ], [ test -e "${splsrc5}/spl.release.in"], [
 335                         splsrc=$(readlink -f "${splsrc5}")
 336                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 337                         splsrc=${splsrc6}
 338                 ], [
 339                         splsrc="[Not found]"
 340                 ])
 341         ], [
 342                 [all_spl_sources="$withval"],
 343                 AS_IF([test "$splsrc" = "NONE"], [
 344                         splbuild=NONE
 345                         splsrcver=NONE
 346                 ])
 347         ])
 348
 349         AC_MSG_RESULT([$splsrc])
 350         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 351                 AC_MSG_ERROR([
 352         *** Please make sure the kmod spl devel package for your distribution
 353         *** is installed then try again.  If that fails you can specify the
 354         *** location of the spl source with the '--with-spl=PATH' option.
 355         *** The spl version must match the version of ZFS you are building,
 356         *** ${VERSION}.  Failed to find spl.release.in in the following:
 357         $all_spl_sources])
 358         ])
 359
 360         dnl #
 361         dnl # The existence of the spl_config.h is used to identify a valid
 362         dnl # spl object directory.  In many cases the object and source
 363         dnl # directory are the same, however the objects may also reside
 364         dnl # is a subdirectory named after the kernel version.
 365         dnl #
 366         dnl # This file is supposed to be available after DKMS finishes
 367         dnl # building the SPL kernel module for the target kernel.  The
 368         dnl # '--with-spl-timeout' option can be passed to pause here,
 369         dnl # waiting for the file to appear from a concurrently building
 370         dnl # SPL package.
 371         dnl #
 372         AC_MSG_CHECKING([spl build directory])
 373
 374         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 375         ${splsrc}"
 376
 377         while true; do
 378                 AS_IF([test -z "$splbuild"], [
 379                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 380                                 splbuild="${splsrc}/${LINUX_VERSION}"
 381                         ], [ test -e "${splsrc}/spl_config.h" ], [
 382                                 splbuild="${splsrc}"
 383                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 384                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 385                         ], [
 386                                 splbuild="[Not found]"
 387                         ])
 388                 ])
 389                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 390                         break;
 391                 ], [
 392                         sleep 1
 393                         timeout=$((timeout-1))
 394                 ])
 395         done
 396
 397         AC_MSG_RESULT([$splbuild])
 398         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 399                 AC_MSG_ERROR([
 400         *** Please make sure the kmod spl devel <kernel> package for your
 401         *** distribution is installed then try again.  If that fails you
 402         *** can specify the location of the spl objects with the
 403         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 404         *** any of the following:
 405         $all_spl_config_locs])
 406         ])
 407
 408         AC_MSG_CHECKING([spl source version])
 409         AS_IF([test -r $splbuild/spl_config.h &&
 410                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 411
 412                 splsrcver=`(echo "#include <spl_config.h>";
 413                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 414                             cpp -I $splbuild |
 415                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 416         ])
 417
 418         AS_IF([test -z "$splsrcver"], [
 419                 AC_MSG_RESULT([Not found])
 420                 AC_MSG_ERROR([
 421         *** Cannot determine the version of the spl source.
 422         *** Please prepare the spl source before running this script])
 423         ])
 424
 425         AC_MSG_RESULT([$splsrcver])
 426
 427         SPL=${splsrc}
 428         SPL_OBJ=${splbuild}
 429         SPL_VERSION=${splsrcver}
 430
 431         AC_SUBST(SPL)
 432         AC_SUBST(SPL_OBJ)
 433         AC_SUBST(SPL_VERSION)
 434
 435         dnl #
 436         dnl # Detect the name used for the SPL Module.symvers file.  If one
 437         dnl # does not exist this is likely because the SPL has been configured
 438         dnl # but not built.  The '--with-spl-timeout' option can be passed
 439         dnl # to pause here, waiting for the file to appear from a concurrently
 440         dnl # building SPL package.  If the file does not appear in time, a good
 441         dnl # guess is made as to what this file will be named based on what it
 442         dnl # is named in the kernel build products.  This file will first be
 443         dnl # used at link time so if the guess is wrong the build will fail
 444         dnl # then.  This unfortunately means the ZFS package does not contain a
 445         dnl # reliable mechanism to detect symbols exported by the SPL at
 446         dnl # configure time.
 447         dnl #
 448         AC_MSG_CHECKING([spl file name for module symbols])
 449         SPL_SYMBOLS=NONE
 450
 451         while true; do
 452                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 453                         SPL_SYMBOLS=Module.symvers
 454                 ], [test -r $SPL_OBJ/Modules.symvers], [
 455                         SPL_SYMBOLS=Modules.symvers
 456                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 457                         SPL_SYMBOLS=Module.symvers
 458                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 459                         SPL_SYMBOLS=Modules.symvers
 460                 ])
 461
 462                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 463                         break;
 464                 ], [
 465                         sleep 1
 466                         timeout=$((timeout-1))
 467                 ])
 468         done
 469
 470         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 471                 SPL_SYMBOLS=$LINUX_SYMBOLS
 472         ])
 473
 474         AC_MSG_RESULT([$SPL_SYMBOLS])
 475         AC_SUBST(SPL_SYMBOLS)
 476 ])
 477
 478 dnl #
 479 dnl # Detect the QAT module to be built against
 480 dnl # QAT provides hardware acceleration for data compression:
 481 dnl #   https://01.org/intel-quickassist-technology
 482 dnl # * Download and install QAT driver from the above link
 483 dnl # * Start QAT driver in your system:
 484 dnl #   service qat_service start
 485 dnl # * Enable QAT in ZFS, e.g.:
 486 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 487 dnl #   make
 488 dnl # * Set GZIP compression in ZFS dataset:
 489 dnl #   zfs set compression = gzip <dataset>
 490 dnl # Then the data written to this ZFS pool is compressed
 491 dnl # by QAT accelerator automatically, and de-compressed by
 492 dnl # QAT when read from the pool.
 493 dnl # * Get QAT hardware statistics by:
 494 dnl #   cat /proc/icp_dh895xcc_dev/qat
 495 dnl # * To disable QAT:
 496 dnl #   insmod zfs.ko zfs_qat_disable=1
 497 dnl #
 498 AC_DEFUN([ZFS_AC_QAT], [
 499         AC_ARG_WITH([qat],
 500                 AS_HELP_STRING([--with-qat=PATH],
 501                 [Path to qat source]),
 502                 AS_IF([test "$withval" = "yes"],
 503                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 504                         [qatsrc="$withval"]))
 505
 506         AC_ARG_WITH([qat-obj],
 507                 AS_HELP_STRING([--with-qat-obj=PATH],
 508                 [Path to qat build objects]),
 509                 [qatbuild="$withval"])
 510
 511         AS_IF([test ! -z "${qatsrc}"], [
 512                 AC_MSG_CHECKING([qat source directory])
 513                 AC_MSG_RESULT([$qatsrc])
 514                 QAT_SRC="${qatsrc}/quickassist"
 515                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 516                         AC_MSG_ERROR([
 517                 *** Please make sure the qat driver package is installed
 518                 *** and specify the location of the qat source with the
 519                 *** '--with-qat=PATH' option then try again. Failed to
 520                 *** find cpa.h in:
 521                 ${QAT_SRC}/include])
 522                 ])
 523         ])
 524
 525         AS_IF([test ! -z "${qatsrc}"], [
 526                 AC_MSG_CHECKING([qat build directory])
 527                 AS_IF([test -z "$qatbuild"], [
 528                         qatbuild="${qatsrc}/build"
 529                 ])
 530
 531                 AC_MSG_RESULT([$qatbuild])
 532                 QAT_OBJ=${qatbuild}
 533                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko"], [
 534                         AC_MSG_ERROR([
 535                 *** Please make sure the qat driver is installed then try again.
 536                 *** Failed to find icp_qa_al.ko in:
 537                 $QAT_OBJ])
 538                 ])
 539
 540                 AC_SUBST(QAT_SRC)
 541                 AC_SUBST(QAT_OBJ)
 542
 543                 AC_DEFINE(HAVE_QAT, 1,
 544                 [qat is enabled and existed])
 545         ])
 546
 547         dnl #
 548         dnl # Detect the name used for the QAT Module.symvers file.
 549         dnl #
 550         AS_IF([test ! -z "${qatsrc}"], [
 551                 AC_MSG_CHECKING([qat file for module symbols])
 552                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 553
 554                 AS_IF([test -r $QAT_SYMBOLS], [
 555                         AC_MSG_RESULT([$QAT_SYMBOLS])
 556                         AC_SUBST(QAT_SYMBOLS)
 557                 ],[
 558                        AC_MSG_ERROR([
 559                         *** Please make sure the qat driver is installed then try again.
 560                         *** Failed to find Module.symvers in:
 561                         $QAT_SYMBOLS])
 562                         ])
 563                 ])
 564         ])
 565 ])
 566
 567 dnl #
 568 dnl # Basic toolchain sanity check.
 569 dnl #
 570 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 571         AC_MSG_CHECKING([whether modules can be built])
 572         ZFS_LINUX_TRY_COMPILE([],[],[
 573                 AC_MSG_RESULT([yes])
 574         ],[
 575                 AC_MSG_RESULT([no])
 576                 if test "x$enable_linux_builtin" != xyes; then
 577                         AC_MSG_ERROR([*** Unable to build an empty module.])
 578                 else
 579                         AC_MSG_ERROR([
 580         *** Unable to build an empty module.
 581         *** Please run 'make scripts' inside the kernel source tree.])
 582                 fi
 583         ])
 584 ])
 585
 586 dnl #
 587 dnl # Certain kernel build options are not supported.  These must be
 588 dnl # detected at configure time and cause a build failure.  Otherwise
 589 dnl # modules may be successfully built that behave incorrectly.
 590 dnl #
 591 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 592         AS_IF([test "x$cross_compiling" != xyes], [
 593                 AC_RUN_IFELSE([
 594                         AC_LANG_PROGRAM([
 595                                 #include "$LINUX/include/linux/license.h"
 596                         ], [
 597                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 598                         ])
 599                 ], [
 600                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 601                             [Define to 1 if GPL-only symbols can be used])
 602                 ], [
 603                 ])
 604         ])
 605
 606         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 607         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 608 ])
 609
 610 dnl #
 611 dnl # Check configured THREAD_SIZE
 612 dnl #
 613 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 614 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 615 dnl # on newer kernels and some architectures stack usage optimizations can be
 616 dnl # conditionally applied to improve performance without negatively impacting
 617 dnl # stability.
 618 dnl #
 619 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 620         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 621         ZFS_LINUX_TRY_COMPILE([
 622                 #include <linux/module.h>
 623         ],[
 624                 #if (THREAD_SIZE < 16384)
 625                 #error "THREAD_SIZE is less than 16K"
 626                 #endif
 627         ],[
 628                 AC_MSG_RESULT([yes])
 629                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 630         ],[
 631                 AC_MSG_RESULT([no])
 632         ])
 633 ])
 634
 635 dnl #
 636 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 637 dnl #
 638 dnl # This is typically only set for debug kernels because it comes with
 639 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 640 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 641 dnl # This will cause a failure at link time which we'd rather know about
 642 dnl # at compile time.
 643 dnl #
 644 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 645 dnl # with the upstream community we add a check to detect this case.
 646 dnl #
 647 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 648
 649         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 650                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 651                 tmp_flags="$EXTRA_KCFLAGS"
 652                 ZFS_LINUX_TRY_COMPILE([
 653                         #include <linux/module.h>
 654                         #include <linux/mutex.h>
 655
 656                         MODULE_LICENSE("$ZFS_META_LICENSE");
 657                 ],[
 658                         struct mutex lock;
 659
 660                         mutex_init(&lock);
 661                         mutex_lock(&lock);
 662                         mutex_unlock(&lock);
 663                 ],[
 664                         AC_MSG_RESULT(no)
 665                 ],[
 666                         AC_MSG_RESULT(yes)
 667                         AC_MSG_ERROR([
 668         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 669         *** with the CDDL license and will prevent the module linking stage
 670         *** from succeeding.  You must rebuild your kernel without this
 671         *** option enabled.])
 672                 ])
 673                 EXTRA_KCFLAGS="$tmp_flags"
 674         ], [])
 675 ])
 676
 677 dnl #
 678 dnl # ZFS_LINUX_CONFTEST_H
 679 dnl #
 680 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 681 cat - <<_ACEOF >conftest.h
 682 $1
 683 _ACEOF
 684 ])
 685
 686 dnl #
 687 dnl # ZFS_LINUX_CONFTEST_C
 688 dnl #
 689 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 690 cat confdefs.h - <<_ACEOF >conftest.c
 691 $1
 692 _ACEOF
 693 ])
 694
 695 dnl #
 696 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 697 dnl #
 698 m4_define([ZFS_LANG_PROGRAM], [
 699 $1
 700 int
 701 main (void)
 702 {
 703 dnl Do *not* indent the following line: there may be CPP directives.
 704 dnl Don't move the `;' right after for the same reason.
 705 $2
 706   ;
 707   return 0;
 708 }
 709 ])
 710
 711 dnl #
 712 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 713 dnl #
 714 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 715         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 716         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 717         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 718         echo "obj-m := conftest.o" >build/Makefile
 719         modpost_flag=''
 720         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 721         AS_IF(
 722                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 723                 [$4],
 724                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 725         )
 726         rm -Rf build
 727 ])
 728
 729 dnl #
 730 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 731 dnl #
 732 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 733         [ZFS_LINUX_COMPILE_IFELSE(
 734         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 735         [modules],
 736         [test -s build/conftest.o],
 737         [$3], [$4])
 738 ])
 739
 740 dnl #
 741 dnl # ZFS_LINUX_CONFIG
 742 dnl #
 743 AC_DEFUN([ZFS_LINUX_CONFIG],
 744         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 745         ZFS_LINUX_TRY_COMPILE([
 746                 #include <linux/module.h>
 747         ],[
 748                 #ifndef CONFIG_$1
 749                 #error CONFIG_$1 not #defined
 750                 #endif
 751         ],[
 752                 AC_MSG_RESULT([yes])
 753                 $2
 754         ],[
 755                 AC_MSG_RESULT([no])
 756                 $3
 757         ])
 758 ])
 759
 760 dnl #
 761 dnl # ZFS_CHECK_SYMBOL_EXPORT
 762 dnl # check symbol exported or not
 763 dnl #
 764 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 765         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 766                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 767         rc=$?
 768         if test $rc -ne 0; then
 769                 export=0
 770                 for file in $2; do
 771                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 772                                 "$LINUX/$file" 2>/dev/null
 773                         rc=$?
 774                         if test $rc -eq 0; then
 775                                 export=1
 776                                 break;
 777                         fi
 778                 done
 779                 if test $export -eq 0; then :
 780                         $4
 781                 else :
 782                         $3
 783                 fi
 784         else :
 785                 $3
 786         fi
 787 ])
 788
 789 dnl #
 790 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 791 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 792 dnl # is called if not compiling for builtin
 793 dnl #
 794 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 795         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 796         if test $rc -ne 0; then :
 797                 $6
 798         else
 799                 if test "x$enable_linux_builtin" != xyes; then
 800                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 801                 fi
 802                 if test $rc -ne 0; then :
 803                         $6
 804                 else :
 805                         $5
 806                 fi
 807         fi
 808 ])
 809
 810 dnl #
 811 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 812 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 813 dnl # provided via the fifth parameter
 814 dnl #
 815 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 816         [ZFS_LINUX_COMPILE_IFELSE(
 817         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 818         [modules],
 819         [test -s build/conftest.o],
 820         [$3], [$4], [$5])
 821 ])