configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 2)
   6 m4_define([lxc_version_minor], 1)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9
  10 m4_define([lxc_abi_major], 1)
  11 m4_define([lxc_abi_minor], 3)
  12 m4_define([lxc_abi_micro], 0)
  13 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  14
  15 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  16 m4_define([lxc_version],
  17           [ifelse(lxc_devel, 1,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  19         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  20
  21 AC_INIT([lxc], [lxc_version])
  22
  23 # We need pkg-config
  24 PKG_PROG_PKG_CONFIG
  25
  26 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  27 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  28
  29 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  30 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  31 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  32 AC_SUBST([LXC_VERSION], [lxc_version])
  33 AC_SUBST([LXC_DEVEL], [lxc_devel])
  34
  35 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  36 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  37 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  38 AC_SUBST([LXC_ABI], [lxc_abi])
  39
  40 AC_CONFIG_SRCDIR([configure.ac])
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_HEADERS([src/config.h])
  43 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  44 AC_CANONICAL_HOST
  45 AM_PROG_CC_C_O
  46 AC_GNU_SOURCE
  47
  48 # libtool
  49 LT_INIT
  50 AC_SUBST([LIBTOOL_DEPS])
  51
  52 # Detect the distribution. This is used for the default configuration and
  53 # for some distro-specific build options.
  54 AC_MSG_CHECKING([host distribution])
  55 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  56 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  57         with_distro=`lsb_release -is`
  58 fi
  59 if test "z$with_distro" = "z"; then
  60         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  61         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  62         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  63         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  64         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  65         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  66         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  67         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  68         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  69         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  70         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  71         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  72         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  73         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  74         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  75         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  76         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  77 fi
  78 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  79
  80 if test "z$with_distro" = "zforsparc"; then
  81         with_distro="sparclinux"
  82 fi
  83
  84 if test "z$with_distro" = "z"; then
  85         with_distro="unknown"
  86 fi
  87 case $with_distro in
  88         ubuntu|raspbian)
  89                 distroconf=default.conf.lxcbr
  90                 distrosysconf="$sysconfdir/default"
  91                 ;;
  92         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  93                 distroconf=default.conf.lxcbr
  94                 distrosysconf="$sysconfdir/sysconfig"
  95                 ;;
  96         *)
  97                 distroconf=default.conf.unknown
  98                 distrosysconf="$sysconfdir/default"
  99                 ;;
 100 esac
 101 AC_MSG_RESULT([$with_distro])
 102 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 103 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 104
 105 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 106
 107 # Check for init system type
 108 AC_MSG_CHECKING([for init system type])
 109 AC_ARG_WITH([init-script],
 110             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 111                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 112                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 113 case "$with_init_script" in
 114         distro)
 115                 case $with_distro in
 116                         fedora|altlinux|opensuse*)
 117                                 init_script=systemd
 118                                 ;;
 119                         redhat|oracle|oracleserver|sparclinux|plamo)
 120                                 init_script=sysvinit
 121                                 ;;
 122                         centos)
 123                                 init_script=sysvinit,systemd
 124                                 ;;
 125                         debian|raspbian|ubuntu)
 126                                 init_script=upstart,systemd
 127                                 ;;
 128                         pld)
 129                                 init_script=sysvinit,upstart,systemd
 130                                 ;;
 131                         *)
 132                                 echo -n "Linux distribution init system unknown."
 133                                 init_script=
 134                                 ;;
 135                 esac
 136                 ;;
 137         *)
 138                 init_script=$with_init_script
 139                 ;;
 140 esac
 141
 142 # Check valid init systems were given, run in subshell so we don't mess up IFS
 143 (IFS="," ; for init_sys in $init_script;
 144 do
 145         case "$init_sys" in
 146                 none|sysvinit|systemd|upstart)
 147                         ;;
 148                 *)
 149                         exit 1
 150                         ;;
 151         esac
 152 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 153
 154 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 155 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 156 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 157 AC_MSG_RESULT($init_script)
 158
 159 # systemd unit dir
 160 AC_ARG_WITH([systemdsystemunitdir],
 161             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 162             [],
 163             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 164 if test -z "$with_systemdsystemunitdir"; then
 165   with_systemdsystemunitdir=/lib/systemd/system
 166 fi
 167 if test "x$with_systemdsystemunitdir" != "xno"; then
 168   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 169 fi
 170
 171 AC_ARG_ENABLE([werror],
 172         [AC_HELP_STRING([--disable-werror],
 173         [do not treat warnings as errors])],
 174         [], [enable_werror=yes])
 175
 176 # Allow enabling deprecated executables
 177 AC_ARG_ENABLE([deprecated],
 178         [AC_HELP_STRING([--enable-deprecated],
 179         [enable deprecated executables [default=no]])],
 180         [], [enable_deprecated=false])
 181 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 182
 183 # Allow disabling rpath
 184 AC_ARG_ENABLE([rpath],
 185         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 186         [], [enable_rpath=no])
 187 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 188
 189 # Documentation (manpages)
 190 AC_ARG_ENABLE([doc],
 191         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 192         [], [enable_doc=auto])
 193
 194 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 195         db2xman=""
 196         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 197
 198         AC_MSG_CHECKING(for docbook2x-man)
 199         for name in ${dbparsers}; do
 200                 if "$name" --help >/dev/null 2>&1; then
 201                         db2xman="$name"
 202                         break;
 203                 fi
 204         done
 205
 206         if test -n "${db2xman}"; then
 207                 AC_MSG_RESULT([${db2xman}])
 208                 enable_doc="yes"
 209         else
 210                 AC_MSG_RESULT([no])
 211                 if test "x$enable_doc" = "xyes"; then
 212                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 213                 fi
 214                 enable_doc="no"
 215         fi
 216
 217         AC_SUBST(db2xman)
 218 fi
 219 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 220 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 221
 222 if test "x$db2xman" = "xdocbook2man"; then
 223         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 224 else
 225         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 226 fi
 227 AC_SUBST(docdtd)
 228
 229 # Documentation (API)
 230 AC_ARG_ENABLE([api-docs],
 231         [AC_HELP_STRING([--enable-api-docs],
 232         [make API documentation [default=auto]])],
 233         [], [enable_api_docs=auto])
 234
 235 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 236         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 237         AC_SUBST([HAVE_DOXYGEN])
 238
 239         if test "x$HAVE_DOXYGEN" != "x"; then
 240                 enable_api_docs="yes"
 241         else
 242                 if test "x$enable_api_docs" = "xyes"; then
 243                         AC_MSG_ERROR([doxygen is required, but could not be found])
 244                 fi
 245                 enable_api_docs="no"
 246         fi
 247 fi
 248
 249 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 250
 251 # Apparmor
 252 AC_ARG_ENABLE([apparmor],
 253         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 254         [], [enable_apparmor=auto])
 255
 256 if test "$enable_apparmor" = "auto" ; then
 257         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 258 fi
 259 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 260
 261 AM_COND_IF([ENABLE_APPARMOR],
 262         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 263         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 264         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 265
 266 # GnuTLS
 267 AC_ARG_ENABLE([gnutls],
 268         [AC_HELP_STRING([--enable-gnutls], [enable GnuTLS support [default=auto]])],
 269         [], [enable_gnutls=auto])
 270
 271 if test "$enable_gnutls" = "auto" ; then
 272         AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 273 fi
 274 AM_CONDITIONAL([ENABLE_GNUTLS], [test "x$enable_gnutls" = "xyes"])
 275
 276 AM_COND_IF([ENABLE_GNUTLS],
 277         [AC_CHECK_HEADER([gnutls/gnutls.h],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 278         AC_CHECK_LIB([gnutls], [gnutls_hash_fast],[],[AC_MSG_ERROR([You must install the GnuTLS development package in order to compile lxc])])
 279         AC_SUBST([GNUTLS_LIBS], [-lgnutls])])
 280
 281 # SELinux
 282 AC_ARG_ENABLE([selinux],
 283         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 284         [], [enable_selinux=auto])
 285
 286 if test "x$enable_selinux" = xauto; then
 287         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 288 fi
 289 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 290 AM_COND_IF([ENABLE_SELINUX],
 291         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 292         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 293         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 294
 295 # Seccomp syscall filter
 296 AC_ARG_ENABLE([seccomp],
 297         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 298         [], [enable_seccomp=auto])
 299
 300 if test "x$enable_seccomp" = "xauto" ; then
 301         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 302 fi
 303 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 304
 305 AM_COND_IF([ENABLE_SECCOMP],
 306         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 307                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 308                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 309                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 310                 ])
 311         ])
 312
 313 # cgmanager
 314 AC_ARG_ENABLE([cgmanager],
 315         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 316         [], [enable_cgmanager=auto])
 317
 318 if test "x$enable_cgmanager" = "xauto" ; then
 319         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 320 fi
 321 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 322
 323 AM_COND_IF([ENABLE_CGMANAGER],
 324         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 325         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 326         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 327         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 328         ])
 329
 330 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 331 save_LIBS=$LIBS
 332 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 333 LIBS=$save_LIBS
 334 if test "x$have_abs_cgroups" = "xyes"; then
 335         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 336         AC_MSG_RESULT([yes])
 337 else
 338         AC_MSG_RESULT([no])
 339 fi
 340
 341 AC_MSG_CHECKING(for cgmanager_list_controllers)
 342 save_LIBS=$LIBS
 343 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 344 LIBS=$save_LIBS
 345 if test "x$have_list_controllers" = "xyes"; then
 346         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 347         AC_MSG_RESULT([yes])
 348 else
 349         AC_MSG_RESULT([no])
 350 fi
 351
 352 AC_MSG_CHECKING(for static libcap)
 353 # Check for static libcap, make sure the function checked for differs from the
 354 # the one checked below so the cache doesn't give a wrong answer
 355 OLD_CFLAGS="$CFLAGS"
 356 OLD_CPPFLAGS="$CPPFLAGS"
 357 OLD_LDFLAGS="$LDFLAGS"
 358 OLD_LIBS="$LIBS"
 359 CFLAGS=""
 360 CPPFLAGS=""
 361 LDFLAGS="-static"
 362 LIBS="-lcap"
 363 AC_LINK_IFELSE([
 364   AC_LANG_SOURCE(
 365     [[int main() { return 0; }]]
 366   )],[have_static_libcap=yes],[have_static_libcap=no])
 367 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 368 if test "x$have_static_libcap" = "xyes"; then
 369         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 370         AC_MSG_RESULT([yes])
 371 else
 372         AC_MSG_RESULT([no])
 373 fi
 374 CPPFLAGS="$OLD_CPPFLAGS"
 375 CFLAGS="$OLD_CFLAGS"
 376 LDFLAGS="$OLD_LDFLAGS"
 377 LIBS="$OLD_LIBS"
 378
 379
 380 # Linux capabilities
 381 AC_ARG_ENABLE([capabilities],
 382         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 383         [], [enable_capabilities=auto])
 384
 385 if test "x$enable_capabilities" = "xauto"; then
 386         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 387 fi
 388 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 389
 390 AM_COND_IF([ENABLE_CAP],
 391         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 392         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 393         # Test whether we support getting file capabilities via cap_get_file().
 394         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 395         AC_SUBST([CAP_LIBS], [-lcap])])
 396
 397 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 398 OLD_CFLAGS="$CFLAGS"
 399 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 400 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 401 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 402 CFLAGS="$OLD_CFLAGS"
 403
 404 # Configuration examples
 405 AC_ARG_ENABLE([examples],
 406         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 407         [], [enable_examples=yes])
 408 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 409
 410 # Python3 module and scripts
 411 AC_ARG_ENABLE([python],
 412         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 413         [], [enable_python=auto])
 414
 415 if test "x$enable_python" = "xauto"; then
 416         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 417         if test "$CC" = "clang"; then
 418                 enable_python=no
 419         fi
 420 fi
 421
 422 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 423         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 424 fi
 425
 426 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 427
 428 AM_COND_IF([ENABLE_PYTHON],
 429         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 430         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 431         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 432
 433 # Enable dumping stack traces
 434 AC_ARG_ENABLE([mutex-debugging],
 435         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 436         [], [enable_mutex_debugging=no])
 437 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 438
 439 AM_COND_IF([MUTEX_DEBUGGING],
 440         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 441
 442 # Not in older autoconf versions
 443 # AS_VAR_COPY(DEST, SOURCE)
 444 # -------------------------
 445 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 446 # shell variable SOURCE.
 447 m4_ifdef([AS_VAR_COPY], [],
 448 [AC_DEFUN([AS_VAR_COPY],
 449     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 450 ])
 451
 452 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 453 m4_ifdef([PKG_CHECK_VAR], [],
 454 [AC_DEFUN([PKG_CHECK_VAR],
 455     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 456      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 457      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 458      AS_VAR_COPY([$1], [pkg_cv_][$1])
 459      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 460     ])# PKG_CHECK_VAR
 461 ])
 462
 463 # Lua module and scripts
 464 AC_ARG_ENABLE([lua],
 465         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 466         [], [enable_lua=auto])
 467
 468 AC_ARG_WITH([lua-pc],
 469         [AS_HELP_STRING(
 470                 [--with-lua-pc=PKG],
 471                 [Specify pkg-config package name for lua]
 472         )], [], [with_lua_pc=no])
 473
 474 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 475         # exit with error if not found
 476         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 477 fi
 478
 479 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 480         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 481                 [LUAPKGCONFIG=$with_lua_pc
 482                 enable_lua=yes],
 483                 [enable_lua=no])
 484 fi
 485
 486 if test "x$enable_lua" != "xno"; then
 487         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 488                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 489                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 490                                 [AS_IF([test "x$enable_lua" = "xyes"],
 491                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 492                                         [enable_lua=no])]
 493                         )]
 494                 )])
 495         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 496 fi
 497
 498 AM_CONDITIONAL([ENABLE_LUA],
 499         [test "x$enable_lua" = "xyes"])
 500
 501 AM_COND_IF([ENABLE_LUA],
 502         [AC_MSG_CHECKING([Lua version])
 503         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 504                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 505         AC_MSG_RESULT([$LUA_VERSION])
 506         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 507         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 508         ])
 509
 510 # Optional bash integration
 511 AC_ARG_ENABLE([bash],
 512         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 513         [], [enable_bash=yes])
 514 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 515
 516 AM_COND_IF([ENABLE_BASH],
 517         [AC_MSG_CHECKING([bash completion directory])
 518         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 519                 bashcompdir="${sysconfdir}/bash_completion.d")
 520         AC_MSG_RESULT([$bashcompdir])
 521         AC_SUBST(bashcompdir)
 522         ])
 523
 524 # Optional test binaries
 525 AC_ARG_ENABLE([tests],
 526         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 527         [], [enable_tests=no])
 528 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 529
 530 # Allow overriding the default runtime dir (/run)
 531 AC_ARG_WITH([runtime-path],
 532         [AC_HELP_STRING(
 533                 [--with-runtime-path=dir],
 534                 [runtime directory (default: /run)]
 535         )], [], [with_runtime_path=['/run']])
 536
 537 # LXC container path, where the containers are actually stored
 538 # This is overridden by an entry in the file called LXCCONF
 539 # (i.e. /etc/lxc/lxc.conf)
 540 AC_ARG_WITH([config-path],
 541         [AC_HELP_STRING(
 542                 [--with-config-path=dir],
 543                 [lxc configuration repository path]
 544         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 545
 546 # The path of the global lxc configuration file.
 547 AC_ARG_WITH([global-conf],
 548         [AC_HELP_STRING(
 549                 [--with-global-conf=dir],
 550                 [global lxc configuration file]
 551         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 552
 553 # The path of the userns network configuration file
 554 AC_ARG_WITH([usernic-conf],
 555         [AC_HELP_STRING(
 556                 [--with-usernic-conf],
 557                 [user network interface configuration file]
 558         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 559
 560 # The path of the runtime usernic database
 561 AC_ARG_WITH([usernic-db],
 562         [AC_HELP_STRING(
 563                 [--with-usernic-db],
 564                 [lxc user nic database]
 565         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 566
 567 # Rootfs path, where the container mount structure is assembled
 568 AC_ARG_WITH([rootfs-path],
 569         [AC_HELP_STRING(
 570                 [--with-rootfs-path=dir],
 571                 [lxc rootfs mount point]
 572         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 573
 574 # cgroup pattern specification
 575 AC_ARG_WITH([cgroup-pattern],
 576         [AC_HELP_STRING(
 577                 [--with-cgroup-pattern=pattern],
 578                 [pattern for container cgroups]
 579         )], [], [with_cgroup_pattern=['lxc/%n']])
 580
 581 # Container log path.  By default, use $lxcpath.
 582 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 583 AC_ARG_ENABLE([configpath-log],
 584         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 585         [], [enable_configpath_log=no])
 586 AC_MSG_RESULT([$enable_configpath_log])
 587 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 588
 589 if test "$enable_configpath_log" = "yes"; then
 590         default_log_path="${with_config_path}"
 591 else
 592         default_log_path="${localstatedir}/log/lxc"
 593 fi
 594
 595 AC_ARG_WITH([log-path],
 596         [AC_HELP_STRING(
 597                 [--with-log-path=dir],
 598                 [per container log path]
 599         )], [], [with_log_path=['${default_log_path}']])
 600
 601 # Expand some useful variables
 602 AS_AC_EXPAND(PREFIX, "$prefix")
 603 AS_AC_EXPAND(LIBDIR, "$libdir")
 604 AS_AC_EXPAND(BINDIR, "$bindir")
 605 AS_AC_EXPAND(SBINDIR, "$sbindir")
 606 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 607 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 608 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 609 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 610 AS_AC_EXPAND(DATADIR, "$datadir")
 611 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 612 AS_AC_EXPAND(DOCDIR, "$docdir")
 613 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 614 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 615 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 616 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 617 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 618 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 619 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 620 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 621 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 622 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 623 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 624 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 625 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 626 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 627 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 628
 629 # We need the install path so criu knows where to reference the hook scripts.
 630 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 631
 632 # Check for some standard kernel headers
 633 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 634                                 [],
 635                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 636                                 [#include <sys/socket.h>])
 637
 638 # Check for alternate C libraries
 639 AC_MSG_CHECKING(for bionic libc)
 640 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 641         [[#ifndef __ANDROID__
 642 error: Not bionic!
 643 #endif]])],
 644         [is_bionic=yes],
 645         [is_bionic=no])
 646 if test "x$is_bionic" = "xyes"; then
 647         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 648         AC_MSG_RESULT([yes])
 649 else
 650         AC_MSG_RESULT([no])
 651 fi
 652 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 653
 654 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 655 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 656
 657 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 658 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 659 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 660
 661 # Check for some headers
 662 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/memfd.h sys/personality.h utmpx.h sys/timerfd.h sys/resource.h])
 663
 664 # lookup major()/minor()/makedev()
 665 AC_HEADER_MAJOR
 666
 667 # Check for some syscalls functions
 668 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create])
 669
 670 # Check for some functions
 671 AC_CHECK_LIB(pthread, main)
 672 AC_CHECK_FUNCS(pthread_atfork)
 673 AC_CHECK_FUNCS(statvfs)
 674 AC_CHECK_LIB(util, openpty)
 675 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 676 AC_CHECK_FUNCS([getline],
 677         AM_CONDITIONAL(HAVE_GETLINE, true)
 678         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 679         AM_CONDITIONAL(HAVE_GETLINE, false))
 680 AC_CHECK_FUNCS([getsubopt],
 681         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 682         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 683         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 684 AC_CHECK_FUNCS([fgetln],
 685         AM_CONDITIONAL(HAVE_FGETLN, true)
 686         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 687         AM_CONDITIONAL(HAVE_FGETLN, false))
 688 AC_CHECK_FUNCS([prlimit],
 689         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 690         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 691         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 692 AC_CHECK_FUNCS([prlimit64],
 693         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 694         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 695         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 696
 697 # Check for some libraries
 698 AX_PTHREAD
 699 AC_SEARCH_LIBS(clock_gettime, [rt])
 700
 701 # Check for some standard binaries
 702 AC_PROG_GCC_TRADITIONAL
 703 AC_PROG_SED
 704
 705 # See if we support thread-local storage.
 706 LXC_CHECK_TLS
 707
 708 if test "x$GCC" = "xyes"; then
 709         CFLAGS="$CFLAGS -Wall"
 710         if test "x$enable_werror" = "xyes"; then
 711                 CFLAGS="$CFLAGS -Werror"
 712         fi
 713 fi
 714
 715 # Files requiring some variable expansion
 716 AC_CONFIG_FILES([
 717         Makefile
 718         lxc.pc
 719         lxc.spec
 720
 721         config/Makefile
 722         config/apparmor/Makefile
 723         config/selinux/Makefile
 724         config/bash/Makefile
 725         config/bash/lxc
 726         config/init/Makefile
 727         config/init/common/Makefile
 728         config/init/common/lxc-containers
 729         config/init/common/lxc-net
 730         config/init/systemd/Makefile
 731         config/init/systemd/lxc.service
 732         config/init/systemd/lxc@.service
 733         config/init/systemd/lxc-net.service
 734         config/init/sysvinit/Makefile
 735         config/init/sysvinit/lxc-containers
 736         config/init/sysvinit/lxc-net
 737         config/init/upstart/lxc.conf
 738         config/init/upstart/lxc-net.conf
 739         config/init/upstart/Makefile
 740         config/etc/Makefile
 741         config/templates/Makefile
 742         config/templates/alpine.common.conf
 743         config/templates/alpine.userns.conf
 744         config/templates/archlinux.common.conf
 745         config/templates/archlinux.userns.conf
 746         config/templates/centos.common.conf
 747         config/templates/centos.userns.conf
 748         config/templates/common.conf
 749         config/templates/common.conf.d/Makefile
 750         config/templates/debian.common.conf
 751         config/templates/debian.userns.conf
 752         config/templates/fedora.common.conf
 753         config/templates/fedora.userns.conf
 754         config/templates/gentoo.common.conf
 755         config/templates/gentoo.moresecure.conf
 756         config/templates/gentoo.userns.conf
 757         config/templates/nesting.conf
 758         config/templates/oci.common.conf
 759         config/templates/opensuse.common.conf
 760         config/templates/opensuse.userns.conf
 761         config/templates/oracle.common.conf
 762         config/templates/oracle.userns.conf
 763         config/templates/plamo.common.conf
 764         config/templates/plamo.userns.conf
 765         config/templates/slackware.common.conf
 766         config/templates/slackware.userns.conf
 767         config/templates/ubuntu-cloud.common.conf
 768         config/templates/ubuntu-cloud.lucid.conf
 769         config/templates/ubuntu-cloud.userns.conf
 770         config/templates/ubuntu.common.conf
 771         config/templates/ubuntu.lucid.conf
 772         config/templates/ubuntu.userns.conf
 773         config/templates/openwrt.common.conf
 774         config/templates/sparclinux.common.conf
 775         config/templates/sparclinux.userns.conf
 776         config/templates/voidlinux.common.conf
 777         config/templates/voidlinux.userns.conf
 778         config/templates/sabayon.common.conf
 779         config/templates/sabayon.userns.conf
 780         config/templates/userns.conf
 781         config/yum/Makefile
 782         config/sysconfig/Makefile
 783         config/sysconfig/lxc
 784
 785         doc/Makefile
 786         doc/api/Makefile
 787         doc/lxc-attach.sgml
 788         doc/lxc-autostart.sgml
 789         doc/lxc-cgroup.sgml
 790         doc/lxc-checkconfig.sgml
 791         doc/lxc-checkpoint.sgml
 792         doc/lxc-clone.sgml
 793         doc/lxc-config.sgml
 794         doc/lxc-console.sgml
 795         doc/lxc-copy.sgml
 796         doc/lxc-create.sgml
 797         doc/lxc-destroy.sgml
 798         doc/lxc-device.sgml
 799         doc/lxc-execute.sgml
 800         doc/lxc-freeze.sgml
 801         doc/lxc-info.sgml
 802         doc/lxc-ls.sgml
 803         doc/lxc-monitor.sgml
 804         doc/lxc-snapshot.sgml
 805         doc/lxc-start-ephemeral.sgml
 806         doc/lxc-start.sgml
 807         doc/lxc-stop.sgml
 808         doc/lxc-top.sgml
 809         doc/lxc-unfreeze.sgml
 810         doc/lxc-unshare.sgml
 811         doc/lxc-update-config.sgml
 812         doc/lxc-user-nic.sgml
 813         doc/lxc-usernsexec.sgml
 814         doc/lxc-wait.sgml
 815
 816         doc/lxc.conf.sgml
 817         doc/lxc.container.conf.sgml
 818         doc/lxc.system.conf.sgml
 819         doc/lxc-usernet.sgml
 820         doc/lxc.sgml
 821         doc/common_options.sgml
 822         doc/see_also.sgml
 823
 824         doc/rootfs/Makefile
 825
 826         doc/examples/Makefile
 827         doc/examples/lxc-macvlan.conf
 828         doc/examples/lxc-vlan.conf
 829         doc/examples/lxc-no-netns.conf
 830         doc/examples/lxc-empty-netns.conf
 831         doc/examples/lxc-phys.conf
 832         doc/examples/lxc-veth.conf
 833         doc/examples/lxc-complex.conf
 834
 835         doc/ja/Makefile
 836         doc/ja/lxc-attach.sgml
 837         doc/ja/lxc-autostart.sgml
 838         doc/ja/lxc-cgroup.sgml
 839         doc/ja/lxc-checkconfig.sgml
 840         doc/ja/lxc-checkpoint.sgml
 841         doc/ja/lxc-clone.sgml
 842         doc/ja/lxc-config.sgml
 843         doc/ja/lxc-console.sgml
 844         doc/ja/lxc-copy.sgml
 845         doc/ja/lxc-create.sgml
 846         doc/ja/lxc-destroy.sgml
 847         doc/ja/lxc-device.sgml
 848         doc/ja/lxc-execute.sgml
 849         doc/ja/lxc-freeze.sgml
 850         doc/ja/lxc-info.sgml
 851         doc/ja/lxc-ls.sgml
 852         doc/ja/lxc-monitor.sgml
 853         doc/ja/lxc-snapshot.sgml
 854         doc/ja/lxc-start-ephemeral.sgml
 855         doc/ja/lxc-start.sgml
 856         doc/ja/lxc-stop.sgml
 857         doc/ja/lxc-top.sgml
 858         doc/ja/lxc-unfreeze.sgml
 859         doc/ja/lxc-unshare.sgml
 860         doc/ja/lxc-update-config.sgml
 861         doc/ja/lxc-user-nic.sgml
 862         doc/ja/lxc-usernsexec.sgml
 863         doc/ja/lxc-wait.sgml
 864
 865         doc/ja/lxc.conf.sgml
 866         doc/ja/lxc.container.conf.sgml
 867         doc/ja/lxc.system.conf.sgml
 868         doc/ja/lxc-usernet.sgml
 869         doc/ja/lxc.sgml
 870         doc/ja/common_options.sgml
 871         doc/ja/see_also.sgml
 872
 873         doc/ko/Makefile
 874         doc/ko/lxc-attach.sgml
 875         doc/ko/lxc-autostart.sgml
 876         doc/ko/lxc-cgroup.sgml
 877         doc/ko/lxc-checkconfig.sgml
 878         doc/ko/lxc-checkpoint.sgml
 879         doc/ko/lxc-clone.sgml
 880         doc/ko/lxc-config.sgml
 881         doc/ko/lxc-console.sgml
 882         doc/ko/lxc-copy.sgml
 883         doc/ko/lxc-create.sgml
 884         doc/ko/lxc-destroy.sgml
 885         doc/ko/lxc-device.sgml
 886         doc/ko/lxc-execute.sgml
 887         doc/ko/lxc-freeze.sgml
 888         doc/ko/lxc-info.sgml
 889         doc/ko/lxc-ls.sgml
 890         doc/ko/lxc-monitor.sgml
 891         doc/ko/lxc-snapshot.sgml
 892         doc/ko/lxc-start-ephemeral.sgml
 893         doc/ko/lxc-start.sgml
 894         doc/ko/lxc-stop.sgml
 895         doc/ko/lxc-top.sgml
 896         doc/ko/lxc-unfreeze.sgml
 897         doc/ko/lxc-unshare.sgml
 898         doc/ko/lxc-user-nic.sgml
 899         doc/ko/lxc-usernsexec.sgml
 900         doc/ko/lxc-wait.sgml
 901
 902         doc/ko/lxc.conf.sgml
 903         doc/ko/lxc.container.conf.sgml
 904         doc/ko/lxc.system.conf.sgml
 905         doc/ko/lxc-usernet.sgml
 906         doc/ko/lxc.sgml
 907         doc/ko/common_options.sgml
 908         doc/ko/see_also.sgml
 909
 910         hooks/Makefile
 911         hooks/dhclient
 912
 913         templates/Makefile
 914         templates/lxc-alpine
 915         templates/lxc-altlinux
 916         templates/lxc-archlinux
 917         templates/lxc-busybox
 918         templates/lxc-centos
 919         templates/lxc-cirros
 920         templates/lxc-debian
 921         templates/lxc-download
 922         templates/lxc-fedora
 923         templates/lxc-fedora-legacy
 924         templates/lxc-gentoo
 925         templates/lxc-oci
 926         templates/lxc-openmandriva
 927         templates/lxc-opensuse
 928         templates/lxc-oracle
 929         templates/lxc-plamo
 930         templates/lxc-pld
 931         templates/lxc-slackware
 932         templates/lxc-sshd
 933         templates/lxc-ubuntu
 934         templates/lxc-ubuntu-cloud
 935         templates/lxc-sparclinux
 936         templates/lxc-voidlinux
 937         templates/lxc-sabayon
 938
 939         src/Makefile
 940         src/lxc/Makefile
 941         src/lxc/lxc.functions
 942         src/lxc/tools/lxc-checkconfig
 943         src/lxc/tools/lxc-start-ephemeral
 944         src/lxc/tools/lxc-update-config
 945         src/lxc/version.h
 946         src/python-lxc/Makefile
 947
 948         src/lua-lxc/Makefile
 949
 950         src/tests/Makefile
 951         src/tests/lxc-test-usernic
 952 ])
 953 AC_CONFIG_COMMANDS([default],[[]],[[]])
 954 AC_OUTPUT
 955
 956 # Configuration overview
 957 cat << EOF
 958
 959 ----------------------------
 960 Environment:
 961  - compiler: $CC
 962  - distribution: $with_distro
 963  - init script type(s): $init_script
 964  - rpath: $enable_rpath
 965  - GnuTLS: $enable_gnutls
 966  - Bash integration: $enable_bash
 967
 968 Security features:
 969  - Apparmor: $enable_apparmor
 970  - Linux capabilities: $enable_capabilities
 971  - seccomp: $enable_seccomp
 972  - SELinux: $enable_selinux
 973  - cgmanager: $enable_cgmanager
 974
 975 Bindings:
 976  - lua: $enable_lua
 977  - python3: $enable_python
 978
 979 Documentation:
 980  - examples: $enable_examples
 981  - API documentation: $enable_api_docs
 982  - user documentation: $enable_doc
 983
 984 Debugging:
 985  - tests: $enable_tests
 986  - mutex debugging: $enable_mutex_debugging
 987
 988 Paths:
 989  - Logs in configpath: $enable_configpath_log
 990 EOF
 991
 992 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 993 cat << EOF
 994
 995 WARNING: Threading not supported on your platform
 996
 997         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 998         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 999 EOF
1000 fi