config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  18         ZFS_AC_KERNEL_BIO_FAILFAST
  19         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  20         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  21         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  22         ZFS_AC_KERNEL_BIO_RW_SYNC
  23         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  24         ZFS_AC_KERNEL_REQ_SYNC
  25         ZFS_AC_KERNEL_BLK_END_REQUEST
  26         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  27         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  29         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  30         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  31         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  32         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  33         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  34         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  35         ZFS_AC_KERNEL_BLK_RQ_BYTES
  36         ZFS_AC_KERNEL_BLK_RQ_POS
  37         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_RQ_IS_SYNC
  41         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  46         ZFS_AC_KERNEL_SHOW_OPTIONS
  47         ZFS_AC_KERNEL_FSYNC
  48         ZFS_AC_KERNEL_EVICT_INODE
  49         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  50         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  51         ZFS_AC_KERNEL_FALLOCATE
  52         ZFS_AC_KERNEL_TRUNCATE_RANGE
  53         ZFS_AC_KERNEL_CREATE_UMODE_T
  54         ZFS_AC_KERNEL_AUTOMOUNT
  55         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  56         ZFS_AC_KERNEL_CLEAR_INODE
  57         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  58         ZFS_AC_KERNEL_D_MAKE_ROOT
  59         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  60         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  61         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  62         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  63         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  64         ZFS_AC_KERNEL_MOUNT_NODEV
  65         ZFS_AC_KERNEL_SHRINK
  66         ZFS_AC_KERNEL_BDI
  67         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  68         ZFS_AC_KERNEL_SET_NLINK
  69
  70         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  71                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  72         ])
  73         AC_SUBST(KERNELMAKE_PARAMS)
  74
  75
  76         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  77         dnl # compiler options are added by the kernel build system.
  78         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  79         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  80         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  81
  82         AC_SUBST(KERNELCPPFLAGS)
  83 ])
  84
  85 dnl #
  86 dnl # Detect name used for Module.symvers file in kernel
  87 dnl #
  88 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  89         modpost=$LINUX/scripts/Makefile.modpost
  90         AC_MSG_CHECKING([kernel file name for module symbols])
  91         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  92                 AS_IF([grep -q Modules.symvers $modpost], [
  93                         LINUX_SYMBOLS=Modules.symvers
  94                 ], [
  95                         LINUX_SYMBOLS=Module.symvers
  96                 ])
  97
  98                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
  99                         AC_MSG_ERROR([
 100         *** Please make sure the kernel devel package for your distribution
 101         *** is installed.  If your building with a custom kernel make sure the
 102         *** kernel is configured, built, and the '--with-linux=PATH' configure
 103         *** option refers to the location of the kernel source.])
 104                 ])
 105         ], [
 106                 LINUX_SYMBOLS=NONE
 107         ])
 108         AC_MSG_RESULT($LINUX_SYMBOLS)
 109         AC_SUBST(LINUX_SYMBOLS)
 110 ])
 111
 112 dnl #
 113 dnl # Detect the kernel to be built against
 114 dnl #
 115 AC_DEFUN([ZFS_AC_KERNEL], [
 116         AC_ARG_WITH([linux],
 117                 AS_HELP_STRING([--with-linux=PATH],
 118                 [Path to kernel source]),
 119                 [kernelsrc="$withval"])
 120
 121         AC_ARG_WITH(linux-obj,
 122                 AS_HELP_STRING([--with-linux-obj=PATH],
 123                 [Path to kernel build objects]),
 124                 [kernelbuild="$withval"])
 125
 126         AC_MSG_CHECKING([kernel source directory])
 127         AS_IF([test -z "$kernelsrc"], [
 128                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 129                         headersdir="/lib/modules/$(uname -r)/source"
 130                         sourcelink=$(readlink -f "$headersdir")
 131                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 132                         headersdir="/lib/modules/$(uname -r)/build"
 133                         sourcelink=$(readlink -f "$headersdir")
 134                 ], [
 135                         sourcelink=$(ls -1d /usr/src/kernels/* \
 136                                      /usr/src/linux-* \
 137                                      2>/dev/null | grep -v obj | tail -1)
 138                 ])
 139
 140                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 141                         kernelsrc=`readlink -f ${sourcelink}`
 142                 ], [
 143                         AC_MSG_RESULT([Not found])
 144                         AC_MSG_ERROR([
 145         *** Please make sure the kernel devel package for your distribution
 146         *** is installed then try again.  If that fails you can specify the
 147         *** location of the kernel source with the '--with-linux=PATH' option.])
 148                 ])
 149         ], [
 150                 AS_IF([test "$kernelsrc" = "NONE"], [
 151                         kernsrcver=NONE
 152                 ])
 153         ])
 154
 155         AC_MSG_RESULT([$kernelsrc])
 156         AC_MSG_CHECKING([kernel build directory])
 157         AS_IF([test -z "$kernelbuild"], [
 158                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 159                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 160                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 161                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 162                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 163                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 164                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 165                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 166                 ], [
 167                         kernelbuild=${kernelsrc}
 168                 ])
 169         ])
 170         AC_MSG_RESULT([$kernelbuild])
 171
 172         AC_MSG_CHECKING([kernel source version])
 173         utsrelease1=$kernelbuild/include/linux/version.h
 174         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 175         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 176         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 177                 utsrelease=linux/version.h
 178         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 179                 utsrelease=linux/utsrelease.h
 180         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 181                 utsrelease=generated/utsrelease.h
 182         ])
 183
 184         AS_IF([test "$utsrelease"], [
 185                 kernsrcver=`(echo "#include <$utsrelease>";
 186                              echo "kernsrcver=UTS_RELEASE") |
 187                              cpp -I $kernelbuild/include |
 188                              grep "^kernsrcver=" | cut -d \" -f 2`
 189
 190                 AS_IF([test -z "$kernsrcver"], [
 191                         AC_MSG_RESULT([Not found])
 192                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 193                 ])
 194         ], [
 195                 AC_MSG_RESULT([Not found])
 196                 if test "x$enable_linux_builtin" != xyes; then
 197                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 198                 else
 199                         AC_MSG_ERROR([
 200         *** Cannot find UTS_RELEASE definition.
 201         *** Please run 'make prepare' inside the kernel source tree.])
 202                 fi
 203         ])
 204
 205         AC_MSG_RESULT([$kernsrcver])
 206
 207         LINUX=${kernelsrc}
 208         LINUX_OBJ=${kernelbuild}
 209         LINUX_VERSION=${kernsrcver}
 210
 211         AC_SUBST(LINUX)
 212         AC_SUBST(LINUX_OBJ)
 213         AC_SUBST(LINUX_VERSION)
 214
 215         ZFS_AC_MODULE_SYMVERS
 216 ])
 217
 218 dnl #
 219 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 220 dnl # does not exist this is likely because the SPL has been configured
 221 dnl # but not built.  The '--with-spl-timeout' option can be passed
 222 dnl # to pause here, waiting for the file to appear from a concurrently
 223 dnl # building SPL package.  If the file does not appear in time, a good
 224 dnl # guess is made as to what this file will be named based on what it
 225 dnl # is named in the kernel build products.  This file will first be
 226 dnl # used at link time so if the guess is wrong the build will fail
 227 dnl # then.  This unfortunately means the ZFS package does not contain a
 228 dnl # reliable mechanism to detect symbols exported by the SPL at
 229 dnl # configure time.
 230 dnl #
 231 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 232         AC_ARG_WITH([spl-timeout],
 233                 AS_HELP_STRING([--with-spl-timeout=SECS],
 234                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 235                 [timeout="$withval"], [timeout=0])
 236
 237         AC_MSG_CHECKING([spl file name for module symbols])
 238         SPL_SYMBOLS=NONE
 239
 240         while true; do
 241                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 242                         SPL_SYMBOLS=Module.symvers
 243                 ], [test -r $SPL_OBJ/Modules.symvers], [
 244                         SPL_SYMBOLS=Modules.symvers
 245                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 246                         SPL_SYMBOLS=Module.symvers
 247                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 248                         SPL_SYMBOLS=Modules.symvers
 249                 ])
 250
 251                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 252                         break;
 253                 ], [
 254                         sleep 1
 255                         timeout=$((timeout-1))
 256                 ])
 257         done
 258
 259         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 260                 SPL_SYMBOLS=$LINUX_SYMBOLS
 261         ])
 262
 263         AC_MSG_RESULT([$SPL_SYMBOLS])
 264         AC_SUBST(SPL_SYMBOLS)
 265 ])
 266
 267 dnl #
 268 dnl # Detect the SPL module to be built against
 269 dnl #
 270 AC_DEFUN([ZFS_AC_SPL], [
 271         AC_ARG_WITH([spl],
 272                 AS_HELP_STRING([--with-spl=PATH],
 273                 [Path to spl source]),
 274                 [splsrc="$withval"])
 275
 276         AC_ARG_WITH([spl-obj],
 277                 AS_HELP_STRING([--with-spl-obj=PATH],
 278                 [Path to spl build objects]),
 279                 [splbuild="$withval"])
 280
 281
 282         AC_MSG_CHECKING([spl source directory])
 283         AS_IF([test -z "$splsrc"], [
 284                 dnl #
 285                 dnl # Look in the standard development package location
 286                 dnl #
 287                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 288                             2>/dev/null | tail -1`
 289
 290                 dnl #
 291                 dnl # Look in the DKMS source location
 292                 dnl #
 293                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 294                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 295                                     2>/dev/null | tail -1`
 296                 ])
 297
 298                 dnl #
 299                 dnl # Look in the parent directory
 300                 dnl #
 301                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 302                         sourcelink=../spl
 303                 ])
 304
 305                 AS_IF([test -e $sourcelink/spl_config.h], [
 306                         splsrc=`readlink -f ${sourcelink}`
 307                 ], [
 308                         AC_MSG_RESULT([Not found])
 309                         AC_MSG_ERROR([
 310         *** Please make sure the spl devel package for your distribution
 311         *** is installed then try again.  If that fails you can specify the
 312         *** location of the spl source with the '--with-spl=PATH' option.])
 313                 ])
 314         ], [
 315                 AS_IF([test "$splsrc" = "NONE"], [
 316                         splbuild=NONE
 317                         splsrcver=NONE
 318                 ])
 319         ])
 320
 321         AC_MSG_RESULT([$splsrc])
 322         AC_MSG_CHECKING([spl build directory])
 323         AS_IF([test -z "$splbuild"], [
 324                 splbuild=${splsrc}
 325         ])
 326         AC_MSG_RESULT([$splbuild])
 327
 328         AC_MSG_CHECKING([spl source version])
 329         AS_IF([test -r $splbuild/spl_config.h &&
 330                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 331
 332                 splsrcver=`(echo "#include <spl_config.h>";
 333                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 334                             cpp -I $splbuild |
 335                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 336         ])
 337
 338         AS_IF([test -z "$splsrcver"], [
 339                 AC_MSG_RESULT([Not found])
 340                 AC_MSG_ERROR([
 341         *** Cannot determine the version of the spl source.
 342         *** Please prepare the spl source before running this script])
 343         ])
 344
 345         AC_MSG_RESULT([$splsrcver])
 346
 347         SPL=${splsrc}
 348         SPL_OBJ=${splbuild}
 349         SPL_VERSION=${splsrcver}
 350
 351         AC_SUBST(SPL)
 352         AC_SUBST(SPL_OBJ)
 353         AC_SUBST(SPL_VERSION)
 354
 355         ZFS_AC_SPL_MODULE_SYMVERS
 356 ])
 357
 358 dnl #
 359 dnl # Basic toolchain sanity check.
 360 dnl #
 361 AC_DEFUN([ZFS_AC_TEST_MODULE],
 362         [AC_MSG_CHECKING([whether modules can be built])
 363         ZFS_LINUX_TRY_COMPILE([],[],[
 364                 AC_MSG_RESULT([yes])
 365         ],[
 366                 AC_MSG_RESULT([no])
 367                 if test "x$enable_linux_builtin" != xyes; then
 368                         AC_MSG_ERROR([*** Unable to build an empty module.])
 369                 else
 370                         AC_MSG_ERROR([
 371         *** Unable to build an empty module.
 372         *** Please run 'make scripts' inside the kernel source tree.])
 373                 fi
 374         ])
 375 ])
 376
 377 dnl #
 378 dnl # Certain kernel build options are not supported.  These must be
 379 dnl # detected at configure time and cause a build failure.  Otherwise
 380 dnl # modules may be successfully built that behave incorrectly.
 381 dnl #
 382 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 383
 384         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 385                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 386                         [Define to 1 if licensed under the GPL])
 387         ])
 388
 389         ZFS_AC_KERNEL_CONFIG_PREEMPT
 390         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 391 ])
 392
 393 dnl #
 394 dnl # Check CONFIG_PREEMPT
 395 dnl #
 396 dnl # Premptible kernels will be supported in the future.  But at the
 397 dnl # moment there are a few places in the code which need to be updated
 398 dnl # to accomidate them.  Until that work occurs we should detect this
 399 dnl # at configure time and fail with a sensible message.  Otherwise,
 400 dnl # people will be able to build successfully, however they will have
 401 dnl # stability problems.  See https://github.com/zfsonlinux/zfs/issues/83
 402 dnl #
 403 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [
 404
 405         ZFS_LINUX_CONFIG([PREEMPT],
 406                 AC_MSG_ERROR([
 407         *** Kernel built with CONFIG_PREEMPT which is not supported.
 408         *** You must rebuild your kernel without this option.]), [])
 409 ])
 410
 411 dnl #
 412 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 413 dnl #
 414 dnl # This is typically only set for debug kernels because it comes with
 415 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 416 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 417 dnl # This will cause a failure at link time which we'd rather know about
 418 dnl # at compile time.
 419 dnl #
 420 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 421 dnl # with the upstream community we add a check to detect this case.
 422 dnl #
 423 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 424
 425         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 426                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 427                 tmp_flags="$EXTRA_KCFLAGS"
 428                 ZFS_LINUX_TRY_COMPILE([
 429                         #include <linux/module.h>
 430                         #include <linux/mutex.h>
 431
 432                         MODULE_LICENSE("$ZFS_META_LICENSE");
 433                 ],[
 434                         struct mutex lock;
 435
 436                         mutex_init(&lock);
 437                         mutex_lock(&lock);
 438                         mutex_unlock(&lock);
 439                 ],[
 440                         AC_MSG_RESULT(no)
 441                 ],[
 442                         AC_MSG_RESULT(yes)
 443                         AC_MSG_ERROR([
 444         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 445         *** with the CDDL license and will prevent the module linking stage
 446         *** from succeeding.  You must rebuild your kernel without this
 447         *** option enabled.])
 448                 ])
 449                 EXTRA_KCFLAGS="$tmp_flags"
 450         ], [])
 451 ])
 452
 453 dnl #
 454 dnl # ZFS_LINUX_CONFTEST
 455 dnl #
 456 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 457 cat confdefs.h - <<_ACEOF >conftest.c
 458 $1
 459 _ACEOF
 460 ])
 461
 462 dnl #
 463 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 464 dnl #
 465 m4_define([ZFS_LANG_PROGRAM], [
 466 $1
 467 int
 468 main (void)
 469 {
 470 dnl Do *not* indent the following line: there may be CPP directives.
 471 dnl Don't move the `;' right after for the same reason.
 472 $2
 473   ;
 474   return 0;
 475 }
 476 ])
 477
 478 dnl #
 479 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 480 dnl #
 481 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 482         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 483         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 484         echo "obj-m := conftest.o" >build/Makefile
 485         modpost_flag=''
 486         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 487         AS_IF(
 488                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 489                 [$4],
 490                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 491         )
 492         rm -Rf build
 493 ])
 494
 495 dnl #
 496 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 497 dnl #
 498 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 499         [ZFS_LINUX_COMPILE_IFELSE(
 500         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 501         [modules],
 502         [test -s build/conftest.o],
 503         [$3], [$4])
 504 ])
 505
 506 dnl #
 507 dnl # ZFS_LINUX_CONFIG
 508 dnl #
 509 AC_DEFUN([ZFS_LINUX_CONFIG],
 510         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 511         ZFS_LINUX_TRY_COMPILE([
 512                 #include <linux/module.h>
 513         ],[
 514                 #ifndef CONFIG_$1
 515                 #error CONFIG_$1 not #defined
 516                 #endif
 517         ],[
 518                 AC_MSG_RESULT([yes])
 519                 $2
 520         ],[
 521                 AC_MSG_RESULT([no])
 522                 $3
 523         ])
 524 ])
 525
 526 dnl #
 527 dnl # ZFS_CHECK_SYMBOL_EXPORT
 528 dnl # check symbol exported or not
 529 dnl #
 530 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 531         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 532                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 533         rc=$?
 534         if test $rc -ne 0; then
 535                 export=0
 536                 for file in $2; do
 537                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 538                                 "$LINUX/$file" 2>/dev/null
 539                         rc=$?
 540                         if test $rc -eq 0; then
 541                                 export=1
 542                                 break;
 543                         fi
 544                 done
 545                 if test $export -eq 0; then :
 546                         $4
 547                 else :
 548                         $3
 549                 fi
 550         else :
 551                 $3
 552         fi
 553 ])
 554
 555 dnl #
 556 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 557 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 558 dnl # is called if not compiling for builtin
 559 dnl #
 560 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 561         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 562         if test $rc -ne 0; then :
 563                 $6
 564         else
 565                 if test "x$enable_linux_builtin" != xyes; then
 566                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 567                 fi
 568                 if test $rc -ne 0; then :
 569                         $6
 570                 else :
 571                         $5
 572                 fi
 573         fi
 574 ])