configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.5-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[$4]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "$cachename" = "yes"; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "$enable_gcov" = "yes"; then
 246    if test "$orig_cflags" = ""; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 fi
 253
 254 if test "$enable_clang_coverage" = "yes"; then
 255    AC_C_FLAG([-fprofile-instr-generate], [
 256      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 257    ])
 258    AC_C_FLAG([-fcoverage-mapping], [
 259      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 260    ])
 261 fi
 262
 263 if test "$enable_dev_build" = "yes"; then
 264    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 265    if test "$orig_cflags" = ""; then
 266       AC_C_FLAG([-g3])
 267       AC_C_FLAG([-O0])
 268    fi
 269    if test "$enable_lua" = "yes"; then
 270       AX_PROG_LUA([5.3])
 271       AX_LUA_HEADERS
 272       AX_LUA_LIBS([
 273          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 274          LIBS="$LIBS $LUA_LIB"
 275       ])
 276    fi
 277 else
 278    if test "$enable_lua" = "yes"; then
 279       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 280    fi
 281    if test "$orig_cflags" = ""; then
 282       AC_C_FLAG([-g])
 283       AC_C_FLAG([-O2])
 284    fi
 285 fi
 286 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 287
 288 dnl always want these CFLAGS
 289 AC_C_FLAG([-fno-omit-frame-pointer])
 290 AC_C_FLAG([-funwind-tables])
 291 AC_C_FLAG([-Wall])
 292 AC_C_FLAG([-Wextra])
 293 AC_C_FLAG([-Wmissing-prototypes])
 294 AC_C_FLAG([-Wmissing-declarations])
 295 AC_C_FLAG([-Wpointer-arith])
 296 AC_C_FLAG([-Wbad-function-cast])
 297 AC_C_FLAG([-Wwrite-strings])
 298 AC_C_FLAG([-Wundef])
 299 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 300   AC_C_FLAG([-Wcast-qual])
 301   AC_C_FLAG([-Wstrict-prototypes])
 302   AC_C_FLAG([-Wmissing-noreturn])
 303   AC_C_FLAG([-Wmissing-format-attribute])
 304   AC_C_FLAG([-Wunreachable-code])
 305   AC_C_FLAG([-Wpacked])
 306   AC_C_FLAG([-Wpadded])
 307   AC_C_FLAG([-Wshadow])
 308 else
 309   AC_C_FLAG([-Wno-unused-result])
 310 fi
 311 AC_C_FLAG([-Wno-unused-parameter])
 312 AC_C_FLAG([-Wno-missing-field-initializers])
 313
 314 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 315 AC_SUBST([CXX_COMPAT_CFLAGS])
 316
 317 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 318 dnl for some reason the string consts get 'promoted' to char *,
 319 dnl triggering a const to non-const conversion warning.
 320 AC_C_FLAG([-diag-disable 3179])
 321
 322 if test "$enable_werror" = "yes" ; then
 323   WERROR="-Werror"
 324 fi
 325 AC_SUBST([WERROR])
 326
 327 SAN_FLAGS=""
 328 if test "$enable_address_sanitizer" = "yes"; then
 329   AC_C_FLAG([-fsanitize=address], [
 330     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 331   ], [
 332     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 333   ])
 334 fi
 335 if test "$enable_thread_sanitizer" = "yes"; then
 336   AC_C_FLAG([-fsanitize=thread], [
 337     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 338   ], [
 339     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 340   ])
 341 fi
 342 if test "$enable_memory_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 344     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 347   ])
 348 fi
 349 if test "$enable_undefined_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=undefined], [
 351     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 354   ])
 355 fi
 356 AC_SUBST([SAN_FLAGS])
 357
 358 dnl frr-format.so
 359 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 360   AC_C_FLAG([-fplugin=${with_frr_format}], [
 361     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 362   ],,[
 363 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 364 #error plugin not loaded
 365 #endif
 366 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 367 #error plugin too old
 368 #endif
 369   ])
 370 elif test "$with_frr_format" = "no"; then
 371   : #nothing
 372 else
 373   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 374     AC_C_FLAG([-fplugin=frr-format],[
 375       if test "$with_frr_format" = "yes"; then
 376         AC_MSG_ERROR([frr-format plugin requested but not found])
 377       fi
 378     ],,[
 379 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 380 #error plugin not loaded
 381 #endif
 382 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 383 #error plugin too old
 384 #endif
 385     ])
 386   ],,[
 387 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 388 #error plugin not loaded
 389 #endif
 390 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 391 #error plugin too old
 392 #endif
 393   ])
 394 fi
 395
 396 dnl ----------
 397 dnl Essentials
 398 dnl ----------
 399
 400 AX_PTHREAD([
 401   CC="$PTHREAD_CC"
 402   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 403   LIBS="$PTHREAD_LIBS $LIBS"
 404 ], [
 405   AC_MSG_FAILURE([This FRR version needs pthreads])
 406 ])
 407
 408 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 409                 [frr_cv_pthread_condattr_setclock=yes],
 410                 [frr_cv_pthread_condattr_setclock=no])
 411 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 412   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 413 fi
 414
 415 dnl --------------
 416 dnl Check programs
 417 dnl --------------
 418 AC_PROG_INSTALL
 419 AC_PROG_LN_S
 420 AC_CHECK_TOOL([AR], [ar])
 421
 422 dnl -------
 423 dnl libtool
 424 dnl -------
 425 AC_ARG_ENABLE([static-bin],
 426   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 427 LT_INIT
 428 _LT_CONFIG_LIBTOOL([
 429   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 430     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 431   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 432   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 433   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 434 ])
 435 if test "$enable_static_bin" = "yes"; then
 436   AC_LDFLAGS="-static"
 437   if test "$enable_static" != "yes"; then
 438     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 439   fi
 440 fi
 441 if test "$enable_shared" != "yes"; then
 442   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 443 fi
 444 AC_SUBST([AC_LDFLAGS])
 445 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 446
 447 dnl $AR and $RANLIB are set by LT_INIT above
 448 AC_MSG_CHECKING([whether $AR supports D option])
 449 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 450   AC_MSG_RESULT([yes])
 451   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 452   ARFLAGS="crD"
 453   AR_FLAGS="crD"
 454 else
 455   AC_MSG_RESULT([no])
 456   ARFLAGS="cru"
 457   AR_FLAGS="cru"
 458 fi
 459 AC_SUBST([ARFLAGS])
 460 AC_SUBST([AR_FLAGS])
 461
 462 AC_MSG_CHECKING([whether $RANLIB supports D option])
 463 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 464   if grep -q -- '-D' conftest.err; then
 465     AC_MSG_RESULT([no])
 466   else
 467     AC_MSG_RESULT([yes])
 468     RANLIB="$RANLIB -D"
 469   fi
 470 else
 471   AC_MSG_RESULT([no])
 472 fi
 473 AC_SUBST([RANLIB])
 474
 475 test -f conftest.err && rm conftest.err
 476 test -f conftest.a && rm conftest.a
 477
 478 dnl ----------------------
 479 dnl Packages configuration
 480 dnl ----------------------
 481 if test -f config.version; then
 482   . ./config.version
 483 elif test -f "${srcdir}/config.version"; then
 484   . "${srcdir}/config.version"
 485 fi
 486 AC_ARG_WITH([pkg-extra-version],
 487   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 488   if test "$withval" = "no"; then
 489     EXTRAVERSION=
 490   else
 491     EXTRAVERSION=$withval
 492   fi
 493 ], [])
 494 AC_ARG_WITH([pkg-git-version],
 495         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 496         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 497 AC_ARG_WITH([clippy],
 498   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 499 AC_ARG_WITH([vtysh_pager],
 500         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 501         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 502 AC_ARG_ENABLE([vtysh],
 503   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 504 AC_ARG_ENABLE([doc],
 505   AS_HELP_STRING([--disable-doc], [do not build docs]))
 506 AC_ARG_ENABLE([doc-html],
 507   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 508 AC_ARG_ENABLE([zebra],
 509   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 510 AC_ARG_ENABLE([bgpd],
 511   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 512 AC_ARG_ENABLE([ripd],
 513   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 514 AC_ARG_ENABLE([ripngd],
 515   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 516 AC_ARG_ENABLE([ospfd],
 517   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 518 AC_ARG_ENABLE([ospf6d],
 519   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 520 AC_ARG_ENABLE([ldpd],
 521   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 522 AC_ARG_ENABLE([nhrpd],
 523   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 524 AC_ARG_ENABLE([eigrpd],
 525   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 526 AC_ARG_ENABLE([babeld],
 527   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 528 AC_ARG_ENABLE([watchfrr],
 529   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 530 AC_ARG_ENABLE([isisd],
 531   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 532 AC_ARG_ENABLE([pimd],
 533   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 534 AC_ARG_ENABLE([pbrd],
 535   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 536 AC_ARG_ENABLE([sharpd],
 537   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 538 AC_ARG_ENABLE([staticd],
 539   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 540 AC_ARG_ENABLE([fabricd],
 541   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 542 AC_ARG_ENABLE([vrrpd],
 543   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 544 AC_ARG_ENABLE([bgp-announce],
 545   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 546 AC_ARG_ENABLE([bgp-vnc],
 547   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 548 AC_ARG_ENABLE([bgp-bmp],
 549   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 550 AC_ARG_ENABLE([snmp],
 551   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 552 AC_ARG_ENABLE([config_rollbacks],
 553   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 554 AC_ARG_ENABLE([confd],
 555   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 556 AC_ARG_ENABLE([sysrepo],
 557   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 558 AC_ARG_ENABLE([grpc],
 559   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 560 AC_ARG_ENABLE([zeromq],
 561   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 562 AC_ARG_WITH([libpam],
 563   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 564 AC_ARG_ENABLE([ospfapi],
 565   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 566 AC_ARG_ENABLE([ospfclient],
 567   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 568                           (this is the default if --disable-ospfapi is set)]))
 569 AC_ARG_ENABLE([multipath],
 570   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 571 AC_ARG_ENABLE([user],
 572   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 573 AC_ARG_ENABLE([group],
 574   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 575 AC_ARG_ENABLE([vty_group],
 576   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 577 AC_ARG_ENABLE([configfile_mask],
 578   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 579 AC_ARG_ENABLE([logfile_mask],
 580   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 581 AC_ARG_ENABLE([shell_access],
 582   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 583 AC_ARG_ENABLE([realms],
 584   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 585 AC_ARG_ENABLE([rtadv],
 586   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 587 AC_ARG_ENABLE([irdp],
 588   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 589 AC_ARG_ENABLE([capabilities],
 590   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 591 AC_ARG_ENABLE([rusage],
 592   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 593 AC_ARG_ENABLE([gcc_ultra_verbose],
 594   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 595 AC_ARG_ENABLE([backtrace],
 596   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 597 AC_ARG_ENABLE([time-check],
 598   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 599 AC_ARG_ENABLE([cpu-time],
 600   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 601 AC_ARG_ENABLE([pcreposix],
 602   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 603 AC_ARG_ENABLE([fpm],
 604   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 605 AC_ARG_ENABLE([systemd],
 606   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 607 AC_ARG_ENABLE([werror],
 608   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 609 AC_ARG_ENABLE([cumulus],
 610   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 611 AC_ARG_ENABLE([datacenter],
 612   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 613 AC_ARG_ENABLE([fuzzing],
 614   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 615 AC_ARG_ENABLE([netlink_fuzzing],
 616   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 617 AC_ARG_ENABLE([rr-semantics],
 618   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 619 AC_ARG_ENABLE([protobuf],
 620   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 621 AC_ARG_ENABLE([oldvpn_commands],
 622   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 623 AC_ARG_ENABLE([rpki],
 624   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 625 AC_ARG_ENABLE([clippy-only],
 626   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 627 AC_ARG_ENABLE([numeric_version],
 628   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 629 AC_ARG_ENABLE([gcov],
 630   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 631 AC_ARG_ENABLE([clang_coverage],
 632   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 633 AC_ARG_ENABLE([bfdd],
 634   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 635 AC_ARG_ENABLE([address-sanitizer],
 636   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 637 AC_ARG_ENABLE([thread-sanitizer],
 638   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 639 AC_ARG_ENABLE([memory-sanitizer],
 640   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 641 AC_ARG_ENABLE([undefined-sanitizer],
 642   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 643 AC_ARG_WITH([crypto],
 644   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 645 AC_ARG_WITH([frr-format],
 646   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 647
 648 AC_ARG_ENABLE([version-build-config],
 649   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 650
 651 #if openssl, else use the internal
 652 AS_IF([test "$with_crypto" = "openssl"], [
 653 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 654 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 655   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 656 else
 657   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 658 fi
 659 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 660 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 661 )
 662
 663 AS_IF([test "$enable_clippy_only" != "yes"], [
 664 AC_CHECK_HEADERS([json-c/json.h])
 665 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 666 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 667   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 668   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 669       AC_MSG_ERROR([libjson is needed to compile])
 670   fi
 671 fi
 672 ])
 673
 674 AC_ARG_ENABLE([dev_build],
 675     AS_HELP_STRING([--enable-dev-build], [build for development]))
 676
 677 AC_ARG_ENABLE([lua],
 678     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 679
 680 if test "$enable_time_check" != "no" ; then
 681   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 682     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 683   else
 684     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 685   fi
 686 fi
 687
 688 case "${enable_cpu_time}" in
 689   "no")
 690   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 691   ;;
 692   "*")
 693   ;;
 694 esac
 695
 696 case "${enable_systemd}" in
 697   "no") ;;
 698   "yes")
 699   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 700   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 701     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 702   else
 703     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 704   fi
 705   ;;
 706   "*") ;;
 707 esac
 708
 709 if test "$enable_rr_semantics" != "no" ; then
 710   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 711 fi
 712
 713 if test "$enable_datacenter" = "yes" ; then
 714   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 715   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 716   DFLT_NAME="datacenter"
 717 else
 718   DFLT_NAME="traditional"
 719 fi
 720
 721 if test "$enable_fuzzing" = "yes" ; then
 722   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 723 fi
 724
 725 if test "$enable_netlink_fuzzing" = "yes" ; then
 726   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 727 fi
 728
 729 if test "$enable_cumulus" = "yes" ; then
 730   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 731 fi
 732
 733 AC_SUBST([DFLT_NAME])
 734 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 735
 736 if test "$enable_shell_access" = "yes"; then
 737    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 738 fi
 739
 740 #
 741 # Python for clippy
 742 #
 743
 744 AS_IF([test "$host" = "$build"], [
 745   FRR_PYTHON_DEV
 746 ], [
 747   FRR_PYTHON
 748 ])
 749
 750 FRR_PYTHON_MODULES([pytest])
 751
 752 if test "$enable_doc" != "no"; then
 753   FRR_PYTHON_MODULES([sphinx], , [
 754     if test "$enable_doc" = "yes"; then
 755       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 756     fi
 757   ])
 758 fi
 759 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 760 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 761
 762 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 763   PYSPHINX="-m sphinx"
 764 ], [
 765   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 766 ])
 767 AC_SUBST([PYSPHINX])
 768
 769 #
 770 # Logic for old vpn commands support.
 771 #
 772 if test "$enable_oldvpn_commands" = "yes"; then
 773    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 774 fi
 775
 776 #
 777 # End of logic for protobuf support.
 778 #
 779
 780 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 781 if test "$enable_rtadv" != "no"; then
 782   AC_MSG_RESULT([yes])
 783   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 784 else
 785   AC_MSG_RESULT([no])
 786 fi
 787
 788 if test "$enable_user" = "no"; then
 789   enable_user=""
 790 else
 791   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 792     enable_user="frr"
 793   fi
 794   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 795 fi
 796
 797 if test "$enable_group" = "no"; then
 798   enable_group=""
 799 else
 800   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 801     enable_group="frr"
 802   fi
 803   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 804 fi
 805
 806 if test "$enable_vty_group" = "yes" ; then
 807   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 808 elif test "$enable_vty_group" != ""; then
 809   if test "$enable_vty_group" != "no"; then
 810     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 811   fi
 812 fi
 813 AC_SUBST([enable_user])
 814 AC_SUBST([enable_group])
 815 AC_SUBST([enable_vty_group])
 816
 817 enable_configfile_mask=${enable_configfile_mask:-0600}
 818 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 819 AC_SUBST([enable_configfile_mask])
 820
 821 enable_logfile_mask=${enable_logfile_mask:-0600}
 822 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 823
 824 MPATH_NUM=16
 825
 826 case "${enable_multipath}" in
 827   0)
 828     MPATH_NUM=64
 829     ;;
 830   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 831     MPATH_NUM="${enable_multipath}"
 832     ;;
 833   "")
 834     ;;
 835   *)
 836     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 837     ;;
 838 esac
 839
 840 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 841
 842 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 843
 844 dnl --------------------
 845 dnl Enable code coverage
 846 dnl --------------------
 847 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 848
 849 dnl ------------------------------------
 850 dnl Alpine only accepts numeric versions
 851 dnl ------------------------------------
 852 if test "$enable_numeric_version" != "" ; then
 853   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 854   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 855 fi
 856
 857 dnl -----------------------------------
 858 dnl Add extra version string to package
 859 dnl name, string and version fields.
 860 dnl -----------------------------------
 861 if test "$EXTRAVERSION" != "" ; then
 862   VERSION="${VERSION}${EXTRAVERSION}"
 863   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 864   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 865   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 866 fi
 867 AC_SUBST([EXTRAVERSION])
 868
 869 if test "$with_pkg_git_version" = "yes"; then
 870         if test -e "${srcdir}/.git"; then
 871                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 872         else    with_pkg_git_version="no"
 873                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 874         fi
 875 fi
 876 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 877
 878 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 879 if test "$OBJCOPY" != ":"; then
 880   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 881     frr_cv_interp=""
 882     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 883       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 884         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 885       fi
 886       test -f conftest.interp && rm conftest.interp
 887     ])
 888   ])
 889 fi
 890 if test -n "$frr_cv_interp"; then
 891   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 892 fi
 893
 894 dnl -------------------------
 895 dnl Check other header files.
 896 dnl -------------------------
 897 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 898         linux/version.h asm/types.h])
 899
 900 ac_stdatomic_ok=false
 901 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 902 AC_CHECK_HEADER([stdatomic.h],[
 903
 904   AC_MSG_CHECKING([whether _Atomic qualifier works])
 905   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 906 #include <stdatomic.h>
 907 int main(int argc, char **argv) {
 908   _Atomic int i = 0;
 909   return i;
 910 }
 911 ]])], [
 912     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 913     AC_MSG_RESULT([yes])
 914     ac_stdatomic_ok=true
 915   ], [
 916     AC_MSG_RESULT([no])
 917   ])
 918 ])
 919
 920 AS_IF([$ac_stdatomic_ok], [true], [
 921   AC_MSG_CHECKING([for __atomic_* builtins])
 922   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 923 int main(int argc, char **argv) {
 924   volatile int i = 1;
 925   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 926   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 927 }
 928 ]])], [
 929     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 930     AC_MSG_RESULT([yes])
 931   ], [
 932     AC_MSG_RESULT([no])
 933
 934     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 935     AC_MSG_CHECKING([for __sync_* builtins])
 936     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 937 int main(int argc, char **argv) {
 938   volatile int i = 1;
 939   __sync_fetch_and_sub (&i, 1);
 940   return __sync_val_compare_and_swap (&i, 0, 1);
 941 }
 942 ]])], [
 943       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 944       AC_MSG_RESULT([yes])
 945
 946       AC_MSG_CHECKING([for __sync_swap builtin])
 947       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 948 int main(int argc, char **argv) {
 949   volatile int i = 1;
 950   return __sync_swap (&i, 2);
 951 }
 952 ]])], [
 953         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 954         AC_MSG_RESULT([yes])
 955       ], [
 956         AC_MSG_RESULT([no])
 957       ])
 958
 959     ], [
 960       AC_MSG_RESULT([no])
 961       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 962     ])
 963   ])
 964 ])
 965
 966 AC_CHECK_HEADERS([pthread_np.h],,, [
 967 #include <pthread.h>
 968 ])
 969 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 970
 971 needsync=true
 972
 973 AS_IF([$needsync], [
 974   dnl Linux
 975   AC_MSG_CHECKING([for Linux futex() support])
 976   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 977 #ifndef _GNU_SOURCE
 978 #define _GNU_SOURCE
 979 #endif
 980 #include <unistd.h>
 981 #include <limits.h>
 982 #include <sys/time.h>
 983 #include <sys/syscall.h>
 984 #include <linux/futex.h>
 985
 986 int main(void);
 987 ],
 988 [
 989 {
 990   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 991 }
 992 ])], [
 993     AC_MSG_RESULT([yes])
 994     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 995     needsync=false
 996   ], [
 997     AC_MSG_RESULT([no])
 998   ])
 999 ])
1000
1001 AS_IF([$needsync], [
1002   dnl FreeBSD
1003   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1004   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1005 #include <errno.h>
1006 #include <stdlib.h>
1007 #include <sys/types.h>
1008 #include <sys/umtx.h>
1009 int main(void);
1010 ],
1011 [
1012 {
1013   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1014 }
1015 ])], [
1016     AC_MSG_RESULT([yes])
1017     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1018     needsync=false
1019   ], [
1020     AC_MSG_RESULT([no])
1021   ])
1022 ])
1023
1024 AS_IF([$needsync], [
1025   dnl OpenBSD patch (not upstream at the time of writing this)
1026   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1027   AC_MSG_CHECKING([for OpenBSD futex() support])
1028   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1029 #include <sys/futex.h>
1030 int main(void);
1031 ],
1032 [
1033 {
1034   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1035 }
1036 ])], [
1037     AC_MSG_RESULT([yes])
1038     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1039     needsync=false
1040   ], [
1041     AC_MSG_RESULT([no])
1042   ])
1043 ])
1044
1045 dnl Utility macro to avoid retyping includes all the time
1046 m4_define([FRR_INCLUDES],
1047 [#ifdef SUNOS_5
1048 #define _POSIX_C_SOURCE 200809L
1049 #define __EXTENSIONS__
1050 #endif
1051 #include <stdio.h>
1052 #include <stdlib.h>
1053 #include <stddef.h>
1054 #include <sys/types.h>
1055 /* sys/conf.h depends on param.h on FBSD at least */
1056 #include <sys/param.h>
1057 /* Required for MAXSIG */
1058 #include <signal.h>
1059 #include <sys/socket.h>
1060 #ifdef __APPLE__
1061 # define __APPLE_USE_RFC_3542
1062 #endif
1063 #include <netinet/in.h>
1064 #include <sys/time.h>
1065 #include <time.h>
1066 #include <net/if.h>
1067 ])dnl
1068
1069 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1070 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1071 dnl an additional round for it.
1072
1073 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1074
1075 m4_define([FRR_INCLUDES],
1076 FRR_INCLUDES
1077 [#ifdef HAVE_NET_IF_VAR_H
1078 # include <net/if_var.h>
1079 #endif
1080 ])dnl
1081
1082 AC_CHECK_HEADERS([netinet/in_var.h \
1083         net/if_dl.h net/netopt.h \
1084         inet/nd.h netinet/ip_icmp.h \
1085         sys/sysctl.h sys/sockio.h sys/conf.h],
1086         [], [], [FRR_INCLUDES])
1087
1088 AC_CHECK_HEADERS([ucontext.h], [], [],
1089 [#ifndef __USE_GNU
1090 #define __USE_GNU
1091 #endif /* __USE_GNU */
1092 FRR_INCLUDES
1093 ])
1094
1095 m4_define([UCONTEXT_INCLUDES],
1096 [#include <ucontext.h>])dnl
1097
1098 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1099   [], [], [UCONTEXT_INCLUDES])
1100 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1101   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1102    [], [], [UCONTEXT_INCLUDES])],
1103   [], [UCONTEXT_INCLUDES])
1104 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1105   [], [], [UCONTEXT_INCLUDES])
1106
1107 m4_define([FRR_INCLUDES],
1108 FRR_INCLUDES
1109 [
1110 #include <sys/un.h>
1111 #include <netinet/in_systm.h>
1112 #ifdef HAVE_NETINET_IN_VAR_H
1113 # include <netinet/in_var.h>
1114 #endif
1115 #ifdef HAVE_NET_IF_DL_H
1116 # include <net/if_dl.h>
1117 #endif
1118 #ifdef HAVE_NET_NETOPT_H
1119 # include <net/netopt.h>
1120 #endif
1121 #include <net/route.h>
1122 #ifdef HAVE_INET_ND_H
1123 # include <inet/nd.h>
1124 #endif
1125 #include <arpa/inet.h>
1126 /* Required for IDRP */
1127 #ifdef HAVE_NETINET_IP_ICMP_H
1128 # include <netinet/ip_icmp.h>
1129 #endif
1130 ])dnl
1131
1132 dnl V6 headers are checked below, after we check for v6
1133
1134 is_linux=false
1135
1136 AC_MSG_CHECKING([which operating system interface to use])
1137 case "$host_os" in
1138   sunos* | solaris2*)
1139     AC_MSG_RESULT([Solaris])
1140
1141     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1142     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1143     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1144
1145     AC_CHECK_LIB([socket], [main])
1146     AC_CHECK_LIB([nsl], [main])
1147     AC_CHECK_LIB([umem], [main])
1148     SOLARIS="solaris"
1149     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1150     ;;
1151   linux*)
1152     AC_MSG_RESULT([Linux])
1153
1154     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1155     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1156     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1157
1158     dnl Linux has a compilation problem with mixing
1159     dnl netinet/in.h and linux/in6.h they are not
1160     dnl compatible.  There has been discussion on
1161     dnl how to fix it but no real progress on implementation
1162     dnl when they fix it, remove this
1163     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1164
1165     is_linux=true
1166     ;;
1167   openbsd*)
1168     AC_MSG_RESULT([OpenBSD])
1169
1170     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1171     AC_DEFINE([KAME], [1], [KAME IPv6])
1172     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1173     ;;
1174   *)
1175     AC_MSG_RESULT([BSD])
1176
1177     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1178     AC_DEFINE([KAME], [1], [KAME IPv6])
1179     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1180     ;;
1181 esac
1182 AM_CONDITIONAL([SOLARIS], [test "$SOLARIS" = "solaris"])
1183 AM_CONDITIONAL([LINUX], [${is_linux}])
1184
1185 AC_SYS_LARGEFILE
1186
1187 dnl ------------------------
1188 dnl Integrated REALMS option
1189 dnl ------------------------
1190 if test "$enable_realms" = "yes"; then
1191     case "$host_os" in
1192       linux*)
1193        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1194        ;;
1195       *)
1196        echo "Sorry, only Linux has REALMS support"
1197        exit 1
1198        ;;
1199     esac
1200 fi
1201
1202 dnl -------------------------------
1203 dnl Endian-ness check
1204 dnl -------------------------------
1205 AC_WORDS_BIGENDIAN
1206
1207 dnl ---------------
1208 dnl other functions
1209 dnl ---------------
1210 AC_CHECK_FUNCS([ \
1211         strlcat strlcpy \
1212         getgrouplist \
1213         openat \
1214         unlinkat \
1215         posix_fallocate \
1216         ])
1217
1218 dnl ##########################################################################
1219 dnl LARGE if block spans a lot of "configure"!
1220 if test "$enable_clippy_only" != "yes"; then
1221 dnl ##########################################################################
1222
1223 #
1224 # Logic for protobuf support.
1225 #
1226 PROTO3=false
1227 if test "$enable_protobuf" = "yes"; then
1228   # Check for protoc & protoc-c
1229
1230   # protoc is not required, it's only for a "be nice" helper target
1231   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1232
1233   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1234   if test "$PROTOC_C" = "/bin/false"; then
1235     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1236   fi
1237
1238   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1239     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1240   ])
1241
1242   PROTO3=true
1243   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1244                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1245                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1246                                             [1], [Have Protobuf version 3]),
1247                                   [PROTO3=false],
1248                                   [#include <google/protobuf-c/protobuf-c.h>])],
1249                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1250
1251   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1252 fi
1253
1254
1255 dnl ---------------------
1256 dnl Integrated VTY option
1257 dnl ---------------------
1258 case "${enable_vtysh}" in
1259 "no")
1260   VTYSH="";;
1261 *)
1262   VTYSH="vtysh";
1263   AC_DEFINE([VTYSH], [1], [VTY shell])
1264
1265   prev_libs="$LIBS"
1266   AC_CHECK_LIB([readline], [main], [
1267     LIBREADLINE="-lreadline"
1268   ], [
1269     dnl readline failed - it might be incorrectly linked and missing its
1270     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1271     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1272       LIBREADLINE="$ac_cv_search_tputs"
1273     ], [
1274       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1275     ])
1276
1277     dnl re-try with the lib we found above
1278     unset ac_cv_lib_readline_main
1279     AC_CHECK_LIB([readline], [main], [
1280       LIBREADLINE="-lreadline $LIBREADLINE"
1281     ], [
1282       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1283     ], [$LIBREADLINE])
1284   ], [])
1285   LIBS="$prev_libs"
1286
1287   AC_CHECK_HEADER([readline/history.h])
1288   if test "$ac_cv_header_readline_history_h" = "no"; then
1289     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1290   fi
1291   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1292   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1293     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1294   fi
1295   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1296   if test "$frr_cv_append_history" = "yes"; then
1297     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1298   fi
1299   ;;
1300 esac
1301 AC_SUBST([LIBREADLINE])
1302
1303 dnl ----------
1304 dnl PAM module
1305 dnl
1306 dnl FRR detects the PAM library it is built against by checking for a
1307 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1308 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1309 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1310 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1311 dnl of OpenPAM.
1312 dnl ----------
1313 if test "$with_libpam" = "yes"; then
1314   AC_CHECK_HEADER([security/pam_misc.h],
1315     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1316      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1317      pam_conv_func="misc_conv"
1318     ],
1319     [], FRR_INCLUDES)
1320   AC_CHECK_HEADER([security/openpam.h],
1321     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1322      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1323      pam_conv_func="openpam_ttyconv"
1324     ],
1325     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1326   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1327     AC_MSG_WARN([*** pam support will not be built ***])
1328     with_libpam="no"
1329   fi
1330 fi
1331
1332 if test "$with_libpam" = "yes"; then
1333 dnl took this test from proftpds configure.in and suited to our needs
1334 dnl -------------------------------------------------------------------------
1335 dnl
1336 dnl This next check looks funky due to a linker problem with some versions
1337 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1338 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1339 dnl with RedHat 6.2 and Debian 2.2 or better.
1340 AC_CHECK_LIB([pam], [pam_start],
1341   [AC_CHECK_LIB([pam], [$pam_conv_func],
1342     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1343      LIBPAM="-lpam"],
1344     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1345      LIBPAM="-lpam -lpam_misc"]
1346     )
1347   ],
1348
1349   [AC_CHECK_LIB([pam], [pam_end],
1350     [AC_CHECK_LIB([pam], [$pam_conv_func],
1351       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1352        LIBPAM="-lpam -ldl"],
1353       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1354        LIBPAM="-lpam -ldl -lpam_misc"]
1355      )
1356   ],AC_MSG_WARN([*** pam support will not be built ***]),
1357   [-ldl])
1358   ]
1359 )
1360 fi
1361 AC_SUBST([LIBPAM])
1362
1363 dnl -------------------------------
1364 dnl bgpd needs pow() and hence libm
1365 dnl -------------------------------
1366 TMPLIBS="$LIBS"
1367 LIBS=""
1368 AC_SEARCH_LIBS([pow], [m], [
1369   LIBM="$LIBS"
1370 ], [
1371   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1372 ])
1373 LIBS="$TMPLIBS"
1374 AC_SUBST([LIBM])
1375
1376 AC_CHECK_FUNCS([ppoll], [
1377   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1378 ])
1379 AC_CHECK_FUNCS([pollts], [
1380   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1381 ])
1382
1383 AC_CHECK_HEADER([asm-generic/unistd.h],
1384                 [AC_CHECK_DECL(__NR_setns,
1385                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1386                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1387                                ])
1388                  AC_CHECK_FUNCS([setns])]
1389                )
1390
1391 dnl --------------------------
1392 dnl Determine IS-IS I/O method
1393 dnl --------------------------
1394 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1395 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1396 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1397 AC_CHECK_HEADER([net/bpf.h])
1398 AC_CHECK_HEADER([sys/dlpi.h])
1399 AC_MSG_CHECKING([zebra IS-IS I/O method])
1400
1401 case "$host_os" in
1402   linux*)
1403     AC_MSG_RESULT([pfpacket])
1404     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1405     ;;
1406   solaris* | sunos*)
1407     AC_MSG_RESULT([DLPI])
1408     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1409     ;;
1410   *)
1411     if test "$ac_cv_header_net_bpf_h" = "no"; then
1412       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1413         AC_MSG_RESULT([none])
1414         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1415           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1416         fi
1417         AC_MSG_WARN([*** IS-IS support will not be built ***])
1418         enable_isisd="no"
1419         enable_fabricd="no"
1420       else
1421         AC_MSG_RESULT([DLPI])
1422       fi
1423       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1424     else
1425       AC_MSG_RESULT([BPF])
1426       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1427     fi
1428     ;;
1429 esac
1430 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1431
1432 dnl ---------------------------------------------------------------
1433 dnl figure out how to specify an interface in multicast sockets API
1434 dnl ---------------------------------------------------------------
1435 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1436
1437 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1438         #include <sys/socket.h>
1439         #include <netinet/in.h>
1440         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1441         #include <linux/types.h>
1442 ])
1443
1444 m4_define([FRR_INCLUDES],
1445 FRR_INCLUDES
1446 [#ifdef HAVE_LINUX_MROUTE_H
1447 # include <linux/mroute.h>
1448 #endif
1449 ])dnl
1450
1451 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1452         #include <sys/socket.h>
1453         #include <sys/types.h>
1454         #include <netinet/in.h>
1455         #include <net/route.h>
1456 ])
1457
1458 m4_define([FRR_INCLUDES],
1459 FRR_INCLUDES
1460 [#ifdef HAVE_NETINET_IP_MROUTE_H
1461 # include <netinet/ip_mroute.h>
1462 #endif
1463 ])dnl
1464
1465 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1466 AC_TRY_COMPILE([#include <sys/param.h>],
1467 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1468   return (0);
1469 #else
1470   #error No support for BSD struct ip_mreq hack detected
1471 #endif],[AC_MSG_RESULT([yes])
1472 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1473 AC_MSG_RESULT([no]))
1474
1475 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1476 AC_TRY_COMPILE([
1477 #include <sys/types.h>
1478 #include <netinet/in.h>
1479 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1480 ], [AC_MSG_RESULT([yes])
1481 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1482 AC_MSG_RESULT([no]))
1483
1484 dnl ---------------------------------------------------------------
1485 dnl figure out how to check link-state
1486 dnl ---------------------------------------------------------------
1487 AC_CHECK_HEADER([net/if_media.h],
1488   [m4_define([LINK_DETECT_INCLUDES],
1489     FRR_INCLUDES
1490     [#include <net/if_media.h>
1491   ])
1492   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1493     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1494     [], LINK_DETECT_INCLUDES)],
1495   [],
1496   FRR_INCLUDES)
1497
1498 dnl ---------------------------------------------------------------
1499 dnl Additional, newer way to check link-state using ifi_link_state.
1500 dnl Not available in all BSD's when ifmediareq available
1501 dnl ---------------------------------------------------------------
1502 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1503   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1504   [], FRR_INCLUDES)
1505
1506 dnl ------------------------
1507 dnl TCP_MD5SIG socket option
1508 dnl ------------------------
1509
1510 AC_CHECK_HEADER([netinet/tcp.h],
1511    [m4_define([MD5_INCLUDES],
1512       FRR_INCLUDES
1513       [#include <netinet/tcp.h>
1514     ])
1515     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1516    [],
1517    FRR_INCLUDES)
1518 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1519   AC_CHECK_HEADER([linux/tcp.h],
1520        [m4_define([MD5_INCLUDES],
1521           FRR_INCLUDES
1522           [#include <linux/tcp.h>
1523         ])
1524        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1525 fi
1526
1527 AC_SUBST([SOLARIS])
1528 AC_CHECK_LIB([crypt], [crypt], [],
1529                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1530 AC_CHECK_LIB([resolv], [res_init])
1531
1532 dnl ---------------------------
1533 dnl check system has PCRE regexp
1534 dnl ---------------------------
1535 if test "$enable_pcreposix" = "yes"; then
1536   AC_CHECK_LIB([pcreposix], [regexec], [], [
1537     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1538   ])
1539 fi
1540 AC_SUBST([HAVE_LIBPCREPOSIX])
1541
1542 dnl ##########################################################################
1543 dnl test "$enable_clippy_only" != "yes"
1544 fi
1545 dnl END OF LARGE if block
1546 dnl ##########################################################################
1547
1548 dnl ------------------
1549 dnl check C-Ares library
1550 dnl ------------------
1551 PKG_CHECK_MODULES([CARES], [libcares], [
1552   c_ares_found=true
1553 ],[
1554   c_ares_found=false
1555 ])
1556 AM_CONDITIONAL([CARES], [$c_ares_found])
1557
1558
1559 dnl ----------------------------------------------------------------------------
1560 dnl figure out if domainname is available in the utsname struct (GNU extension).
1561 dnl ----------------------------------------------------------------------------
1562 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1563
1564 dnl ------------------
1565 dnl IPv6 header checks
1566 dnl ------------------
1567 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1568         netinet6/in6_var.h netinet6/nd6.h], [], [],
1569         FRR_INCLUDES)
1570
1571 m4_define([FRR_INCLUDES],dnl
1572 FRR_INCLUDES
1573 [#ifdef HAVE_NETINET6_IN6_H
1574 #include <netinet6/in6.h>
1575 #endif
1576 #ifdef HAVE_NETINET_IN6_VAR_H
1577 #include <netinet/in6_var.h>
1578 #endif
1579 #include <netinet/icmp6.h>
1580 #ifdef HAVE_NETINET6_IN6_VAR_H
1581 # include <netinet6/in6_var.h>
1582 #endif
1583 #ifdef HAVE_NETINET6_ND6_H
1584 # include <netinet6/nd6.h>
1585 #endif
1586 ])dnl
1587
1588 dnl --------------------
1589 dnl Daemon disable check
1590 dnl --------------------
1591
1592 AS_IF([test "$enable_ldpd" != "no"], [
1593   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1594 ])
1595
1596 if test "$enable_bfdd" = "no"; then
1597   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1598   BFDD=""
1599 else
1600   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1601   BFDD="bfdd"
1602
1603   case $host_os in
1604     linux*)
1605       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1606       ;;
1607
1608     *)
1609       AC_DEFINE([BFD_BSD], [1], [bfdd])
1610       ;;
1611   esac
1612 fi
1613
1614 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1615   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1616 fi
1617
1618 NHRPD=""
1619 case "$host_os" in
1620   linux*)
1621     case "${enable_nhrpd}" in
1622       no)
1623         ;;
1624       yes)
1625         if test "$enable_clippy_only" != "yes"; then
1626         if test "$c_ares_found" != "true" ; then
1627           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1628         fi
1629         fi
1630         NHRPD="nhrpd"
1631         ;;
1632       *)
1633         if test "$c_ares_found" = "true" ; then
1634           NHRPD="nhrpd"
1635         fi
1636         ;;
1637     esac
1638     ;;
1639   *)
1640     if test "$enable_nhrpd" = "yes"; then
1641       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1642     fi
1643     ;;
1644 esac
1645
1646 if test "$enable_watchfrr" = "no";then
1647   WATCHFRR=""
1648 else
1649   WATCHFRR="watchfrr"
1650 fi
1651
1652 OSPFCLIENT=""
1653 if test "$enable_ospfapi" != "no";then
1654     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1655
1656   if test "$enable_ospfclient" != "no";then
1657       OSPFCLIENT="ospfclient"
1658   fi
1659 fi
1660
1661 if test "$enable_bgp_announce" = "no";then
1662   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1663 else
1664   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1665 fi
1666
1667 if test "$enable_bgp_vnc" != "no";then
1668   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1669 fi
1670
1671 bgpd_bmp=false
1672 case "${enable_bmp}" in
1673   no)
1674     ;;
1675   yes)
1676     if test "$c_ares_found" != "true" ; then
1677       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1678     fi
1679     bgpd_bmp=true
1680     ;;
1681   *)
1682     if test "$c_ares_found" = "true" ; then
1683       bgpd_bmp=true
1684     fi
1685     ;;
1686 esac
1687
1688 if test "$enable_version_build_config" != "no";then
1689   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1690 fi
1691
1692 dnl ##########################################################################
1693 dnl LARGE if block
1694 if test "$enable_clippy_only" != "yes"; then
1695 dnl ##########################################################################
1696
1697 dnl ------------------
1698 dnl check Net-SNMP library
1699 dnl ------------------
1700 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1701    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1702    if test "$NETSNMP_CONFIG" = "no"; then
1703       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1704    fi
1705    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1706    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1707    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1708    # among other things we avoid a GPL vs. OpenSSL license conflict here
1709    for removelib in crypto ssl sensors pci wrap; do
1710      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1711    done
1712    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1713    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1714 int main(void);
1715 ],
1716 [
1717 {
1718   return 0;
1719 }
1720 ])], [
1721      AC_MSG_RESULT([no])
1722      AC_MSG_ERROR([--enable-snmp given but not usable])])
1723    case "${enable_snmp}" in
1724      yes)
1725       SNMP_METHOD=agentx
1726       ;;
1727      agentx)
1728       SNMP_METHOD="${enable_snmp}"
1729       ;;
1730      *)
1731       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1732       ;;
1733    esac
1734    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1735    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1736 fi
1737 AC_SUBST([SNMP_LIBS])
1738 AC_SUBST([SNMP_CFLAGS])
1739
1740 dnl ---------------
1741 dnl libyang
1742 dnl ---------------
1743 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1744   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1745 ])
1746 ac_cflags_save="$CFLAGS"
1747 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1748 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1749   AC_MSG_ERROR([m4_normalize([
1750     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1751     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1752   ])
1753 ], [[#include <libyang/libyang.h>]])
1754 CFLAGS="$ac_cflags_save"
1755
1756 dnl ---------------
1757 dnl configuration rollbacks
1758 dnl ---------------
1759 SQLITE3=false
1760 if test "$enable_config_rollbacks" = "yes"; then
1761   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1762     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1763     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1764     SQLITE3=true
1765   ], [
1766     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1767   ])
1768 fi
1769
1770 dnl ---------------
1771 dnl confd
1772 dnl ---------------
1773 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1774    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1775    if test "$CONFD" = "/bin/false"; then
1776       AC_MSG_ERROR([confd was not found on your system.])]
1777    fi
1778    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1779    AC_SUBST([CONFD_CFLAGS])
1780    CONFD_LIBS="-lconfd"
1781    AC_SUBST([CONFD_LIBS])
1782    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1783 fi
1784
1785 dnl ---------------
1786 dnl sysrepo
1787 dnl ---------------
1788 if test "$enable_sysrepo" = "yes"; then
1789   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1790       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1791       SYSREPO=true],
1792       [SYSREPO=false
1793       AC_MSG_ERROR([sysrepo was not found on your system.])]
1794   )
1795 fi
1796
1797 dnl ---------------
1798 dnl gRPC
1799 dnl ---------------
1800 if test "$enable_grpc" = "yes"; then
1801   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1802     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1803     if test "$PROTOC" = "/bin/false"; then
1804       AC_MSG_FAILURE([grpc requested but protoc not found.])
1805     fi
1806
1807     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1808     GRPC=true
1809   ], [
1810     GRPC=false
1811     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1812   ])
1813 fi
1814
1815 dnl ------
1816 dnl ZeroMQ
1817 dnl ------
1818 if test "$enable_zeromq" != "no"; then
1819   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1820     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1821     ZEROMQ=true
1822   ], [
1823     if test "$enable_zeromq" = "yes"; then
1824       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1825     fi
1826   ])
1827 fi
1828
1829 dnl ------------------------------------
1830 dnl Enable RPKI and add librtr to libs
1831 dnl ------------------------------------
1832 if test "$enable_rpki" = "yes"; then
1833   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1834       [RPKI=true],
1835       [RPKI=false
1836       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1837   )
1838 fi
1839
1840 dnl ------------------------------------
1841 dnl pimd is not supported on OpenBSD and MacOS
1842 dnl ------------------------------------
1843 if test "$enable_pimd" != "no"; then
1844 AC_MSG_CHECKING([for pimd OS support])
1845 case "$host_os" in
1846   darwin*)
1847     AC_MSG_RESULT([no])
1848     enable_pimd="no"
1849     ;;
1850   openbsd*)
1851     AC_MSG_RESULT([no])
1852     enable_pimd="no"
1853     ;;
1854   *)
1855     AC_MSG_RESULT([yes])
1856     ;;
1857 esac
1858 fi
1859
1860 dnl -------------------------------------
1861 dnl VRRP is only supported on linux
1862 dnl -------------------------------------
1863 if test "$enable_vrrpd" != "no"; then
1864 AC_MSG_CHECKING([for VRRP OS support])
1865 case "$host_os" in
1866   linux*)
1867     AC_MSG_RESULT([yes])
1868     ;;
1869   *)
1870     AC_MSG_RESULT([no])
1871     enable_vrrpd="no"
1872     ;;
1873 esac
1874 fi
1875
1876 dnl ------------------------------------------
1877 dnl Check whether rtrlib was build with ssh support
1878 dnl ------------------------------------------
1879 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1880 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1881                         [[struct tr_ssh_config config;]])],
1882         [AC_MSG_RESULT([yes])
1883         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1884         AC_MSG_RESULT([no])
1885 )
1886
1887 dnl ---------------
1888 dnl dlopen & dlinfo
1889 dnl ---------------
1890 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1891   AC_MSG_ERROR([unable to find the dlopen()])
1892 ])
1893
1894 AC_CHECK_HEADERS([link.h])
1895
1896 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1897   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1898 #include <stdlib.h>
1899 #ifdef HAVE_LINK_H
1900 #include <link.h>
1901 #endif
1902 #include <dlfcn.h>
1903 ]], [[
1904   char origin[1];
1905   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1906 ]])], [
1907     frr_cv_rtld_di_origin=yes
1908   ], [
1909     frr_cv_rtld_di_origin=no
1910   ])
1911 ])
1912 if test "$frr_cv_rtld_di_origin" = "yes"; then
1913   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1914 fi
1915
1916 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1917   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1918 #include <stdlib.h>
1919 #ifdef HAVE_LINK_H
1920 #include <link.h>
1921 #endif
1922 #include <dlfcn.h>
1923 ]], [[
1924   struct link_map *lm = NULL;
1925   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1926 ]])], [
1927     frr_cv_rtld_di_linkmap=yes
1928   ], [
1929     frr_cv_rtld_di_linkmap=no
1930   ])
1931 ])
1932 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
1933   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1934 fi
1935
1936 dnl ##########################################################################
1937 dnl test "$enable_clippy_only" != "yes"
1938 fi
1939 dnl END OF LARGE if block
1940 dnl ##########################################################################
1941
1942 dnl ---------------------------
1943 dnl sockaddr and netinet checks
1944 dnl ---------------------------
1945 AC_CHECK_TYPES([
1946         struct sockaddr_dl,
1947         struct vifctl, struct mfcctl, struct sioc_sg_req,
1948         vifi_t, struct sioc_vif_req, struct igmpmsg,
1949         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1950         struct nd_opt_adv_interval,
1951         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1952         struct nd_opt_rdnss, struct nd_opt_dnssl],
1953         [], [], FRR_INCLUDES)
1954
1955 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1956         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1957         struct sockaddr_dl.sdl_len,
1958         struct if6_aliasreq.ifra_lifetime,
1959         struct nd_opt_adv_interval.nd_opt_ai_type],
1960         [], [], FRR_INCLUDES)
1961
1962 dnl ---------------------------
1963 dnl IRDP/pktinfo/icmphdr checks
1964 dnl ---------------------------
1965
1966 AC_CHECK_TYPES([struct in_pktinfo], [
1967   AC_CHECK_TYPES([struct icmphdr], [
1968     IRDP=true
1969   ], [
1970     IRDP=false
1971   ], [FRR_INCLUDES])
1972 ], [
1973   IRDP=false
1974 ], [FRR_INCLUDES])
1975
1976 case "${enable_irdp}" in
1977 yes)
1978   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1979   ;;
1980 no)
1981   IRDP=false
1982   ;;
1983 esac
1984
1985
1986 dnl -----------------------
1987 dnl checking for IP_PKTINFO
1988 dnl -----------------------
1989 AC_MSG_CHECKING([for IP_PKTINFO])
1990 AC_TRY_COMPILE([#include <netdb.h>], [
1991   int opt = IP_PKTINFO;
1992 ], [
1993   AC_MSG_RESULT([yes])
1994   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1995 ], [
1996   AC_MSG_RESULT([no])
1997 ])
1998
1999 dnl ---------------------------
2000 dnl checking for IP_RECVDSTADDR
2001 dnl ---------------------------
2002 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2003 AC_TRY_COMPILE([#include <netinet/in.h>], [
2004   int opt = IP_RECVDSTADDR;
2005 ], [
2006   AC_MSG_RESULT([yes])
2007   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2008 ], [
2009   AC_MSG_RESULT([no])
2010 ])
2011
2012 dnl ----------------------
2013 dnl checking for IP_RECVIF
2014 dnl ----------------------
2015 AC_MSG_CHECKING([for IP_RECVIF])
2016 AC_TRY_COMPILE([#include <netinet/in.h>], [
2017   int opt = IP_RECVIF;
2018 ], [
2019   AC_MSG_RESULT([yes])
2020   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2021 ], [
2022   AC_MSG_RESULT([no])
2023 ])
2024
2025 dnl ----------------------
2026 dnl checking for SO_BINDANY
2027 dnl ----------------------
2028 AC_MSG_CHECKING([for SO_BINDANY])
2029 AC_TRY_COMPILE([#include <sys/socket.h>], [
2030   int opt = SO_BINDANY;
2031 ], [
2032   AC_MSG_RESULT([yes])
2033   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2034 ], [
2035   AC_MSG_RESULT([no])
2036 ])
2037
2038 dnl ----------------------
2039 dnl checking for IP_FREEBIND
2040 dnl ----------------------
2041 AC_MSG_CHECKING([for IP_FREEBIND])
2042 AC_TRY_COMPILE([#include <netinet/in.h>], [
2043   int opt = IP_FREEBIND;
2044 ], [
2045   AC_MSG_RESULT([yes])
2046   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2047 ], [
2048   AC_MSG_RESULT([no])
2049 ])
2050
2051 dnl --------------------------------------
2052 dnl checking for be32dec existence or not
2053 dnl --------------------------------------
2054 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2055                [#include <sys/endian.h>])
2056
2057 dnl --------------------------------------
2058 dnl checking for clock_time monotonic struct and call
2059 dnl --------------------------------------
2060 AC_CHECK_DECL([CLOCK_MONOTONIC],
2061         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2062          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2063 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2064
2065 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2066   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2067 ])
2068
2069 dnl --------------------------------------
2070 dnl checking for flex and bison
2071 dnl --------------------------------------
2072
2073 AM_PROG_LEX
2074 AC_MSG_CHECKING([version of flex])
2075 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2076 frr_ac_flex_version="${frr_ac_flex_version##* }"
2077 AC_MSG_RESULT([$frr_ac_flex_version])
2078 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2079   LEX="$SHELL $missing_dir/missing flex"
2080   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2081     AC_MSG_WARN([using pregenerated flex output files])
2082   else
2083     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2084   fi
2085   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2086   AC_SUBST([LEXLIB], [''])
2087 ])
2088
2089 AC_PROG_YACC
2090 dnl thanks GNU bison for this b*llshit...
2091 AC_MSG_CHECKING([version of bison])
2092 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2093 frr_ac_bison_version="${frr_ac_bison_version##* }"
2094 frr_ac_bison_missing="false"
2095 case "x${frr_ac_bison_version}x" in
2096   x2.7*)
2097     BISON_OPENBRACE='"'
2098     BISON_CLOSEBRACE='"'
2099     BISON_VERBOSE=''
2100     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2101     ;;
2102   x2.*|x1.*)
2103     AC_MSG_RESULT([$frr_ac_bison_version])
2104     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2105     frr_ac_bison_missing="true"
2106     ;;
2107   x)
2108     AC_MSG_RESULT([none])
2109     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2110     frr_ac_bison_missing="true"
2111     ;;
2112   x3.[012][^0-9]*)
2113     BISON_OPENBRACE='{'
2114     BISON_CLOSEBRACE='}'
2115     BISON_VERBOSE='-Dparse.error=verbose'
2116     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2117     ;;
2118   *)
2119     BISON_OPENBRACE='{'
2120     BISON_CLOSEBRACE='}'
2121     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2122     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2123     ;;
2124 esac
2125 AC_SUBST([BISON_OPENBRACE])
2126 AC_SUBST([BISON_CLOSEBRACE])
2127 AC_SUBST([BISON_VERBOSE])
2128
2129 if $frr_ac_bison_missing; then
2130   YACC="$SHELL $missing_dir/missing bison -y"
2131   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2132     AC_MSG_WARN([using pregenerated bison output files])
2133   else
2134     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2135   fi
2136 fi
2137
2138 dnl -------------------
2139 dnl capabilities checks
2140 dnl -------------------
2141 if test "$enable_capabilities" != "no"; then
2142   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2143   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2144     [AC_MSG_RESULT([yes])
2145      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2146      frr_ac_keepcaps="yes"],
2147      AC_MSG_RESULT([no])
2148   )
2149   if test "$frr_ac_keepcaps" = "yes"; then
2150     AC_CHECK_HEADERS([sys/capability.h])
2151   fi
2152   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2153     AC_CHECK_LIB([cap], [cap_init],
2154       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2155        LIBCAP="-lcap"
2156        frr_ac_lcaps="yes"]
2157     )
2158   else
2159     AC_CHECK_HEADERS([priv.h],
2160      [AC_MSG_CHECKING([Solaris style privileges are available])
2161       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2162           [AC_MSG_RESULT([yes])
2163            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2164            frr_ac_scaps="yes"],
2165            AC_MSG_RESULT(no)
2166       )
2167      ]
2168    )
2169   fi
2170   if test "$frr_ac_scaps" = "yes" \
2171        -o "$frr_ac_lcaps" = "yes"; then
2172     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2173   fi
2174
2175   case "$host_os" in
2176   linux*)
2177     if test "$enable_clippy_only" != "yes"; then
2178     if test "$frr_ac_lcaps" != "yes"; then
2179       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2180     fi
2181     fi
2182     ;;
2183   esac
2184 else
2185   case "$host_os" in
2186   linux*)
2187     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2188     ;;
2189   esac
2190 fi
2191 AC_SUBST([LIBCAP])
2192
2193 dnl ---------------------------
2194 dnl check for glibc 'backtrace'
2195 dnl ---------------------------
2196 if test "$enable_backtrace" != "no" ; then
2197   backtrace_ok=no
2198   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2199     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2200     backtrace_ok=yes
2201   ], [
2202     true
2203   ])
2204
2205   if test "$backtrace_ok" = "no"; then
2206     AC_CHECK_HEADER([unwind.h], [
2207       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2208         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2209         backtrace_ok=yes
2210       ])
2211     ])
2212   fi
2213
2214   if test "$backtrace_ok" = "no"; then
2215     AC_CHECK_HEADER([execinfo.h], [
2216       AC_SEARCH_LIBS([backtrace], [execinfo], [
2217         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2218         backtrace_ok=yes
2219       ],, [-lm])
2220     ])
2221   fi
2222
2223   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2224     dnl user explicitly requested backtrace but we failed to find support
2225     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2226   fi
2227 fi
2228
2229 dnl -----------------------------------------
2230 dnl check for malloc mallinfo struct and call
2231 dnl this must try and link using LIBS, in
2232 dnl order to check no alternative allocator
2233 dnl has been specified, which might not provide
2234 dnl mallinfo, e.g. such as Umem on Solaris.
2235 dnl -----------------------------------------
2236 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2237
2238 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2239   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2240 #ifdef HAVE_MALLOC_H
2241 #include <malloc.h>
2242 #endif
2243 #ifdef HAVE_MALLOC_NP_H
2244 #include <malloc_np.h>
2245 #endif
2246 #ifdef HAVE_MALLOC_MALLOC_H
2247 #include <malloc/malloc.h>
2248 #endif
2249 ]], [[
2250 struct mallinfo ac_x; ac_x = mallinfo ();
2251 ]])], [
2252     frr_cv_mallinfo=yes
2253   ], [
2254     frr_cv_mallinfo=no
2255   ])
2256 ])
2257 if test "$frr_cv_mallinfo" = "yes"; then
2258   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2259 fi
2260
2261 AC_MSG_CHECKING([whether malloc_usable_size is available])
2262 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2263 #ifdef HAVE_MALLOC_H
2264 #include <malloc.h>
2265 #endif
2266 #ifdef HAVE_MALLOC_MALLOC_H
2267 #include <malloc/malloc.h>
2268 #endif
2269 ]], [[
2270 size_t ac_x; ac_x = malloc_usable_size(NULL);
2271 ]])], [
2272   AC_MSG_RESULT([yes])
2273   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2274 ], [
2275   AC_MSG_RESULT([no])
2276
2277   AC_MSG_CHECKING([whether malloc_size is available])
2278   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2279 #ifdef HAVE_MALLOC_H
2280 #include <malloc.h>
2281 #endif
2282 #ifdef HAVE_MALLOC_MALLOC_H
2283 #include <malloc/malloc.h>
2284 #endif
2285 ]], [[
2286 size_t ac_x; ac_x = malloc_size(NULL);
2287 ]])], [
2288     AC_MSG_RESULT([yes])
2289     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2290   ], [
2291     AC_MSG_RESULT([no])
2292   ])
2293 ])
2294
2295 dnl ----------
2296 dnl configure date
2297 dnl ----------
2298 dev_version=`echo $VERSION | grep dev`
2299 #don't expire deprecated code in non 'dev' branch
2300 if test "$dev_version" = ""; then
2301    CONFDATE=0
2302 else
2303    CONFDATE=`date '+%Y%m%d'`
2304 fi
2305 AC_SUBST([CONFDATE])
2306
2307 dnl ------------------------------
2308 dnl set paths for state directory
2309 dnl ------------------------------
2310 AC_MSG_CHECKING([directory to use for state file])
2311 if test "$prefix" = "NONE"; then
2312   frr_statedir_prefix="";
2313 else
2314   frr_statedir_prefix=${prefix}
2315 fi
2316 if test "$localstatedir" = '${prefix}/var'; then
2317   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2318                         ${frr_statedir_prefix}/var/adm dnl
2319                         ${frr_statedir_prefix}/etc dnl
2320                         /var/run        dnl
2321                         /var/adm        dnl
2322                         /etc            dnl
2323                         /dev/null;
2324   do
2325     test -d $FRR_STATE_DIR && break
2326   done
2327   frr_statedir=$FRR_STATE_DIR
2328 else
2329   frr_statedir=${localstatedir}
2330 fi
2331 if test "$frr_statedir" = "/dev/null"; then
2332     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2333 fi
2334 AC_MSG_RESULT([${frr_statedir}])
2335 AC_SUBST([frr_statedir])
2336
2337 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2338 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2339 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2340 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2341 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2342
2343 dnl autoconf does this, but it does it too late...
2344 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2345 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2346
2347 dnl get the full path, recursing through variables...
2348 vtysh_bin="$bindir/vtysh"
2349 for I in 1 2 3 4 5 6 7 8 9 10; do
2350         eval vtysh_bin="\"$vtysh_bin\""
2351 done
2352 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2353 AC_SUBST([vtysh_bin])
2354
2355 CFG_SYSCONF="$sysconfdir"
2356 CFG_SBIN="$sbindir"
2357 CFG_STATE="$frr_statedir"
2358 CFG_MODULE="$moduledir"
2359 CFG_YANGMODELS="$yangmodelsdir"
2360 for I in 1 2 3 4 5 6 7 8 9 10; do
2361         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2362         eval CFG_SBIN="\"$CFG_SBIN\""
2363         eval CFG_STATE="\"$CFG_STATE\""
2364         eval CFG_MODULE="\"$CFG_MODULE\""
2365         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2366 done
2367 AC_SUBST([CFG_SYSCONF])
2368 AC_SUBST([CFG_SBIN])
2369 AC_SUBST([CFG_STATE])
2370 AC_SUBST([CFG_MODULE])
2371 AC_SUBST([CFG_YANGMODELS])
2372 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2373 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2374 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2375
2376 dnl various features
2377 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2378 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2379 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2380 dnl northbound
2381 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2382 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2383 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2384 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2385 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2386 dnl plugins
2387 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2388 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2389 AM_CONDITIONAL([IRDP], [$IRDP])
2390 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2391 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2392 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2393 dnl daemons
2394 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2395 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2396 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2397 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2398 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2399 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2400 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2401 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2402 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2403 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2404 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2405 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2406 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2407 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2408 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2409 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2410 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2411 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2412 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2413 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2414 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2415
2416 AC_CONFIG_FILES([Makefile],[
2417         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2418         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2419 ], [
2420         PYTHON="$PYTHON"
2421         enable_dev_build="$enable_dev_build"
2422 ])
2423
2424 AC_CONFIG_FILES([
2425           config.version
2426           changelog-auto
2427           redhat/frr.spec
2428           solaris/Makefile
2429           alpine/APKBUILD
2430           snapcraft/snapcraft.yaml
2431           lib/version.h
2432           tests/lib/cli/test_cli.refout
2433           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2434           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2435           pkgsrc/eigrpd.sh])
2436
2437 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2438 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2439 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2440 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2441 AC_CONFIG_FILES([tools/frrcommon.sh])
2442
2443 AC_CONFIG_COMMANDS([lib/route_types.h], [
2444         dst="${ac_abs_top_builddir}/lib/route_types.h"
2445         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2446                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2447                 > "${dst}.tmp"
2448         test -f "$dst" \
2449                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2450                 && rm "${dst}.tmp" \
2451                 || mv "${dst}.tmp" "${dst}"
2452 ], [
2453         PERL="$PERL"
2454 ])
2455
2456 AS_IF([test "$with_pkg_git_version" = "yes"], [
2457     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2458         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2459         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2460                 "${ac_abs_top_srcdir}" \
2461                 > "${dst}.tmp"
2462         test -f "$dst" \
2463                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2464                 && rm "${dst}.tmp" \
2465                 || mv "${dst}.tmp" "${dst}"
2466     ], [
2467         PERL="$PERL"
2468     ])
2469 ])
2470
2471 ## Hack, but working solution to avoid rebuilding of frr.info.
2472 ## It's already in CVS until texinfo 4.7 is more common.
2473 AC_OUTPUT
2474
2475 echo "
2476 FRRouting configuration
2477 ------------------------------
2478 FRR version             : ${PACKAGE_VERSION}
2479 host operating system   : ${host_os}
2480 source code location    : ${srcdir}
2481 compiler                : ${CC}
2482 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2483 make                    : ${MAKE-make}
2484 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2485 state file directory    : ${frr_statedir}
2486 config file directory   : `eval echo \`echo ${sysconfdir}\``
2487 example directory       : `eval echo \`echo ${exampledir}\``
2488 module directory        : ${CFG_MODULE}
2489 user to run as          : ${enable_user}
2490 group to run as         : ${enable_group}
2491 group for vty sockets   : ${enable_vty_group}
2492 config file mask        : ${enable_configfile_mask}
2493 log file mask           : ${enable_logfile_mask}
2494 zebra protobuf enabled  : ${enable_protobuf:-no}
2495
2496 The above user and group must have read/write access to the state file
2497 directory and to the config files in the config file directory."
2498
2499 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2500   AC_MSG_WARN([sphinx is missing but required to build documentation])
2501 fi
2502 if test "$frr_py_mod_pytest" = "false"; then
2503   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2504 fi