configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([--coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 284
 285 if test "$enable_scripting" = "yes"; then
 286    AX_PROG_LUA([5.3], [5.4], [], [
 287      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 288    ])
 289    AX_LUA_HEADERS([], [
 290      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 291    ])
 292    AX_LUA_LIBS([
 293      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 294      LIBS="$LIBS $LUA_LIB"
 295      SCRIPTING=true
 296    ], [
 297      SCRIPTING=false
 298      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 299    ])
 300 fi
 301
 302 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 303 dnl sense to be overridden by the user
 304 if test "$enable_dev_build" = "yes"; then
 305    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 306    if test "$orig_cflags" = ""; then
 307       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 308       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 309       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 310    fi
 311 else
 312    if test "$orig_cflags" = ""; then
 313       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 314       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 315    fi
 316 fi
 317
 318 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 319
 320 dnl always want these CFLAGS
 321 AC_C_FLAG([-fno-omit-frame-pointer])
 322 AC_C_FLAG([-funwind-tables])
 323 AC_C_FLAG([-Wall])
 324 AC_C_FLAG([-Wextra])
 325 AC_C_FLAG([-Wstrict-prototypes])
 326 AC_C_FLAG([-Wmissing-prototypes])
 327 AC_C_FLAG([-Wmissing-declarations])
 328 AC_C_FLAG([-Wpointer-arith])
 329 AC_C_FLAG([-Wbad-function-cast])
 330 AC_C_FLAG([-Wwrite-strings])
 331 AC_C_FLAG([-Wundef])
 332 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 333   AC_C_FLAG([-Wcast-qual])
 334   AC_C_FLAG([-Wmissing-noreturn])
 335   AC_C_FLAG([-Wmissing-format-attribute])
 336   AC_C_FLAG([-Wunreachable-code])
 337   AC_C_FLAG([-Wpacked])
 338   AC_C_FLAG([-Wpadded])
 339   AC_C_FLAG([-Wshadow])
 340 else
 341   AC_C_FLAG([-Wno-unused-result])
 342 fi
 343 AC_C_FLAG([-Wno-unused-parameter])
 344 AC_C_FLAG([-Wno-missing-field-initializers])
 345
 346 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 347 AC_SUBST([CXX_COMPAT_CFLAGS])
 348
 349 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 350 dnl for some reason the string consts get 'promoted' to char *,
 351 dnl triggering a const to non-const conversion warning.
 352 if test "$cc_is_icc" = "yes"; then
 353     AC_C_FLAG([-diag-disable 3179])
 354 fi
 355
 356 if test "$enable_werror" = "yes" ; then
 357   WERROR="-Werror"
 358 fi
 359 AC_SUBST([WERROR])
 360
 361 SAN_FLAGS=""
 362 if test "$enable_address_sanitizer" = "yes"; then
 363   AC_C_FLAG([-fsanitize=address], [
 364     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 365   ], [
 366     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 367   ])
 368 fi
 369 if test "$enable_thread_sanitizer" = "yes"; then
 370   AC_C_FLAG([-fsanitize=thread], [
 371     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 372   ], [
 373     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 374   ])
 375 fi
 376 if test "$enable_memory_sanitizer" = "yes"; then
 377   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 378     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 379   ], [
 380     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 381   ])
 382 fi
 383 if test "$enable_undefined_sanitizer" = "yes"; then
 384   AC_C_FLAG([-fsanitize=undefined], [
 385     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 386   ], [
 387     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 388   ])
 389 fi
 390 AC_SUBST([SAN_FLAGS])
 391
 392 dnl frr-format.so
 393 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 394   AC_C_FLAG([-fplugin=${with_frr_format}], [
 395     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 396   ],,[
 397 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 398 #error plugin not loaded
 399 #endif
 400 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 401 #error plugin too old
 402 #endif
 403   ])
 404 elif test "$with_frr_format" = "no"; then
 405   : #nothing
 406 else
 407   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 408     AC_C_FLAG([-fplugin=frr-format],[
 409       if test "$with_frr_format" = "yes"; then
 410         AC_MSG_ERROR([frr-format plugin requested but not found])
 411       fi
 412     ],,[
 413 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 414 #error plugin not loaded
 415 #endif
 416 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 417 #error plugin too old
 418 #endif
 419     ])
 420   ],,[
 421 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 422 #error plugin not loaded
 423 #endif
 424 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 425 #error plugin too old
 426 #endif
 427   ])
 428 fi
 429
 430 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 431 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 432 #include <stdio.h>
 433 int __attribute__((section("secttest"))) var = 1;
 434 extern int __start_secttest, __stop_secttest;
 435 ]], [[
 436   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 437   printf("%p %p %p\n", a, b, c);
 438 ]])], [
 439   AC_MSG_RESULT(yes)
 440   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 441 ], [
 442   AC_MSG_RESULT(no)
 443 ])
 444
 445 dnl ----------
 446 dnl Essentials
 447 dnl ----------
 448
 449 AX_PTHREAD([
 450   CC="$PTHREAD_CC"
 451   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 452   LIBS="$PTHREAD_LIBS $LIBS"
 453 ], [
 454   AC_MSG_FAILURE([This FRR version needs pthreads])
 455 ])
 456
 457 orig_cflags="$CFLAGS"
 458 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 459
 460 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 461                 [frr_cv_pthread_condattr_setclock=yes],
 462                 [frr_cv_pthread_condattr_setclock=no])
 463 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 464   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 465 fi
 466
 467 AC_CHECK_HEADERS([pthread_np.h],,, [
 468 #include <pthread.h>
 469 ])
 470 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 471
 472 CFLAGS="$orig_cflags"
 473
 474 dnl --------------
 475 dnl Check programs
 476 dnl --------------
 477 AC_PROG_INSTALL
 478 AC_PROG_LN_S
 479 AC_CHECK_TOOL([AR], [ar])
 480
 481 dnl -------
 482 dnl libtool
 483 dnl -------
 484 AC_ARG_ENABLE([static-bin],
 485   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 486 LT_INIT
 487 _LT_CONFIG_LIBTOOL([
 488   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 489     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 490 dnl the -i option is not POSIX sed and the BSDs implement it differently
 491 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 492   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 493   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 494   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 495   test -f libtool.sed && rm libtool.sed
 496 ])
 497 if test "$enable_static_bin" = "yes"; then
 498   AC_LDFLAGS_EXEC="-static"
 499   if test "$enable_static" != "yes"; then
 500     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 501   fi
 502 fi
 503 if test "$enable_shared" != "yes"; then
 504   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 505 fi
 506 AC_SUBST([AC_LDFLAGS])
 507 AC_SUBST([AC_LDFLAGS_EXEC])
 508 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 509
 510 AC_ARG_ENABLE([rpath],
 511   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 512   [],
 513   [enable_rpath=yes])
 514
 515 dnl $AR and $RANLIB are set by LT_INIT above
 516 AC_MSG_CHECKING([whether $AR supports D option])
 517 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 518   AC_MSG_RESULT([yes])
 519   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 520   ARFLAGS="crD"
 521   AR_FLAGS="crD"
 522 else
 523   AC_MSG_RESULT([no])
 524   ARFLAGS="cru"
 525   AR_FLAGS="cru"
 526 fi
 527 AC_SUBST([ARFLAGS])
 528 AC_SUBST([AR_FLAGS])
 529
 530 AC_MSG_CHECKING([whether $RANLIB supports D option])
 531 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 532   if grep -q -- '-D' conftest.err; then
 533     AC_MSG_RESULT([no])
 534   else
 535     AC_MSG_RESULT([yes])
 536     RANLIB="$RANLIB -D"
 537   fi
 538 else
 539   AC_MSG_RESULT([no])
 540 fi
 541 AC_SUBST([RANLIB])
 542
 543 test -f conftest.err && rm conftest.err
 544 test -f conftest.a && rm conftest.a
 545
 546 dnl ----------------------
 547 dnl Packages configuration
 548 dnl ----------------------
 549 if test -f config.version; then
 550   . ./config.version
 551 elif test -f "${srcdir}/config.version"; then
 552   . "${srcdir}/config.version"
 553 fi
 554 AC_ARG_WITH([pkg-extra-version],
 555   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 556   if test "$withval" = "no"; then
 557     EXTRAVERSION=
 558   else
 559     EXTRAVERSION=$withval
 560   fi
 561 ], [])
 562 AC_ARG_WITH([pkg-git-version],
 563         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 564         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 565 AC_ARG_WITH([clippy],
 566   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 567 AC_ARG_WITH([vtysh_pager],
 568         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 569         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 570 AC_ARG_ENABLE([vtysh],
 571   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 572 AC_ARG_ENABLE([doc],
 573   AS_HELP_STRING([--disable-doc], [do not build docs]))
 574 AC_ARG_ENABLE([doc-html],
 575   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 576 AC_ARG_ENABLE([zebra],
 577   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 578 AC_ARG_ENABLE([bgpd],
 579   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 580 AC_ARG_ENABLE([ripd],
 581   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 582 AC_ARG_ENABLE([ripngd],
 583   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 584 AC_ARG_ENABLE([ospfd],
 585   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 586 AC_ARG_ENABLE([ospf6d],
 587   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 588 AC_ARG_ENABLE([ldpd],
 589   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 590 AC_ARG_ENABLE([nhrpd],
 591   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 592 AC_ARG_ENABLE([eigrpd],
 593   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 594 AC_ARG_ENABLE([babeld],
 595   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 596 AC_ARG_ENABLE([watchfrr],
 597   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 598 AC_ARG_ENABLE([isisd],
 599   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 600 AC_ARG_ENABLE([pimd],
 601   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 602 AC_ARG_ENABLE([pbrd],
 603   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 604 AC_ARG_ENABLE([sharpd],
 605   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 606 AC_ARG_ENABLE([staticd],
 607   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 608 AC_ARG_ENABLE([fabricd],
 609   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 610 AC_ARG_ENABLE([vrrpd],
 611   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 612 AC_ARG_ENABLE([pathd],
 613   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 614 AC_ARG_ENABLE([bgp-announce],
 615   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 616 AC_ARG_ENABLE([bgp-vnc],
 617   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 618 AC_ARG_ENABLE([bgp-bmp],
 619   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 620 AC_ARG_ENABLE([snmp],
 621   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 622 AC_ARG_ENABLE([config_rollbacks],
 623   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 624 AC_ARG_ENABLE([confd],
 625   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 626 AC_ARG_ENABLE([sysrepo],
 627   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 628 AC_ARG_ENABLE([grpc],
 629   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 630 AC_ARG_ENABLE([zeromq],
 631   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 632 AC_ARG_ENABLE([lttng],
 633   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 634 AC_ARG_ENABLE([usdt],
 635   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 636 AC_ARG_WITH([libpam],
 637   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 638 AC_ARG_ENABLE([ospfapi],
 639   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 640 AC_ARG_ENABLE([ospfclient],
 641   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 642                           (this is the default if --disable-ospfapi is set)]))
 643 AC_ARG_ENABLE([multipath],
 644   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 645 AC_ARG_ENABLE([user],
 646   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 647 AC_ARG_ENABLE([group],
 648   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 649 AC_ARG_ENABLE([vty_group],
 650   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 651 AC_ARG_ENABLE([configfile_mask],
 652   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 653 AC_ARG_ENABLE([logfile_mask],
 654   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 655 AC_ARG_ENABLE([shell_access],
 656   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 657 AC_ARG_ENABLE([realms],
 658   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 659 AC_ARG_ENABLE([rtadv],
 660   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 661 AC_ARG_ENABLE([irdp],
 662   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 663 AC_ARG_ENABLE([capabilities],
 664   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 665 AC_ARG_ENABLE([gcc_ultra_verbose],
 666   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 667 AC_ARG_ENABLE([backtrace],
 668   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 669 AC_ARG_ENABLE([time-check],
 670   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 671 AC_ARG_ENABLE([cpu-time],
 672   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 673 AC_ARG_ENABLE([pcreposix],
 674   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 675 AC_ARG_ENABLE([fpm],
 676   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 677 AC_ARG_ENABLE([pcep],
 678   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 679 AC_ARG_ENABLE([werror],
 680   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 681 AC_ARG_ENABLE([cumulus],
 682   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 683 AC_ARG_ENABLE([datacenter],
 684   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 685 AC_ARG_ENABLE([rr-semantics],
 686   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 687 AC_ARG_ENABLE([protobuf],
 688   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 689 AC_ARG_ENABLE([oldvpn_commands],
 690   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 691 AC_ARG_ENABLE([rpki],
 692   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 693 AC_ARG_ENABLE([clippy-only],
 694   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 695 AC_ARG_ENABLE([numeric_version],
 696   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 697 AC_ARG_ENABLE([gcov],
 698   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 699 AC_ARG_ENABLE([clang_coverage],
 700   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 701 AC_ARG_ENABLE([bfdd],
 702   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 703 AC_ARG_ENABLE([address-sanitizer],
 704   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 705 AC_ARG_ENABLE([thread-sanitizer],
 706   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 707 AC_ARG_ENABLE([memory-sanitizer],
 708   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 709 AC_ARG_ENABLE([undefined-sanitizer],
 710   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 711 AC_ARG_WITH([crypto],
 712   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 713 AC_ARG_WITH([frr-format],
 714   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 715
 716 AC_ARG_ENABLE([version-build-config],
 717   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 718
 719 #if openssl, else use the internal
 720 AS_IF([test "$with_crypto" = "openssl"], [
 721 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 722 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 723   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 724 else
 725   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 726 fi
 727 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 728 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 729 )
 730
 731 AS_IF([test "$enable_clippy_only" != "yes"], [
 732 AC_CHECK_HEADERS([json-c/json.h])
 733 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 734 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 735   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 736   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 737       AC_MSG_ERROR([libjson is needed to compile])
 738   fi
 739 fi
 740 ])
 741
 742 AC_ARG_ENABLE([dev_build],
 743     AS_HELP_STRING([--enable-dev-build], [build for development]))
 744
 745 AC_ARG_ENABLE([scripting],
 746     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 747
 748 AC_ARG_ENABLE([netlink-debug],
 749   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 750
 751 if test "$enable_netlink_debug" != "no" ; then
 752   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 753 fi
 754
 755 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 756
 757 if test "$enable_time_check" != "no" ; then
 758   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 759     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 760   else
 761     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 762   fi
 763 fi
 764
 765 case "${enable_cpu_time}" in
 766   "no")
 767   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 768   ;;
 769   "*")
 770   ;;
 771 esac
 772
 773 if test "$enable_rr_semantics" != "no" ; then
 774   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 775 fi
 776
 777 if test "$enable_datacenter" = "yes" ; then
 778   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 779   DFLT_NAME="datacenter"
 780 else
 781   DFLT_NAME="traditional"
 782 fi
 783
 784 if test "$enable_cumulus" = "yes" ; then
 785   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 786 fi
 787
 788 AC_SUBST([DFLT_NAME])
 789 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 790
 791 if test "$enable_shell_access" = "yes"; then
 792    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 793 fi
 794
 795 #
 796 # Python for clippy
 797 #
 798
 799 AS_IF([test "$host" = "$build"], [
 800   AM_PATH_PYTHON([3])
 801   AC_CHECK_HEADER([gelf.h], [], [
 802     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 803   ])
 804   AC_CHECK_LIB([elf], [elf_memory], [], [
 805     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 806   ])
 807
 808   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 809     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 810   ])
 811   AC_CHECK_LIB([elf], [gelf_getnote], [
 812     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 813   ])
 814
 815   FRR_PYTHON_DEV
 816 ], [
 817   FRR_PYTHON
 818 ])
 819
 820 FRR_PYTHON_MODULES([pytest])
 821
 822 if test "$enable_doc" != "no"; then
 823   FRR_PYTHON_MODULES([sphinx], , [
 824     if test "$enable_doc" = "yes"; then
 825       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 826     fi
 827   ])
 828 fi
 829 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 830 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 831
 832 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 833   PYSPHINX="-m sphinx"
 834 ], [
 835   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 836 ])
 837 AC_SUBST([PYSPHINX])
 838
 839 #
 840 # Logic for old vpn commands support.
 841 #
 842 if test "$enable_oldvpn_commands" = "yes"; then
 843    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 844 fi
 845
 846 #
 847 # End of logic for protobuf support.
 848 #
 849
 850 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 851 if test "$enable_rtadv" != "no"; then
 852   AC_MSG_RESULT([yes])
 853   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 854 else
 855   AC_MSG_RESULT([no])
 856 fi
 857
 858 if test "$enable_user" = "no"; then
 859   enable_user=""
 860 else
 861   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 862     enable_user="frr"
 863   fi
 864   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 865 fi
 866
 867 if test "$enable_group" = "no"; then
 868   enable_group=""
 869 else
 870   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 871     enable_group="frr"
 872   fi
 873   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 874 fi
 875
 876 if test "$enable_vty_group" = "yes" ; then
 877   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 878 elif test "$enable_vty_group" != ""; then
 879   if test "$enable_vty_group" != "no"; then
 880     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 881   fi
 882 fi
 883 AC_SUBST([enable_user])
 884 AC_SUBST([enable_group])
 885 AC_SUBST([enable_vty_group])
 886
 887 enable_configfile_mask=${enable_configfile_mask:-0600}
 888 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 889 AC_SUBST([enable_configfile_mask])
 890
 891 enable_logfile_mask=${enable_logfile_mask:-0600}
 892 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 893
 894 MPATH_NUM=16
 895
 896 case "${enable_multipath}" in
 897   0)
 898     MPATH_NUM=64
 899     ;;
 900   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 901     MPATH_NUM="${enable_multipath}"
 902     ;;
 903   "")
 904     ;;
 905   *)
 906     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 907     ;;
 908 esac
 909
 910 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 911
 912 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 913
 914 dnl --------------------
 915 dnl Enable code coverage
 916 dnl --------------------
 917 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 918
 919 dnl ------------------------------------
 920 dnl Alpine only accepts numeric versions
 921 dnl ------------------------------------
 922 if test "$enable_numeric_version" != "" ; then
 923   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 924   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 925 fi
 926
 927 dnl -----------------------------------
 928 dnl Add extra version string to package
 929 dnl name, string and version fields.
 930 dnl -----------------------------------
 931 if test "$EXTRAVERSION" != "" ; then
 932   VERSION="${VERSION}${EXTRAVERSION}"
 933   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 934   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 935   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 936 fi
 937 AC_SUBST([EXTRAVERSION])
 938
 939 if test "$with_pkg_git_version" = "yes"; then
 940         if test -e "${srcdir}/.git"; then
 941                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 942         else    with_pkg_git_version="no"
 943                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 944         fi
 945 fi
 946 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 947
 948 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 949 if test "$OBJCOPY" != ":"; then
 950   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 951     frr_cv_interp=""
 952     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 953       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 954         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 955       fi
 956       test -f conftest.interp && rm conftest.interp
 957     ])
 958   ])
 959 fi
 960 if test -n "$frr_cv_interp"; then
 961   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 962 fi
 963
 964 dnl -------------------------
 965 dnl Check other header files.
 966 dnl -------------------------
 967 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 968         linux/version.h asm/types.h endian.h sys/endian.h])
 969
 970 ac_stdatomic_ok=false
 971 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 972 AC_CHECK_HEADER([stdatomic.h],[
 973
 974   AC_MSG_CHECKING([whether _Atomic qualifier works])
 975   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 976 #include <stdatomic.h>
 977 int main(int argc, char **argv) {
 978   _Atomic int i = 0;
 979   return i;
 980 }
 981 ]])], [
 982     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 983     AC_MSG_RESULT([yes])
 984     ac_stdatomic_ok=true
 985   ], [
 986     AC_MSG_RESULT([no])
 987   ])
 988 ])
 989
 990 AS_IF([$ac_stdatomic_ok], [true], [
 991   AC_MSG_CHECKING([for __atomic_* builtins])
 992   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 993 int main(int argc, char **argv) {
 994   volatile int i = 1;
 995   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 996   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 997 }
 998 ]])], [
 999     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1000     AC_MSG_RESULT([yes])
1001   ], [
1002     AC_MSG_RESULT([no])
1003
1004     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1005     AC_MSG_CHECKING([for __sync_* builtins])
1006     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1007 int main(int argc, char **argv) {
1008   volatile int i = 1;
1009   __sync_fetch_and_sub (&i, 1);
1010   return __sync_val_compare_and_swap (&i, 0, 1);
1011 }
1012 ]])], [
1013       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1014       AC_MSG_RESULT([yes])
1015
1016       AC_MSG_CHECKING([for __sync_swap builtin])
1017       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1018 int main(int argc, char **argv) {
1019   volatile int i = 1;
1020   return __sync_swap (&i, 2);
1021 }
1022 ]])], [
1023         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1024         AC_MSG_RESULT([yes])
1025       ], [
1026         AC_MSG_RESULT([no])
1027       ])
1028
1029     ], [
1030       AC_MSG_RESULT([no])
1031       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1032     ])
1033   ])
1034 ])
1035
1036 needsync=true
1037
1038 AS_IF([$needsync], [
1039   dnl Linux
1040   AC_MSG_CHECKING([for Linux futex() support])
1041   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1042 #ifndef _GNU_SOURCE
1043 #define _GNU_SOURCE
1044 #endif
1045 #include <unistd.h>
1046 #include <limits.h>
1047 #include <sys/time.h>
1048 #include <sys/syscall.h>
1049 #include <linux/futex.h>
1050
1051 int main(void);
1052 ],
1053 [
1054 {
1055   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1056 }
1057 ])], [
1058     AC_MSG_RESULT([yes])
1059     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1060     needsync=false
1061   ], [
1062     AC_MSG_RESULT([no])
1063   ])
1064 ])
1065
1066 AS_IF([$needsync], [
1067   dnl FreeBSD
1068   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1069   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1070 #include <errno.h>
1071 #include <stdlib.h>
1072 #include <sys/types.h>
1073 #include <sys/umtx.h>
1074 int main(void);
1075 ],
1076 [
1077 {
1078   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1079 }
1080 ])], [
1081     AC_MSG_RESULT([yes])
1082     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1083     needsync=false
1084   ], [
1085     AC_MSG_RESULT([no])
1086   ])
1087 ])
1088
1089 AS_IF([$needsync], [
1090   dnl OpenBSD patch (not upstream at the time of writing this)
1091   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1092   AC_MSG_CHECKING([for OpenBSD futex() support])
1093   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1094 #include <sys/futex.h>
1095 int main(void);
1096 ],
1097 [
1098 {
1099   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1100 }
1101 ])], [
1102     AC_MSG_RESULT([yes])
1103     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1104     needsync=false
1105   ], [
1106     AC_MSG_RESULT([no])
1107   ])
1108 ])
1109
1110 dnl Utility macro to avoid retyping includes all the time
1111 m4_define([FRR_INCLUDES],
1112 [#ifdef SUNOS_5
1113 #define _POSIX_C_SOURCE 200809L
1114 #define __EXTENSIONS__
1115 #endif
1116 #include <stdio.h>
1117 #include <stdlib.h>
1118 #include <stddef.h>
1119 #include <sys/types.h>
1120 /* sys/conf.h depends on param.h on FBSD at least */
1121 #include <sys/param.h>
1122 /* Required for MAXSIG */
1123 #include <signal.h>
1124 #include <sys/socket.h>
1125 #ifdef __APPLE__
1126 # define __APPLE_USE_RFC_3542
1127 #endif
1128 #include <netinet/in.h>
1129 #include <sys/time.h>
1130 #include <time.h>
1131 #include <net/if.h>
1132 ])dnl
1133
1134 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1135 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1136 dnl an additional round for it.
1137
1138 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1139
1140 m4_define([FRR_INCLUDES],
1141 FRR_INCLUDES
1142 [#ifdef HAVE_NET_IF_VAR_H
1143 # include <net/if_var.h>
1144 #endif
1145 ])dnl
1146
1147 AC_CHECK_HEADERS([netinet/in_var.h \
1148         net/if_dl.h net/netopt.h \
1149         inet/nd.h netinet/ip_icmp.h \
1150         sys/sysctl.h sys/sockio.h sys/conf.h],
1151         [], [], [FRR_INCLUDES])
1152
1153 AC_CHECK_HEADERS([ucontext.h], [], [],
1154 [#ifndef __USE_GNU
1155 #define __USE_GNU
1156 #endif /* __USE_GNU */
1157 FRR_INCLUDES
1158 ])
1159
1160 m4_define([UCONTEXT_INCLUDES],
1161 [#include <ucontext.h>])dnl
1162
1163 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1164   [], [], [UCONTEXT_INCLUDES])
1165 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1166   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1167    [], [], [UCONTEXT_INCLUDES])],
1168   [], [UCONTEXT_INCLUDES])
1169 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1170   [], [], [UCONTEXT_INCLUDES])
1171
1172 m4_define([FRR_INCLUDES],
1173 FRR_INCLUDES
1174 [
1175 #include <sys/un.h>
1176 #include <netinet/in_systm.h>
1177 #ifdef HAVE_NETINET_IN_VAR_H
1178 # include <netinet/in_var.h>
1179 #endif
1180 #ifdef HAVE_NET_IF_DL_H
1181 # include <net/if_dl.h>
1182 #endif
1183 #ifdef HAVE_NET_NETOPT_H
1184 # include <net/netopt.h>
1185 #endif
1186 #include <net/route.h>
1187 #ifdef HAVE_INET_ND_H
1188 # include <inet/nd.h>
1189 #endif
1190 #include <arpa/inet.h>
1191 /* Required for IDRP */
1192 #ifdef HAVE_NETINET_IP_ICMP_H
1193 # include <netinet/ip_icmp.h>
1194 #endif
1195 ])dnl
1196
1197 dnl V6 headers are checked below, after we check for v6
1198
1199 is_linux=false
1200
1201 AC_MSG_CHECKING([which operating system interface to use])
1202 case "$host_os" in
1203   sunos* | solaris2*)
1204     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1205     ;;
1206   linux*)
1207     AC_MSG_RESULT([Linux])
1208
1209     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1210     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1211     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1212
1213     dnl Linux has a compilation problem with mixing
1214     dnl netinet/in.h and linux/in6.h they are not
1215     dnl compatible.  There has been discussion on
1216     dnl how to fix it but no real progress on implementation
1217     dnl when they fix it, remove this
1218     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1219
1220     is_linux=true
1221     ;;
1222   openbsd*)
1223     AC_MSG_RESULT([OpenBSD])
1224
1225     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1226     AC_DEFINE([KAME], [1], [KAME IPv6])
1227     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1228     ;;
1229   *)
1230     AC_MSG_RESULT([BSD])
1231
1232     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1233     AC_DEFINE([KAME], [1], [KAME IPv6])
1234     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1235     ;;
1236 esac
1237 AM_CONDITIONAL([LINUX], [${is_linux}])
1238
1239 AC_SYS_LARGEFILE
1240
1241 dnl ------------------------
1242 dnl Integrated REALMS option
1243 dnl ------------------------
1244 if test "$enable_realms" = "yes"; then
1245     case "$host_os" in
1246       linux*)
1247        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1248        ;;
1249       *)
1250        echo "Sorry, only Linux has REALMS support"
1251        exit 1
1252        ;;
1253     esac
1254 fi
1255
1256 dnl ---------------
1257 dnl other functions
1258 dnl ---------------
1259 AC_CHECK_FUNCS([ \
1260         strlcat strlcpy \
1261         getgrouplist \
1262         openat \
1263         unlinkat \
1264         posix_fallocate \
1265         ])
1266
1267 dnl ##########################################################################
1268 dnl LARGE if block spans a lot of "configure"!
1269 if test "$enable_clippy_only" != "yes"; then
1270 dnl ##########################################################################
1271
1272 #
1273 # Logic for protobuf support.
1274 #
1275 PROTO3=false
1276 if test "$enable_protobuf" = "yes"; then
1277   # Check for protoc & protoc-c
1278
1279   # protoc is not required, it's only for a "be nice" helper target
1280   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1281
1282   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1283   if test "$PROTOC_C" = "/bin/false"; then
1284     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1285   fi
1286
1287   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1288     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1289   ])
1290
1291   PROTO3=true
1292   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1293                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1294                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1295                                             [1], [Have Protobuf version 3]),
1296                                   [PROTO3=false],
1297                                   [#include <google/protobuf-c/protobuf-c.h>])],
1298                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1299
1300   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1301 fi
1302
1303
1304 dnl ---------------------
1305 dnl Integrated VTY option
1306 dnl ---------------------
1307 case "${enable_vtysh}" in
1308 "no")
1309   VTYSH="";;
1310 *)
1311   VTYSH="vtysh";
1312   AC_DEFINE([VTYSH], [1], [VTY shell])
1313
1314   prev_libs="$LIBS"
1315   AC_CHECK_LIB([readline], [main], [
1316     LIBREADLINE="-lreadline"
1317   ], [
1318     dnl readline failed - it might be incorrectly linked and missing its
1319     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1320     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1321       LIBREADLINE="$ac_cv_search_tputs"
1322     ], [
1323       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1324     ])
1325
1326     dnl re-try with the lib we found above
1327     unset ac_cv_lib_readline_main
1328     AC_CHECK_LIB([readline], [main], [
1329       LIBREADLINE="-lreadline $LIBREADLINE"
1330     ], [
1331       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1332     ], [$LIBREADLINE])
1333   ], [])
1334   LIBS="$prev_libs"
1335
1336   AC_CHECK_HEADER([readline/history.h])
1337   if test "$ac_cv_header_readline_history_h" = "no"; then
1338     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1339   fi
1340   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1341   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1342     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1343   fi
1344   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1345   if test "$frr_cv_append_history" = "yes"; then
1346     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1347   fi
1348   ;;
1349 esac
1350 AC_SUBST([LIBREADLINE])
1351
1352 dnl ----------
1353 dnl PAM module
1354 dnl
1355 dnl FRR detects the PAM library it is built against by checking for a
1356 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1357 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1358 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1359 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1360 dnl of OpenPAM.
1361 dnl ----------
1362 if test "$with_libpam" = "yes"; then
1363   AC_CHECK_HEADER([security/pam_misc.h],
1364     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1365      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1366      pam_conv_func="misc_conv"
1367     ],
1368     [], FRR_INCLUDES)
1369   AC_CHECK_HEADER([security/openpam.h],
1370     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1371      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1372      pam_conv_func="openpam_ttyconv"
1373     ],
1374     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1375   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1376     AC_MSG_WARN([*** pam support will not be built ***])
1377     with_libpam="no"
1378   fi
1379 fi
1380
1381 if test "$with_libpam" = "yes"; then
1382 dnl took this test from proftpds configure.in and suited to our needs
1383 dnl -------------------------------------------------------------------------
1384 dnl
1385 dnl This next check looks funky due to a linker problem with some versions
1386 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1387 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1388 dnl with RedHat 6.2 and Debian 2.2 or better.
1389 AC_CHECK_LIB([pam], [pam_start],
1390   [AC_CHECK_LIB([pam], [$pam_conv_func],
1391     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1392      LIBPAM="-lpam"],
1393     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1394      LIBPAM="-lpam -lpam_misc"]
1395     )
1396   ],
1397
1398   [AC_CHECK_LIB([pam], [pam_end],
1399     [AC_CHECK_LIB([pam], [$pam_conv_func],
1400       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1401        LIBPAM="-lpam -ldl"],
1402       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1403        LIBPAM="-lpam -ldl -lpam_misc"]
1404      )
1405   ],AC_MSG_WARN([*** pam support will not be built ***]),
1406   [-ldl])
1407   ]
1408 )
1409 fi
1410 AC_SUBST([LIBPAM])
1411
1412 dnl -------------------------------
1413 dnl bgpd needs pow() and hence libm
1414 dnl -------------------------------
1415 TMPLIBS="$LIBS"
1416 LIBS=""
1417 AC_SEARCH_LIBS([pow], [m], [
1418   LIBM="$LIBS"
1419 ], [
1420   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1421 ])
1422 LIBS="$TMPLIBS"
1423 AC_SUBST([LIBM])
1424
1425 AC_CHECK_FUNCS([ppoll], [
1426   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1427 ])
1428 AC_CHECK_FUNCS([pollts], [
1429   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1430 ])
1431
1432 AC_CHECK_HEADER([asm-generic/unistd.h],
1433                 [AC_CHECK_DECL(__NR_setns,
1434                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1435                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1436                                ])
1437                  AC_CHECK_FUNCS([setns])]
1438                )
1439
1440 dnl --------------------------
1441 dnl Determine IS-IS I/O method
1442 dnl --------------------------
1443 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1444 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1445 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1446 AC_CHECK_HEADER([net/bpf.h])
1447 AC_CHECK_HEADER([sys/dlpi.h])
1448 AC_MSG_CHECKING([zebra IS-IS I/O method])
1449
1450 case "$host_os" in
1451   linux*)
1452     AC_MSG_RESULT([pfpacket])
1453     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1454     ;;
1455   *)
1456     if test "$ac_cv_header_net_bpf_h" = "no"; then
1457       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1458         AC_MSG_RESULT([none])
1459         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1460           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1461         fi
1462         AC_MSG_WARN([*** IS-IS support will not be built ***])
1463         enable_isisd="no"
1464         enable_fabricd="no"
1465       else
1466         AC_MSG_RESULT([DLPI])
1467       fi
1468       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1469     else
1470       AC_MSG_RESULT([BPF])
1471       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1472     fi
1473     ;;
1474 esac
1475 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1476
1477 dnl ---------------------------------------------------------------
1478 dnl figure out how to specify an interface in multicast sockets API
1479 dnl ---------------------------------------------------------------
1480 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1481
1482 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1483         #include <sys/socket.h>
1484         #include <netinet/in.h>
1485         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1486         #include <linux/types.h>
1487 ])
1488
1489 m4_define([FRR_INCLUDES],
1490 FRR_INCLUDES
1491 [#ifdef HAVE_LINUX_MROUTE_H
1492 # include <linux/mroute.h>
1493 #endif
1494 ])dnl
1495
1496 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1497         #include <sys/socket.h>
1498         #include <sys/types.h>
1499         #include <netinet/in.h>
1500         #include <net/route.h>
1501 ])
1502
1503 m4_define([FRR_INCLUDES],
1504 FRR_INCLUDES
1505 [#ifdef HAVE_NETINET_IP_MROUTE_H
1506 # include <netinet/ip_mroute.h>
1507 #endif
1508 ])dnl
1509
1510 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1511 AC_COMPILE_IFELSE(
1512 [ AC_LANG_PROGRAM([[
1513       #include <sys/types.h>
1514       #include <netinet/in.h>
1515   ]], [[
1516       struct group_req gr;
1517       int sock;
1518       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1519   ]])
1520 ],[
1521   AC_MSG_RESULT([yes])
1522   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1523 ],[
1524   AC_MSG_RESULT(no)
1525 ])
1526
1527 dnl ---------------------------------------------------------------
1528 dnl figure out how to check link-state
1529 dnl ---------------------------------------------------------------
1530 AC_CHECK_HEADER([net/if_media.h],
1531   [m4_define([LINK_DETECT_INCLUDES],
1532     FRR_INCLUDES
1533     [#include <net/if_media.h>
1534   ])
1535   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1536     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1537     [], LINK_DETECT_INCLUDES)],
1538   [],
1539   FRR_INCLUDES)
1540
1541 dnl ---------------------------------------------------------------
1542 dnl Additional, newer way to check link-state using ifi_link_state.
1543 dnl Not available in all BSD's when ifmediareq available
1544 dnl ---------------------------------------------------------------
1545 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1546   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1547   [], FRR_INCLUDES)
1548
1549 dnl ------------------------
1550 dnl TCP_MD5SIG socket option
1551 dnl ------------------------
1552
1553 AC_CHECK_HEADER([netinet/tcp.h],
1554    [m4_define([MD5_INCLUDES],
1555       FRR_INCLUDES
1556       [#include <netinet/tcp.h>
1557     ])
1558     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1559    [],
1560    FRR_INCLUDES)
1561 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1562   AC_CHECK_HEADER([linux/tcp.h],
1563        [m4_define([MD5_INCLUDES],
1564           FRR_INCLUDES
1565           [#include <linux/tcp.h>
1566         ])
1567        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1568 fi
1569
1570 AC_CHECK_LIB([crypt], [crypt], [],
1571                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1572 AC_CHECK_LIB([resolv], [res_init])
1573
1574 dnl ---------------------------
1575 dnl check system has PCRE regexp
1576 dnl ---------------------------
1577 if test "$enable_pcreposix" = "yes"; then
1578   AC_CHECK_LIB([pcreposix], [regexec], [], [
1579     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1580   ])
1581 fi
1582 AC_SUBST([HAVE_LIBPCREPOSIX])
1583
1584 dnl ##########################################################################
1585 dnl test "$enable_clippy_only" != "yes"
1586 fi
1587 dnl END OF LARGE if block
1588 dnl ##########################################################################
1589
1590 dnl ------------------
1591 dnl check C-Ares library
1592 dnl ------------------
1593 PKG_CHECK_MODULES([CARES], [libcares], [
1594   c_ares_found=true
1595 ],[
1596   c_ares_found=false
1597 ])
1598 AM_CONDITIONAL([CARES], [$c_ares_found])
1599
1600
1601 dnl ----------------------------------------------------------------------------
1602 dnl figure out if domainname is available in the utsname struct (GNU extension).
1603 dnl ----------------------------------------------------------------------------
1604 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1605
1606 dnl ------------------
1607 dnl IPv6 header checks
1608 dnl ------------------
1609 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1610         netinet6/in6_var.h netinet6/nd6.h], [], [],
1611         FRR_INCLUDES)
1612
1613 m4_define([FRR_INCLUDES],dnl
1614 FRR_INCLUDES
1615 [#ifdef HAVE_NETINET6_IN6_H
1616 #include <netinet6/in6.h>
1617 #endif
1618 #ifdef HAVE_NETINET_IN6_VAR_H
1619 #include <netinet/in6_var.h>
1620 #endif
1621 #include <netinet/icmp6.h>
1622 #ifdef HAVE_NETINET6_IN6_VAR_H
1623 # include <netinet6/in6_var.h>
1624 #endif
1625 #ifdef HAVE_NETINET6_ND6_H
1626 # include <netinet6/nd6.h>
1627 #endif
1628 ])dnl
1629
1630 dnl --------------------
1631 dnl Daemon disable check
1632 dnl --------------------
1633
1634 AS_IF([test "$enable_bgpd" != "no"], [
1635   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1636 ])
1637
1638 AS_IF([test "$enable_ripd" != "no"], [
1639   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1640 ])
1641
1642 AS_IF([test "$enable_ripngd" != "no"], [
1643   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1644 ])
1645
1646 AS_IF([test "$enable_ospfd" != "no"], [
1647   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1648 ])
1649
1650 AS_IF([test "$enable_ospf6d" != "no"], [
1651   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1652 ])
1653
1654 AS_IF([test "$enable_ldpd" != "no"], [
1655   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1656 ])
1657
1658 AS_IF([test "$enable_nhrpd" != "no"], [
1659   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1660 ])
1661
1662 AS_IF([test "$enable_eigrpd" != "no"], [
1663   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1664 ])
1665
1666 AS_IF([test "$enable_babeld" != "no"], [
1667   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1668 ])
1669
1670 AS_IF([test "$enable_isisd" != "no"], [
1671   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1672 ])
1673
1674 AS_IF([test "$enable_pimd" != "no"], [
1675   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1676 ])
1677
1678 AS_IF([test "$enable_pbrd" != "no"], [
1679   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1680 ])
1681
1682 AS_IF([test "$enable_sharpd" = "yes"], [
1683   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1684 ])
1685
1686 AS_IF([test "$enable_staticd" != "no"], [
1687   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1688 ])
1689
1690 AS_IF([test "$enable_fabricd" != "no"], [
1691   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1692 ])
1693
1694 AS_IF([test "$enable_vrrpd" != "no"], [
1695   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1696 ])
1697
1698 if test "$enable_bfdd" = "no"; then
1699   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1700   BFDD=""
1701 else
1702   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1703   BFDD="bfdd"
1704
1705   case $host_os in
1706     linux*)
1707       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1708       ;;
1709
1710     *)
1711       AC_DEFINE([BFD_BSD], [1], [bfdd])
1712       ;;
1713   esac
1714 fi
1715
1716 AS_IF([test "$enable_pathd" != "no"], [
1717   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1718   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1719 ])
1720
1721
1722 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1723   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1724 fi
1725
1726 NHRPD=""
1727 case "$host_os" in
1728   linux*)
1729     case "${enable_nhrpd}" in
1730       no)
1731         ;;
1732       yes)
1733         if test "$enable_clippy_only" != "yes"; then
1734         if test "$c_ares_found" != "true" ; then
1735           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1736         fi
1737         fi
1738         NHRPD="nhrpd"
1739         ;;
1740       *)
1741         if test "$c_ares_found" = "true" ; then
1742           NHRPD="nhrpd"
1743         fi
1744         ;;
1745     esac
1746     ;;
1747   *)
1748     if test "$enable_nhrpd" = "yes"; then
1749       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1750     fi
1751     ;;
1752 esac
1753
1754 if test "$enable_watchfrr" = "no";then
1755   WATCHFRR=""
1756 else
1757   WATCHFRR="watchfrr"
1758 fi
1759
1760 OSPFCLIENT=""
1761 if test "$enable_ospfapi" != "no";then
1762     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1763
1764   if test "$enable_ospfclient" != "no";then
1765       OSPFCLIENT="ospfclient"
1766   fi
1767 fi
1768
1769 if test "$enable_bgp_announce" = "no";then
1770   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1771 else
1772   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1773 fi
1774
1775 if test "$enable_bgp_vnc" != "no";then
1776   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1777 fi
1778
1779 bgpd_bmp=false
1780 case "${enable_bmp}" in
1781   no)
1782     ;;
1783   yes)
1784     if test "$c_ares_found" != "true" ; then
1785       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1786     fi
1787     bgpd_bmp=true
1788     ;;
1789   *)
1790     if test "$c_ares_found" = "true" ; then
1791       bgpd_bmp=true
1792     fi
1793     ;;
1794 esac
1795
1796 if test "$enable_version_build_config" != "no";then
1797   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1798 fi
1799
1800 dnl ##########################################################################
1801 dnl LARGE if block
1802 if test "$enable_clippy_only" != "yes"; then
1803 dnl ##########################################################################
1804
1805 dnl ------------------
1806 dnl check Net-SNMP library
1807 dnl ------------------
1808 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1809    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1810    if test "$NETSNMP_CONFIG" = "no"; then
1811       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1812    fi
1813    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1814    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1815    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1816    # among other things we avoid a GPL vs. OpenSSL license conflict here
1817    for removelib in crypto ssl sensors pci wrap; do
1818      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1819    done
1820    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1821    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1822 int main(void);
1823 ],
1824 [
1825 {
1826   return 0;
1827 }
1828 ])], [
1829      AC_MSG_RESULT([no])
1830      AC_MSG_ERROR([--enable-snmp given but not usable])])
1831    case "${enable_snmp}" in
1832      yes)
1833       SNMP_METHOD=agentx
1834       ;;
1835      agentx)
1836       SNMP_METHOD="${enable_snmp}"
1837       ;;
1838      *)
1839       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1840       ;;
1841    esac
1842    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1843    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1844 fi
1845 AC_SUBST([SNMP_LIBS])
1846 AC_SUBST([SNMP_CFLAGS])
1847
1848 dnl ---------------
1849 dnl libyang
1850 dnl ---------------
1851 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1852   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1853 ])
1854 ac_cflags_save="$CFLAGS"
1855 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1856 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1857   AC_MSG_ERROR([m4_normalize([
1858     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1859     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1860   ])
1861 ], [[#include <libyang/libyang.h>]])
1862 CFLAGS="$ac_cflags_save"
1863
1864 dnl ---------------
1865 dnl configuration rollbacks
1866 dnl ---------------
1867 SQLITE3=false
1868 if test "$enable_config_rollbacks" = "yes"; then
1869   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1870     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1871     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1872     SQLITE3=true
1873   ], [
1874     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1875   ])
1876 fi
1877
1878 dnl ---------------
1879 dnl confd
1880 dnl ---------------
1881 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1882    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1883    if test "$CONFD" = "/bin/false"; then
1884       AC_MSG_ERROR([confd was not found on your system.])]
1885    fi
1886    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1887    AC_SUBST([CONFD_CFLAGS])
1888    CONFD_LIBS="-lconfd"
1889    AC_SUBST([CONFD_LIBS])
1890    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1891 fi
1892
1893 dnl ---------------
1894 dnl sysrepo
1895 dnl ---------------
1896 if test "$enable_sysrepo" = "yes"; then
1897   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1898       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1899       SYSREPO=true],
1900       [SYSREPO=false
1901       AC_MSG_ERROR([sysrepo was not found on your system.])]
1902   )
1903 fi
1904
1905 dnl ---------------
1906 dnl gRPC
1907 dnl ---------------
1908 if test "$enable_grpc" = "yes"; then
1909   AC_LANG_PUSH([C++])
1910   AX_CXX_COMPILE_STDCXX([11], [ext])
1911   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1912     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1913     if test "$PROTOC" = "/bin/false"; then
1914       AC_MSG_FAILURE([grpc requested but protoc not found.])
1915     fi
1916
1917     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1918     GRPC=true
1919   ], [
1920     GRPC=false
1921     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1922   ])
1923   AC_LANG_POP([C++])
1924 fi
1925
1926 dnl -----
1927 dnl LTTng
1928 dnl -----
1929 if test "$enable_lttng" = "yes"; then
1930   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
1931     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1932     LTTNG=true
1933   ], [
1934     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1935   ])
1936 fi
1937
1938 dnl ----
1939 dnl USDT
1940 dnl ----
1941 if test "$enable_usdt" = "yes"; then
1942   AC_CHECK_HEADERS([sys/sdt.h], [
1943     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1944     USDT=true
1945   ], [
1946     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1947   ])
1948 fi
1949
1950 dnl ------
1951 dnl ZeroMQ
1952 dnl ------
1953 if test "$enable_zeromq" != "no"; then
1954   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1955     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1956     ZEROMQ=true
1957   ], [
1958     if test "$enable_zeromq" = "yes"; then
1959       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1960     fi
1961   ])
1962 fi
1963
1964 dnl ------------------------------------
1965 dnl Enable RPKI and add librtr to libs
1966 dnl ------------------------------------
1967 if test "$enable_rpki" = "yes"; then
1968   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1969       [RPKI=true],
1970       [RPKI=false
1971       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1972   )
1973 fi
1974
1975 dnl ------------------------------------
1976 dnl pimd is not supported on OpenBSD and MacOS
1977 dnl ------------------------------------
1978 if test "$enable_pimd" != "no"; then
1979 AC_MSG_CHECKING([for pimd OS support])
1980 case "$host_os" in
1981   darwin*)
1982     AC_MSG_RESULT([no])
1983     enable_pimd="no"
1984     ;;
1985   openbsd*)
1986     AC_MSG_RESULT([no])
1987     enable_pimd="no"
1988     ;;
1989   *)
1990     AC_MSG_RESULT([yes])
1991     ;;
1992 esac
1993 fi
1994
1995 dnl -------------------------------------
1996 dnl VRRP is only supported on linux
1997 dnl -------------------------------------
1998 if test "$enable_vrrpd" != "no"; then
1999 AC_MSG_CHECKING([for VRRP OS support])
2000 case "$host_os" in
2001   linux*)
2002     AC_MSG_RESULT([yes])
2003     ;;
2004   *)
2005     AC_MSG_RESULT([no])
2006     enable_vrrpd="no"
2007     ;;
2008 esac
2009 fi
2010
2011 dnl ------------------------------------------
2012 dnl Check whether rtrlib was build with ssh support
2013 dnl ------------------------------------------
2014 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2015 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2016                         [[struct tr_ssh_config config;]])],
2017         [AC_MSG_RESULT([yes])
2018         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2019         AC_MSG_RESULT([no])
2020 )
2021
2022 dnl ---------------
2023 dnl dlopen & dlinfo
2024 dnl ---------------
2025 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2026   AC_MSG_ERROR([unable to find the dlopen()])
2027 ])
2028
2029 AC_CHECK_HEADERS([link.h])
2030
2031 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2032   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2033 #include <stdlib.h>
2034 #ifdef HAVE_LINK_H
2035 #include <link.h>
2036 #endif
2037 #include <dlfcn.h>
2038 ]], [[
2039   char origin[1];
2040   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2041 ]])], [
2042     frr_cv_rtld_di_origin=yes
2043   ], [
2044     frr_cv_rtld_di_origin=no
2045   ])
2046 ])
2047 if test "$frr_cv_rtld_di_origin" = "yes"; then
2048   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2049 fi
2050
2051 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2052   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2053 #include <stdlib.h>
2054 #ifdef HAVE_LINK_H
2055 #include <link.h>
2056 #endif
2057 #include <dlfcn.h>
2058 ]], [[
2059   struct link_map *lm = NULL;
2060   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2061 ]])], [
2062     frr_cv_rtld_di_linkmap=yes
2063   ], [
2064     frr_cv_rtld_di_linkmap=no
2065   ])
2066 ])
2067 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2068   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2069 fi
2070
2071 dnl ##########################################################################
2072 dnl test "$enable_clippy_only" != "yes"
2073 fi
2074 dnl END OF LARGE if block
2075 dnl ##########################################################################
2076
2077 dnl ---------------------------
2078 dnl sockaddr and netinet checks
2079 dnl ---------------------------
2080 AC_CHECK_TYPES([
2081         struct sockaddr_dl,
2082         struct vifctl, struct mfcctl, struct sioc_sg_req,
2083         vifi_t, struct sioc_vif_req, struct igmpmsg,
2084         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2085         struct nd_opt_adv_interval,
2086         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2087         struct nd_opt_rdnss, struct nd_opt_dnssl],
2088         [], [], FRR_INCLUDES)
2089
2090 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2091         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2092         struct sockaddr_dl.sdl_len,
2093         struct if6_aliasreq.ifra_lifetime,
2094         struct nd_opt_adv_interval.nd_opt_ai_type],
2095         [], [], FRR_INCLUDES)
2096
2097 dnl ---------------------------
2098 dnl IRDP/pktinfo/icmphdr checks
2099 dnl ---------------------------
2100
2101 AC_CHECK_TYPES([struct in_pktinfo], [
2102   AC_CHECK_TYPES([struct icmphdr], [
2103     IRDP=true
2104   ], [
2105     IRDP=false
2106   ], [FRR_INCLUDES])
2107 ], [
2108   IRDP=false
2109 ], [FRR_INCLUDES])
2110
2111 case "${enable_irdp}" in
2112 yes)
2113   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2114   ;;
2115 no)
2116   IRDP=false
2117   ;;
2118 esac
2119
2120
2121 dnl -----------------------
2122 dnl checking for IP_PKTINFO
2123 dnl -----------------------
2124 AC_MSG_CHECKING([for IP_PKTINFO])
2125 AC_COMPILE_IFELSE(
2126 [ AC_LANG_PROGRAM([[
2127         #include <netdb.h>
2128    ]], [[
2129         int opt = IP_PKTINFO;
2130    ]])
2131 ],[
2132   AC_MSG_RESULT([yes])
2133   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2134 ],[
2135   AC_MSG_RESULT([no])
2136 ])
2137
2138 dnl ---------------------------
2139 dnl checking for IP_RECVDSTADDR
2140 dnl ---------------------------
2141 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2142 AC_COMPILE_IFELSE(
2143 [ AC_LANG_PROGRAM([[
2144         #include <netinet/in.h>
2145   ]], [[
2146         int opt = IP_RECVDSTADDR;
2147   ]])
2148 ],[
2149   AC_MSG_RESULT([yes])
2150   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2151 ],[
2152   AC_MSG_RESULT([no])
2153 ])
2154
2155 dnl ----------------------
2156 dnl checking for IP_RECVIF
2157 dnl ----------------------
2158 AC_MSG_CHECKING([for IP_RECVIF])
2159 AC_COMPILE_IFELSE(
2160 [ AC_LANG_PROGRAM([[
2161         #include <netinet/in.h>
2162   ]], [[
2163         int opt = IP_RECVIF;
2164   ]])
2165 ],[
2166   AC_MSG_RESULT([yes])
2167   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2168 ],[
2169   AC_MSG_RESULT([no])
2170 ])
2171
2172 dnl ----------------------
2173 dnl checking for SO_BINDANY
2174 dnl ----------------------
2175 AC_MSG_CHECKING([for SO_BINDANY])
2176 AC_COMPILE_IFELSE(
2177 [ AC_LANG_PROGRAM([[
2178         #include <sys/socket.h>
2179   ]], [[
2180         int opt = SO_BINDANY;
2181   ]])
2182 ],[
2183   AC_MSG_RESULT([yes])
2184   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2185 ],[
2186   AC_MSG_RESULT([no])
2187 ])
2188
2189 dnl ----------------------
2190 dnl checking for IP_FREEBIND
2191 dnl ----------------------
2192 AC_MSG_CHECKING([for IP_FREEBIND])
2193 AC_COMPILE_IFELSE(
2194 [ AC_LANG_PROGRAM([[
2195         #include <netinet/in.h>
2196   ]], [[
2197         int opt = IP_FREEBIND;
2198   ]])
2199 ],[
2200   AC_MSG_RESULT([yes])
2201   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2202 ],[
2203   AC_MSG_RESULT([no])
2204 ])
2205
2206 dnl --------------------------------------
2207 dnl checking for be32dec existence or not
2208 dnl --------------------------------------
2209 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2210         #ifdef HAVE_SYS_ENDIAN_H
2211         #include <sys/endian.h>
2212         #endif
2213         #ifdef HAVE_ENDIAN_H
2214         #include <endian.h>
2215         #endif
2216 ])
2217
2218 dnl --------------------------------------
2219 dnl checking for clock_time monotonic struct and call
2220 dnl --------------------------------------
2221 AC_CHECK_DECL([CLOCK_MONOTONIC],
2222         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2223          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2224 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2225
2226 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2227          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2228 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2229
2230 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2231   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2232 ])
2233
2234 dnl --------------------------------------
2235 dnl checking for flex and bison
2236 dnl --------------------------------------
2237
2238 AM_PROG_LEX
2239 AC_MSG_CHECKING([version of flex])
2240 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2241 frr_ac_flex_version="${frr_ac_flex_version##* }"
2242 AC_MSG_RESULT([$frr_ac_flex_version])
2243 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2244   LEX="$SHELL $missing_dir/missing flex"
2245   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2246     AC_MSG_WARN([using pregenerated flex output files])
2247   else
2248     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2249   fi
2250   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2251   AC_SUBST([LEXLIB], [''])
2252 ])
2253
2254 AC_PROG_YACC
2255 dnl thanks GNU bison for this b*llshit...
2256 AC_MSG_CHECKING([version of bison])
2257 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2258 frr_ac_bison_version="${frr_ac_bison_version##* }"
2259 frr_ac_bison_missing="false"
2260 case "x${frr_ac_bison_version}x" in
2261   x2.7*)
2262     BISON_OPENBRACE='"'
2263     BISON_CLOSEBRACE='"'
2264     BISON_VERBOSE=''
2265     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2266     ;;
2267   x2.*|x1.*)
2268     AC_MSG_RESULT([$frr_ac_bison_version])
2269     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2270     frr_ac_bison_missing="true"
2271     ;;
2272   x)
2273     AC_MSG_RESULT([none])
2274     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2275     frr_ac_bison_missing="true"
2276     ;;
2277   x3.[012][^0-9]*)
2278     BISON_OPENBRACE='{'
2279     BISON_CLOSEBRACE='}'
2280     BISON_VERBOSE='-Dparse.error=verbose'
2281     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2282     ;;
2283   *)
2284     BISON_OPENBRACE='{'
2285     BISON_CLOSEBRACE='}'
2286     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2287     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2288     ;;
2289 esac
2290 AC_SUBST([BISON_OPENBRACE])
2291 AC_SUBST([BISON_CLOSEBRACE])
2292 AC_SUBST([BISON_VERBOSE])
2293
2294 if $frr_ac_bison_missing; then
2295   YACC="$SHELL $missing_dir/missing bison -y"
2296   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2297     AC_MSG_WARN([using pregenerated bison output files])
2298   else
2299     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2300   fi
2301 fi
2302
2303 dnl -------------------
2304 dnl capabilities checks
2305 dnl -------------------
2306 if test "$enable_capabilities" != "no"; then
2307   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2308   AC_COMPILE_IFELSE(
2309   [ AC_LANG_PROGRAM([[
2310         #include <sys/prctl.h>
2311     ]], [[
2312         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2313     ]])
2314   ],[AC_MSG_RESULT([yes])
2315      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2316      frr_ac_keepcaps="yes"
2317   ],[AC_MSG_RESULT(no)
2318   ])
2319   if test "$frr_ac_keepcaps" = "yes"; then
2320     AC_CHECK_HEADERS([sys/capability.h])
2321   fi
2322   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2323     AC_CHECK_LIB([cap], [cap_init],
2324       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2325        LIBCAP="-lcap"
2326        frr_ac_lcaps="yes"]
2327     )
2328   fi
2329   if test "$frr_ac_scaps" = "yes" \
2330        -o "$frr_ac_lcaps" = "yes"; then
2331     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2332   fi
2333
2334   case "$host_os" in
2335   linux*)
2336     if test "$enable_clippy_only" != "yes"; then
2337     if test "$frr_ac_lcaps" != "yes"; then
2338       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2339     fi
2340     fi
2341     ;;
2342   esac
2343 else
2344   case "$host_os" in
2345   linux*)
2346     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2347     ;;
2348   esac
2349 fi
2350 AC_SUBST([LIBCAP])
2351
2352 dnl ---------------------------
2353 dnl check for glibc 'backtrace'
2354 dnl ---------------------------
2355 if test "$enable_backtrace" != "no" ; then
2356   backtrace_ok=no
2357   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2358     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2359     backtrace_ok=yes
2360   ], [
2361     true
2362   ])
2363
2364   if test "$backtrace_ok" = "no"; then
2365     AC_CHECK_HEADER([unwind.h], [
2366       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2367         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2368         backtrace_ok=yes
2369       ])
2370     ])
2371   fi
2372
2373   if test "$backtrace_ok" = "no"; then
2374     AC_CHECK_HEADER([execinfo.h], [
2375       AC_SEARCH_LIBS([backtrace], [execinfo], [
2376         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2377         backtrace_ok=yes
2378       ],, [-lm])
2379     ])
2380   fi
2381
2382   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2383     dnl user explicitly requested backtrace but we failed to find support
2384     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2385   fi
2386 fi
2387
2388 dnl -----------------------------------------
2389 dnl check for malloc mallinfo struct and call
2390 dnl this must try and link using LIBS, in
2391 dnl order to check no alternative allocator
2392 dnl has been specified, which might not provide
2393 dnl mallinfo
2394 dnl -----------------------------------------
2395 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2396
2397 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2398   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2399 #ifdef HAVE_MALLOC_H
2400 #include <malloc.h>
2401 #endif
2402 #ifdef HAVE_MALLOC_NP_H
2403 #include <malloc_np.h>
2404 #endif
2405 #ifdef HAVE_MALLOC_MALLOC_H
2406 #include <malloc/malloc.h>
2407 #endif
2408 ]], [[
2409 struct mallinfo ac_x; ac_x = mallinfo ();
2410 ]])], [
2411     frr_cv_mallinfo=yes
2412   ], [
2413     frr_cv_mallinfo=no
2414   ])
2415 ])
2416 if test "$frr_cv_mallinfo" = "yes"; then
2417   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2418 fi
2419
2420 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2421   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2422 #ifdef HAVE_MALLOC_H
2423 #include <malloc.h>
2424 #endif
2425 #ifdef HAVE_MALLOC_NP_H
2426 #include <malloc_np.h>
2427 #endif
2428 #ifdef HAVE_MALLOC_MALLOC_H
2429 #include <malloc/malloc.h>
2430 #endif
2431 ]], [[
2432 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2433 ]])], [
2434     frr_cv_mallinfo2=yes
2435   ], [
2436     frr_cv_mallinfo2=no
2437   ])
2438 ])
2439 if test "$frr_cv_mallinfo2" = "yes"; then
2440   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2441 fi
2442
2443 AC_MSG_CHECKING([whether malloc_usable_size is available])
2444 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2445 #ifdef HAVE_MALLOC_H
2446 #include <malloc.h>
2447 #endif
2448 #ifdef HAVE_MALLOC_MALLOC_H
2449 #include <malloc/malloc.h>
2450 #endif
2451 ]], [[
2452 size_t ac_x; ac_x = malloc_usable_size(NULL);
2453 ]])], [
2454   AC_MSG_RESULT([yes])
2455   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2456 ], [
2457   AC_MSG_RESULT([no])
2458
2459   AC_MSG_CHECKING([whether malloc_size is available])
2460   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2461 #ifdef HAVE_MALLOC_H
2462 #include <malloc.h>
2463 #endif
2464 #ifdef HAVE_MALLOC_MALLOC_H
2465 #include <malloc/malloc.h>
2466 #endif
2467 ]], [[
2468 size_t ac_x; ac_x = malloc_size(NULL);
2469 ]])], [
2470     AC_MSG_RESULT([yes])
2471     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2472   ], [
2473     AC_MSG_RESULT([no])
2474   ])
2475 ])
2476
2477 dnl ----------
2478 dnl configure date
2479 dnl ----------
2480 dev_version=`echo $VERSION | grep dev`
2481 #don't expire deprecated code in non 'dev' branch
2482 if test "$dev_version" = ""; then
2483    CONFDATE=0
2484 else
2485    CONFDATE=`date '+%Y%m%d'`
2486 fi
2487 AC_SUBST([CONFDATE])
2488
2489 dnl ------------------------------
2490 dnl set paths for state directory
2491 dnl ------------------------------
2492 AC_MSG_CHECKING([directory to use for state file])
2493 if test "$prefix" = "NONE"; then
2494   frr_statedir_prefix="";
2495 else
2496   frr_statedir_prefix=${prefix}
2497 fi
2498 if test "$localstatedir" = '${prefix}/var'; then
2499   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2500                         ${frr_statedir_prefix}/var/adm dnl
2501                         ${frr_statedir_prefix}/etc dnl
2502                         /var/run        dnl
2503                         /var/adm        dnl
2504                         /etc            dnl
2505                         /dev/null;
2506   do
2507     test -d $FRR_STATE_DIR && break
2508   done
2509   frr_statedir=$FRR_STATE_DIR
2510 else
2511   frr_statedir=${localstatedir}
2512 fi
2513 if test "$frr_statedir" = "/dev/null"; then
2514     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2515 fi
2516 AC_MSG_RESULT([${frr_statedir}])
2517 AC_SUBST([frr_statedir])
2518
2519 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2520 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2521 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2522 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2523 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2524 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2525 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2526
2527 dnl autoconf does this, but it does it too late...
2528 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2529 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2530
2531 dnl get the full path, recursing through variables...
2532 vtysh_bin="$bindir/vtysh"
2533 for I in 1 2 3 4 5 6 7 8 9 10; do
2534         eval vtysh_bin="\"$vtysh_bin\""
2535 done
2536 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2537 AC_SUBST([vtysh_bin])
2538
2539 CFG_SYSCONF="$sysconfdir"
2540 CFG_SBIN="$sbindir"
2541 CFG_STATE="$frr_statedir"
2542 CFG_MODULE="$moduledir"
2543 CFG_YANGMODELS="$yangmodelsdir"
2544 CFG_SCRIPT="$scriptdir"
2545 for I in 1 2 3 4 5 6 7 8 9 10; do
2546         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2547         eval CFG_SBIN="\"$CFG_SBIN\""
2548         eval CFG_STATE="\"$CFG_STATE\""
2549         eval CFG_MODULE="\"$CFG_MODULE\""
2550         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2551         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2552 done
2553 AC_SUBST([CFG_SYSCONF])
2554 AC_SUBST([CFG_SBIN])
2555 AC_SUBST([CFG_STATE])
2556 AC_SUBST([CFG_MODULE])
2557 AC_SUBST([CFG_SCRIPT])
2558 AC_SUBST([CFG_YANGMODELS])
2559 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2560 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2561 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2562 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2563
2564 dnl various features
2565 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2566 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2567 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2568 dnl northbound
2569 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2570 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2571 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2572 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2573 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2574 dnl plugins
2575 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2576 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2577 AM_CONDITIONAL([IRDP], [$IRDP])
2578 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2579 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2580 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2581
2582 dnl PCEP plugin
2583 AS_IF([test "$enable_pathd" != "no"], [
2584        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2585        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2586        ])
2587 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2588 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2589 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2590 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2591
2592 dnl daemons
2593 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2594 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2595 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2596 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2597 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2598 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2599 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2600 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2601 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2602 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2603 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2604 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2605 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2606 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2607 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2608 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2609 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2610 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2611 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2612 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2613 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2614 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2615 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2616
2617 AC_CONFIG_FILES([Makefile],[
2618         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2619         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2620 ], [
2621         PYTHON="$PYTHON"
2622         enable_dev_build="$enable_dev_build"
2623 ])
2624
2625 AC_CONFIG_FILES([
2626           config.version
2627           redhat/frr.spec
2628           alpine/APKBUILD
2629           snapcraft/snapcraft.yaml
2630           lib/version.h
2631           tests/lib/cli/test_cli.refout
2632           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2633           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2634           pkgsrc/eigrpd.sh])
2635
2636 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2637 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2638 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2639 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2640 AC_CONFIG_FILES([tools/frrcommon.sh])
2641 AC_CONFIG_FILES([tools/frr.service])
2642 AC_CONFIG_FILES([tools/frr@.service])
2643
2644 AS_IF([test "$with_pkg_git_version" = "yes"], [
2645     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2646         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2647         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2648                 "${ac_abs_top_srcdir}" \
2649                 > "${dst}.tmp"
2650         test -f "$dst" \
2651                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2652                 && rm "${dst}.tmp" \
2653                 || mv "${dst}.tmp" "${dst}"
2654     ], [
2655         PERL="$PERL"
2656     ])
2657 ])
2658
2659 ## Hack, but working solution to avoid rebuilding of frr.info.
2660 ## It's already in CVS until texinfo 4.7 is more common.
2661 AC_OUTPUT
2662
2663 if test "$enable_rpath" = "yes" ; then
2664         true
2665 else
2666         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2667         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2668         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2669         test -f libtool.sed && rm libtool.sed
2670 fi
2671
2672 echo "
2673 FRRouting configuration
2674 ------------------------------
2675 FRR version             : ${PACKAGE_VERSION}
2676 host operating system   : ${host_os}
2677 source code location    : ${srcdir}
2678 compiler                : ${CC}
2679 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2680 make                    : ${MAKE-make}
2681 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2682 state file directory    : ${frr_statedir}
2683 config file directory   : `eval echo \`echo ${sysconfdir}\``
2684 module directory        : ${CFG_MODULE}
2685 script directory        : ${CFG_SCRIPT}
2686 user to run as          : ${enable_user}
2687 group to run as         : ${enable_group}
2688 group for vty sockets   : ${enable_vty_group}
2689 config file mask        : ${enable_configfile_mask}
2690 log file mask           : ${enable_logfile_mask}
2691 zebra protobuf enabled  : ${enable_protobuf:-no}
2692 vici socket path        : ${vici_socket}
2693
2694 The above user and group must have read/write access to the state file
2695 directory and to the config files in the config file directory."
2696
2697 if test -n "$enable_datacenter"; then
2698   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2699 fi
2700 if test -n "$enable_time_check"; then
2701   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2702 fi
2703 if test -n "$enable_cpu_time"; then
2704   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2705 fi
2706
2707 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2708   AC_MSG_WARN([sphinx is missing but required to build documentation])
2709 fi
2710 if test "$frr_py_mod_pytest" = "false"; then
2711   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2712 fi