configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.6-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AC_ARG_VAR([AR],[archiver command])
  29 AC_ARG_VAR([LD],[linker command])
  30 AC_ARG_VAR([OBJCOPY],[objcopy command])
  31 AC_ARG_VAR([OBJDUMP],[objdump command])
  32 AC_ARG_VAR([RANLIB],[ranlib command])
  33 AC_ARG_VAR([STRIP],[strip command])
  34
  35 hosttools_clippy="false"
  36 build_clippy="true"
  37
  38 dnl case 1: external clippy
  39 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  40   if test "$enable_clippy_only" = "yes"; then
  41     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  42   fi
  43
  44   CLIPPY="$with_clippy"
  45   build_clippy="false"
  46   if test ! -x "$with_clippy"; then
  47     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  48   fi
  49
  50 dnl case 2: cross-compiling internal clippy
  51 elif test "$host" != "$build"; then
  52   if test "$srcdir" = "."; then
  53     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  54   fi
  55   test -d hosttools || mkdir hosttools
  56   abssrc="`cd \"${srcdir}\"; pwd`"
  57
  58   AC_MSG_NOTICE([...])
  59   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  60   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  61   AC_MSG_NOTICE([...])
  62
  63   (
  64     for var in $ac_precious_vars; do
  65       dnl special cases
  66       case "$var" in
  67       YACC|YFLAGS) continue;;
  68       PYTHON*)     retain=true;;
  69       *)           retain=false;
  70       esac
  71
  72       eval "hostvar=\"\${HOST_$var}\""
  73       eval "targetvar=\"\${$var}\""
  74       if test -n "$hostvar"; then
  75         eval "$var='$hostvar'"
  76         _AS_ECHO_LOG([host $var='$hostvar'])
  77       elif $retain; then
  78         _AS_ECHO_LOG([host retain $var='$targetvar'])
  79       else
  80         eval "unset $var"
  81         _AS_ECHO_LOG([host unset $var])
  82       fi
  83     done
  84     cd hosttools
  85     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  86   ) || exit 1
  87
  88   AC_MSG_NOTICE([...])
  89   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  90   AC_MSG_NOTICE([...])
  91
  92   build_clippy="false"
  93   hosttools_clippy="true"
  94   CLIPPY="hosttools/lib/clippy"
  95
  96 dnl case 3: normal build internal clippy
  97 else
  98   CLIPPY="lib/clippy\$(EXEEXT)"
  99 fi
 100 AC_SUBST([CLIPPY])
 101 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 102 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 103 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 104
 105 # Disable portability warnings -- our automake code (in particular
 106 # common.am) uses some constructs specific to gmake.
 107 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 108 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 109 AM_SILENT_RULES([yes])
 110 AC_CONFIG_HEADERS([config.h])
 111
 112 AC_PATH_PROG([PERL], [perl])
 113 PKG_PROG_PKG_CONFIG
 114
 115 dnl default is to match previous behavior
 116 exampledir=${sysconfdir}
 117 AC_ARG_ENABLE([exampledir],
 118           AS_HELP_STRING([--enable-exampledir],
 119                          [specify alternate directory for examples]),
 120                          exampledir="$enableval",)
 121 dnl XXX add --exampledir to autoconf standard directory list somehow
 122 AC_SUBST([exampledir])
 123
 124 dnl default is to match previous behavior
 125 pkgsrcrcdir=""
 126 AC_ARG_ENABLE([pkgsrcrcdir],
 127           AS_HELP_STRING([--enable-pkgsrcrcdir],
 128                          [specify directory for rc.d scripts]),
 129                          pkgsrcrcdir="$enableval",)
 130 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 131 AC_SUBST([pkgsrcrcdir])
 132 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 133
 134 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 135         moduledir="$withval"
 136 ], [
 137         moduledir="\${libdir}/frr/modules"
 138 ])
 139 AC_SUBST([moduledir], [$moduledir])
 140
 141
 142 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 143         yangmodelsdir="$withval"
 144 ], [
 145         yangmodelsdir="\${datarootdir}/yang"
 146 ])
 147 AC_SUBST([yangmodelsdir])
 148
 149 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 150         vici_socket="$withval"
 151 ], [
 152         vici_socket="/var/run/charon.vici"
 153 ])
 154 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 155
 156 AC_ARG_ENABLE(tcmalloc,
 157         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 158 [case "${enableval}" in
 159   yes) tcmalloc_enabled=true
 160 LIBS="$LIBS -ltcmalloc_minimal"
 161  ;;
 162   no)  tcmalloc_enabled=false ;;
 163   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 164 esac],[tcmalloc_enabled=false])
 165
 166
 167 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 168 dnl flag determination logic.
 169 CFLAGS="${CFLAGS:-}"
 170
 171 dnl --------------------
 172 dnl Check CC and friends
 173 dnl --------------------
 174 dnl note orig_cflags is also used further down
 175 orig_cflags="$CFLAGS"
 176 orig_cxxflags="$CXXFLAGS"
 177 AC_LANG([C])
 178 AC_PROG_CC
 179 AC_PROG_CPP
 180 AC_PROG_CXX
 181 AM_PROG_CC_C_O
 182 dnl remove autoconf default "-g -O2"
 183 CFLAGS="$orig_cflags"
 184 CXXFLAGS="$orig_cxxflags"
 185 AC_PROG_CC_C99
 186 dnl NB: see C11 below
 187
 188 PKG_PROG_PKG_CONFIG
 189
 190 dnl it's 2019, sed is sed.
 191 SED=sed
 192 AC_SUBST([SED])
 193
 194 dnl try and enable CFLAGS that are useful for FRR
 195 dnl - specifically, options to control warnings
 196
 197 AC_USE_SYSTEM_EXTENSIONS
 198 AC_DEFUN([AC_C_FLAG], [{
 199     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 200     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 201         AC_LANG_PUSH([C])
 202         ac_c_flag_save="$CFLAGS"
 203         CFLAGS="$CFLAGS $1"
 204         AC_COMPILE_IFELSE(
 205                 [AC_LANG_PROGRAM([[$4]])],
 206                 [
 207                         cachename=yes
 208                 ], [
 209                         cachename=no
 210                 ])
 211         CFLAGS="$ac_c_flag_save"
 212         AC_LANG_POP([C])
 213     ])
 214     if test "$cachename" = "yes"; then
 215         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 216     else
 217         :
 218         $2
 219     fi
 220     m4_popdef([cachename])
 221 }])
 222
 223 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 224         AC_LANG_PUSH([C])
 225         ac_cflags_save="$CFLAGS"
 226         ac_libs_save="$LIBS"
 227         CFLAGS="$CFLAGS $1"
 228         LIBS="$LIBS $2"
 229         AC_LINK_IFELSE(
 230                 [$3],
 231                 [
 232                         CFLAGS="$ac_cflags_save"
 233                         LIBS="$ac_libs_save"
 234                         m4_default([$5], [
 235                                 AC_MSG_RESULT([yes])
 236                         ])
 237                 ], [
 238                         CFLAGS="$ac_cflags_save"
 239                         LIBS="$ac_libs_save"
 240                         m4_default([$4], [
 241                                 AC_MSG_RESULT([no])
 242                         ])
 243                 ])
 244         AC_LANG_POP([C])
 245         }])
 246
 247 dnl ICC won't bail on unknown options without -diag-error 10006
 248 dnl need to do this first so we get useful results for the other options
 249 AC_C_FLAG([-diag-error 10006])
 250
 251 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 252 ac_cc="$CC"
 253 CC="${CC% -std=gnu99}"
 254 CC="${CC% -std=c99}"
 255
 256 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 257
 258 dnl if the user has specified any CFLAGS, override our settings
 259 if test "$enable_gcov" = "yes"; then
 260    if test "$orig_cflags" = ""; then
 261       AC_C_FLAG([-coverage])
 262       AC_C_FLAG([-O0])
 263    fi
 264
 265    LDFLAGS="${LDFLAGS} -lgcov"
 266 fi
 267
 268 if test "$enable_clang_coverage" = "yes"; then
 269    AC_C_FLAG([-fprofile-instr-generate], [
 270      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 271    ])
 272    AC_C_FLAG([-fcoverage-mapping], [
 273      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 274    ])
 275 fi
 276
 277 if test "$enable_dev_build" = "yes"; then
 278    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 279    if test "$orig_cflags" = ""; then
 280       AC_C_FLAG([-g3])
 281       AC_C_FLAG([-O0])
 282    fi
 283    if test "$enable_lua" = "yes"; then
 284       AX_PROG_LUA([5.3])
 285       AX_LUA_HEADERS
 286       AX_LUA_LIBS([
 287          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 288          LIBS="$LIBS $LUA_LIB"
 289       ])
 290    fi
 291 else
 292    if test "$enable_lua" = "yes"; then
 293       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 294    fi
 295    if test "$orig_cflags" = ""; then
 296       AC_C_FLAG([-g])
 297       AC_C_FLAG([-O2])
 298    fi
 299 fi
 300 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 301
 302 dnl always want these CFLAGS
 303 AC_C_FLAG([-fno-omit-frame-pointer])
 304 AC_C_FLAG([-funwind-tables])
 305 AC_C_FLAG([-Wall])
 306 AC_C_FLAG([-Wextra])
 307 AC_C_FLAG([-Wmissing-prototypes])
 308 AC_C_FLAG([-Wmissing-declarations])
 309 AC_C_FLAG([-Wpointer-arith])
 310 AC_C_FLAG([-Wbad-function-cast])
 311 AC_C_FLAG([-Wwrite-strings])
 312 AC_C_FLAG([-Wundef])
 313 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 314   AC_C_FLAG([-Wcast-qual])
 315   AC_C_FLAG([-Wstrict-prototypes])
 316   AC_C_FLAG([-Wmissing-noreturn])
 317   AC_C_FLAG([-Wmissing-format-attribute])
 318   AC_C_FLAG([-Wunreachable-code])
 319   AC_C_FLAG([-Wpacked])
 320   AC_C_FLAG([-Wpadded])
 321   AC_C_FLAG([-Wshadow])
 322 else
 323   AC_C_FLAG([-Wno-unused-result])
 324 fi
 325 AC_C_FLAG([-Wno-unused-parameter])
 326 AC_C_FLAG([-Wno-missing-field-initializers])
 327
 328 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 329 AC_SUBST([CXX_COMPAT_CFLAGS])
 330
 331 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 332 dnl for some reason the string consts get 'promoted' to char *,
 333 dnl triggering a const to non-const conversion warning.
 334 AC_C_FLAG([-diag-disable 3179])
 335
 336 if test "$enable_werror" = "yes" ; then
 337   WERROR="-Werror"
 338 fi
 339 AC_SUBST([WERROR])
 340
 341 SAN_FLAGS=""
 342 if test "$enable_address_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=address], [
 344     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 347   ])
 348 fi
 349 if test "$enable_thread_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=thread], [
 351     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 354   ])
 355 fi
 356 if test "$enable_memory_sanitizer" = "yes"; then
 357   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 358     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 359   ], [
 360     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 361   ])
 362 fi
 363 if test "$enable_undefined_sanitizer" = "yes"; then
 364   AC_C_FLAG([-fsanitize=undefined], [
 365     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 366   ], [
 367     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 368   ])
 369 fi
 370 AC_SUBST([SAN_FLAGS])
 371
 372 dnl frr-format.so
 373 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 374   AC_C_FLAG([-fplugin=${with_frr_format}], [
 375     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 376   ],,[
 377 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 378 #error plugin not loaded
 379 #endif
 380 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 381 #error plugin too old
 382 #endif
 383   ])
 384 elif test "$with_frr_format" = "no"; then
 385   : #nothing
 386 else
 387   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 388     AC_C_FLAG([-fplugin=frr-format],[
 389       if test "$with_frr_format" = "yes"; then
 390         AC_MSG_ERROR([frr-format plugin requested but not found])
 391       fi
 392     ],,[
 393 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 394 #error plugin not loaded
 395 #endif
 396 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 397 #error plugin too old
 398 #endif
 399     ])
 400   ],,[
 401 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 402 #error plugin not loaded
 403 #endif
 404 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 405 #error plugin too old
 406 #endif
 407   ])
 408 fi
 409
 410 dnl ----------
 411 dnl Essentials
 412 dnl ----------
 413
 414 AX_PTHREAD([
 415   CC="$PTHREAD_CC"
 416   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 417   LIBS="$PTHREAD_LIBS $LIBS"
 418 ], [
 419   AC_MSG_FAILURE([This FRR version needs pthreads])
 420 ])
 421
 422 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 423                 [frr_cv_pthread_condattr_setclock=yes],
 424                 [frr_cv_pthread_condattr_setclock=no])
 425 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 426   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 427 fi
 428
 429 dnl --------------
 430 dnl Check programs
 431 dnl --------------
 432 AC_PROG_INSTALL
 433 AC_PROG_LN_S
 434 AC_CHECK_TOOL([AR], [ar])
 435
 436 dnl -------
 437 dnl libtool
 438 dnl -------
 439 AC_ARG_ENABLE([static-bin],
 440   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 441 LT_INIT
 442 _LT_CONFIG_LIBTOOL([
 443   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 444     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 445   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 446   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 447   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 448 ])
 449 if test "$enable_static_bin" = "yes"; then
 450   AC_LDFLAGS="-static"
 451   if test "$enable_static" != "yes"; then
 452     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 453   fi
 454 fi
 455 if test "$enable_shared" != "yes"; then
 456   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 457 fi
 458 AC_SUBST([AC_LDFLAGS])
 459 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 460
 461 AC_ARG_ENABLE([rpath],
 462   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 463   [],
 464   [enable_rpath=yes])
 465
 466 dnl $AR and $RANLIB are set by LT_INIT above
 467 AC_MSG_CHECKING([whether $AR supports D option])
 468 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 469   AC_MSG_RESULT([yes])
 470   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 471   ARFLAGS="crD"
 472   AR_FLAGS="crD"
 473 else
 474   AC_MSG_RESULT([no])
 475   ARFLAGS="cru"
 476   AR_FLAGS="cru"
 477 fi
 478 AC_SUBST([ARFLAGS])
 479 AC_SUBST([AR_FLAGS])
 480
 481 AC_MSG_CHECKING([whether $RANLIB supports D option])
 482 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 483   if grep -q -- '-D' conftest.err; then
 484     AC_MSG_RESULT([no])
 485   else
 486     AC_MSG_RESULT([yes])
 487     RANLIB="$RANLIB -D"
 488   fi
 489 else
 490   AC_MSG_RESULT([no])
 491 fi
 492 AC_SUBST([RANLIB])
 493
 494 test -f conftest.err && rm conftest.err
 495 test -f conftest.a && rm conftest.a
 496
 497 dnl ----------------------
 498 dnl Packages configuration
 499 dnl ----------------------
 500 if test -f config.version; then
 501   . ./config.version
 502 elif test -f "${srcdir}/config.version"; then
 503   . "${srcdir}/config.version"
 504 fi
 505 AC_ARG_WITH([pkg-extra-version],
 506   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 507   if test "$withval" = "no"; then
 508     EXTRAVERSION=
 509   else
 510     EXTRAVERSION=$withval
 511   fi
 512 ], [])
 513 AC_ARG_WITH([pkg-git-version],
 514         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 515         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 516 AC_ARG_WITH([clippy],
 517   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 518 AC_ARG_WITH([vtysh_pager],
 519         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 520         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 521 AC_ARG_ENABLE([vtysh],
 522   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 523 AC_ARG_ENABLE([doc],
 524   AS_HELP_STRING([--disable-doc], [do not build docs]))
 525 AC_ARG_ENABLE([doc-html],
 526   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 527 AC_ARG_ENABLE([zebra],
 528   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 529 AC_ARG_ENABLE([bgpd],
 530   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 531 AC_ARG_ENABLE([ripd],
 532   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 533 AC_ARG_ENABLE([ripngd],
 534   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 535 AC_ARG_ENABLE([ospfd],
 536   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 537 AC_ARG_ENABLE([ospf6d],
 538   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 539 AC_ARG_ENABLE([ldpd],
 540   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 541 AC_ARG_ENABLE([nhrpd],
 542   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 543 AC_ARG_ENABLE([eigrpd],
 544   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 545 AC_ARG_ENABLE([babeld],
 546   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 547 AC_ARG_ENABLE([watchfrr],
 548   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 549 AC_ARG_ENABLE([isisd],
 550   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 551 AC_ARG_ENABLE([pimd],
 552   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 553 AC_ARG_ENABLE([pbrd],
 554   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 555 AC_ARG_ENABLE([sharpd],
 556   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 557 AC_ARG_ENABLE([staticd],
 558   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 559 AC_ARG_ENABLE([fabricd],
 560   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 561 AC_ARG_ENABLE([vrrpd],
 562   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 563 AC_ARG_ENABLE([bgp-announce],
 564   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 565 AC_ARG_ENABLE([bgp-vnc],
 566   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 567 AC_ARG_ENABLE([bgp-bmp],
 568   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 569 AC_ARG_ENABLE([snmp],
 570   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 571 AC_ARG_ENABLE([config_rollbacks],
 572   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 573 AC_ARG_ENABLE([confd],
 574   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 575 AC_ARG_ENABLE([sysrepo],
 576   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 577 AC_ARG_ENABLE([grpc],
 578   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 579 AC_ARG_ENABLE([zeromq],
 580   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 581 AC_ARG_ENABLE([lttng],
 582   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 583 AC_ARG_ENABLE([usdt],
 584   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 585 AC_ARG_WITH([libpam],
 586   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 587 AC_ARG_ENABLE([ospfapi],
 588   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 589 AC_ARG_ENABLE([ospfclient],
 590   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 591                           (this is the default if --disable-ospfapi is set)]))
 592 AC_ARG_ENABLE([multipath],
 593   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 594 AC_ARG_ENABLE([user],
 595   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 596 AC_ARG_ENABLE([group],
 597   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 598 AC_ARG_ENABLE([vty_group],
 599   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 600 AC_ARG_ENABLE([configfile_mask],
 601   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 602 AC_ARG_ENABLE([logfile_mask],
 603   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 604 AC_ARG_ENABLE([shell_access],
 605   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 606 AC_ARG_ENABLE([realms],
 607   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 608 AC_ARG_ENABLE([rtadv],
 609   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 610 AC_ARG_ENABLE([irdp],
 611   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 612 AC_ARG_ENABLE([capabilities],
 613   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 614 AC_ARG_ENABLE([rusage],
 615   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 616 AC_ARG_ENABLE([gcc_ultra_verbose],
 617   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 618 AC_ARG_ENABLE([backtrace],
 619   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 620 AC_ARG_ENABLE([time-check],
 621   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 622 AC_ARG_ENABLE([cpu-time],
 623   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 624 AC_ARG_ENABLE([pcreposix],
 625   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 626 AC_ARG_ENABLE([fpm],
 627   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 628 AC_ARG_ENABLE([systemd],
 629   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 630 AC_ARG_ENABLE([werror],
 631   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 632 AC_ARG_ENABLE([cumulus],
 633   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 634 AC_ARG_ENABLE([datacenter],
 635   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 636 AC_ARG_ENABLE([rr-semantics],
 637   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 638 AC_ARG_ENABLE([protobuf],
 639   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 640 AC_ARG_ENABLE([oldvpn_commands],
 641   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 642 AC_ARG_ENABLE([rpki],
 643   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 644 AC_ARG_ENABLE([clippy-only],
 645   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 646 AC_ARG_ENABLE([numeric_version],
 647   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 648 AC_ARG_ENABLE([gcov],
 649   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 650 AC_ARG_ENABLE([clang_coverage],
 651   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 652 AC_ARG_ENABLE([bfdd],
 653   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 654 AC_ARG_ENABLE([address-sanitizer],
 655   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 656 AC_ARG_ENABLE([thread-sanitizer],
 657   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 658 AC_ARG_ENABLE([memory-sanitizer],
 659   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 660 AC_ARG_ENABLE([undefined-sanitizer],
 661   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 662 AC_ARG_WITH([crypto],
 663   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 664 AC_ARG_WITH([frr-format],
 665   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 666
 667 AC_ARG_ENABLE([version-build-config],
 668   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 669
 670 #if openssl, else use the internal
 671 AS_IF([test "$with_crypto" = "openssl"], [
 672 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 673 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 674   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 675 else
 676   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 677 fi
 678 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 679 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 680 )
 681
 682 AS_IF([test "$enable_clippy_only" != "yes"], [
 683 AC_CHECK_HEADERS([json-c/json.h])
 684 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 685 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 686   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 687   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 688       AC_MSG_ERROR([libjson is needed to compile])
 689   fi
 690 fi
 691 ])
 692
 693 AC_ARG_ENABLE([dev_build],
 694     AS_HELP_STRING([--enable-dev-build], [build for development]))
 695
 696 AC_ARG_ENABLE([lua],
 697     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 698
 699 AC_ARG_ENABLE([netlink-debug],
 700   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 701
 702 if test "$enable_netlink_debug" != "no" ; then
 703   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 704 fi
 705
 706 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 707
 708 if test "$enable_time_check" != "no" ; then
 709   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 710     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 711   else
 712     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 713   fi
 714 fi
 715
 716 case "${enable_cpu_time}" in
 717   "no")
 718   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 719   ;;
 720   "*")
 721   ;;
 722 esac
 723
 724 case "${enable_systemd}" in
 725   "no") ;;
 726   "yes")
 727   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 728   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 729     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 730   else
 731     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 732   fi
 733   ;;
 734   "*") ;;
 735 esac
 736
 737 if test "$enable_rr_semantics" != "no" ; then
 738   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 739 fi
 740
 741 if test "$enable_datacenter" = "yes" ; then
 742   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 743   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 744   DFLT_NAME="datacenter"
 745 else
 746   DFLT_NAME="traditional"
 747 fi
 748
 749 if test "$enable_cumulus" = "yes" ; then
 750   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 751 fi
 752
 753 AC_SUBST([DFLT_NAME])
 754 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 755
 756 if test "$enable_shell_access" = "yes"; then
 757    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 758 fi
 759
 760 #
 761 # Python for clippy
 762 #
 763
 764 AS_IF([test "$host" = "$build"], [
 765   FRR_PYTHON_DEV
 766 ], [
 767   FRR_PYTHON
 768 ])
 769
 770 FRR_PYTHON_MODULES([pytest])
 771
 772 if test "$enable_doc" != "no"; then
 773   FRR_PYTHON_MODULES([sphinx], , [
 774     if test "$enable_doc" = "yes"; then
 775       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 776     fi
 777   ])
 778 fi
 779 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 780 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 781
 782 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 783   PYSPHINX="-m sphinx"
 784 ], [
 785   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 786 ])
 787 AC_SUBST([PYSPHINX])
 788
 789 #
 790 # Logic for old vpn commands support.
 791 #
 792 if test "$enable_oldvpn_commands" = "yes"; then
 793    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 794 fi
 795
 796 #
 797 # End of logic for protobuf support.
 798 #
 799
 800 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 801 if test "$enable_rtadv" != "no"; then
 802   AC_MSG_RESULT([yes])
 803   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 804 else
 805   AC_MSG_RESULT([no])
 806 fi
 807
 808 if test "$enable_user" = "no"; then
 809   enable_user=""
 810 else
 811   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 812     enable_user="frr"
 813   fi
 814   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 815 fi
 816
 817 if test "$enable_group" = "no"; then
 818   enable_group=""
 819 else
 820   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 821     enable_group="frr"
 822   fi
 823   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 824 fi
 825
 826 if test "$enable_vty_group" = "yes" ; then
 827   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 828 elif test "$enable_vty_group" != ""; then
 829   if test "$enable_vty_group" != "no"; then
 830     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 831   fi
 832 fi
 833 AC_SUBST([enable_user])
 834 AC_SUBST([enable_group])
 835 AC_SUBST([enable_vty_group])
 836
 837 enable_configfile_mask=${enable_configfile_mask:-0600}
 838 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 839 AC_SUBST([enable_configfile_mask])
 840
 841 enable_logfile_mask=${enable_logfile_mask:-0600}
 842 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 843
 844 MPATH_NUM=16
 845
 846 case "${enable_multipath}" in
 847   0)
 848     MPATH_NUM=64
 849     ;;
 850   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 851     MPATH_NUM="${enable_multipath}"
 852     ;;
 853   "")
 854     ;;
 855   *)
 856     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 857     ;;
 858 esac
 859
 860 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 861
 862 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 863
 864 dnl --------------------
 865 dnl Enable code coverage
 866 dnl --------------------
 867 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 868
 869 dnl ------------------------------------
 870 dnl Alpine only accepts numeric versions
 871 dnl ------------------------------------
 872 if test "$enable_numeric_version" != "" ; then
 873   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 874   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 875 fi
 876
 877 dnl -----------------------------------
 878 dnl Add extra version string to package
 879 dnl name, string and version fields.
 880 dnl -----------------------------------
 881 if test "$EXTRAVERSION" != "" ; then
 882   VERSION="${VERSION}${EXTRAVERSION}"
 883   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 884   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 885   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 886 fi
 887 AC_SUBST([EXTRAVERSION])
 888
 889 if test "$with_pkg_git_version" = "yes"; then
 890         if test -e "${srcdir}/.git"; then
 891                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 892         else    with_pkg_git_version="no"
 893                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 894         fi
 895 fi
 896 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 897
 898 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 899 if test "$OBJCOPY" != ":"; then
 900   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 901     frr_cv_interp=""
 902     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 903       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 904         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 905       fi
 906       test -f conftest.interp && rm conftest.interp
 907     ])
 908   ])
 909 fi
 910 if test -n "$frr_cv_interp"; then
 911   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 912 fi
 913
 914 dnl -------------------------
 915 dnl Check other header files.
 916 dnl -------------------------
 917 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 918         linux/version.h asm/types.h])
 919
 920 ac_stdatomic_ok=false
 921 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 922 AC_CHECK_HEADER([stdatomic.h],[
 923
 924   AC_MSG_CHECKING([whether _Atomic qualifier works])
 925   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 926 #include <stdatomic.h>
 927 int main(int argc, char **argv) {
 928   _Atomic int i = 0;
 929   return i;
 930 }
 931 ]])], [
 932     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 933     AC_MSG_RESULT([yes])
 934     ac_stdatomic_ok=true
 935   ], [
 936     AC_MSG_RESULT([no])
 937   ])
 938 ])
 939
 940 AS_IF([$ac_stdatomic_ok], [true], [
 941   AC_MSG_CHECKING([for __atomic_* builtins])
 942   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 943 int main(int argc, char **argv) {
 944   volatile int i = 1;
 945   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 946   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 947 }
 948 ]])], [
 949     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 950     AC_MSG_RESULT([yes])
 951   ], [
 952     AC_MSG_RESULT([no])
 953
 954     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 955     AC_MSG_CHECKING([for __sync_* builtins])
 956     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 957 int main(int argc, char **argv) {
 958   volatile int i = 1;
 959   __sync_fetch_and_sub (&i, 1);
 960   return __sync_val_compare_and_swap (&i, 0, 1);
 961 }
 962 ]])], [
 963       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 964       AC_MSG_RESULT([yes])
 965
 966       AC_MSG_CHECKING([for __sync_swap builtin])
 967       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 968 int main(int argc, char **argv) {
 969   volatile int i = 1;
 970   return __sync_swap (&i, 2);
 971 }
 972 ]])], [
 973         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 974         AC_MSG_RESULT([yes])
 975       ], [
 976         AC_MSG_RESULT([no])
 977       ])
 978
 979     ], [
 980       AC_MSG_RESULT([no])
 981       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 982     ])
 983   ])
 984 ])
 985
 986 AC_CHECK_HEADERS([pthread_np.h],,, [
 987 #include <pthread.h>
 988 ])
 989 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 990
 991 needsync=true
 992
 993 AS_IF([$needsync], [
 994   dnl Linux
 995   AC_MSG_CHECKING([for Linux futex() support])
 996   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 997 #ifndef _GNU_SOURCE
 998 #define _GNU_SOURCE
 999 #endif
1000 #include <unistd.h>
1001 #include <limits.h>
1002 #include <sys/time.h>
1003 #include <sys/syscall.h>
1004 #include <linux/futex.h>
1005
1006 int main(void);
1007 ],
1008 [
1009 {
1010   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1011 }
1012 ])], [
1013     AC_MSG_RESULT([yes])
1014     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1015     needsync=false
1016   ], [
1017     AC_MSG_RESULT([no])
1018   ])
1019 ])
1020
1021 AS_IF([$needsync], [
1022   dnl FreeBSD
1023   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1024   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1025 #include <errno.h>
1026 #include <stdlib.h>
1027 #include <sys/types.h>
1028 #include <sys/umtx.h>
1029 int main(void);
1030 ],
1031 [
1032 {
1033   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1034 }
1035 ])], [
1036     AC_MSG_RESULT([yes])
1037     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1038     needsync=false
1039   ], [
1040     AC_MSG_RESULT([no])
1041   ])
1042 ])
1043
1044 AS_IF([$needsync], [
1045   dnl OpenBSD patch (not upstream at the time of writing this)
1046   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1047   AC_MSG_CHECKING([for OpenBSD futex() support])
1048   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1049 #include <sys/futex.h>
1050 int main(void);
1051 ],
1052 [
1053 {
1054   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1055 }
1056 ])], [
1057     AC_MSG_RESULT([yes])
1058     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1059     needsync=false
1060   ], [
1061     AC_MSG_RESULT([no])
1062   ])
1063 ])
1064
1065 dnl Utility macro to avoid retyping includes all the time
1066 m4_define([FRR_INCLUDES],
1067 [#ifdef SUNOS_5
1068 #define _POSIX_C_SOURCE 200809L
1069 #define __EXTENSIONS__
1070 #endif
1071 #include <stdio.h>
1072 #include <stdlib.h>
1073 #include <stddef.h>
1074 #include <sys/types.h>
1075 /* sys/conf.h depends on param.h on FBSD at least */
1076 #include <sys/param.h>
1077 /* Required for MAXSIG */
1078 #include <signal.h>
1079 #include <sys/socket.h>
1080 #ifdef __APPLE__
1081 # define __APPLE_USE_RFC_3542
1082 #endif
1083 #include <netinet/in.h>
1084 #include <sys/time.h>
1085 #include <time.h>
1086 #include <net/if.h>
1087 ])dnl
1088
1089 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1090 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1091 dnl an additional round for it.
1092
1093 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1094
1095 m4_define([FRR_INCLUDES],
1096 FRR_INCLUDES
1097 [#ifdef HAVE_NET_IF_VAR_H
1098 # include <net/if_var.h>
1099 #endif
1100 ])dnl
1101
1102 AC_CHECK_HEADERS([netinet/in_var.h \
1103         net/if_dl.h net/netopt.h \
1104         inet/nd.h netinet/ip_icmp.h \
1105         sys/sysctl.h sys/sockio.h sys/conf.h],
1106         [], [], [FRR_INCLUDES])
1107
1108 AC_CHECK_HEADERS([ucontext.h], [], [],
1109 [#ifndef __USE_GNU
1110 #define __USE_GNU
1111 #endif /* __USE_GNU */
1112 FRR_INCLUDES
1113 ])
1114
1115 m4_define([UCONTEXT_INCLUDES],
1116 [#include <ucontext.h>])dnl
1117
1118 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1119   [], [], [UCONTEXT_INCLUDES])
1120 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1121   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1122    [], [], [UCONTEXT_INCLUDES])],
1123   [], [UCONTEXT_INCLUDES])
1124 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1125   [], [], [UCONTEXT_INCLUDES])
1126
1127 m4_define([FRR_INCLUDES],
1128 FRR_INCLUDES
1129 [
1130 #include <sys/un.h>
1131 #include <netinet/in_systm.h>
1132 #ifdef HAVE_NETINET_IN_VAR_H
1133 # include <netinet/in_var.h>
1134 #endif
1135 #ifdef HAVE_NET_IF_DL_H
1136 # include <net/if_dl.h>
1137 #endif
1138 #ifdef HAVE_NET_NETOPT_H
1139 # include <net/netopt.h>
1140 #endif
1141 #include <net/route.h>
1142 #ifdef HAVE_INET_ND_H
1143 # include <inet/nd.h>
1144 #endif
1145 #include <arpa/inet.h>
1146 /* Required for IDRP */
1147 #ifdef HAVE_NETINET_IP_ICMP_H
1148 # include <netinet/ip_icmp.h>
1149 #endif
1150 ])dnl
1151
1152 dnl V6 headers are checked below, after we check for v6
1153
1154 is_linux=false
1155
1156 AC_MSG_CHECKING([which operating system interface to use])
1157 case "$host_os" in
1158   sunos* | solaris2*)
1159     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1160     ;;
1161   linux*)
1162     AC_MSG_RESULT([Linux])
1163
1164     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1165     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1166     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1167
1168     dnl Linux has a compilation problem with mixing
1169     dnl netinet/in.h and linux/in6.h they are not
1170     dnl compatible.  There has been discussion on
1171     dnl how to fix it but no real progress on implementation
1172     dnl when they fix it, remove this
1173     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1174
1175     is_linux=true
1176     ;;
1177   openbsd*)
1178     AC_MSG_RESULT([OpenBSD])
1179
1180     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1181     AC_DEFINE([KAME], [1], [KAME IPv6])
1182     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1183     ;;
1184   *)
1185     AC_MSG_RESULT([BSD])
1186
1187     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1188     AC_DEFINE([KAME], [1], [KAME IPv6])
1189     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1190     ;;
1191 esac
1192 AM_CONDITIONAL([LINUX], [${is_linux}])
1193
1194 AC_SYS_LARGEFILE
1195
1196 dnl ------------------------
1197 dnl Integrated REALMS option
1198 dnl ------------------------
1199 if test "$enable_realms" = "yes"; then
1200     case "$host_os" in
1201       linux*)
1202        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1203        ;;
1204       *)
1205        echo "Sorry, only Linux has REALMS support"
1206        exit 1
1207        ;;
1208     esac
1209 fi
1210
1211 dnl -------------------------------
1212 dnl Endian-ness check
1213 dnl -------------------------------
1214 AC_WORDS_BIGENDIAN
1215
1216 dnl ---------------
1217 dnl other functions
1218 dnl ---------------
1219 AC_CHECK_FUNCS([ \
1220         strlcat strlcpy \
1221         getgrouplist \
1222         openat \
1223         unlinkat \
1224         posix_fallocate \
1225         ])
1226
1227 dnl ##########################################################################
1228 dnl LARGE if block spans a lot of "configure"!
1229 if test "$enable_clippy_only" != "yes"; then
1230 dnl ##########################################################################
1231
1232 #
1233 # Logic for protobuf support.
1234 #
1235 PROTO3=false
1236 if test "$enable_protobuf" = "yes"; then
1237   # Check for protoc & protoc-c
1238
1239   # protoc is not required, it's only for a "be nice" helper target
1240   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1241
1242   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1243   if test "$PROTOC_C" = "/bin/false"; then
1244     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1245   fi
1246
1247   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1248     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1249   ])
1250
1251   PROTO3=true
1252   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1253                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1254                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1255                                             [1], [Have Protobuf version 3]),
1256                                   [PROTO3=false],
1257                                   [#include <google/protobuf-c/protobuf-c.h>])],
1258                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1259
1260   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1261 fi
1262
1263
1264 dnl ---------------------
1265 dnl Integrated VTY option
1266 dnl ---------------------
1267 case "${enable_vtysh}" in
1268 "no")
1269   VTYSH="";;
1270 *)
1271   VTYSH="vtysh";
1272   AC_DEFINE([VTYSH], [1], [VTY shell])
1273
1274   prev_libs="$LIBS"
1275   AC_CHECK_LIB([readline], [main], [
1276     LIBREADLINE="-lreadline"
1277   ], [
1278     dnl readline failed - it might be incorrectly linked and missing its
1279     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1280     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1281       LIBREADLINE="$ac_cv_search_tputs"
1282     ], [
1283       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1284     ])
1285
1286     dnl re-try with the lib we found above
1287     unset ac_cv_lib_readline_main
1288     AC_CHECK_LIB([readline], [main], [
1289       LIBREADLINE="-lreadline $LIBREADLINE"
1290     ], [
1291       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1292     ], [$LIBREADLINE])
1293   ], [])
1294   LIBS="$prev_libs"
1295
1296   AC_CHECK_HEADER([readline/history.h])
1297   if test "$ac_cv_header_readline_history_h" = "no"; then
1298     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1299   fi
1300   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1301   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1302     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1303   fi
1304   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1305   if test "$frr_cv_append_history" = "yes"; then
1306     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1307   fi
1308   ;;
1309 esac
1310 AC_SUBST([LIBREADLINE])
1311
1312 dnl ----------
1313 dnl PAM module
1314 dnl
1315 dnl FRR detects the PAM library it is built against by checking for a
1316 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1317 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1318 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1319 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1320 dnl of OpenPAM.
1321 dnl ----------
1322 if test "$with_libpam" = "yes"; then
1323   AC_CHECK_HEADER([security/pam_misc.h],
1324     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1325      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1326      pam_conv_func="misc_conv"
1327     ],
1328     [], FRR_INCLUDES)
1329   AC_CHECK_HEADER([security/openpam.h],
1330     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1331      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1332      pam_conv_func="openpam_ttyconv"
1333     ],
1334     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1335   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1336     AC_MSG_WARN([*** pam support will not be built ***])
1337     with_libpam="no"
1338   fi
1339 fi
1340
1341 if test "$with_libpam" = "yes"; then
1342 dnl took this test from proftpds configure.in and suited to our needs
1343 dnl -------------------------------------------------------------------------
1344 dnl
1345 dnl This next check looks funky due to a linker problem with some versions
1346 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1347 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1348 dnl with RedHat 6.2 and Debian 2.2 or better.
1349 AC_CHECK_LIB([pam], [pam_start],
1350   [AC_CHECK_LIB([pam], [$pam_conv_func],
1351     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1352      LIBPAM="-lpam"],
1353     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1354      LIBPAM="-lpam -lpam_misc"]
1355     )
1356   ],
1357
1358   [AC_CHECK_LIB([pam], [pam_end],
1359     [AC_CHECK_LIB([pam], [$pam_conv_func],
1360       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1361        LIBPAM="-lpam -ldl"],
1362       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1363        LIBPAM="-lpam -ldl -lpam_misc"]
1364      )
1365   ],AC_MSG_WARN([*** pam support will not be built ***]),
1366   [-ldl])
1367   ]
1368 )
1369 fi
1370 AC_SUBST([LIBPAM])
1371
1372 dnl -------------------------------
1373 dnl bgpd needs pow() and hence libm
1374 dnl -------------------------------
1375 TMPLIBS="$LIBS"
1376 LIBS=""
1377 AC_SEARCH_LIBS([pow], [m], [
1378   LIBM="$LIBS"
1379 ], [
1380   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1381 ])
1382 LIBS="$TMPLIBS"
1383 AC_SUBST([LIBM])
1384
1385 AC_CHECK_FUNCS([ppoll], [
1386   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1387 ])
1388 AC_CHECK_FUNCS([pollts], [
1389   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1390 ])
1391
1392 AC_CHECK_HEADER([asm-generic/unistd.h],
1393                 [AC_CHECK_DECL(__NR_setns,
1394                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1395                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1396                                ])
1397                  AC_CHECK_FUNCS([setns])]
1398                )
1399
1400 dnl --------------------------
1401 dnl Determine IS-IS I/O method
1402 dnl --------------------------
1403 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1404 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1405 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1406 AC_CHECK_HEADER([net/bpf.h])
1407 AC_CHECK_HEADER([sys/dlpi.h])
1408 AC_MSG_CHECKING([zebra IS-IS I/O method])
1409
1410 case "$host_os" in
1411   linux*)
1412     AC_MSG_RESULT([pfpacket])
1413     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1414     ;;
1415   *)
1416     if test "$ac_cv_header_net_bpf_h" = "no"; then
1417       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1418         AC_MSG_RESULT([none])
1419         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1420           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1421         fi
1422         AC_MSG_WARN([*** IS-IS support will not be built ***])
1423         enable_isisd="no"
1424         enable_fabricd="no"
1425       else
1426         AC_MSG_RESULT([DLPI])
1427       fi
1428       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1429     else
1430       AC_MSG_RESULT([BPF])
1431       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1432     fi
1433     ;;
1434 esac
1435 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1436
1437 dnl ---------------------------------------------------------------
1438 dnl figure out how to specify an interface in multicast sockets API
1439 dnl ---------------------------------------------------------------
1440 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1441
1442 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1443         #include <sys/socket.h>
1444         #include <netinet/in.h>
1445         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1446         #include <linux/types.h>
1447 ])
1448
1449 m4_define([FRR_INCLUDES],
1450 FRR_INCLUDES
1451 [#ifdef HAVE_LINUX_MROUTE_H
1452 # include <linux/mroute.h>
1453 #endif
1454 ])dnl
1455
1456 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1457         #include <sys/socket.h>
1458         #include <sys/types.h>
1459         #include <netinet/in.h>
1460         #include <net/route.h>
1461 ])
1462
1463 m4_define([FRR_INCLUDES],
1464 FRR_INCLUDES
1465 [#ifdef HAVE_NETINET_IP_MROUTE_H
1466 # include <netinet/ip_mroute.h>
1467 #endif
1468 ])dnl
1469
1470 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1471 AC_TRY_COMPILE([#include <sys/param.h>],
1472 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1473   return (0);
1474 #else
1475   #error No support for BSD struct ip_mreq hack detected
1476 #endif],[AC_MSG_RESULT([yes])
1477 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1478 AC_MSG_RESULT([no]))
1479
1480 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1481 AC_TRY_COMPILE([
1482 #include <sys/types.h>
1483 #include <netinet/in.h>
1484 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1485 ], [AC_MSG_RESULT([yes])
1486 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1487 AC_MSG_RESULT([no]))
1488
1489 dnl ---------------------------------------------------------------
1490 dnl figure out how to check link-state
1491 dnl ---------------------------------------------------------------
1492 AC_CHECK_HEADER([net/if_media.h],
1493   [m4_define([LINK_DETECT_INCLUDES],
1494     FRR_INCLUDES
1495     [#include <net/if_media.h>
1496   ])
1497   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1498     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1499     [], LINK_DETECT_INCLUDES)],
1500   [],
1501   FRR_INCLUDES)
1502
1503 dnl ---------------------------------------------------------------
1504 dnl Additional, newer way to check link-state using ifi_link_state.
1505 dnl Not available in all BSD's when ifmediareq available
1506 dnl ---------------------------------------------------------------
1507 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1508   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1509   [], FRR_INCLUDES)
1510
1511 dnl ------------------------
1512 dnl TCP_MD5SIG socket option
1513 dnl ------------------------
1514
1515 AC_CHECK_HEADER([netinet/tcp.h],
1516    [m4_define([MD5_INCLUDES],
1517       FRR_INCLUDES
1518       [#include <netinet/tcp.h>
1519     ])
1520     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1521    [],
1522    FRR_INCLUDES)
1523 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1524   AC_CHECK_HEADER([linux/tcp.h],
1525        [m4_define([MD5_INCLUDES],
1526           FRR_INCLUDES
1527           [#include <linux/tcp.h>
1528         ])
1529        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1530 fi
1531
1532 AC_CHECK_LIB([crypt], [crypt], [],
1533                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1534 AC_CHECK_LIB([resolv], [res_init])
1535
1536 dnl ---------------------------
1537 dnl check system has PCRE regexp
1538 dnl ---------------------------
1539 if test "$enable_pcreposix" = "yes"; then
1540   AC_CHECK_LIB([pcreposix], [regexec], [], [
1541     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1542   ])
1543 fi
1544 AC_SUBST([HAVE_LIBPCREPOSIX])
1545
1546 dnl ##########################################################################
1547 dnl test "$enable_clippy_only" != "yes"
1548 fi
1549 dnl END OF LARGE if block
1550 dnl ##########################################################################
1551
1552 dnl ------------------
1553 dnl check C-Ares library
1554 dnl ------------------
1555 PKG_CHECK_MODULES([CARES], [libcares], [
1556   c_ares_found=true
1557 ],[
1558   c_ares_found=false
1559 ])
1560 AM_CONDITIONAL([CARES], [$c_ares_found])
1561
1562
1563 dnl ----------------------------------------------------------------------------
1564 dnl figure out if domainname is available in the utsname struct (GNU extension).
1565 dnl ----------------------------------------------------------------------------
1566 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1567
1568 dnl ------------------
1569 dnl IPv6 header checks
1570 dnl ------------------
1571 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1572         netinet6/in6_var.h netinet6/nd6.h], [], [],
1573         FRR_INCLUDES)
1574
1575 m4_define([FRR_INCLUDES],dnl
1576 FRR_INCLUDES
1577 [#ifdef HAVE_NETINET6_IN6_H
1578 #include <netinet6/in6.h>
1579 #endif
1580 #ifdef HAVE_NETINET_IN6_VAR_H
1581 #include <netinet/in6_var.h>
1582 #endif
1583 #include <netinet/icmp6.h>
1584 #ifdef HAVE_NETINET6_IN6_VAR_H
1585 # include <netinet6/in6_var.h>
1586 #endif
1587 #ifdef HAVE_NETINET6_ND6_H
1588 # include <netinet6/nd6.h>
1589 #endif
1590 ])dnl
1591
1592 dnl --------------------
1593 dnl Daemon disable check
1594 dnl --------------------
1595
1596 AS_IF([test "$enable_bgpd" != "no"], [
1597   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1598 ])
1599
1600 AS_IF([test "$enable_ripd" != "no"], [
1601   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1602 ])
1603
1604 AS_IF([test "$enable_ripngd" != "no"], [
1605   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1606 ])
1607
1608 AS_IF([test "$enable_ospfd" != "no"], [
1609   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1610 ])
1611
1612 AS_IF([test "$enable_ospf6d" != "no"], [
1613   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1614 ])
1615
1616 AS_IF([test "$enable_ldpd" != "no"], [
1617   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1618 ])
1619
1620 AS_IF([test "$enable_nhrpd" != "no"], [
1621   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1622 ])
1623
1624 AS_IF([test "$enable_eigrpd" != "no"], [
1625   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1626 ])
1627
1628 AS_IF([test "$enable_babeld" != "no"], [
1629   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1630 ])
1631
1632 AS_IF([test "$enable_isisd" != "no"], [
1633   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1634 ])
1635
1636 AS_IF([test "$enable_pimd" != "no"], [
1637   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1638 ])
1639
1640 AS_IF([test "$enable_pbrd" != "no"], [
1641   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1642 ])
1643
1644 AS_IF([test "$enable_sharpd" = "yes"], [
1645   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1646 ])
1647
1648 AS_IF([test "$enable_staticd" != "no"], [
1649   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1650 ])
1651
1652 AS_IF([test "$enable_fabricd" != "no"], [
1653   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1654 ])
1655
1656 AS_IF([test "$enable_vrrpd" != "no"], [
1657   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1658 ])
1659
1660 if test "$enable_bfdd" = "no"; then
1661   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1662   BFDD=""
1663 else
1664   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1665   BFDD="bfdd"
1666
1667   case $host_os in
1668     linux*)
1669       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1670       ;;
1671
1672     *)
1673       AC_DEFINE([BFD_BSD], [1], [bfdd])
1674       ;;
1675   esac
1676 fi
1677
1678 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1679   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1680 fi
1681
1682 NHRPD=""
1683 case "$host_os" in
1684   linux*)
1685     case "${enable_nhrpd}" in
1686       no)
1687         ;;
1688       yes)
1689         if test "$enable_clippy_only" != "yes"; then
1690         if test "$c_ares_found" != "true" ; then
1691           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1692         fi
1693         fi
1694         NHRPD="nhrpd"
1695         ;;
1696       *)
1697         if test "$c_ares_found" = "true" ; then
1698           NHRPD="nhrpd"
1699         fi
1700         ;;
1701     esac
1702     ;;
1703   *)
1704     if test "$enable_nhrpd" = "yes"; then
1705       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1706     fi
1707     ;;
1708 esac
1709
1710 if test "$enable_watchfrr" = "no";then
1711   WATCHFRR=""
1712 else
1713   WATCHFRR="watchfrr"
1714 fi
1715
1716 OSPFCLIENT=""
1717 if test "$enable_ospfapi" != "no";then
1718     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1719
1720   if test "$enable_ospfclient" != "no";then
1721       OSPFCLIENT="ospfclient"
1722   fi
1723 fi
1724
1725 if test "$enable_bgp_announce" = "no";then
1726   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1727 else
1728   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1729 fi
1730
1731 if test "$enable_bgp_vnc" != "no";then
1732   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1733 fi
1734
1735 bgpd_bmp=false
1736 case "${enable_bmp}" in
1737   no)
1738     ;;
1739   yes)
1740     if test "$c_ares_found" != "true" ; then
1741       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1742     fi
1743     bgpd_bmp=true
1744     ;;
1745   *)
1746     if test "$c_ares_found" = "true" ; then
1747       bgpd_bmp=true
1748     fi
1749     ;;
1750 esac
1751
1752 if test "$enable_version_build_config" != "no";then
1753   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1754 fi
1755
1756 dnl ##########################################################################
1757 dnl LARGE if block
1758 if test "$enable_clippy_only" != "yes"; then
1759 dnl ##########################################################################
1760
1761 dnl ------------------
1762 dnl check Net-SNMP library
1763 dnl ------------------
1764 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1765    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1766    if test "$NETSNMP_CONFIG" = "no"; then
1767       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1768    fi
1769    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1770    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1771    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1772    # among other things we avoid a GPL vs. OpenSSL license conflict here
1773    for removelib in crypto ssl sensors pci wrap; do
1774      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1775    done
1776    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1777    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1778 int main(void);
1779 ],
1780 [
1781 {
1782   return 0;
1783 }
1784 ])], [
1785      AC_MSG_RESULT([no])
1786      AC_MSG_ERROR([--enable-snmp given but not usable])])
1787    case "${enable_snmp}" in
1788      yes)
1789       SNMP_METHOD=agentx
1790       ;;
1791      agentx)
1792       SNMP_METHOD="${enable_snmp}"
1793       ;;
1794      *)
1795       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1796       ;;
1797    esac
1798    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1799    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1800 fi
1801 AC_SUBST([SNMP_LIBS])
1802 AC_SUBST([SNMP_CFLAGS])
1803
1804 dnl ---------------
1805 dnl libyang
1806 dnl ---------------
1807 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1808   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1809 ])
1810 ac_cflags_save="$CFLAGS"
1811 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1812 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1813   AC_MSG_ERROR([m4_normalize([
1814     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1815     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1816   ])
1817 ], [[#include <libyang/libyang.h>]])
1818 CFLAGS="$ac_cflags_save"
1819
1820 dnl ---------------
1821 dnl configuration rollbacks
1822 dnl ---------------
1823 SQLITE3=false
1824 if test "$enable_config_rollbacks" = "yes"; then
1825   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1826     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1827     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1828     SQLITE3=true
1829   ], [
1830     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1831   ])
1832 fi
1833
1834 dnl ---------------
1835 dnl confd
1836 dnl ---------------
1837 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1838    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1839    if test "$CONFD" = "/bin/false"; then
1840       AC_MSG_ERROR([confd was not found on your system.])]
1841    fi
1842    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1843    AC_SUBST([CONFD_CFLAGS])
1844    CONFD_LIBS="-lconfd"
1845    AC_SUBST([CONFD_LIBS])
1846    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1847 fi
1848
1849 dnl ---------------
1850 dnl sysrepo
1851 dnl ---------------
1852 if test "$enable_sysrepo" = "yes"; then
1853   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1854       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1855       SYSREPO=true],
1856       [SYSREPO=false
1857       AC_MSG_ERROR([sysrepo was not found on your system.])]
1858   )
1859 fi
1860
1861 dnl ---------------
1862 dnl gRPC
1863 dnl ---------------
1864 if test "$enable_grpc" = "yes"; then
1865   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1866     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1867     if test "$PROTOC" = "/bin/false"; then
1868       AC_MSG_FAILURE([grpc requested but protoc not found.])
1869     fi
1870
1871     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1872     GRPC=true
1873   ], [
1874     GRPC=false
1875     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1876   ])
1877 fi
1878
1879 dnl -----
1880 dnl LTTng
1881 dnl -----
1882 if test "$enable_lttng" = "yes"; then
1883   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1884     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1885     LTTNG=true
1886   ], [
1887     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1888   ])
1889 fi
1890
1891 dnl ----
1892 dnl USDT
1893 dnl ----
1894 if test "$enable_usdt" = "yes"; then
1895   AC_CHECK_HEADERS([sys/sdt.h], [
1896     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1897     USDT=true
1898   ], [
1899     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1900   ])
1901 fi
1902
1903 dnl ------
1904 dnl ZeroMQ
1905 dnl ------
1906 if test "$enable_zeromq" != "no"; then
1907   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1908     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1909     ZEROMQ=true
1910   ], [
1911     if test "$enable_zeromq" = "yes"; then
1912       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1913     fi
1914   ])
1915 fi
1916
1917 dnl ------------------------------------
1918 dnl Enable RPKI and add librtr to libs
1919 dnl ------------------------------------
1920 if test "$enable_rpki" = "yes"; then
1921   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1922       [RPKI=true],
1923       [RPKI=false
1924       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1925   )
1926 fi
1927
1928 dnl ------------------------------------
1929 dnl pimd is not supported on OpenBSD and MacOS
1930 dnl ------------------------------------
1931 if test "$enable_pimd" != "no"; then
1932 AC_MSG_CHECKING([for pimd OS support])
1933 case "$host_os" in
1934   darwin*)
1935     AC_MSG_RESULT([no])
1936     enable_pimd="no"
1937     ;;
1938   openbsd*)
1939     AC_MSG_RESULT([no])
1940     enable_pimd="no"
1941     ;;
1942   *)
1943     AC_MSG_RESULT([yes])
1944     ;;
1945 esac
1946 fi
1947
1948 dnl -------------------------------------
1949 dnl VRRP is only supported on linux
1950 dnl -------------------------------------
1951 if test "$enable_vrrpd" != "no"; then
1952 AC_MSG_CHECKING([for VRRP OS support])
1953 case "$host_os" in
1954   linux*)
1955     AC_MSG_RESULT([yes])
1956     ;;
1957   *)
1958     AC_MSG_RESULT([no])
1959     enable_vrrpd="no"
1960     ;;
1961 esac
1962 fi
1963
1964 dnl ------------------------------------------
1965 dnl Check whether rtrlib was build with ssh support
1966 dnl ------------------------------------------
1967 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1968 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1969                         [[struct tr_ssh_config config;]])],
1970         [AC_MSG_RESULT([yes])
1971         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1972         AC_MSG_RESULT([no])
1973 )
1974
1975 dnl ---------------
1976 dnl dlopen & dlinfo
1977 dnl ---------------
1978 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1979   AC_MSG_ERROR([unable to find the dlopen()])
1980 ])
1981
1982 AC_CHECK_HEADERS([link.h])
1983
1984 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1985   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1986 #include <stdlib.h>
1987 #ifdef HAVE_LINK_H
1988 #include <link.h>
1989 #endif
1990 #include <dlfcn.h>
1991 ]], [[
1992   char origin[1];
1993   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1994 ]])], [
1995     frr_cv_rtld_di_origin=yes
1996   ], [
1997     frr_cv_rtld_di_origin=no
1998   ])
1999 ])
2000 if test "$frr_cv_rtld_di_origin" = "yes"; then
2001   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2002 fi
2003
2004 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2005   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2006 #include <stdlib.h>
2007 #ifdef HAVE_LINK_H
2008 #include <link.h>
2009 #endif
2010 #include <dlfcn.h>
2011 ]], [[
2012   struct link_map *lm = NULL;
2013   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2014 ]])], [
2015     frr_cv_rtld_di_linkmap=yes
2016   ], [
2017     frr_cv_rtld_di_linkmap=no
2018   ])
2019 ])
2020 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2021   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2022 fi
2023
2024 dnl ##########################################################################
2025 dnl test "$enable_clippy_only" != "yes"
2026 fi
2027 dnl END OF LARGE if block
2028 dnl ##########################################################################
2029
2030 dnl ---------------------------
2031 dnl sockaddr and netinet checks
2032 dnl ---------------------------
2033 AC_CHECK_TYPES([
2034         struct sockaddr_dl,
2035         struct vifctl, struct mfcctl, struct sioc_sg_req,
2036         vifi_t, struct sioc_vif_req, struct igmpmsg,
2037         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2038         struct nd_opt_adv_interval,
2039         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2040         struct nd_opt_rdnss, struct nd_opt_dnssl],
2041         [], [], FRR_INCLUDES)
2042
2043 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2044         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2045         struct sockaddr_dl.sdl_len,
2046         struct if6_aliasreq.ifra_lifetime,
2047         struct nd_opt_adv_interval.nd_opt_ai_type],
2048         [], [], FRR_INCLUDES)
2049
2050 dnl ---------------------------
2051 dnl IRDP/pktinfo/icmphdr checks
2052 dnl ---------------------------
2053
2054 AC_CHECK_TYPES([struct in_pktinfo], [
2055   AC_CHECK_TYPES([struct icmphdr], [
2056     IRDP=true
2057   ], [
2058     IRDP=false
2059   ], [FRR_INCLUDES])
2060 ], [
2061   IRDP=false
2062 ], [FRR_INCLUDES])
2063
2064 case "${enable_irdp}" in
2065 yes)
2066   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2067   ;;
2068 no)
2069   IRDP=false
2070   ;;
2071 esac
2072
2073
2074 dnl -----------------------
2075 dnl checking for IP_PKTINFO
2076 dnl -----------------------
2077 AC_MSG_CHECKING([for IP_PKTINFO])
2078 AC_TRY_COMPILE([#include <netdb.h>], [
2079   int opt = IP_PKTINFO;
2080 ], [
2081   AC_MSG_RESULT([yes])
2082   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2083 ], [
2084   AC_MSG_RESULT([no])
2085 ])
2086
2087 dnl ---------------------------
2088 dnl checking for IP_RECVDSTADDR
2089 dnl ---------------------------
2090 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2091 AC_TRY_COMPILE([#include <netinet/in.h>], [
2092   int opt = IP_RECVDSTADDR;
2093 ], [
2094   AC_MSG_RESULT([yes])
2095   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2096 ], [
2097   AC_MSG_RESULT([no])
2098 ])
2099
2100 dnl ----------------------
2101 dnl checking for IP_RECVIF
2102 dnl ----------------------
2103 AC_MSG_CHECKING([for IP_RECVIF])
2104 AC_TRY_COMPILE([#include <netinet/in.h>], [
2105   int opt = IP_RECVIF;
2106 ], [
2107   AC_MSG_RESULT([yes])
2108   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2109 ], [
2110   AC_MSG_RESULT([no])
2111 ])
2112
2113 dnl ----------------------
2114 dnl checking for SO_BINDANY
2115 dnl ----------------------
2116 AC_MSG_CHECKING([for SO_BINDANY])
2117 AC_TRY_COMPILE([#include <sys/socket.h>], [
2118   int opt = SO_BINDANY;
2119 ], [
2120   AC_MSG_RESULT([yes])
2121   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2122 ], [
2123   AC_MSG_RESULT([no])
2124 ])
2125
2126 dnl ----------------------
2127 dnl checking for IP_FREEBIND
2128 dnl ----------------------
2129 AC_MSG_CHECKING([for IP_FREEBIND])
2130 AC_TRY_COMPILE([#include <netinet/in.h>], [
2131   int opt = IP_FREEBIND;
2132 ], [
2133   AC_MSG_RESULT([yes])
2134   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2135 ], [
2136   AC_MSG_RESULT([no])
2137 ])
2138
2139 dnl --------------------------------------
2140 dnl checking for be32dec existence or not
2141 dnl --------------------------------------
2142 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2143                [#include <sys/endian.h>])
2144
2145 dnl --------------------------------------
2146 dnl checking for clock_time monotonic struct and call
2147 dnl --------------------------------------
2148 AC_CHECK_DECL([CLOCK_MONOTONIC],
2149         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2150          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2151 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2152
2153 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2154   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2155 ])
2156
2157 dnl --------------------------------------
2158 dnl checking for flex and bison
2159 dnl --------------------------------------
2160
2161 AM_PROG_LEX
2162 AC_MSG_CHECKING([version of flex])
2163 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2164 frr_ac_flex_version="${frr_ac_flex_version##* }"
2165 AC_MSG_RESULT([$frr_ac_flex_version])
2166 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2167   LEX="$SHELL $missing_dir/missing flex"
2168   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2169     AC_MSG_WARN([using pregenerated flex output files])
2170   else
2171     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2172   fi
2173   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2174   AC_SUBST([LEXLIB], [''])
2175 ])
2176
2177 AC_PROG_YACC
2178 dnl thanks GNU bison for this b*llshit...
2179 AC_MSG_CHECKING([version of bison])
2180 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2181 frr_ac_bison_version="${frr_ac_bison_version##* }"
2182 frr_ac_bison_missing="false"
2183 case "x${frr_ac_bison_version}x" in
2184   x2.7*)
2185     BISON_OPENBRACE='"'
2186     BISON_CLOSEBRACE='"'
2187     BISON_VERBOSE=''
2188     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2189     ;;
2190   x2.*|x1.*)
2191     AC_MSG_RESULT([$frr_ac_bison_version])
2192     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2193     frr_ac_bison_missing="true"
2194     ;;
2195   x)
2196     AC_MSG_RESULT([none])
2197     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2198     frr_ac_bison_missing="true"
2199     ;;
2200   x3.[012][^0-9]*)
2201     BISON_OPENBRACE='{'
2202     BISON_CLOSEBRACE='}'
2203     BISON_VERBOSE='-Dparse.error=verbose'
2204     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2205     ;;
2206   *)
2207     BISON_OPENBRACE='{'
2208     BISON_CLOSEBRACE='}'
2209     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2210     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2211     ;;
2212 esac
2213 AC_SUBST([BISON_OPENBRACE])
2214 AC_SUBST([BISON_CLOSEBRACE])
2215 AC_SUBST([BISON_VERBOSE])
2216
2217 if $frr_ac_bison_missing; then
2218   YACC="$SHELL $missing_dir/missing bison -y"
2219   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2220     AC_MSG_WARN([using pregenerated bison output files])
2221   else
2222     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2223   fi
2224 fi
2225
2226 dnl -------------------
2227 dnl capabilities checks
2228 dnl -------------------
2229 if test "$enable_capabilities" != "no"; then
2230   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2231   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2232     [AC_MSG_RESULT([yes])
2233      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2234      frr_ac_keepcaps="yes"],
2235      AC_MSG_RESULT([no])
2236   )
2237   if test "$frr_ac_keepcaps" = "yes"; then
2238     AC_CHECK_HEADERS([sys/capability.h])
2239   fi
2240   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2241     AC_CHECK_LIB([cap], [cap_init],
2242       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2243        LIBCAP="-lcap"
2244        frr_ac_lcaps="yes"]
2245     )
2246   fi
2247   if test "$frr_ac_scaps" = "yes" \
2248        -o "$frr_ac_lcaps" = "yes"; then
2249     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2250   fi
2251
2252   case "$host_os" in
2253   linux*)
2254     if test "$enable_clippy_only" != "yes"; then
2255     if test "$frr_ac_lcaps" != "yes"; then
2256       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2257     fi
2258     fi
2259     ;;
2260   esac
2261 else
2262   case "$host_os" in
2263   linux*)
2264     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2265     ;;
2266   esac
2267 fi
2268 AC_SUBST([LIBCAP])
2269
2270 dnl ---------------------------
2271 dnl check for glibc 'backtrace'
2272 dnl ---------------------------
2273 if test "$enable_backtrace" != "no" ; then
2274   backtrace_ok=no
2275   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2276     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2277     backtrace_ok=yes
2278   ], [
2279     true
2280   ])
2281
2282   if test "$backtrace_ok" = "no"; then
2283     AC_CHECK_HEADER([unwind.h], [
2284       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2285         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2286         backtrace_ok=yes
2287       ])
2288     ])
2289   fi
2290
2291   if test "$backtrace_ok" = "no"; then
2292     AC_CHECK_HEADER([execinfo.h], [
2293       AC_SEARCH_LIBS([backtrace], [execinfo], [
2294         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2295         backtrace_ok=yes
2296       ],, [-lm])
2297     ])
2298   fi
2299
2300   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2301     dnl user explicitly requested backtrace but we failed to find support
2302     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2303   fi
2304 fi
2305
2306 dnl -----------------------------------------
2307 dnl check for malloc mallinfo struct and call
2308 dnl this must try and link using LIBS, in
2309 dnl order to check no alternative allocator
2310 dnl has been specified, which might not provide
2311 dnl mallinfo
2312 dnl -----------------------------------------
2313 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2314
2315 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2316   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2317 #ifdef HAVE_MALLOC_H
2318 #include <malloc.h>
2319 #endif
2320 #ifdef HAVE_MALLOC_NP_H
2321 #include <malloc_np.h>
2322 #endif
2323 #ifdef HAVE_MALLOC_MALLOC_H
2324 #include <malloc/malloc.h>
2325 #endif
2326 ]], [[
2327 struct mallinfo ac_x; ac_x = mallinfo ();
2328 ]])], [
2329     frr_cv_mallinfo=yes
2330   ], [
2331     frr_cv_mallinfo=no
2332   ])
2333 ])
2334 if test "$frr_cv_mallinfo" = "yes"; then
2335   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2336 fi
2337
2338 AC_MSG_CHECKING([whether malloc_usable_size is available])
2339 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2340 #ifdef HAVE_MALLOC_H
2341 #include <malloc.h>
2342 #endif
2343 #ifdef HAVE_MALLOC_MALLOC_H
2344 #include <malloc/malloc.h>
2345 #endif
2346 ]], [[
2347 size_t ac_x; ac_x = malloc_usable_size(NULL);
2348 ]])], [
2349   AC_MSG_RESULT([yes])
2350   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2351 ], [
2352   AC_MSG_RESULT([no])
2353
2354   AC_MSG_CHECKING([whether malloc_size is available])
2355   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2356 #ifdef HAVE_MALLOC_H
2357 #include <malloc.h>
2358 #endif
2359 #ifdef HAVE_MALLOC_MALLOC_H
2360 #include <malloc/malloc.h>
2361 #endif
2362 ]], [[
2363 size_t ac_x; ac_x = malloc_size(NULL);
2364 ]])], [
2365     AC_MSG_RESULT([yes])
2366     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2367   ], [
2368     AC_MSG_RESULT([no])
2369   ])
2370 ])
2371
2372 dnl ----------
2373 dnl configure date
2374 dnl ----------
2375 dev_version=`echo $VERSION | grep dev`
2376 #don't expire deprecated code in non 'dev' branch
2377 if test "$dev_version" = ""; then
2378    CONFDATE=0
2379 else
2380    CONFDATE=`date '+%Y%m%d'`
2381 fi
2382 AC_SUBST([CONFDATE])
2383
2384 dnl ------------------------------
2385 dnl set paths for state directory
2386 dnl ------------------------------
2387 AC_MSG_CHECKING([directory to use for state file])
2388 if test "$prefix" = "NONE"; then
2389   frr_statedir_prefix="";
2390 else
2391   frr_statedir_prefix=${prefix}
2392 fi
2393 if test "$localstatedir" = '${prefix}/var'; then
2394   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2395                         ${frr_statedir_prefix}/var/adm dnl
2396                         ${frr_statedir_prefix}/etc dnl
2397                         /var/run        dnl
2398                         /var/adm        dnl
2399                         /etc            dnl
2400                         /dev/null;
2401   do
2402     test -d $FRR_STATE_DIR && break
2403   done
2404   frr_statedir=$FRR_STATE_DIR
2405 else
2406   frr_statedir=${localstatedir}
2407 fi
2408 if test "$frr_statedir" = "/dev/null"; then
2409     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2410 fi
2411 AC_MSG_RESULT([${frr_statedir}])
2412 AC_SUBST([frr_statedir])
2413
2414 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2415 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2416 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2417 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2418 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2419
2420 dnl autoconf does this, but it does it too late...
2421 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2422 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2423
2424 dnl get the full path, recursing through variables...
2425 vtysh_bin="$bindir/vtysh"
2426 for I in 1 2 3 4 5 6 7 8 9 10; do
2427         eval vtysh_bin="\"$vtysh_bin\""
2428 done
2429 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2430 AC_SUBST([vtysh_bin])
2431
2432 CFG_SYSCONF="$sysconfdir"
2433 CFG_SBIN="$sbindir"
2434 CFG_STATE="$frr_statedir"
2435 CFG_MODULE="$moduledir"
2436 CFG_YANGMODELS="$yangmodelsdir"
2437 for I in 1 2 3 4 5 6 7 8 9 10; do
2438         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2439         eval CFG_SBIN="\"$CFG_SBIN\""
2440         eval CFG_STATE="\"$CFG_STATE\""
2441         eval CFG_MODULE="\"$CFG_MODULE\""
2442         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2443 done
2444 AC_SUBST([CFG_SYSCONF])
2445 AC_SUBST([CFG_SBIN])
2446 AC_SUBST([CFG_STATE])
2447 AC_SUBST([CFG_MODULE])
2448 AC_SUBST([CFG_YANGMODELS])
2449 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2450 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2451 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2452
2453 dnl various features
2454 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2455 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2456 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2457 dnl northbound
2458 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2459 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2460 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2461 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2462 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2463 dnl plugins
2464 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2465 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2466 AM_CONDITIONAL([IRDP], [$IRDP])
2467 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2468 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2469 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2470 dnl daemons
2471 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2472 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2473 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2474 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2475 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2476 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2477 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2478 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2479 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2480 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2481 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2482 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2483 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2484 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2485 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2486 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2487 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2488 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2489 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2490 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2491 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2492
2493 AC_CONFIG_FILES([Makefile],[
2494         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2495         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2496 ], [
2497         PYTHON="$PYTHON"
2498         enable_dev_build="$enable_dev_build"
2499 ])
2500
2501 AC_CONFIG_FILES([
2502           config.version
2503           changelog-auto
2504           redhat/frr.spec
2505           alpine/APKBUILD
2506           snapcraft/snapcraft.yaml
2507           lib/version.h
2508           tests/lib/cli/test_cli.refout
2509           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2510           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2511           pkgsrc/eigrpd.sh])
2512
2513 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2514 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2515 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2516 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2517 AC_CONFIG_FILES([tools/frrcommon.sh])
2518
2519 AS_IF([test "$with_pkg_git_version" = "yes"], [
2520     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2521         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2522         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2523                 "${ac_abs_top_srcdir}" \
2524                 > "${dst}.tmp"
2525         test -f "$dst" \
2526                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2527                 && rm "${dst}.tmp" \
2528                 || mv "${dst}.tmp" "${dst}"
2529     ], [
2530         PERL="$PERL"
2531     ])
2532 ])
2533
2534 ## Hack, but working solution to avoid rebuilding of frr.info.
2535 ## It's already in CVS until texinfo 4.7 is more common.
2536 AC_OUTPUT
2537
2538 if test "$enable_rpath" = "yes" ; then
2539         true
2540 else
2541         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2542         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2543         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2544 fi
2545
2546 echo "
2547 FRRouting configuration
2548 ------------------------------
2549 FRR version             : ${PACKAGE_VERSION}
2550 host operating system   : ${host_os}
2551 source code location    : ${srcdir}
2552 compiler                : ${CC}
2553 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2554 make                    : ${MAKE-make}
2555 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2556 state file directory    : ${frr_statedir}
2557 config file directory   : `eval echo \`echo ${sysconfdir}\``
2558 example directory       : `eval echo \`echo ${exampledir}\``
2559 module directory        : ${CFG_MODULE}
2560 user to run as          : ${enable_user}
2561 group to run as         : ${enable_group}
2562 group for vty sockets   : ${enable_vty_group}
2563 config file mask        : ${enable_configfile_mask}
2564 log file mask           : ${enable_logfile_mask}
2565 zebra protobuf enabled  : ${enable_protobuf:-no}
2566 vici socket path        : ${vici_socket}
2567
2568 The above user and group must have read/write access to the state file
2569 directory and to the config files in the config file directory."
2570
2571 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2572   AC_MSG_WARN([sphinx is missing but required to build documentation])
2573 fi
2574 if test "$frr_py_mod_pytest" = "false"; then
2575   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2576 fi