configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lxc], [0.9.0])
   5
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_AUX_DIR([config])
   8 AC_CONFIG_HEADERS([src/config.h])
   9 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability])
  10 AC_CANONICAL_HOST
  11 AM_PROG_CC_C_O
  12 AC_GNU_SOURCE
  13
  14 # Detect the distribution. This is used for the default configuration and
  15 # for some distro-specific build options.
  16 AC_MSG_CHECKING([host distribution])
  17 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, fedora, suse, gentoo, debian, arch, slackware, paldo, mandriva or pardus.]))
  18 if test "z$with_distro" = "z"; then
  19         with_distro=`lsb_release -is`
  20 fi
  21 if test "z$with_distro" = "z"; then
  22         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  23         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  24         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  25         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  26         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  27         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  28         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  29         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  30         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  31         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="mandriva")
  32         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
  33         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  34 fi
  35 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  36
  37 if test "z$with_distro" = "z"; then
  38         with_distro="unknown"
  39 fi
  40 case $with_distro in
  41         ubuntu)
  42                 defaultconf=default.conf.ubuntu
  43                 ;;
  44         redhat|fedora|oracle|oracleserver)
  45                 defaultconf=default.conf.libvirt
  46                 ;;
  47         *)
  48                 echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty"
  49                 defaultconf=default.conf.unknown
  50                 ;;
  51 esac
  52 AC_MSG_RESULT([$with_distro])
  53 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  54
  55 # Allow disabling rpath
  56 AC_ARG_ENABLE([rpath],
  57         [AC_HELP_STRING([--disable-rpath], [do not set rpath in executables])],
  58         [], [enable_rpath=yes])
  59 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
  60
  61 # Documentation (manpages)
  62 AC_ARG_ENABLE([doc],
  63         [AC_HELP_STRING([--enable-doc], [make mans (requires docbook2man or docbook2x-man to be installed) [default=auto]])],
  64         [], [enable_doc=auto])
  65
  66 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
  67         db2xman=""
  68         dbparsers="docbook2x-man db2x_docbook2man docbook2man"
  69
  70         AC_MSG_CHECKING(for docbook2x-man)
  71         for name in ${dbparsers}; do
  72                 if "$name" --help >/dev/null 2>&1; then
  73                         db2xman="$name"
  74                         break;
  75                 fi
  76         done
  77
  78         if test -n "${db2xman}"; then
  79                 AC_MSG_RESULT([${db2xman}])
  80         else
  81                 AC_MSG_RESULT([no])
  82                 if test "x$enable_doc" = "xyes"; then
  83                         AC_MSG_ERROR([docbook2x-man required by man request, but not found])
  84                 fi
  85         fi
  86
  87         AC_SUBST(db2xman)
  88 fi
  89 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
  90
  91 if test "x$db2xman" = "xdocbook2man"; then
  92         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
  93 else
  94         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
  95 fi
  96 AC_SUBST(docdtd)
  97
  98 # Apparmor
  99 AC_ARG_ENABLE([apparmor],
 100         [AC_HELP_STRING([--enable-apparmor], [enable apparmor])],
 101         [], [enable_apparmor=check])
 102
 103 if test "$enable_apparmor" = "check" ; then
 104         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 105 fi
 106 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 107
 108 AM_COND_IF([ENABLE_APPARMOR],
 109         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 110         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 111         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 112
 113 # Seccomp syscall filter
 114 AC_ARG_ENABLE([seccomp],
 115         [AC_HELP_STRING([--enable-seccomp], [enable seccomp])],
 116         [], [enable_seccomp=check])
 117
 118 if test "$enable_seccomp" = "check" ; then
 119         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 120 fi
 121 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 122
 123 AM_COND_IF([ENABLE_SECCOMP],
 124         [AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 125         AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 126         AC_SUBST([SECCOMP_LIBS], [-lseccomp])])
 127
 128 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 129 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [#include <seccomp.h>])
 130
 131 # Configuration examples
 132 AC_ARG_ENABLE([examples],
 133         [AC_HELP_STRING([--disable-examples], [do not install configuration examples])],
 134         [], [enable_examples=yes])
 135 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 136
 137 # Python3 module and scripts
 138 AC_ARG_ENABLE([python],
 139         [AC_HELP_STRING([--enable-python], [enable python binding])],
 140         [enable_python=yes], [enable_python=no])
 141 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 142
 143 AM_COND_IF([ENABLE_PYTHON],
 144         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 145         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 146         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 147
 148 # Lua module and scripts
 149 if test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" ; then
 150     LUAPKGCONFIG=lua5.1
 151 else
 152     LUAPKGCONFIG=lua
 153 fi
 154
 155 AC_ARG_ENABLE([lua],
 156         [AC_HELP_STRING([--enable-lua], [enable lua binding])],
 157         [enable_lua=yes], [enable_lua=no])
 158
 159 AM_CONDITIONAL([ENABLE_LUA], [test "x$enable_lua" = "xyes"])
 160
 161 AM_COND_IF([ENABLE_LUA],
 162         [PKG_CHECK_MODULES([LUA], [$LUAPKGCONFIG >= 5.1],[],[AC_MSG_ERROR([You must install lua-devel for lua 5.1])])
 163         AC_DEFINE_UNQUOTED([ENABLE_LUA], 1, [Lua is available])])
 164
 165 # Optional test binaries
 166 AC_ARG_ENABLE([tests],
 167         [AC_HELP_STRING([--enable-tests], [build test/example binaries])],
 168         [enable_tests=yes], [enable_tests=no])
 169 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 170
 171 # LXC container path, where the containers are actually stored
 172 # This is overridden by an entry in the file called LXCCONF
 173 # (i.e. /etc/lxc/lxc.conf)
 174 AC_ARG_WITH([config-path],
 175         [AC_HELP_STRING(
 176                 [--with-config-path=dir],
 177                 [lxc configuration repository path]
 178         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 179
 180 # The path of the global lxc configuration file.
 181 AC_ARG_WITH([global-conf],
 182         [AC_HELP_STRING(
 183                 [--with-global-conf=dir],
 184                 [global lxc configuration file]
 185         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 186
 187 # Rootfs path, where the container mount structure is assembled
 188 AC_ARG_WITH([rootfs-path],
 189         [AC_HELP_STRING(
 190                 [--with-rootfs-path=dir],
 191                 [lxc rootfs mount point]
 192         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 193
 194 # Container log path.  By default, use $lxcpath.
 195 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 196 AC_ARG_ENABLE([configpath-log],
 197         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path])],
 198         [use_configpath_logs=yes], [use_configpath_logs=no])
 199 AC_MSG_RESULT([$use_configpath_logs])
 200 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$use_configpath_logs" = "yes"])
 201
 202 if test "$use_configpath_logs" = "yes"; then
 203         default_log_path="${with_config_path}"
 204 else
 205         default_log_path="${localstatedir}/log/lxc"
 206 fi
 207
 208 AC_ARG_WITH([log-path],
 209         [AC_HELP_STRING(
 210                 [--with-log-path=dir],
 211                 [per container log path]
 212         )], [], [with_log_path=['${default_log_path}']])
 213
 214 # Expand some useful variables
 215 AS_AC_EXPAND(PREFIX, "$prefix")
 216 AS_AC_EXPAND(LIBDIR, "$libdir")
 217 AS_AC_EXPAND(BINDIR, "$bindir")
 218 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 219 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 220 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 221 AS_AC_EXPAND(DATADIR, "$datadir")
 222 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 223 AS_AC_EXPAND(DOCDIR, "$docdir")
 224 AS_AC_EXPAND(LXC_DEFAULT_CONF, "$defaultconf")
 225 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 226 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 227 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 228 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 229 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 230 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 231 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 232 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 233
 234 # Check for some standard kernel headers
 235 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 236                                 [],
 237                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 238                                 [#include <sys/socket.h>])
 239
 240 # Allow disabling libcap support
 241 AC_ARG_ENABLE([capabilities],
 242         [AC_HELP_STRING([--disable-capabilities], [disable kernel capabilities])],
 243         [], [enable_capabilities=yes])
 244
 245 # Check for libcap support
 246 if test "x$enable_capabilities" = "xyes"; then
 247         AC_CHECK_LIB(cap,cap_set_proc,caplib=yes,caplib=no)
 248         AC_MSG_CHECKING([linux capabilities])
 249         if test "x$caplib" = "xyes" ; then
 250                 CAP_LIBS="-lcap"
 251                 AC_MSG_RESULT([$CAP_LIBS])
 252         else
 253                 AC_MSG_RESULT([no])
 254                 AC_MSG_ERROR([You are missing libcap support. If you really want to build without kernel capabilities, use --disable-capabilities])
 255         fi
 256 else
 257         CAP_LIBS=""
 258 fi
 259 AC_SUBST([CAP_LIBS])
 260
 261 # Check for alternate C libraries
 262 AC_MSG_CHECKING(for bionic libc)
 263 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 264         [[#ifndef __ANDROID__
 265 error: Not bionic!
 266 #endif]])],
 267         [is_bionic=yes],
 268         [is_bionic=no])
 269 if test "x$is_bionic" = "xyes"; then
 270         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 271         AC_MSG_RESULT([yes])
 272 else
 273         AC_MSG_RESULT([no])
 274 fi
 275 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 276
 277 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 278 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 279
 280 # Check for some headers
 281 AC_CHECK_HEADERS([sys/signalfd.h pty.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 282
 283 # Check for some syscalls functions
 284 AC_CHECK_FUNCS([setns pivot_root sethostname unshare])
 285
 286 # Check for some functions
 287 AC_CHECK_LIB(util, openpty)
 288 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent])
 289 AC_CHECK_FUNCS([getline],
 290         AM_CONDITIONAL(HAVE_GETLINE, true)
 291         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 292         AM_CONDITIONAL(HAVE_GETLINE, false))
 293 AC_CHECK_FUNCS([fgetln],
 294         AM_CONDITIONAL(HAVE_FGETLN, true)
 295         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 296         AM_CONDITIONAL(HAVE_FGETLN, false))
 297
 298 # Check for some libraries
 299 AC_SEARCH_LIBS(sem_open, [rt pthread])
 300 AC_SEARCH_LIBS(clock_gettime, [rt])
 301
 302 # Check for some standard binaries
 303 AC_PROG_GCC_TRADITIONAL
 304 AC_PROG_SED
 305
 306 if test "x$GCC" = "xyes"; then
 307         CFLAGS="$CFLAGS -Wall -Werror"
 308 fi
 309
 310 # Files requiring some variable expansion
 311 AC_CONFIG_FILES([
 312         Makefile
 313         lxc.pc
 314         lxc.spec
 315         config/Makefile
 316
 317         doc/Makefile
 318         doc/legacy/lxc-ls.sgml
 319         doc/lxc-attach.sgml
 320         doc/lxc-cgroup.sgml
 321         doc/lxc-checkconfig.sgml
 322         doc/lxc-checkpoint.sgml
 323         doc/lxc-clone.sgml
 324         doc/lxc-console.sgml
 325         doc/lxc-create.sgml
 326         doc/lxc-destroy.sgml
 327         doc/lxc-device.sgml
 328         doc/lxc-execute.sgml
 329         doc/lxc-freeze.sgml
 330         doc/lxc-info.sgml
 331         doc/lxc-kill.sgml
 332         doc/lxc-ls.sgml
 333         doc/lxc-monitor.sgml
 334         doc/lxc-netstat.sgml
 335         doc/lxc-ps.sgml
 336         doc/lxc-restart.sgml
 337         doc/lxc-start-ephemeral.sgml
 338         doc/lxc-start.sgml
 339         doc/lxc-stop.sgml
 340         doc/lxc-top.sgml
 341         doc/lxc-unfreeze.sgml
 342         doc/lxc-unshare.sgml
 343         doc/lxc-version.sgml
 344         doc/lxc-wait.sgml
 345
 346         doc/lxc.conf.sgml
 347         doc/lxc.sgml
 348         doc/common_options.sgml
 349         doc/see_also.sgml
 350
 351         doc/rootfs/Makefile
 352
 353         doc/examples/Makefile
 354         doc/examples/lxc-macvlan.conf
 355         doc/examples/lxc-vlan.conf
 356         doc/examples/lxc-no-netns.conf
 357         doc/examples/lxc-empty-netns.conf
 358         doc/examples/lxc-phys.conf
 359         doc/examples/lxc-veth.conf
 360         doc/examples/lxc-complex.conf
 361
 362         hooks/Makefile
 363
 364         templates/Makefile
 365         templates/lxc-cirros
 366         templates/lxc-debian
 367         templates/lxc-ubuntu
 368         templates/lxc-ubuntu-cloud
 369         templates/lxc-opensuse
 370         templates/lxc-busybox
 371         templates/lxc-fedora
 372         templates/lxc-oracle
 373         templates/lxc-altlinux
 374         templates/lxc-sshd
 375         templates/lxc-archlinux
 376         templates/lxc-alpine
 377
 378         src/Makefile
 379         src/lxc/Makefile
 380         src/lxc/lxc-ps
 381         src/lxc/lxc-netstat
 382         src/lxc/lxc-checkconfig
 383         src/lxc/lxc-version
 384         src/lxc/lxc-create
 385         src/lxc/lxc-start-ephemeral
 386         src/lxc/legacy/lxc-ls
 387         src/lxc/lxc.functions
 388
 389         src/python-lxc/Makefile
 390
 391         src/lua-lxc/Makefile
 392
 393         src/tests/Makefile
 394 ])
 395 AC_CONFIG_COMMANDS([default],[[]],[[]])
 396 AC_OUTPUT