config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         WITH_DEBUG="true"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16
  17         KERNEL_DEBUG_CFLAGS="-Werror"
  18         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  19 ])
  20
  21 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  22         DEBUG_CFLAGS=""
  23         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  24         DEBUG_LDFLAGS=""
  25         DEBUG_ZFS="_without_debug"
  26         WITH_DEBUG=""
  27
  28         KERNEL_DEBUG_CFLAGS=""
  29         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  30 ])
  31
  32 dnl #
  33 dnl # When debugging is enabled:
  34 dnl # - Enable all ASSERTs (-DDEBUG)
  35 dnl # - Promote all compiler warnings to errors (-Werror)
  36 dnl #
  37 dnl # (If INVARIANTS is detected, we need to force DEBUG, or strange panics
  38 dnl # can ensue.)
  39 dnl #
  40 AC_DEFUN([ZFS_AC_DEBUG], [
  41         AC_MSG_CHECKING([whether assertion support will be enabled])
  42         AC_ARG_ENABLE([debug],
  43                 [AS_HELP_STRING([--enable-debug],
  44                 [Enable compiler and code assertions @<:@default=no@:>@])],
  45                 [],
  46                 [enable_debug=no])
  47
  48         AS_CASE(["x$enable_debug"],
  49                 ["xyes"],
  50                 [ZFS_AC_DEBUG_ENABLE],
  51                 ["xno"],
  52                 [ZFS_AC_DEBUG_DISABLE],
  53                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  54
  55         AS_CASE(["x$enable_invariants"],
  56                 ["xyes"],
  57                 [],
  58                 ["xno"],
  59                 [],
  60                 [ZFS_AC_DEBUG_INVARIANTS_DETECT])
  61
  62         AS_CASE(["x$enable_invariants"],
  63                 ["xyes"],
  64                 [ZFS_AC_DEBUG_ENABLE],
  65                 ["xno"],
  66                 [],
  67                 [AC_MSG_ERROR([Unknown option $enable_invariants])])
  68
  69         AC_SUBST(DEBUG_CFLAGS)
  70         AC_SUBST(DEBUG_CPPFLAGS)
  71         AC_SUBST(DEBUG_LDFLAGS)
  72         AC_SUBST(DEBUG_ZFS)
  73         AC_SUBST(WITH_DEBUG)
  74
  75         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  76         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  77
  78         AC_MSG_RESULT([$enable_debug])
  79 ])
  80
  81 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  82         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  83
  84         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
  85         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  86
  87         DEBUGINFO_ZFS="_with_debuginfo"
  88 ])
  89
  90 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  91         DEBUGINFO_ZFS="_without_debuginfo"
  92 ])
  93
  94 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  95         AC_MSG_CHECKING([whether debuginfo support will be forced])
  96         AC_ARG_ENABLE([debuginfo],
  97                 [AS_HELP_STRING([--enable-debuginfo],
  98                 [Force generation of debuginfo @<:@default=no@:>@])],
  99                 [],
 100                 [enable_debuginfo=no])
 101
 102         AS_CASE(["x$enable_debuginfo"],
 103                 ["xyes"],
 104                 [ZFS_AC_DEBUGINFO_ENABLE],
 105                 ["xno"],
 106                 [ZFS_AC_DEBUGINFO_DISABLE],
 107                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
 108
 109         AC_SUBST(DEBUG_CFLAGS)
 110         AC_SUBST(DEBUGINFO_ZFS)
 111
 112         AC_SUBST(KERNEL_DEBUG_CFLAGS)
 113         AC_SUBST(KERNEL_MAKE)
 114
 115         AC_MSG_RESULT([$enable_debuginfo])
 116 ])
 117
 118 dnl #
 119 dnl # Disabled by default, provides basic memory tracking.  Track the total
 120 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 121 dnl # Then at module unload time if any bytes were leaked it will be reported
 122 dnl # on the console.
 123 dnl #
 124 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 125         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 126         AC_ARG_ENABLE([debug-kmem],
 127                 [AS_HELP_STRING([--enable-debug-kmem],
 128                 [Enable basic kmem accounting @<:@default=no@:>@])],
 129                 [],
 130                 [enable_debug_kmem=no])
 131
 132         AS_IF([test "x$enable_debug_kmem" = xyes], [
 133                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
 134                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 135         ], [
 136                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 137         ])
 138
 139         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 140         AC_SUBST(DEBUG_KMEM_ZFS)
 141
 142         AC_MSG_RESULT([$enable_debug_kmem])
 143 ])
 144
 145 dnl #
 146 dnl # Disabled by default, provides detailed memory tracking.  This feature
 147 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 148 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 149 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 150 dnl # and where they were allocated will be dumped to the console.  Enabling
 151 dnl # this feature has a significant impact on performance but it makes finding
 152 dnl # memory leaks straight forward.
 153 dnl #
 154 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 155         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 156         AC_ARG_ENABLE([debug-kmem-tracking],
 157                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 158                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 159                 [],
 160                 [enable_debug_kmem_tracking=no])
 161
 162         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 163                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
 164                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 165         ], [
 166                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 167         ])
 168
 169         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 170         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 171
 172         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 173 ])
 174
 175 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD], [
 176         AS_IF([sysctl -n kern.conftxt | fgrep -qx $'options\tINVARIANTS'],
 177                 [enable_invariants="yes"],
 178                 [enable_invariants="no"])
 179 ])
 180
 181 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT], [
 182         AM_COND_IF([BUILD_FREEBSD],
 183                 [ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD],
 184                 [enable_invariants="no"])
 185 ])
 186
 187 dnl #
 188 dnl # Detected for the running kernel by default, enables INVARIANTS features
 189 dnl # in the FreeBSD kernel module.  This feature must be used when building
 190 dnl # for a FreeBSD kernel with "options INVARIANTS" in the KERNCONF and must
 191 dnl # not be used when the INVARIANTS option is absent.
 192 dnl #
 193 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS], [
 194         AC_MSG_CHECKING([whether FreeBSD kernel INVARIANTS checks are enabled])
 195         AC_ARG_ENABLE([invariants],
 196                 [AS_HELP_STRING([--enable-invariants],
 197                 [Enable FreeBSD kernel INVARIANTS checks [[default: detect]]])],
 198                 [], [ZFS_AC_DEBUG_INVARIANTS_DETECT])
 199
 200         AS_IF([test "x$enable_invariants" = xyes],
 201                 [WITH_INVARIANTS="true"],
 202                 [WITH_INVARIANTS=""])
 203         AC_SUBST(WITH_INVARIANTS)
 204
 205         AC_MSG_RESULT([$enable_invariants])
 206 ])
 207
 208 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 209         AX_COUNT_CPUS([])
 210         AC_SUBST(CPU_COUNT)
 211
 212         ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
 213         ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
 214         ZFS_AC_CONFIG_ALWAYS_CC_IMPLICIT_FALLTHROUGH
 215         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 216         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 217         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 218         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 219         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 220         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 221         ZFS_AC_CONFIG_ALWAYS_CC_UBSAN
 222         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 223         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 224         ZFS_AC_CONFIG_ALWAYS_ARCH
 225         ZFS_AC_CONFIG_ALWAYS_PYTHON
 226         ZFS_AC_CONFIG_ALWAYS_PYZFS
 227         ZFS_AC_CONFIG_ALWAYS_SED
 228         ZFS_AC_CONFIG_ALWAYS_CPPCHECK
 229         ZFS_AC_CONFIG_ALWAYS_SHELLCHECK
 230         ZFS_AC_CONFIG_ALWAYS_PARALLEL
 231 ])
 232
 233 AC_DEFUN([ZFS_AC_CONFIG], [
 234
 235         dnl # Remove the previous build test directory.
 236         rm -Rf build
 237
 238         ZFS_CONFIG=all
 239         AC_ARG_WITH([config],
 240                 AS_HELP_STRING([--with-config=CONFIG],
 241                 [Config file 'kernel|user|all|srpm']),
 242                 [ZFS_CONFIG="$withval"])
 243         AC_ARG_ENABLE([linux-builtin],
 244                 [AS_HELP_STRING([--enable-linux-builtin],
 245                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 246                 [],
 247                 [enable_linux_builtin=no])
 248
 249         AC_MSG_CHECKING([zfs config])
 250         AC_MSG_RESULT([$ZFS_CONFIG]);
 251         AC_SUBST(ZFS_CONFIG)
 252
 253         ZFS_AC_CONFIG_ALWAYS
 254
 255         AM_COND_IF([BUILD_LINUX], [
 256                 AC_ARG_VAR([TEST_JOBS], [simultaneous jobs during configure])
 257                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 258                         TEST_JOBS=$CPU_COUNT
 259                 fi
 260                 AC_SUBST(TEST_JOBS)
 261         ])
 262
 263         case "$ZFS_CONFIG" in
 264                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 265                 user)   ZFS_AC_CONFIG_USER   ;;
 266                 all)    ZFS_AC_CONFIG_USER
 267                         ZFS_AC_CONFIG_KERNEL ;;
 268                 srpm)                        ;;
 269                 *)
 270                 AC_MSG_RESULT([Error!])
 271                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 272                               user kernel|user|all|srpm]) ;;
 273         esac
 274
 275         AM_CONDITIONAL([CONFIG_USER],
 276             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 277         AM_CONDITIONAL([CONFIG_KERNEL],
 278             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 279             [test "x$enable_linux_builtin" != xyes ])
 280         AM_CONDITIONAL([CONFIG_QAT],
 281             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 282             [test "x$qatsrc" != x ])
 283         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 284         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 285         AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
 286 ])
 287
 288 dnl #
 289 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 290 dnl # are missing it is non-fatal but you will not be able to build
 291 dnl # RPM packages and will be warned if you try too.
 292 dnl #
 293 dnl # By default the generic spec file will be used because it requires
 294 dnl # minimal dependencies.  Distribution specific spec files can be
 295 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 296 dnl # the --with-spec=<distribution> configure option.
 297 dnl #
 298 AC_DEFUN([ZFS_AC_RPM], [
 299         RPM=rpm
 300         RPMBUILD=rpmbuild
 301
 302         AC_MSG_CHECKING([whether $RPM is available])
 303         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 304                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 305                 HAVE_RPM=yes
 306                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 307         ],[
 308                 HAVE_RPM=no
 309                 AC_MSG_RESULT([$HAVE_RPM])
 310         ])
 311
 312         AC_MSG_CHECKING([whether $RPMBUILD is available])
 313         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 314                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 315                 HAVE_RPMBUILD=yes
 316                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 317         ],[
 318                 HAVE_RPMBUILD=no
 319                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 320         ])
 321
 322         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 323         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
 324         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
 325         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 326         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
 327         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(UBSAN_ZFS) 1"'
 328
 329         RPM_DEFINE_UTIL=' --define "_initconfdir $(initconfdir)"'
 330
 331         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 332         dnl # their values may not be set when running:
 333         dnl #
 334         dnl #   ./configure --with-config=srpm
 335         dnl #
 336         AS_IF([test -n "$dracutdir" ], [
 337                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
 338         ])
 339         AS_IF([test -n "$udevdir" ], [
 340                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
 341         ])
 342         AS_IF([test -n "$udevruledir" ], [
 343                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
 344         ])
 345         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
 346         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
 347         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
 348         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
 349         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
 350
 351         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 352         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 353         dnl # specify the correct path for multiarch systems as described
 354         dnl # by the packaging guidelines.
 355         dnl #
 356         dnl # https://wiki.ubuntu.com/MultiarchSpec
 357         dnl # https://wiki.debian.org/Multiarch/Implementation
 358         dnl #
 359         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 360                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 361                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
 362                 AC_SUBST(MULTIARCH_LIBDIR)
 363         ])
 364
 365         dnl # Make RPM_DEFINE_KMOD additions conditional on CONFIG_KERNEL,
 366         dnl # since the values will not be set otherwise. The spec files
 367         dnl # provide defaults for them.
 368         dnl #
 369         RPM_DEFINE_KMOD='--define "_wrong_version_format_terminate_build 0"'
 370         AM_COND_IF([CONFIG_KERNEL], [
 371                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernels $(LINUX_VERSION)"'
 372                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
 373                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
 374         ])
 375
 376         RPM_DEFINE_DKMS=''
 377
 378         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 379         SRPM_DEFINE_UTIL=
 380         SRPM_DEFINE_KMOD=
 381         SRPM_DEFINE_DKMS=
 382
 383         RPM_SPEC_DIR="rpm/generic"
 384         AC_ARG_WITH([spec],
 385                 AS_HELP_STRING([--with-spec=SPEC],
 386                 [Spec files 'generic|redhat']),
 387                 [RPM_SPEC_DIR="rpm/$withval"])
 388
 389         AC_MSG_CHECKING([whether spec files are available])
 390         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 391
 392         AC_SUBST(HAVE_RPM)
 393         AC_SUBST(RPM)
 394         AC_SUBST(RPM_VERSION)
 395
 396         AC_SUBST(HAVE_RPMBUILD)
 397         AC_SUBST(RPMBUILD)
 398         AC_SUBST(RPMBUILD_VERSION)
 399
 400         AC_SUBST(RPM_SPEC_DIR)
 401         AC_SUBST(RPM_DEFINE_UTIL)
 402         AC_SUBST(RPM_DEFINE_KMOD)
 403         AC_SUBST(RPM_DEFINE_DKMS)
 404         AC_SUBST(RPM_DEFINE_COMMON)
 405         AC_SUBST(SRPM_DEFINE_UTIL)
 406         AC_SUBST(SRPM_DEFINE_KMOD)
 407         AC_SUBST(SRPM_DEFINE_DKMS)
 408         AC_SUBST(SRPM_DEFINE_COMMON)
 409 ])
 410
 411 dnl #
 412 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 413 dnl # tools are missing it is non-fatal but you will not be able to build
 414 dnl # DEB packages and will be warned if you try too.
 415 dnl #
 416 AC_DEFUN([ZFS_AC_DPKG], [
 417         DPKG=dpkg
 418         DPKGBUILD=dpkg-buildpackage
 419
 420         AC_MSG_CHECKING([whether $DPKG is available])
 421         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 422                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 423                 HAVE_DPKG=yes
 424                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 425         ],[
 426                 HAVE_DPKG=no
 427                 AC_MSG_RESULT([$HAVE_DPKG])
 428         ])
 429
 430         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 431         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 432                 DPKGBUILD_VERSION=$(echo $tmp | \
 433                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 434                 HAVE_DPKGBUILD=yes
 435                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 436         ],[
 437                 HAVE_DPKGBUILD=no
 438                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 439         ])
 440
 441         AC_SUBST(HAVE_DPKG)
 442         AC_SUBST(DPKG)
 443         AC_SUBST(DPKG_VERSION)
 444
 445         AC_SUBST(HAVE_DPKGBUILD)
 446         AC_SUBST(DPKGBUILD)
 447         AC_SUBST(DPKGBUILD_VERSION)
 448 ])
 449
 450 dnl #
 451 dnl # Until native packaging for various different packing systems
 452 dnl # can be added the least we can do is attempt to use alien to
 453 dnl # convert the RPM packages to the needed package type.  This is
 454 dnl # a hack but so far it has worked reasonable well.
 455 dnl #
 456 AC_DEFUN([ZFS_AC_ALIEN], [
 457         ALIEN=alien
 458
 459         AC_MSG_CHECKING([whether $ALIEN is available])
 460         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 461                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 462                 ALIEN_MAJOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[1] }')
 463                 ALIEN_MINOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[2] }')
 464                 ALIEN_POINT=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[3] }')
 465                 HAVE_ALIEN=yes
 466                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 467         ],[
 468                 HAVE_ALIEN=no
 469                 AC_MSG_RESULT([$HAVE_ALIEN])
 470         ])
 471
 472         AC_SUBST(HAVE_ALIEN)
 473         AC_SUBST(ALIEN)
 474         AC_SUBST(ALIEN_VERSION)
 475         AC_SUBST(ALIEN_MAJOR)
 476         AC_SUBST(ALIEN_MINOR)
 477         AC_SUBST(ALIEN_POINT)
 478 ])
 479
 480 dnl #
 481 dnl # Using the VENDOR tag from config.guess set the default
 482 dnl # package type for 'make pkg': (rpm | deb | tgz)
 483 dnl #
 484 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 485         AC_MSG_CHECKING([os distribution])
 486         AC_ARG_WITH([vendor],
 487                 [AS_HELP_STRING([--with-vendor],
 488                         [Distribution vendor @<:@default=check@:>@])],
 489                 [with_vendor=$withval],
 490                 [with_vendor=check])
 491         AS_IF([test "x$with_vendor" = "xcheck"],[
 492                 if test -f /etc/toss-release ; then
 493                         VENDOR=toss ;
 494                 elif test -f /etc/fedora-release ; then
 495                         VENDOR=fedora ;
 496                 elif test -f /etc/redhat-release ; then
 497                         VENDOR=redhat ;
 498                 elif test -f /etc/gentoo-release ; then
 499                         VENDOR=gentoo ;
 500                 elif test -f /etc/arch-release ; then
 501                         VENDOR=arch ;
 502                 elif test -f /etc/SuSE-release ; then
 503                         VENDOR=sles ;
 504                 elif test -f /etc/slackware-version ; then
 505                         VENDOR=slackware ;
 506                 elif test -f /etc/lunar.release ; then
 507                         VENDOR=lunar ;
 508                 elif test -f /etc/lsb-release ; then
 509                         VENDOR=ubuntu ;
 510                 elif test -f /etc/debian_version ; then
 511                         VENDOR=debian ;
 512                 elif test -f /etc/alpine-release ; then
 513                         VENDOR=alpine ;
 514                 elif test -f /bin/freebsd-version ; then
 515                         VENDOR=freebsd ;
 516                 else
 517                         VENDOR= ;
 518                 fi],
 519                 [ test "x${with_vendor}" != x],[
 520                         VENDOR="$with_vendor" ],
 521                 [ VENDOR= ; ]
 522         )
 523         AC_MSG_RESULT([$VENDOR])
 524         AC_SUBST(VENDOR)
 525
 526         AC_MSG_CHECKING([default package type])
 527         case "$VENDOR" in
 528                 toss)       DEFAULT_PACKAGE=rpm  ;;
 529                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 530                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 531                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 532                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 533                 arch)       DEFAULT_PACKAGE=tgz  ;;
 534                 sles)       DEFAULT_PACKAGE=rpm  ;;
 535                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 536                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 537                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 538                 debian)     DEFAULT_PACKAGE=deb  ;;
 539                 freebsd)    DEFAULT_PACKAGE=pkg  ;;
 540                 *)          DEFAULT_PACKAGE=rpm  ;;
 541         esac
 542         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 543         AC_SUBST(DEFAULT_PACKAGE)
 544
 545         AC_MSG_CHECKING([default init directory])
 546         case "$VENDOR" in
 547                 freebsd)    initdir=$sysconfdir/rc.d  ;;
 548                 *)          initdir=$sysconfdir/init.d;;
 549         esac
 550         AC_MSG_RESULT([$initdir])
 551         AC_SUBST(initdir)
 552
 553         AC_MSG_CHECKING([default init script type and shell])
 554         case "$VENDOR" in
 555                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 556                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 557                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 558                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 559                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 560                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 561                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 562                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 563                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 564                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 565                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 566                 freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
 567                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 568         esac
 569
 570         case "$VENDOR" in
 571                 gentoo)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 572                 alpine)     DEFAULT_INIT_SHELL="/sbin/openrc-run";;
 573                 *)          DEFAULT_INIT_SHELL="/bin/sh"         ;;
 574         esac
 575
 576         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT:$DEFAULT_INIT_SHELL])
 577         AC_SUBST(DEFAULT_INIT_SCRIPT)
 578         AC_SUBST(DEFAULT_INIT_SHELL)
 579
 580         AC_MSG_CHECKING([default nfs server init script])
 581         AS_IF([test "$VENDOR" = "debian"],
 582                 [DEFAULT_INIT_NFS_SERVER="nfs-kernel-server"],
 583                 [DEFAULT_INIT_NFS_SERVER="nfs"]
 584         )
 585         AC_MSG_RESULT([$DEFAULT_INIT_NFS_SERVER])
 586         AC_SUBST(DEFAULT_INIT_NFS_SERVER)
 587
 588         AC_MSG_CHECKING([default init config directory])
 589         case "$VENDOR" in
 590                 alpine)     initconfdir=/etc/conf.d    ;;
 591                 gentoo)     initconfdir=/etc/conf.d    ;;
 592                 toss)       initconfdir=/etc/sysconfig ;;
 593                 redhat)     initconfdir=/etc/sysconfig ;;
 594                 fedora)     initconfdir=/etc/sysconfig ;;
 595                 sles)       initconfdir=/etc/sysconfig ;;
 596                 ubuntu)     initconfdir=/etc/default   ;;
 597                 debian)     initconfdir=/etc/default   ;;
 598                 freebsd)    initconfdir=$sysconfdir/rc.conf.d;;
 599                 *)          initconfdir=/etc/default   ;;
 600         esac
 601         AC_MSG_RESULT([$initconfdir])
 602         AC_SUBST(initconfdir)
 603
 604         AC_MSG_CHECKING([whether initramfs-tools is available])
 605         if test -d /usr/share/initramfs-tools ; then
 606                 RPM_DEFINE_INITRAMFS='--define "_initramfs 1"'
 607                 AC_MSG_RESULT([yes])
 608         else
 609                 RPM_DEFINE_INITRAMFS=''
 610                 AC_MSG_RESULT([no])
 611         fi
 612         AC_SUBST(RPM_DEFINE_INITRAMFS)
 613 ])
 614
 615 dnl #
 616 dnl # Default ZFS package configuration
 617 dnl #
 618 AC_DEFUN([ZFS_AC_PACKAGE], [
 619         ZFS_AC_DEFAULT_PACKAGE
 620         AS_IF([test x$VENDOR != xfreebsd], [
 621                 ZFS_AC_RPM
 622                 ZFS_AC_DPKG
 623                 ZFS_AC_ALIEN
 624         ])
 625 ])