configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 yangmodelsdir="\${datarootdir}/yang"
  95 AC_SUBST([yangmodelsdir], [$yangmodelsdir])
  96
  97 libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
  98 AC_SUBST(libyang_pluginsdir)
  99
 100 AC_ARG_ENABLE(tcmalloc,
 101         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 102 [case "${enableval}" in
 103   yes) tcmalloc_enabled=true
 104 LIBS="$LIBS -ltcmalloc_minimal"
 105  ;;
 106   no)  tcmalloc_enabled=false ;;
 107   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 108 esac],[tcmalloc_enabled=false])
 109
 110
 111 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 112 dnl flag determination logic.
 113 CFLAGS="${CFLAGS:-}"
 114
 115 dnl --------------------
 116 dnl Check CC and friends
 117 dnl --------------------
 118 dnl note orig_cflags is also used further down
 119 orig_cflags="$CFLAGS"
 120 AC_LANG([C])
 121 AC_PROG_CC
 122 AC_PROG_CPP
 123 AM_PROG_CC_C_O
 124 dnl remove autoconf default "-g -O2"
 125 CFLAGS="$orig_cflags"
 126 AC_PROG_CC_C99
 127 dnl NB: see C11 below
 128
 129 AC_PROG_EGREP
 130 PKG_PROG_PKG_CONFIG
 131
 132 dnl autoconf 2.59 appears not to support AC_PROG_SED
 133 dnl AC_PROG_SED
 134 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 135
 136 dnl try and enable CFLAGS that are useful for FRR
 137 dnl - specifically, options to control warnings
 138
 139 AC_USE_SYSTEM_EXTENSIONS
 140 AC_DEFUN([AC_C_FLAG], [{
 141     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 142     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 143         AC_LANG_PUSH(C)
 144         ac_c_flag_save="$CFLAGS"
 145         CFLAGS="$CFLAGS $1"
 146         AC_COMPILE_IFELSE(
 147                 [AC_LANG_PROGRAM([[]])],
 148                 [
 149                         cachename=yes
 150                 ], [
 151                         cachename=no
 152                 ])
 153         CFLAGS="$ac_c_flag_save"
 154         AC_LANG_POP(C)
 155     ])
 156     if test "${cachename}" = yes; then
 157         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 158     else
 159         :
 160         $2
 161     fi
 162     m4_popdef([cachename])
 163 }])
 164
 165 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 166         AC_LANG_PUSH(C)
 167         ac_cflags_save="$CFLAGS"
 168         ac_libs_save="$LIBS"
 169         CFLAGS="$CFLAGS $1"
 170         LIBS="$LIBS $2"
 171         AC_LINK_IFELSE(
 172                 [$3],
 173                 [
 174                         AC_MSG_RESULT([yes])
 175                         CFLAGS="$ac_cflags_save"
 176                         LIBS="$ac_libs_save"
 177                         $5
 178                 ], [
 179                         AC_MSG_RESULT([no])
 180                         CFLAGS="$ac_cflags_save"
 181                         LIBS="$ac_libs_save"
 182                         $4
 183                 ])
 184         AC_LANG_POP(C)
 185         }])
 186
 187 dnl ICC won't bail on unknown options without -diag-error 10006
 188 dnl need to do this first so we get useful results for the other options
 189 AC_C_FLAG([-diag-error 10006])
 190
 191 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 192 ac_cc="$CC"
 193 CC="${CC% -std=gnu99}"
 194 CC="${CC% -std=c99}"
 195
 196 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 197
 198 dnl if the user has specified any CFLAGS, override our settings
 199 if test "x${enable_gcov}" = "xyes"; then
 200    if test "z$orig_cflags" = "z"; then
 201       AC_C_FLAG([-coverage])
 202       AC_C_FLAG([-O0])
 203    fi
 204
 205    LDFLAGS="${LDFLAGS} -lgcov"
 206 elif test "x${enable_dev_build}" = "xyes"; then
 207    AC_DEFINE(DEV_BUILD,,Build for development)
 208    if test "z$orig_cflags" = "z"; then
 209       AC_C_FLAG([-g3])
 210       AC_C_FLAG([-O0])
 211    fi
 212    if test "x${enable_lua}" = "xyes"; then
 213       AC_CHECK_LIB([lua], [lua_newstate],
 214       [LIBS="$LIBS -llua"])
 215       AC_DEFINE(HAVE_LUA,,Lua enabled for development)
 216    fi
 217 else
 218    if test "x${enable_lua}" = "xyes"; then
 219       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 220    fi
 221    if test "z$orig_cflags" = "z"; then
 222       AC_C_FLAG([-g])
 223       AC_C_FLAG([-Os], [
 224         AC_C_FLAG([-O2])
 225       ])
 226    fi
 227 fi
 228 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 229
 230 dnl always want these CFLAGS
 231 AC_C_FLAG([-fno-omit-frame-pointer])
 232 AC_C_FLAG([-funwind-tables])
 233 AC_C_FLAG([-Wall])
 234 AC_C_FLAG([-Wextra])
 235 AC_C_FLAG([-Wmissing-prototypes])
 236 AC_C_FLAG([-Wmissing-declarations])
 237 AC_C_FLAG([-Wpointer-arith])
 238 AC_C_FLAG([-Wbad-function-cast])
 239 AC_C_FLAG([-Wwrite-strings])
 240 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 241   AC_C_FLAG([-Wcast-qual])
 242   AC_C_FLAG([-Wstrict-prototypes])
 243   AC_C_FLAG([-Wmissing-noreturn])
 244   AC_C_FLAG([-Wmissing-format-attribute])
 245   AC_C_FLAG([-Wunreachable-code])
 246   AC_C_FLAG([-Wpacked])
 247   AC_C_FLAG([-Wpadded])
 248   AC_C_FLAG([-Wshadow])
 249 else
 250   AC_C_FLAG([-Wno-unused-result])
 251 fi
 252 AC_C_FLAG([-Wno-unused-parameter])
 253 AC_C_FLAG([-Wno-missing-field-initializers])
 254
 255 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 256 dnl for some reason the string consts get 'promoted' to char *,
 257 dnl triggering a const to non-const conversion warning.
 258 AC_C_FLAG([-diag-disable 3179])
 259
 260 if test x"${enable_werror}" = x"yes" ; then
 261   WERROR="-Werror"
 262 fi
 263 AC_SUBST(WERROR)
 264
 265 SAN_FLAGS=""
 266 if test "$enable_address_sanitizer" = "yes"; then
 267   AC_C_FLAG([-fsanitize=address], [
 268     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 269   ], [
 270     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 271   ])
 272 fi
 273 if test "$enable_thread_sanitizer" = "yes"; then
 274   AC_C_FLAG([-fsanitize=thread], [
 275     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 276   ], [
 277     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 278   ])
 279 fi
 280 if test "$enable_memory_sanitizer" = "yes"; then
 281   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 282     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 283   ], [
 284     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 285   ])
 286 fi
 287 AC_SUBST([SAN_FLAGS])
 288
 289 dnl ----------
 290 dnl Essentials
 291 dnl ----------
 292
 293 AX_PTHREAD([
 294   CC="$PTHREAD_CC"
 295   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 296   LIBS="$PTHREAD_LIBS $LIBS"
 297 ], [
 298   AC_MSG_FAILURE([This FRR version needs pthreads])
 299 ])
 300
 301 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 302                 [frr_cv_pthread_condattr_setclock=yes],
 303                 [frr_cv_pthread_condattr_setclock=no])
 304 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 305   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 306 fi
 307
 308 dnl --------------
 309 dnl Check programs
 310 dnl --------------
 311 AC_PROG_INSTALL
 312 AC_PROG_LN_S
 313 AC_PROG_MAKE_SET
 314 AC_CHECK_TOOL(AR, ar)
 315
 316 dnl -------
 317 dnl libtool
 318 dnl -------
 319 AC_ARG_ENABLE(static-bin,
 320   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 321 LT_INIT
 322 _LT_CONFIG_LIBTOOL([
 323   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 324     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 325 ])
 326 if test "$enable_static_bin" = "yes"; then
 327   AC_LDFLAGS="-static"
 328 fi
 329 AC_SUBST(AC_LDFLAGS)
 330 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 331
 332 dnl $AR and $RANLIB are set by LT_INIT above
 333 AC_MSG_CHECKING([whether $AR supports D option])
 334 if $AR crD conftest.a; then
 335   AC_MSG_RESULT([yes])
 336   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 337   ARFLAGS="crD"
 338   AR_FLAGS="crD"
 339 else
 340   AC_MSG_RESULT([no])
 341   ARFLAGS="cru"
 342   AR_FLAGS="cru"
 343 fi
 344 AC_SUBST(ARFLAGS)
 345 AC_SUBST(AR_FLAGS)
 346
 347 AC_MSG_CHECKING([whether $RANLIB supports D option])
 348 if $RANLIB -D conftest.a; then
 349   AC_MSG_RESULT([yes])
 350   RANLIB="$RANLIB -D"
 351 else
 352   AC_MSG_RESULT([no])
 353 fi
 354 AC_SUBST(RANLIB)
 355
 356 test -f conftest.a && rm conftest.a
 357
 358 dnl ----------------------
 359 dnl Packages configuration
 360 dnl ----------------------
 361 if test -f config.version; then
 362   . ./config.version
 363 elif test -f "${srcdir}/config.version"; then
 364   . "${srcdir}/config.version"
 365 fi
 366 AC_ARG_WITH(pkg-extra-version,
 367   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 368   if test "$withval" = "no"; then
 369     EXTRAVERSION=
 370   else
 371     EXTRAVERSION=$withval
 372   fi
 373 ], [])
 374 AC_ARG_WITH(pkg-git-version,
 375         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 376         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 377 AC_ARG_WITH(vtysh_pager,
 378         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 379         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 380 AC_ARG_ENABLE(vtysh,
 381   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 382 AC_ARG_ENABLE(doc,
 383   AS_HELP_STRING([--disable-doc], [do not build docs]))
 384 AC_ARG_ENABLE(doc-html,
 385   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 386 AC_ARG_ENABLE(zebra,
 387   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 388 AC_ARG_ENABLE(bgpd,
 389   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 390 AC_ARG_ENABLE(ripd,
 391   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 392 AC_ARG_ENABLE(ripngd,
 393   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 394 AC_ARG_ENABLE(ospfd,
 395   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 396 AC_ARG_ENABLE(ospf6d,
 397   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 398 AC_ARG_ENABLE(ldpd,
 399   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 400 AC_ARG_ENABLE(nhrpd,
 401   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 402 AC_ARG_ENABLE(eigrpd,
 403   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 404 AC_ARG_ENABLE(babeld,
 405   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 406 AC_ARG_ENABLE(watchfrr,
 407   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 408 AC_ARG_ENABLE(isisd,
 409   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 410 AC_ARG_ENABLE(pimd,
 411   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 412 AC_ARG_ENABLE(pbrd,
 413   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 414 AC_ARG_ENABLE(sharpd,
 415   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 416 AC_ARG_ENABLE(staticd,
 417   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 418 AC_ARG_ENABLE(fabricd,
 419   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 420 AC_ARG_ENABLE(bgp-announce,
 421   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 422 AC_ARG_ENABLE(bgp-vnc,
 423   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 424 AC_ARG_ENABLE(snmp,
 425   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 426 AC_ARG_ENABLE(config_rollbacks,
 427   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 428 AC_ARG_ENABLE(confd,
 429   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 430 AC_ARG_ENABLE(sysrepo,
 431   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 432 AC_ARG_ENABLE(zeromq,
 433   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 434 AC_ARG_WITH(libpam,
 435   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 436 AC_ARG_ENABLE(ospfapi,
 437   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 438 AC_ARG_ENABLE(ospfclient,
 439   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 440                           (this is the default if --disable-ospfapi is set)]))
 441 AC_ARG_ENABLE(multipath,
 442   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 443 AC_ARG_ENABLE(user,
 444   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 445 AC_ARG_ENABLE(group,
 446   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 447 AC_ARG_ENABLE(vty_group,
 448   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 449 AC_ARG_ENABLE(configfile_mask,
 450   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 451 AC_ARG_ENABLE(logfile_mask,
 452   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 453 AC_ARG_ENABLE(shell_access,
 454   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 455 AC_ARG_ENABLE(realms,
 456   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 457 AC_ARG_ENABLE(rtadv,
 458   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 459 AC_ARG_ENABLE(irdp,
 460   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 461 AC_ARG_ENABLE(capabilities,
 462   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 463 AC_ARG_ENABLE(rusage,
 464   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 465 AC_ARG_ENABLE(gcc_ultra_verbose,
 466   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 467 AC_ARG_ENABLE(backtrace,
 468   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 469 AC_ARG_ENABLE(time-check,
 470   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 471 AC_ARG_ENABLE(pcreposix,
 472   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 473 AC_ARG_ENABLE(fpm,
 474   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 475 AC_ARG_ENABLE(systemd,
 476   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 477 AC_ARG_ENABLE(werror,
 478   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 479 AC_ARG_ENABLE(cumulus,
 480   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 481 AC_ARG_ENABLE(datacenter,
 482   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 483 AC_ARG_ENABLE(fuzzing,
 484   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 485 AC_ARG_ENABLE(netlink_fuzzing,
 486   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 487 AC_ARG_ENABLE(rr-semantics,
 488   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 489 AC_ARG_ENABLE([protobuf],
 490   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 491 AC_ARG_ENABLE([oldvpn_commands],
 492   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 493 AC_ARG_ENABLE(rpki,
 494   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 495 AC_ARG_ENABLE([clippy-only],
 496   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 497 AC_ARG_ENABLE([numeric_version],
 498   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 499 AC_ARG_ENABLE([gcov],
 500   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 501 AC_ARG_ENABLE(bfdd,
 502   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 503 AC_ARG_ENABLE([address-sanitizer],
 504   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 505 AC_ARG_ENABLE([thread-sanitizer],
 506   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 507 AC_ARG_ENABLE([memory-sanitizer],
 508   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 509
 510 AS_IF([test "${enable_clippy_only}" != "yes"], [
 511 AC_CHECK_HEADERS(json-c/json.h)
 512 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 513 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 514   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 515   if test "$ac_cv_lib_json_json_object_get" = no; then
 516       AC_MSG_ERROR([lib json is needed to compile])
 517   fi
 518 fi
 519 ])
 520
 521 AC_ARG_ENABLE([dev_build],
 522     AS_HELP_STRING([--enable-dev-build], [build for development]))
 523
 524 AC_ARG_ENABLE([lua],
 525     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 526
 527 if test x"${enable_time_check}" != x"no" ; then
 528   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 529     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 530   else
 531     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 532   fi
 533 fi
 534
 535 case "${enable_systemd}" in
 536   "no") ;;
 537   "yes")
 538   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 539   if test $ac_cv_lib_systemd_sd_notify = no; then
 540     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 541   else
 542     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 543   fi
 544   ;;
 545   "*") ;;
 546 esac
 547
 548 if test "${enable_rr_semantics}" != "no" ; then
 549   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 550 fi
 551
 552 if test "${enable_datacenter}" = "yes" ; then
 553   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 554   DFLT_NAME="datacenter"
 555 else
 556   DFLT_NAME="traditional"
 557 fi
 558
 559 if test "${enable_fuzzing}" = "yes" ; then
 560   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 561 fi
 562
 563 if test "${enable_netlink_fuzzing}" = "yes" ; then
 564   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 565 fi
 566
 567 if test "${enable_cumulus}" = "yes" ; then
 568   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 569 fi
 570
 571 AC_SUBST(DFLT_NAME)
 572 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 573
 574 if test "${enable_shell_access}" = "yes"; then
 575    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 576 fi
 577
 578 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 579
 580 #
 581 # Python for clippy
 582 #
 583
 584 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 585   AC_MSG_CHECKING([whether we found a working Python version])
 586   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 587 #include <Python.h>
 588 #if PY_VERSION_HEX < 0x02070000
 589 #error python too old
 590 #endif
 591 int main(void);
 592 ],
 593 [
 594 {
 595   Py_Initialize();
 596   return 0;
 597 }
 598 ])], [
 599     # some python installs are missing the zlib dependency...
 600     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 601     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 602 #include <Python.h>
 603 #if PY_VERSION_HEX < 0x02070000
 604 #error python too old
 605 #endif
 606 int main(void);
 607 ],
 608 [
 609 {
 610   Py_Initialize();
 611   return 0;
 612 }
 613 ])], [
 614       m4_if([$1], [], [
 615         PYTHONCONFIG=""
 616         unset PYTHON_LIBS
 617         unset PYTHON_CFLAGS
 618       ], [$1])
 619     ])
 620   ])
 621 ])
 622
 623 AS_IF([test "$host" = "$build"], [
 624   PYTHONCONFIG=""
 625
 626   # ordering:
 627   # 1.  try python3, but respect the user's preference on which minor ver
 628   # 2.  try python, which might be py3 or py2 again on the user's preference
 629   # 3.  try python2 (can really only be 2.7 but eh)
 630   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 631   #
 632   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 633   # (AX_PYTHON does not do what we need)
 634
 635   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 636         python3-config \
 637         python-config \
 638         python2-config \
 639         python3.6-config \
 640         python3.5-config \
 641         python3.4-config \
 642         python3.3-config \
 643         python3.2-config \
 644         python2.7-config ])
 645   if test -n "$PYTHONCONFIG"; then
 646     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 647     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 648
 649     FRR_PYTHON_CHECK_WORKING([])
 650   fi
 651
 652   if test -z "$PYTHONCONFIG"; then
 653     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 654       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 655         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 656           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 657             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 658               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 659                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 660                 ])])])])])])
 661
 662
 663     FRR_PYTHON_CHECK_WORKING([
 664       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 665     ])
 666   fi
 667 ])
 668 AC_SUBST(PYTHON_CFLAGS)
 669 AC_SUBST(PYTHON_LIBS)
 670
 671 #
 672 # Logic for protobuf support.
 673 #
 674 if test "$enable_protobuf" = "yes"; then
 675   # Check for protoc & protoc-c
 676
 677   # protoc is not required, it's only for a "be nice" helper target
 678   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 679
 680   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 681   if test "$PROTOC_C" = "/bin/false"; then
 682     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 683   fi
 684
 685   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 686     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 687   ])
 688   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 689     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 690   ])
 691
 692   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 693 fi
 694 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 695
 696 #
 697 # Logic for old vpn commans support.
 698 #
 699 if test "$enable_oldvpn_commands" = "yes"; then
 700    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 701 fi
 702
 703 #
 704 # End of logic for protobuf support.
 705 #
 706
 707 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 708 if test "${enable_rtadv}" != "no"; then
 709   AC_MSG_RESULT(yes)
 710   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 711 else
 712   AC_MSG_RESULT(no)
 713 fi
 714
 715 if test x"${enable_user}" = x"no"; then
 716   enable_user=""
 717 else
 718   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 719     enable_user="frr"
 720   fi
 721   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 722 fi
 723
 724 if test x"${enable_group}" = x"no"; then
 725   enable_group=""
 726 else
 727   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 728     enable_group="frr"
 729   fi
 730   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 731 fi
 732
 733 if test x"${enable_vty_group}" = x"yes" ; then
 734   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 735 elif test x"${enable_vty_group}" != x""; then
 736   if test x"${enable_vty_group}" != x"no"; then
 737     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 738   fi
 739 fi
 740 AC_SUBST([enable_user])
 741 AC_SUBST([enable_group])
 742 AC_SUBST([enable_vty_group])
 743
 744 enable_configfile_mask=${enable_configfile_mask:-0600}
 745 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 746
 747 enable_logfile_mask=${enable_logfile_mask:-0600}
 748 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 749
 750 MPATH_NUM=1
 751
 752 case "${enable_multipath}" in
 753   0)
 754     MPATH_NUM=64
 755     ;;
 756   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 757     MPATH_NUM="${enable_multipath}"
 758     ;;
 759   "")
 760     ;;
 761   *)
 762     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 763     ;;
 764 esac
 765
 766 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 767
 768 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 769
 770 dnl --------------------
 771 dnl Enable code coverage
 772 dnl --------------------
 773 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 774
 775 dnl ------------------------------------
 776 dnl Alpine only accepts numeric versions
 777 dnl ------------------------------------
 778 if test "x${enable_numeric_version}" != "x" ; then
 779   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 780   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 781 fi
 782
 783 dnl -----------------------------------
 784 dnl Add extra version string to package
 785 dnl name, string and version fields.
 786 dnl -----------------------------------
 787 if test "x${EXTRAVERSION}" != "x" ; then
 788   VERSION="${VERSION}${EXTRAVERSION}"
 789   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 790   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 791   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 792 fi
 793 AC_SUBST(EXTRAVERSION)
 794
 795 if test "x$with_pkg_git_version" = "xyes"; then
 796         if test -d "${srcdir}/.git"; then
 797                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 798         else    with_pkg_git_version="no"
 799                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 800         fi
 801 fi
 802 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 803
 804 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 805 AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 806   frr_cv_interp=""
 807   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 808     if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 809       frr_cv_interp="`xargs -0 echo < conftest.interp`"
 810     fi
 811     test -f conftest.interp && rm conftest.interp
 812   ])
 813 ])
 814 if test -n "$frr_cv_interp"; then
 815   AC_DEFINE_UNQUOTED(INTERP, ["$frr_cv_interp"], [.interp value])
 816 fi
 817
 818 dnl ------------------------------------
 819 dnl Check C keywords and standard  types
 820 dnl ------------------------------------
 821 AC_C_CONST
 822 AC_C_INLINE
 823 AC_C_VOLATILE
 824 AC_HEADER_STDC
 825 dnl AC_TYPE_PID_T
 826 AC_TYPE_UID_T
 827 AC_TYPE_MODE_T
 828 AC_TYPE_SIZE_T
 829 AC_STRUCT_TM
 830
 831 dnl -------------------------
 832 dnl Check other header files.
 833 dnl -------------------------
 834 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 835         linux/version.h asm/types.h \
 836         sys/cdefs.h])
 837
 838 ac_stdatomic_ok=false
 839 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 840 AC_CHECK_HEADER([stdatomic.h],[
 841
 842   AC_MSG_CHECKING([whether _Atomic qualifier works])
 843   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 844 #include <stdatomic.h>
 845 int main(int argc, char **argv) {
 846   _Atomic int i = 0;
 847   return i;
 848 }
 849 ]])], [
 850     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 851     AC_MSG_RESULT([yes])
 852     ac_stdatomic_ok=true
 853   ], [
 854     AC_MSG_RESULT([no])
 855   ])
 856 ])
 857
 858 AS_IF([$ac_stdatomic_ok], [true], [
 859   AC_MSG_CHECKING([for __atomic_* builtins])
 860   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 861 int main(int argc, char **argv) {
 862   volatile int i = 1;
 863   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 864   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 865 }
 866 ]])], [
 867     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 868     AC_MSG_RESULT([yes])
 869   ], [
 870     AC_MSG_RESULT([no])
 871
 872     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 873     AC_MSG_CHECKING([for __sync_* builtins])
 874     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 875 int main(int argc, char **argv) {
 876   volatile int i = 1;
 877   __sync_fetch_and_sub (&i, 1);
 878   return __sync_val_compare_and_swap (&i, 0, 1);
 879 }
 880 ]])], [
 881       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 882       AC_MSG_RESULT([yes])
 883
 884       AC_MSG_CHECKING([for __sync_swap builtin])
 885       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 886 int main(int argc, char **argv) {
 887   volatile int i = 1;
 888   return __sync_swap (&i, 2);
 889 }
 890 ]])], [
 891         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 892         AC_MSG_RESULT([yes])
 893       ], [
 894         AC_MSG_RESULT([no])
 895       ])
 896
 897     ], [
 898       AC_MSG_RESULT([no])
 899       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 900     ])
 901   ])
 902 ])
 903
 904 AC_CHECK_HEADERS([pthread_np.h],,, [
 905 #include <pthread.h>
 906 ])
 907 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 908
 909 dnl Utility macro to avoid retyping includes all the time
 910 m4_define([FRR_INCLUDES],
 911 [#ifdef SUNOS_5
 912 #define _POSIX_C_SOURCE 200809L
 913 #define __EXTENSIONS__
 914 #endif
 915 #include <stdio.h>
 916 #include <stdlib.h>
 917 #include <stddef.h>
 918 #include <sys/types.h>
 919 /* sys/conf.h depends on param.h on FBSD at least */
 920 #include <sys/param.h>
 921 /* Required for MAXSIG */
 922 #include <signal.h>
 923 #include <sys/socket.h>
 924 #ifdef __APPLE__
 925 # define __APPLE_USE_RFC_3542
 926 #endif
 927 #include <netinet/in.h>
 928 #include <sys/time.h>
 929 #include <time.h>
 930 #include <net/if.h>
 931 ])dnl
 932
 933 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 934 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 935 dnl an additional round for it.
 936
 937 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 938
 939 m4_define([FRR_INCLUDES],
 940 FRR_INCLUDES
 941 [#if HAVE_NET_IF_VAR_H
 942 # include <net/if_var.h>
 943 #endif
 944 ])dnl
 945
 946 AC_CHECK_HEADERS([netinet/in_var.h \
 947         net/if_dl.h net/netopt.h \
 948         inet/nd.h netinet/ip_icmp.h \
 949         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 950         [], [], FRR_INCLUDES)
 951
 952 AC_CHECK_HEADERS([ucontext.h], [], [],
 953 [#ifndef __USE_GNU
 954 #define __USE_GNU
 955 #endif /* __USE_GNU */
 956 FRR_INCLUDES
 957 ])
 958
 959 m4_define([UCONTEXT_INCLUDES],
 960 [#include <ucontext.h>])dnl
 961
 962 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 963   [], [], [UCONTEXT_INCLUDES])
 964 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 965   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 966    [], [], [UCONTEXT_INCLUDES])],
 967   [], [UCONTEXT_INCLUDES])
 968 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 969   [], [], [UCONTEXT_INCLUDES])
 970
 971 m4_define([FRR_INCLUDES],
 972 FRR_INCLUDES
 973 [
 974 #include <sys/un.h>
 975 #include <netinet/in_systm.h>
 976 #if HAVE_NETINET_IN_VAR_H
 977 # include <netinet/in_var.h>
 978 #endif
 979 #if HAVE_NET_IF_DL_H
 980 # include <net/if_dl.h>
 981 #endif
 982 #if HAVE_NET_NETOPT_H
 983 # include <net/netopt.h>
 984 #endif
 985 #include <net/route.h>
 986 #if HAVE_INET_ND_H
 987 # include <inet/nd.h>
 988 #endif
 989 #include <arpa/inet.h>
 990 /* Required for IDRP */
 991 #if HAVE_NETINET_IP_ICMP_H
 992 # include <netinet/ip_icmp.h>
 993 #endif
 994 ])dnl
 995
 996 dnl V6 headers are checked below, after we check for v6
 997
 998 AC_MSG_CHECKING([which operating system interface to use])
 999 case "$host_os" in
1000   sunos* | solaris2*)
1001     AC_MSG_RESULT([Solaris])
1002
1003     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
1004     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1005     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
1006
1007     AC_CHECK_LIB(socket, main)
1008     AC_CHECK_LIB(nsl, main)
1009     AC_CHECK_LIB(umem, main)
1010     SOLARIS="solaris"
1011     ;;
1012   linux*)
1013     AC_MSG_RESULT([Linux])
1014
1015     AC_DEFINE(GNU_LINUX,,GNU Linux)
1016     AC_DEFINE(HAVE_NETLINK,,netlink)
1017     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1018
1019     dnl Linux has a compilation problem with mixing
1020     dnl netinet/in.h and linux/in6.h they are not
1021     dnl compatible.  There has been discussion on
1022     dnl how to fix it but no real progress on implementation
1023     dnl when they fix it, remove this
1024     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
1025     ;;
1026   openbsd*)
1027     AC_MSG_RESULT([OpenBSD])
1028
1029     AC_DEFINE(OPEN_BSD,,OpenBSD)
1030     AC_DEFINE(KAME,1,KAME IPv6)
1031     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
1032
1033     if test "x${enable_pimd}" != "xno"; then
1034       case "$host_os" in
1035       openbsd6.0)
1036         ;;
1037       openbsd[6-9]*)
1038         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1039         ;;
1040       esac
1041     fi
1042     ;;
1043   *)
1044     AC_MSG_RESULT([BSD])
1045
1046     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
1047     AC_DEFINE(KAME,1,KAME IPv6)
1048     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
1049     ;;
1050 esac
1051 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
1052
1053 AC_SYS_LARGEFILE
1054
1055 dnl ------------------------
1056 dnl Integrated REALMS option
1057 dnl ------------------------
1058 if test "${enable_realms}" = "yes"; then
1059     case "$host_os" in
1060       linux*)
1061        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1062        ;;
1063       *)
1064        echo "Sorry, only Linux has REALMS support"
1065        exit 1
1066        ;;
1067     esac
1068 fi
1069 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1070
1071 dnl ---------------------
1072 dnl Integrated VTY option
1073 dnl ---------------------
1074 case "${enable_vtysh}" in
1075 "no")
1076   VTYSH="";;
1077 *)
1078   VTYSH="vtysh";
1079   AC_DEFINE(VTYSH,,VTY shell)
1080
1081   prev_libs="$LIBS"
1082   AC_CHECK_LIB(readline, main, [
1083     LIBREADLINE="-lreadline"
1084   ], [
1085     dnl readline failed - it might be incorrectly linked and missing its
1086     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1087     AC_SEARCH_LIBS(tputs, [termcap tinfo curses ncurses], [
1088       LIBREADLINE="$ac_cv_search_tputs"
1089     ], [
1090       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1091     ])
1092
1093     dnl re-try with the lib we found above
1094     unset ac_cv_lib_readline_main
1095     AC_CHECK_LIB(readline, main, [
1096       LIBREADLINE="-lreadline $LIBREADLINE"
1097     ], [
1098       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1099     ], [$LIBREADLINE])
1100   ], [])
1101   LIBS="$prev_libs"
1102
1103   AC_CHECK_HEADER(readline/history.h)
1104   if test $ac_cv_header_readline_history_h = no;then
1105     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1106   fi
1107   AC_CHECK_LIB(readline, rl_completion_matches, [true], [], [$LIBREADLINE])
1108   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1109     AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1110   fi
1111   AC_CHECK_LIB(readline, [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1112   if test "$frr_cv_append_history" = yes; then
1113     AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1114   fi
1115   ;;
1116 esac
1117 AC_SUBST(LIBREADLINE)
1118 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1119
1120 dnl ----------
1121 dnl PAM module
1122 dnl
1123 dnl FRR detects the PAM library it is built against by checking for a
1124 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1125 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1126 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1127 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1128 dnl of OpenPAM.
1129 dnl ----------
1130 if test "$with_libpam" = "yes"; then
1131   AC_CHECK_HEADER([security/pam_misc.h],
1132     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1133      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1134      pam_conv_func="misc_conv"
1135     ],
1136     [], FRR_INCLUDES)
1137   AC_CHECK_HEADER([security/openpam.h],
1138     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1139      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1140      pam_conv_func="openpam_ttyconv"
1141     ],
1142     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1143   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1144     AC_MSG_WARN([*** pam support will not be built ***])
1145     with_libpam="no"
1146   fi
1147 fi
1148
1149 if test "$with_libpam" = "yes"; then
1150 dnl took this test from proftpds configure.in and suited to our needs
1151 dnl -------------------------------------------------------------------------
1152 dnl
1153 dnl This next check looks funky due to a linker problem with some versions
1154 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1155 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1156 dnl with RedHat 6.2 and Debian 2.2 or better.
1157 AC_CHECK_LIB(pam, pam_start,
1158   [AC_CHECK_LIB(pam, $pam_conv_func,
1159     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1160      LIBPAM="-lpam"],
1161     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1162      LIBPAM="-lpam -lpam_misc"]
1163     )
1164   ],
1165
1166   [AC_CHECK_LIB(pam, pam_end,
1167     [AC_CHECK_LIB(pam, $pam_conv_func,
1168       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1169        LIBPAM="-lpam -ldl"],
1170       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1171        LIBPAM="-lpam -ldl -lpam_misc"]
1172      )
1173   ],AC_MSG_WARN([*** pam support will not be built ***]),
1174   [-ldl])
1175   ]
1176 )
1177 fi
1178 AC_SUBST(LIBPAM)
1179
1180 dnl -------------------------------
1181 dnl Endian-ness check
1182 dnl -------------------------------
1183 AC_WORDS_BIGENDIAN
1184
1185 dnl -------------------------------
1186 dnl check the size in byte of the C
1187 dnl -------------------------------
1188 dnl AC_CHECK_SIZEOF(char)
1189 dnl AC_CHECK_SIZEOF(int)
1190 dnl AC_CHECK_SIZEOF(short)
1191 dnl AC_CHECK_SIZEOF(long)
1192
1193 dnl ----------------------------
1194 dnl check existance of functions
1195 dnl ----------------------------
1196 AC_FUNC_FNMATCH
1197 AC_FUNC_FORK
1198 AC_FUNC_MKTIME
1199 AC_FUNC_STAT
1200
1201 dnl -------------------------------
1202 dnl bgpd needs pow() and hence libm
1203 dnl -------------------------------
1204 TMPLIBS="$LIBS"
1205 AC_CHECK_HEADER([math.h],
1206   [AC_CHECK_LIB([m], [pow],
1207     [LIBM="-lm"
1208      LIBS="$LIBS $LIBM"
1209      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1210     ])
1211 ])
1212 if test x"$LIBM" = x ; then
1213   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1214 fi
1215 LIBS="$TMPLIBS"
1216
1217 AC_SUBST(LIBM)
1218
1219 AC_CHECK_FUNCS([ppoll], [
1220   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1221 ])
1222 AC_CHECK_FUNCS([pollts], [
1223   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1224 ])
1225
1226 dnl ---------------
1227 dnl other functions
1228 dnl ---------------
1229 AC_CHECK_FUNCS([ \
1230         strlcat strlcpy \
1231         getgrouplist])
1232
1233 AC_CHECK_HEADER([asm-generic/unistd.h],
1234                 [AC_CHECK_DECL(__NR_setns,
1235                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1236                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1237                                ])
1238                  AC_CHECK_FUNCS(setns)]
1239                )
1240
1241 dnl --------------------------
1242 dnl Determine IS-IS I/O method
1243 dnl --------------------------
1244 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1245 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1246 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1247 AC_CHECK_HEADER(net/bpf.h)
1248 AC_CHECK_HEADER(sys/dlpi.h)
1249 AC_MSG_CHECKING(zebra IS-IS I/O method)
1250
1251 case "$host_os" in
1252   linux*)
1253     AC_MSG_RESULT(pfpacket)
1254     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1255     ;;
1256   solaris* | sunos*)
1257     AC_MSG_RESULT(DLPI)
1258     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1259     ;;
1260   *)
1261     if test $ac_cv_header_net_bpf_h = no; then
1262       if test $ac_cv_header_sys_dlpi_h = no; then
1263         AC_MSG_RESULT(none)
1264         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1265           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1266         fi
1267         AC_MSG_WARN([*** IS-IS support will not be built ***])
1268         enable_isisd="no"
1269         enable_fabricd="no"
1270       else
1271         AC_MSG_RESULT(DLPI)
1272       fi
1273       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1274     else
1275       AC_MSG_RESULT(BPF)
1276       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1277     fi
1278     ;;
1279 esac
1280 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1281
1282 dnl ---------------------------------------------------------------
1283 dnl figure out how to specify an interface in multicast sockets API
1284 dnl ---------------------------------------------------------------
1285 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1286
1287 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1288         #include <sys/socket.h>
1289         #include <netinet/in.h>
1290         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1291         #include <linux/types.h>
1292 ])
1293
1294 m4_define([FRR_INCLUDES],
1295 FRR_INCLUDES
1296 [#if HAVE_LINUX_MROUTE_H
1297 # include <linux/mroute.h>
1298 #endif
1299 ])dnl
1300
1301 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1302         #include <sys/socket.h>
1303         #include <sys/types.h>
1304         #include <netinet/in.h>
1305         #include <net/route.h>
1306 ])
1307
1308 m4_define([FRR_INCLUDES],
1309 FRR_INCLUDES
1310 [#if HAVE_NETINET_IP_MROUTE_H
1311 # include <netinet/ip_mroute.h>
1312 #endif
1313 ])dnl
1314
1315 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1316 AC_TRY_COMPILE([#include <sys/param.h>],
1317 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1318   return (0);
1319 #else
1320   #error No support for BSD struct ip_mreq hack detected
1321 #endif],[AC_MSG_RESULT(yes)
1322 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1323 AC_MSG_RESULT(no))
1324
1325 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1326 AC_TRY_COMPILE([
1327 #include <sys/types.h>
1328 #include <netinet/in.h>
1329 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1330 ], [AC_MSG_RESULT(yes)
1331 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1332 AC_MSG_RESULT(no))
1333
1334 dnl ---------------------------------------------------------------
1335 dnl figure out how to check link-state
1336 dnl ---------------------------------------------------------------
1337 AC_CHECK_HEADER( [net/if_media.h],
1338   [m4_define([LINK_DETECT_INCLUDES],
1339     FRR_INCLUDES
1340     [#include <net/if_media.h>
1341   ])
1342   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1343     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1344     [], LINK_DETECT_INCLUDES)],
1345   [],
1346   FRR_INCLUDES)
1347
1348 dnl ---------------------------------------------------------------
1349 dnl Additional, newer way to check link-state using ifi_link_state.
1350 dnl Not available in all BSD's when ifmediareq available
1351 dnl ---------------------------------------------------------------
1352 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1353   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1354   [], FRR_INCLUDES)
1355
1356 dnl ------------------------
1357 dnl TCP_MD5SIG socket option
1358 dnl ------------------------
1359
1360 AC_CHECK_HEADER([netinet/tcp.h],
1361    [m4_define([MD5_INCLUDES],
1362       FRR_INCLUDES
1363       [#include <netinet/tcp.h>
1364     ])
1365     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1366    [],
1367    FRR_INCLUDES)
1368 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1369   AC_CHECK_HEADER([linux/tcp.h],
1370        [m4_define([MD5_INCLUDES],
1371           FRR_INCLUDES
1372           [#include <linux/tcp.h>
1373         ])
1374        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1375 fi
1376
1377 dnl ----------------------------------------------------------------------------
1378 dnl figure out if domainname is available in the utsname struct (GNU extension).
1379 dnl ----------------------------------------------------------------------------
1380 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1381
1382 dnl ------------------
1383 dnl IPv6 header checks
1384 dnl ------------------
1385 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1386         netinet6/in6_var.h netinet6/nd6.h], [], [],
1387         FRR_INCLUDES)
1388
1389 m4_define([FRR_INCLUDES],dnl
1390 FRR_INCLUDES
1391 [#if HAVE_NETINET6_IN6_H
1392 #include <netinet6/in6.h>
1393 #endif
1394 #if HAVE_NETINET_IN6_VAR_H
1395 #include <netinet/in6_var.h>
1396 #endif
1397 #include <netinet/icmp6.h>
1398 #if HAVE_NETINET6_IN6_VAR_H
1399 # include <netinet6/in6_var.h>
1400 #endif
1401 #if HAVE_NETINET6_ND6_H
1402 # include <netinet6/nd6.h>
1403 #endif
1404 ])dnl
1405
1406 dnl disable doc check
1407 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1408 if test "$SPHINXBUILD" = "/bin/false"; then
1409   if test "${enable_doc}" = "yes"; then
1410     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1411   fi
1412 fi
1413 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1414 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1415
1416 dnl --------------------
1417 dnl Daemon disable check
1418 dnl --------------------
1419 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1420
1421 if test "${enable_bgpd}" = "no";then
1422   BGPD=""
1423 else
1424   BGPD="bgpd"
1425 fi
1426 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1427
1428 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1429 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1430 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1431
1432 AS_IF([test "${enable_ldpd}" != "no"], [
1433   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1434 ])
1435
1436 if test "$enable_bfdd" = "no"; then
1437   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1438   BFDD=""
1439 else
1440   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1441   BFDD="bfdd"
1442
1443   case $host_os in
1444     linux*)
1445       AC_DEFINE(BFD_LINUX, 1, bfdd)
1446       ;;
1447
1448     *)
1449       AC_DEFINE(BFD_BSD, 1, bfdd)
1450       ;;
1451   esac
1452 fi
1453
1454 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1455
1456 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1457   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1458 fi
1459
1460 NHRPD=""
1461 case "$host_os" in
1462   linux*)
1463     if test "${enable_nhrpd}" != "no"; then
1464       NHRPD="nhrpd"
1465     fi
1466     ;;
1467   *)
1468     if test "${enable_nhrpd}" = "yes"; then
1469       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1470     fi
1471     ;;
1472 esac
1473 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1474
1475 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1476
1477 if test "${enable_watchfrr}" = "no";then
1478   WATCHFRR=""
1479 else
1480   WATCHFRR="watchfrr"
1481 fi
1482 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1483
1484 OSPFCLIENT=""
1485 if test "${enable_ospfapi}" != "no";then
1486     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1487
1488   if test "${enable_ospfclient}" != "no";then
1489       OSPFCLIENT="ospfclient"
1490   fi
1491 fi
1492
1493 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1494 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1495 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1496 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1497 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1498 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1499 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1500 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1501 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1502 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1503
1504 if test "${enable_bgp_announce}" = "no";then
1505   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1506 else
1507   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1508 fi
1509
1510 if test "${enable_bgp_vnc}" != "no";then
1511   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1512 fi
1513 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1514
1515 AC_SUBST(SOLARIS)
1516 AC_CHECK_LIB(crypt, crypt, [],
1517                     [AC_CHECK_LIB(crypto, DES_crypt)])
1518 AC_CHECK_LIB(resolv, res_init)
1519
1520 dnl ---------------------------
1521 dnl check system has PCRE regexp
1522 dnl ---------------------------
1523 if test "x$enable_pcreposix" = "xyes"; then
1524   AC_CHECK_LIB(pcreposix, regexec, [], [
1525     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1526   ])
1527 fi
1528 AC_SUBST(HAVE_LIBPCREPOSIX)
1529
1530 dnl ------------------
1531 dnl check C-Ares library
1532 dnl ------------------
1533 if test "${NHRPD}" != ""; then
1534   PKG_CHECK_MODULES([CARES], [libcares], , [
1535     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1536   ])
1537 fi
1538
1539
1540 dnl ------------------
1541 dnl check Net-SNMP library
1542 dnl ------------------
1543 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1544    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1545    if test x"$NETSNMP_CONFIG" = x"no"; then
1546       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1547    fi
1548    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1549    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1550    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1551    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1552 int main(void);
1553 ],
1554 [
1555 {
1556   return 0;
1557 }
1558 ])], [
1559      AC_MSG_ERROR([--enable-snmp given but not usable])])
1560    case "${enable_snmp}" in
1561      yes)
1562       SNMP_METHOD=agentx
1563       ;;
1564      agentx)
1565       SNMP_METHOD="${enable_snmp}"
1566       ;;
1567      *)
1568       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1569       ;;
1570    esac
1571    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1572    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1573 fi
1574 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1575 AC_SUBST(SNMP_LIBS)
1576 AC_SUBST(SNMP_CFLAGS)
1577
1578 dnl ---------------
1579 dnl libyang
1580 dnl ---------------
1581 PKG_CHECK_MODULES(libyang, [libyang >= 0.16.7], , [
1582   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1583 ])
1584
1585 dnl ---------------
1586 dnl configuration rollbacks
1587 dnl ---------------
1588 SQLITE3=false
1589 if test "$enable_config_rollbacks" = "yes"; then
1590   PKG_CHECK_MODULES(sqlite3,[sqlite3], [
1591     AC_DEFINE(HAVE_CONFIG_ROLLBACKS,1,Enable configuration rollbacks)
1592     AC_DEFINE(HAVE_SQLITE3,1,Enable sqlite3 database)
1593     SQLITE3=true
1594   ], [
1595     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1596   ])
1597 fi
1598 AM_CONDITIONAL(SQLITE3, $SQLITE3)
1599
1600 dnl ---------------
1601 dnl confd
1602 dnl ---------------
1603 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1604    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false])
1605    if test "x$CONFD" = "x/bin/false"; then
1606       AC_MSG_ERROR([confd was not found on your system.])]
1607    fi
1608    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1609    AC_SUBST(CONFD_CFLAGS)
1610    AC_DEFINE(HAVE_CONFD,1,Enable confd integration)
1611 fi
1612 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1613
1614 dnl ---------------
1615 dnl sysrepo
1616 dnl ---------------
1617 if test "$enable_sysrepo" = "yes"; then
1618   PKG_CHECK_MODULES(sysrepo,[libsysrepo],
1619       [AC_DEFINE(HAVE_SYSREPO,1,Enable sysrepo integration)
1620       SYSREPO=true],
1621       [SYSREPO=false
1622       AC_MSG_ERROR([sysrepo was not found on your system.])]
1623   )
1624 fi
1625 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1626
1627 dnl ---------------
1628 dnl math
1629 dnl ---------------
1630 AC_SEARCH_LIBS([sqrt], [m])
1631
1632 dnl ---------------
1633 dnl dlopen & dlinfo
1634 dnl ---------------
1635 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1636   AC_MSG_ERROR([unable to find the dlopen()])
1637 ])
1638
1639 AC_CHECK_HEADERS([link.h])
1640
1641 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1642   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1643 #include <stdlib.h>
1644 #ifdef HAVE_LINK_H
1645 #include <link.h>
1646 #endif
1647 #include <dlfcn.h>
1648 ]], [[
1649   char origin[1];
1650   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1651 ]])], [
1652     frr_cv_rtld_di_origin=yes
1653   ], [
1654     frr_cv_rtld_di_origin=no
1655   ])
1656 ])
1657 if test "$frr_cv_rtld_di_origin" = yes; then
1658   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1659 fi
1660
1661 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1662   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1663 #include <stdlib.h>
1664 #ifdef HAVE_LINK_H
1665 #include <link.h>
1666 #endif
1667 #include <dlfcn.h>
1668 ]], [[
1669   struct link_map *lm = NULL;
1670   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1671 ]])], [
1672     frr_cv_rtld_di_linkmap=yes
1673   ], [
1674     frr_cv_rtld_di_linkmap=no
1675   ])
1676 ])
1677 if test "$frr_cv_rtld_di_linkmap" = yes; then
1678   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1679 fi
1680
1681 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1682
1683 dnl ---------------------------
1684 dnl sockaddr and netinet checks
1685 dnl ---------------------------
1686 AC_CHECK_TYPES([
1687         struct sockaddr_dl,
1688         struct vifctl, struct mfcctl, struct sioc_sg_req,
1689         vifi_t, struct sioc_vif_req, struct igmpmsg,
1690         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1691         struct nd_opt_adv_interval, struct rt_addrinfo,
1692         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1693         [], [], FRR_INCLUDES)
1694
1695 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1696         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1697         struct sockaddr_dl.sdl_len,
1698         struct if6_aliasreq.ifra_lifetime,
1699         struct nd_opt_adv_interval.nd_opt_ai_type],
1700         [], [], FRR_INCLUDES)
1701
1702 dnl ---------------------------
1703 dnl IRDP/pktinfo/icmphdr checks
1704 dnl ---------------------------
1705
1706 AC_CHECK_TYPES([struct in_pktinfo], [
1707   AC_CHECK_TYPES([struct icmphdr], [
1708     IRDP=true
1709   ], [
1710     IRDP=false
1711   ], [FRR_INCLUDES])
1712 ], [
1713   IRDP=false
1714 ], [FRR_INCLUDES])
1715
1716 case "${enable_irdp}" in
1717 yes)
1718   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1719   ;;
1720 no)
1721   IRDP=false
1722   ;;
1723 esac
1724
1725 AM_CONDITIONAL(IRDP, $IRDP)
1726
1727 dnl -----------------------
1728 dnl checking for IP_PKTINFO
1729 dnl -----------------------
1730 AC_MSG_CHECKING(for IP_PKTINFO)
1731 AC_TRY_COMPILE([#include <netdb.h>], [
1732   int opt = IP_PKTINFO;
1733 ], [
1734   AC_MSG_RESULT(yes)
1735   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1736 ], [
1737   AC_MSG_RESULT(no)
1738 ])
1739
1740 dnl ---------------------------
1741 dnl checking for IP_RECVDSTADDR
1742 dnl ---------------------------
1743 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1744 AC_TRY_COMPILE([#include <netinet/in.h>], [
1745   int opt = IP_RECVDSTADDR;
1746 ], [
1747   AC_MSG_RESULT(yes)
1748   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1749 ], [
1750   AC_MSG_RESULT(no)
1751 ])
1752
1753 dnl ----------------------
1754 dnl checking for IP_RECVIF
1755 dnl ----------------------
1756 AC_MSG_CHECKING(for IP_RECVIF)
1757 AC_TRY_COMPILE([#include <netinet/in.h>], [
1758   int opt = IP_RECVIF;
1759 ], [
1760   AC_MSG_RESULT(yes)
1761   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1762 ], [
1763   AC_MSG_RESULT(no)
1764 ])
1765
1766 dnl ----------------------
1767 dnl checking for SO_BINDANY
1768 dnl ----------------------
1769 AC_MSG_CHECKING(for SO_BINDANY)
1770 AC_TRY_COMPILE([#include <sys/socket.h>], [
1771   int opt = SO_BINDANY;
1772 ], [
1773   AC_MSG_RESULT(yes)
1774   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1775 ], [
1776   AC_MSG_RESULT(no)
1777 ])
1778
1779 dnl ----------------------
1780 dnl checking for IP_FREEBIND
1781 dnl ----------------------
1782 AC_MSG_CHECKING(for IP_FREEBIND)
1783 AC_TRY_COMPILE([#include <netinet/in.h>], [
1784   int opt = IP_FREEBIND;
1785 ], [
1786   AC_MSG_RESULT(yes)
1787   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1788 ], [
1789   AC_MSG_RESULT(no)
1790 ])
1791
1792 dnl --------------------------------------
1793 dnl checking for be32dec existence or not
1794 dnl --------------------------------------
1795 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1796                [#include <sys/endian.h>])
1797
1798 dnl --------------------------------------
1799 dnl checking for clock_time monotonic struct and call
1800 dnl --------------------------------------
1801 AC_CHECK_DECL(CLOCK_MONOTONIC,
1802         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1803          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1804 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1805
1806 dnl --------------------------------------
1807 dnl checking for flex and bison
1808 dnl --------------------------------------
1809
1810 AM_PROG_LEX
1811 AC_MSG_CHECKING(version of flex)
1812 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1813 frr_ac_flex_version="${frr_ac_flex_version##* }"
1814 AC_MSG_RESULT([$frr_ac_flex_version])
1815 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1816   LEX="$SHELL $missing_dir/missing flex"
1817   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1818     AC_MSG_WARN([using pregenerated flex output files])
1819   else
1820     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1821   fi
1822   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1823   AC_SUBST([LEXLIB], [''])
1824 ])
1825
1826 AC_PROG_YACC
1827 dnl thanks GNU bison for this b*llshit...
1828 AC_MSG_CHECKING(version of bison)
1829 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1830 frr_ac_bison_version="${frr_ac_bison_version##* }"
1831 frr_ac_bison_missing="false"
1832 case "x${frr_ac_bison_version}" in
1833   x2.7*)
1834     BISON_OPENBRACE='"'
1835     BISON_CLOSEBRACE='"'
1836     BISON_VERBOSE=''
1837     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1838     ;;
1839   x2.*|x1.*)
1840     AC_MSG_RESULT([$frr_ac_bison_version])
1841     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1842     frr_ac_bison_missing="true"
1843     ;;
1844   x)
1845     AC_MSG_RESULT([none])
1846     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1847     frr_ac_bison_missing="true"
1848     ;;
1849   *)
1850     BISON_OPENBRACE='{'
1851     BISON_CLOSEBRACE='}'
1852     BISON_VERBOSE='-Dparse.error=verbose'
1853     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1854     ;;
1855 esac
1856 AC_SUBST(BISON_OPENBRACE)
1857 AC_SUBST(BISON_CLOSEBRACE)
1858 AC_SUBST(BISON_VERBOSE)
1859
1860 if $frr_ac_bison_missing; then
1861   YACC="$SHELL $missing_dir/missing bison -y"
1862   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1863     AC_MSG_WARN([using pregenerated bison output files])
1864   else
1865     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1866   fi
1867 fi
1868
1869 dnl -------------------
1870 dnl capabilities checks
1871 dnl -------------------
1872 if test "${enable_capabilities}" != "no"; then
1873   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1874   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1875     [AC_MSG_RESULT(yes)
1876      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1877      frr_ac_keepcaps="yes"],
1878      AC_MSG_RESULT(no)
1879   )
1880   if test x"${frr_ac_keepcaps}" = x"yes"; then
1881     AC_CHECK_HEADERS(sys/capability.h)
1882   fi
1883   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1884     AC_CHECK_LIB(cap, cap_init,
1885       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1886        LIBCAP="-lcap"
1887        frr_ac_lcaps="yes"]
1888     )
1889   else
1890     AC_CHECK_HEADERS(priv.h,
1891      [AC_MSG_CHECKING(Solaris style privileges are available)
1892       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1893           [AC_MSG_RESULT(yes)
1894            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1895            frr_ac_scaps="yes"],
1896            AC_MSG_RESULT(no)
1897       )
1898      ]
1899    )
1900   fi
1901   if test x"${frr_ac_scaps}" = x"yes" \
1902        -o x"${frr_ac_lcaps}" = x"yes"; then
1903     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1904   fi
1905 fi
1906 AC_SUBST(LIBCAP)
1907
1908 dnl ---------------------------
1909 dnl check for glibc 'backtrace'
1910 dnl ---------------------------
1911 if test x"${enable_backtrace}" != x"no" ; then
1912   backtrace_ok=no
1913   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1914     AC_DEFINE(HAVE_LIBUNWIND, 1, [libunwind])
1915     backtrace_ok=yes
1916   ], [
1917     case "$host_os" in
1918     sunos* | solaris2*)
1919       AC_CHECK_FUNCS([printstack], [
1920         AC_DEFINE([HAVE_PRINTSTACK], 1, [Solaris printstack])
1921         backtrace_ok=yes
1922       ])
1923       ;;
1924     esac
1925     if test "$backtrace_ok" = no; then
1926       AC_CHECK_HEADER([execinfo.h], [
1927         AC_SEARCH_LIBS([backtrace], [execinfo], [
1928           AC_DEFINE(HAVE_GLIBC_BACKTRACE, 1, [Glibc backtrace])
1929           backtrace_ok=yes
1930         ],, [-lm])
1931       ])
1932     fi
1933   ])
1934
1935   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1936     dnl user explicitly requested backtrace but we failed to find support
1937     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
1938   fi
1939 fi
1940
1941 dnl -----------------------------------------
1942 dnl check for malloc mallinfo struct and call
1943 dnl this must try and link using LIBS, in
1944 dnl order to check no alternative allocator
1945 dnl has been specified, which might not provide
1946 dnl mallinfo, e.g. such as Umem on Solaris.
1947 dnl -----------------------------------------
1948 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1949
1950 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1951   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1952 #ifdef HAVE_MALLOC_H
1953 #include <malloc.h>
1954 #endif
1955 #ifdef HAVE_MALLOC_NP_H
1956 #include <malloc_np.h>
1957 #endif
1958 #ifdef HAVE_MALLOC_MALLOC_H
1959 #include <malloc/malloc.h>
1960 #endif
1961 ]], [[
1962 struct mallinfo ac_x; ac_x = mallinfo ();
1963 ]])], [
1964     frr_cv_mallinfo=yes
1965   ], [
1966     frr_cv_mallinfo=no
1967   ])
1968 ])
1969 if test "$frr_cv_mallinfo" = yes; then
1970   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1971 fi
1972
1973 AC_MSG_CHECKING(whether malloc_usable_size is available)
1974 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1975 #ifdef HAVE_MALLOC_H
1976 #include <malloc.h>
1977 #endif
1978 #ifdef HAVE_MALLOC_MALLOC_H
1979 #include <malloc/malloc.h>
1980 #endif
1981 ]], [[
1982 size_t ac_x; ac_x = malloc_usable_size(NULL);
1983 ]])], [
1984   AC_MSG_RESULT(yes)
1985   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1986 ], [
1987   AC_MSG_RESULT(no)
1988
1989   AC_MSG_CHECKING(whether malloc_size is available)
1990   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1991 #ifdef HAVE_MALLOC_H
1992 #include <malloc.h>
1993 #endif
1994 #ifdef HAVE_MALLOC_MALLOC_H
1995 #include <malloc/malloc.h>
1996 #endif
1997 ]], [[
1998 size_t ac_x; ac_x = malloc_size(NULL);
1999 ]])], [
2000     AC_MSG_RESULT(yes)
2001     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
2002   ], [
2003     AC_MSG_RESULT(no)
2004   ])
2005 ])
2006
2007 dnl ------
2008 dnl ZeroMQ
2009 dnl ------
2010 if test "x$enable_zeromq" != "xno"; then
2011   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
2012     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
2013     ZEROMQ=true
2014   ], [
2015     if test "x$enable_zeromq" = "xyes"; then
2016       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2017     fi
2018   ])
2019 fi
2020 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
2021
2022 dnl ----------
2023 dnl configure date
2024 dnl ----------
2025 dev_version=`echo $VERSION | grep dev`
2026 #don't expire deprecated code in non 'dev' branch
2027 if test "${dev_version}" = ""; then
2028    CONFDATE=0
2029 else
2030    CONFDATE=`date '+%Y%m%d'`
2031 fi
2032 AC_SUBST(CONFDATE)
2033
2034 dnl ------------------------------
2035 dnl set paths for state directory
2036 dnl ------------------------------
2037 AC_MSG_CHECKING(directory to use for state file)
2038 if test "${prefix}" = "NONE"; then
2039   frr_statedir_prefix="";
2040 else
2041   frr_statedir_prefix=${prefix}
2042 fi
2043 if test "${localstatedir}" = '${prefix}/var'; then
2044   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2045                         ${frr_statedir_prefix}/var/adm dnl
2046                         ${frr_statedir_prefix}/etc dnl
2047                         /var/run        dnl
2048                         /var/adm        dnl
2049                         /etc            dnl
2050                         /dev/null;
2051   do
2052     test -d $FRR_STATE_DIR && break
2053   done
2054   frr_statedir=$FRR_STATE_DIR
2055 else
2056   frr_statedir=${localstatedir}
2057 fi
2058 if test $frr_statedir = "/dev/null"; then
2059     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
2060 fi
2061 AC_MSG_RESULT(${frr_statedir})
2062 AC_SUBST(frr_statedir)
2063
2064 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
2065 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
2066 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
2067 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
2068 AC_DEFINE_UNQUOTED(DAEMON_DB_DIR, "$frr_statedir",daemon database directory)
2069
2070 dnl autoconf does this, but it does it too late...
2071 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2072 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2073
2074 dnl get the full path, recursing through variables...
2075 vtysh_bin="$bindir/vtysh"
2076 for I in 1 2 3 4 5 6 7 8 9 10; do
2077         eval vtysh_bin="\"$vtysh_bin\""
2078 done
2079 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
2080 AC_SUBST(vtysh_bin)
2081
2082 CFG_SYSCONF="$sysconfdir"
2083 CFG_SBIN="$sbindir"
2084 CFG_STATE="$frr_statedir"
2085 CFG_MODULE="$moduledir"
2086 CFG_YANGMODELS="$yangmodelsdir"
2087 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2088 for I in 1 2 3 4 5 6 7 8 9 10; do
2089         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2090         eval CFG_SBIN="\"$CFG_SBIN\""
2091         eval CFG_STATE="\"$CFG_STATE\""
2092         eval CFG_MODULE="\"$CFG_MODULE\""
2093         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2094         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2095 done
2096 AC_SUBST(CFG_SYSCONF)
2097 AC_SUBST(CFG_SBIN)
2098 AC_SUBST(CFG_STATE)
2099 AC_SUBST(CFG_MODULE)
2100 AC_SUBST(CFG_YANGMODELS)
2101 AC_SUBST(CFG_LIBYANG_PLUGINS)
2102 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
2103 AC_DEFINE_UNQUOTED(YANG_MODELS_PATH, "$CFG_YANGMODELS", path to YANG data models)
2104 AC_DEFINE_UNQUOTED(LIBYANG_PLUGINS_PATH, "$CFG_LIBYANG_PLUGINS", path to libyang plugins)
2105
2106 dnl ------------------------------------
2107 dnl Enable RPKI and add librtr to libs
2108 dnl ------------------------------------
2109 if test "${enable_rpki}" = "yes"; then
2110   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
2111       [RPKI=true],
2112       [RPKI=false
2113       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2114   )
2115 fi
2116 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
2117
2118 dnl ------------------------------------------
2119 dnl Check whether rtrlib was build with ssh support
2120 dnl ------------------------------------------
2121 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2122 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2123                         [[struct tr_ssh_config config;]])],
2124         [AC_MSG_RESULT(yes)
2125         AC_DEFINE(FOUND_SSH,,found_ssh)],
2126         AC_MSG_RESULT(no)
2127 )
2128
2129 dnl ---------------------------
2130 dnl Check htonl works correctly
2131 dnl ---------------------------
2132 AC_MSG_CHECKING(for working htonl)
2133 AC_CACHE_VAL(ac_cv_htonl_works,
2134  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2135                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2136  ]
2137 )
2138 AC_MSG_RESULT($ac_cv_htonl_works)
2139
2140 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2141
2142 AC_CONFIG_FILES([
2143           config.version
2144           redhat/frr.spec
2145           solaris/Makefile
2146           debianpkg/changelog
2147           alpine/APKBUILD
2148           snapcraft/snapcraft.yaml
2149           lib/version.h
2150           tests/lib/cli/test_cli.refout
2151           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2152           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2153           pkgsrc/eigrpd.sh])
2154
2155 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2156 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2157
2158 AC_CONFIG_COMMANDS([lib/route_types.h], [
2159         dst="${ac_abs_top_builddir}/lib/route_types.h"
2160         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2161                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2162                 > "${dst}.tmp"
2163         test -f "${dst}" \
2164                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2165                 && rm "${dst}.tmp" \
2166                 || mv "${dst}.tmp" "${dst}"
2167 ], [
2168         PERL="$PERL"
2169 ])
2170
2171 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2172     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2173         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2174         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2175                 "${ac_abs_top_srcdir}" \
2176                 > "${dst}.tmp"
2177         test -f "${dst}" \
2178                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2179                 && rm "${dst}.tmp" \
2180                 || mv "${dst}.tmp" "${dst}"
2181     ], [
2182         PERL="$PERL"
2183     ])
2184 ])
2185
2186 ## Hack, but working solution to avoid rebuilding of frr.info.
2187 ## It's already in CVS until texinfo 4.7 is more common.
2188 AC_OUTPUT
2189
2190 echo "
2191 FRRouting configuration
2192 ------------------------------
2193 FRR version             : ${PACKAGE_VERSION}
2194 host operating system   : ${host_os}
2195 source code location    : ${srcdir}
2196 compiler                : ${CC}
2197 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2198 make                    : ${MAKE-make}
2199 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2200 state file directory    : ${frr_statedir}
2201 config file directory   : `eval echo \`echo ${sysconfdir}\``
2202 example directory       : `eval echo \`echo ${exampledir}\``
2203 module directory        : ${CFG_MODULE}
2204 user to run as          : ${enable_user}
2205 group to run as         : ${enable_group}
2206 group for vty sockets   : ${enable_vty_group}
2207 config file mask        : ${enable_configfile_mask}
2208 log file mask           : ${enable_logfile_mask}
2209 zebra protobuf enabled  : ${enable_protobuf:-no}
2210
2211 The above user and group must have read/write access to the state file
2212 directory and to the config files in the config file directory."
2213
2214 if test "${enable_doc}" != "no";then
2215   AS_IF([test "$SPHINXBUILD" = /bin/false],
2216      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2217 fi