configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.7-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AC_ARG_VAR([AR],[archiver command])
  29 AC_ARG_VAR([LD],[linker command])
  30 AC_ARG_VAR([OBJCOPY],[objcopy command])
  31 AC_ARG_VAR([OBJDUMP],[objdump command])
  32 AC_ARG_VAR([RANLIB],[ranlib command])
  33 AC_ARG_VAR([STRIP],[strip command])
  34
  35 hosttools_clippy="false"
  36 build_clippy="true"
  37
  38 dnl case 1: external clippy
  39 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  40   if test "$enable_clippy_only" = "yes"; then
  41     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  42   fi
  43
  44   CLIPPY="$with_clippy"
  45   build_clippy="false"
  46   if test ! -x "$with_clippy"; then
  47     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  48   fi
  49
  50 dnl case 2: cross-compiling internal clippy
  51 elif test "$host" != "$build"; then
  52   if test "$srcdir" = "."; then
  53     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  54   fi
  55   test -d hosttools || mkdir hosttools
  56   abssrc="`cd \"${srcdir}\"; pwd`"
  57
  58   AC_MSG_NOTICE([...])
  59   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  60   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  61   AC_MSG_NOTICE([...])
  62
  63   (
  64     for var in $ac_precious_vars; do
  65       dnl special cases
  66       case "$var" in
  67       YACC|YFLAGS) continue;;
  68       PYTHON*)     retain=true;;
  69       *)           retain=false;
  70       esac
  71
  72       eval "hostvar=\"\${HOST_$var}\""
  73       eval "targetvar=\"\${$var}\""
  74       if test -n "$hostvar"; then
  75         eval "$var='$hostvar'"
  76         _AS_ECHO_LOG([host $var='$hostvar'])
  77       elif $retain; then
  78         _AS_ECHO_LOG([host retain $var='$targetvar'])
  79       else
  80         eval "unset $var"
  81         _AS_ECHO_LOG([host unset $var])
  82       fi
  83     done
  84     cd hosttools
  85     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  86   ) || exit 1
  87
  88   AC_MSG_NOTICE([...])
  89   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  90   AC_MSG_NOTICE([...])
  91
  92   build_clippy="false"
  93   hosttools_clippy="true"
  94   CLIPPY="hosttools/lib/clippy"
  95
  96 dnl case 3: normal build internal clippy
  97 else
  98   CLIPPY="lib/clippy\$(EXEEXT)"
  99 fi
 100 AC_SUBST([CLIPPY])
 101 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 102 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 103 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 104
 105 # Disable portability warnings -- our automake code (in particular
 106 # common.am) uses some constructs specific to gmake.
 107 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 108 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 109 AM_SILENT_RULES([yes])
 110 AC_CONFIG_HEADERS([config.h])
 111
 112 AC_PATH_PROG([PERL], [perl])
 113 PKG_PROG_PKG_CONFIG
 114
 115 dnl default is to match previous behavior
 116 exampledir=${sysconfdir}
 117 AC_ARG_ENABLE([exampledir],
 118           AS_HELP_STRING([--enable-exampledir],
 119                          [specify alternate directory for examples]),
 120                          exampledir="$enableval",)
 121 dnl XXX add --exampledir to autoconf standard directory list somehow
 122 AC_SUBST([exampledir])
 123
 124 dnl default is to match previous behavior
 125 pkgsrcrcdir=""
 126 AC_ARG_ENABLE([pkgsrcrcdir],
 127           AS_HELP_STRING([--enable-pkgsrcrcdir],
 128                          [specify directory for rc.d scripts]),
 129                          pkgsrcrcdir="$enableval",)
 130 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 131 AC_SUBST([pkgsrcrcdir])
 132 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 133
 134 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 135         moduledir="$withval"
 136 ], [
 137         moduledir="\${libdir}/frr/modules"
 138 ])
 139 AC_SUBST([moduledir], [$moduledir])
 140
 141 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 142         scriptdir="$withval"
 143 ], [
 144         scriptdir="\${sysconfdir}/scripts"
 145 ])
 146 AC_SUBST([scriptdir], [$scriptdir])
 147
 148 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 149         yangmodelsdir="$withval"
 150 ], [
 151         yangmodelsdir="\${datarootdir}/yang"
 152 ])
 153 AC_SUBST([yangmodelsdir])
 154
 155 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 156         vici_socket="$withval"
 157 ], [
 158         vici_socket="/var/run/charon.vici"
 159 ])
 160 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 161
 162 AC_ARG_ENABLE(tcmalloc,
 163         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 164 [case "${enableval}" in
 165   yes) tcmalloc_enabled=true
 166 LIBS="$LIBS -ltcmalloc_minimal"
 167  ;;
 168   no)  tcmalloc_enabled=false ;;
 169   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 170 esac],[tcmalloc_enabled=false])
 171
 172
 173 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 174 dnl flag determination logic.
 175 CFLAGS="${CFLAGS:-}"
 176
 177 dnl --------------------
 178 dnl Check CC and friends
 179 dnl --------------------
 180 dnl note orig_cflags is also used further down
 181 orig_cflags="$CFLAGS"
 182 orig_cxxflags="$CXXFLAGS"
 183 AC_LANG([C])
 184 AC_PROG_CC
 185 AC_PROG_CPP
 186 AC_PROG_CXX
 187 AM_PROG_CC_C_O
 188 dnl remove autoconf default "-g -O2"
 189 CFLAGS="$orig_cflags"
 190 CXXFLAGS="$orig_cxxflags"
 191 AC_PROG_CC_C99
 192 dnl NB: see C11 below
 193
 194 dnl Some special handling for ICC later on
 195 if test "$CC" = "icc"; then
 196     cc_is_icc="yes"
 197 fi
 198
 199 PKG_PROG_PKG_CONFIG
 200
 201 dnl it's 2019, sed is sed.
 202 SED=sed
 203 AC_SUBST([SED])
 204
 205 dnl try and enable CFLAGS that are useful for FRR
 206 dnl - specifically, options to control warnings
 207
 208 AC_USE_SYSTEM_EXTENSIONS
 209 AC_DEFUN([AC_C_FLAG], [{
 210     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 211     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 212         AC_LANG_PUSH([C])
 213         ac_c_flag_save="$CFLAGS"
 214         CFLAGS="$CFLAGS $1"
 215         AC_COMPILE_IFELSE(
 216                 [AC_LANG_PROGRAM([[$4]])],
 217                 [
 218                         cachename=yes
 219                 ], [
 220                         cachename=no
 221                 ])
 222         CFLAGS="$ac_c_flag_save"
 223         AC_LANG_POP([C])
 224     ])
 225     if test "$cachename" = "yes"; then
 226         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 227     else
 228         :
 229         $2
 230     fi
 231     m4_popdef([cachename])
 232 }])
 233
 234 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 235         AC_LANG_PUSH([C])
 236         ac_cflags_save="$CFLAGS"
 237         ac_libs_save="$LIBS"
 238         CFLAGS="$CFLAGS $1"
 239         LIBS="$LIBS $2"
 240         AC_LINK_IFELSE(
 241                 [$3],
 242                 [
 243                         CFLAGS="$ac_cflags_save"
 244                         LIBS="$ac_libs_save"
 245                         m4_default([$5], [
 246                                 AC_MSG_RESULT([yes])
 247                         ])
 248                 ], [
 249                         CFLAGS="$ac_cflags_save"
 250                         LIBS="$ac_libs_save"
 251                         m4_default([$4], [
 252                                 AC_MSG_RESULT([no])
 253                         ])
 254                 ])
 255         AC_LANG_POP([C])
 256         }])
 257
 258 dnl ICC won't bail on unknown options without -diag-error 10006
 259 dnl need to do this first so we get useful results for the other options
 260 if test "$cc_is_icc" = "yes"; then
 261     AC_C_FLAG([-diag-error 10006])
 262 fi
 263
 264 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 265 ac_cc="$CC"
 266 CC="${CC% -std=gnu99}"
 267 CC="${CC% -std=c99}"
 268
 269 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 270
 271 dnl if the user has specified any CFLAGS, override our settings
 272 if test "$enable_gcov" = "yes"; then
 273    if test "$orig_cflags" = ""; then
 274       AC_C_FLAG([-coverage])
 275       AC_C_FLAG([-O0])
 276    fi
 277
 278    LDFLAGS="${LDFLAGS} -lgcov"
 279 fi
 280
 281 if test "$enable_clang_coverage" = "yes"; then
 282    AC_C_FLAG([-fprofile-instr-generate], [
 283      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 284    ])
 285    AC_C_FLAG([-fcoverage-mapping], [
 286      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 287    ])
 288 fi
 289
 290 if test "$enable_scripting" = "yes"; then
 291    AX_PROG_LUA([5.3])
 292    AX_LUA_HEADERS
 293    AX_LUA_LIBS([
 294       AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 295       LIBS="$LIBS $LUA_LIB"
 296    ])
 297 fi
 298
 299 if test "$enable_dev_build" = "yes"; then
 300    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 301    if test "$orig_cflags" = ""; then
 302       AC_C_FLAG([-g3])
 303       AC_C_FLAG([-O0])
 304    fi
 305 else
 306    if test "$orig_cflags" = ""; then
 307       AC_C_FLAG([-g])
 308       AC_C_FLAG([-O2])
 309    fi
 310 fi
 311 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 312
 313 dnl always want these CFLAGS
 314 AC_C_FLAG([-fno-omit-frame-pointer])
 315 AC_C_FLAG([-funwind-tables])
 316 AC_C_FLAG([-Wall])
 317 AC_C_FLAG([-Wextra])
 318 AC_C_FLAG([-Wmissing-prototypes])
 319 AC_C_FLAG([-Wmissing-declarations])
 320 AC_C_FLAG([-Wpointer-arith])
 321 AC_C_FLAG([-Wbad-function-cast])
 322 AC_C_FLAG([-Wwrite-strings])
 323 AC_C_FLAG([-Wundef])
 324 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 325   AC_C_FLAG([-Wcast-qual])
 326   AC_C_FLAG([-Wstrict-prototypes])
 327   AC_C_FLAG([-Wmissing-noreturn])
 328   AC_C_FLAG([-Wmissing-format-attribute])
 329   AC_C_FLAG([-Wunreachable-code])
 330   AC_C_FLAG([-Wpacked])
 331   AC_C_FLAG([-Wpadded])
 332   AC_C_FLAG([-Wshadow])
 333 else
 334   AC_C_FLAG([-Wno-unused-result])
 335 fi
 336 AC_C_FLAG([-Wno-unused-parameter])
 337 AC_C_FLAG([-Wno-missing-field-initializers])
 338
 339 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 340 AC_SUBST([CXX_COMPAT_CFLAGS])
 341
 342 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 343 dnl for some reason the string consts get 'promoted' to char *,
 344 dnl triggering a const to non-const conversion warning.
 345 if test "$cc_is_icc" = "yes"; then
 346     AC_C_FLAG([-diag-disable 3179])
 347 fi
 348
 349 if test "$enable_werror" = "yes" ; then
 350   WERROR="-Werror"
 351 fi
 352 AC_SUBST([WERROR])
 353
 354 SAN_FLAGS=""
 355 if test "$enable_address_sanitizer" = "yes"; then
 356   AC_C_FLAG([-fsanitize=address], [
 357     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 358   ], [
 359     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 360   ])
 361 fi
 362 if test "$enable_thread_sanitizer" = "yes"; then
 363   AC_C_FLAG([-fsanitize=thread], [
 364     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 365   ], [
 366     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 367   ])
 368 fi
 369 if test "$enable_memory_sanitizer" = "yes"; then
 370   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 371     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 372   ], [
 373     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 374   ])
 375 fi
 376 if test "$enable_undefined_sanitizer" = "yes"; then
 377   AC_C_FLAG([-fsanitize=undefined], [
 378     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 379   ], [
 380     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 381   ])
 382 fi
 383 AC_SUBST([SAN_FLAGS])
 384
 385 dnl frr-format.so
 386 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 387   AC_C_FLAG([-fplugin=${with_frr_format}], [
 388     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 389   ],,[
 390 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 391 #error plugin not loaded
 392 #endif
 393 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 394 #error plugin too old
 395 #endif
 396   ])
 397 elif test "$with_frr_format" = "no"; then
 398   : #nothing
 399 else
 400   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 401     AC_C_FLAG([-fplugin=frr-format],[
 402       if test "$with_frr_format" = "yes"; then
 403         AC_MSG_ERROR([frr-format plugin requested but not found])
 404       fi
 405     ],,[
 406 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 407 #error plugin not loaded
 408 #endif
 409 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 410 #error plugin too old
 411 #endif
 412     ])
 413   ],,[
 414 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 415 #error plugin not loaded
 416 #endif
 417 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 418 #error plugin too old
 419 #endif
 420   ])
 421 fi
 422
 423 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 424 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 425 #include <stdio.h>
 426 int __attribute__((section("secttest"))) var = 1;
 427 extern int __start_secttest, __stop_secttest;
 428 ]], [[
 429   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 430   printf("%p %p %p\n", a, b, c);
 431 ]])], [
 432   AC_MSG_RESULT(yes)
 433   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 434 ], [
 435   AC_MSG_RESULT(no)
 436 ])
 437
 438 dnl ----------
 439 dnl Essentials
 440 dnl ----------
 441
 442 AX_PTHREAD([
 443   CC="$PTHREAD_CC"
 444   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 445   LIBS="$PTHREAD_LIBS $LIBS"
 446 ], [
 447   AC_MSG_FAILURE([This FRR version needs pthreads])
 448 ])
 449
 450 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 451                 [frr_cv_pthread_condattr_setclock=yes],
 452                 [frr_cv_pthread_condattr_setclock=no])
 453 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 454   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 455 fi
 456
 457 dnl --------------
 458 dnl Check programs
 459 dnl --------------
 460 AC_PROG_INSTALL
 461 AC_PROG_LN_S
 462 AC_CHECK_TOOL([AR], [ar])
 463
 464 dnl -------
 465 dnl libtool
 466 dnl -------
 467 AC_ARG_ENABLE([static-bin],
 468   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 469 LT_INIT
 470 _LT_CONFIG_LIBTOOL([
 471   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 472     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 473   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 474   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 475   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 476 ])
 477 if test "$enable_static_bin" = "yes"; then
 478   AC_LDFLAGS="-static"
 479   if test "$enable_static" != "yes"; then
 480     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 481   fi
 482 fi
 483 if test "$enable_shared" != "yes"; then
 484   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 485 fi
 486 AC_SUBST([AC_LDFLAGS])
 487 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 488
 489 AC_ARG_ENABLE([rpath],
 490   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 491   [],
 492   [enable_rpath=yes])
 493
 494 dnl $AR and $RANLIB are set by LT_INIT above
 495 AC_MSG_CHECKING([whether $AR supports D option])
 496 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 497   AC_MSG_RESULT([yes])
 498   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 499   ARFLAGS="crD"
 500   AR_FLAGS="crD"
 501 else
 502   AC_MSG_RESULT([no])
 503   ARFLAGS="cru"
 504   AR_FLAGS="cru"
 505 fi
 506 AC_SUBST([ARFLAGS])
 507 AC_SUBST([AR_FLAGS])
 508
 509 AC_MSG_CHECKING([whether $RANLIB supports D option])
 510 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 511   if grep -q -- '-D' conftest.err; then
 512     AC_MSG_RESULT([no])
 513   else
 514     AC_MSG_RESULT([yes])
 515     RANLIB="$RANLIB -D"
 516   fi
 517 else
 518   AC_MSG_RESULT([no])
 519 fi
 520 AC_SUBST([RANLIB])
 521
 522 test -f conftest.err && rm conftest.err
 523 test -f conftest.a && rm conftest.a
 524
 525 dnl ----------------------
 526 dnl Packages configuration
 527 dnl ----------------------
 528 if test -f config.version; then
 529   . ./config.version
 530 elif test -f "${srcdir}/config.version"; then
 531   . "${srcdir}/config.version"
 532 fi
 533 AC_ARG_WITH([pkg-extra-version],
 534   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 535   if test "$withval" = "no"; then
 536     EXTRAVERSION=
 537   else
 538     EXTRAVERSION=$withval
 539   fi
 540 ], [])
 541 AC_ARG_WITH([pkg-git-version],
 542         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 543         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 544 AC_ARG_WITH([clippy],
 545   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 546 AC_ARG_WITH([vtysh_pager],
 547         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 548         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 549 AC_ARG_ENABLE([vtysh],
 550   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 551 AC_ARG_ENABLE([doc],
 552   AS_HELP_STRING([--disable-doc], [do not build docs]))
 553 AC_ARG_ENABLE([doc-html],
 554   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 555 AC_ARG_ENABLE([zebra],
 556   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 557 AC_ARG_ENABLE([bgpd],
 558   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 559 AC_ARG_ENABLE([ripd],
 560   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 561 AC_ARG_ENABLE([ripngd],
 562   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 563 AC_ARG_ENABLE([ospfd],
 564   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 565 AC_ARG_ENABLE([ospf6d],
 566   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 567 AC_ARG_ENABLE([ldpd],
 568   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 569 AC_ARG_ENABLE([nhrpd],
 570   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 571 AC_ARG_ENABLE([eigrpd],
 572   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 573 AC_ARG_ENABLE([babeld],
 574   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 575 AC_ARG_ENABLE([watchfrr],
 576   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 577 AC_ARG_ENABLE([isisd],
 578   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 579 AC_ARG_ENABLE([pimd],
 580   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 581 AC_ARG_ENABLE([pbrd],
 582   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 583 AC_ARG_ENABLE([sharpd],
 584   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 585 AC_ARG_ENABLE([staticd],
 586   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 587 AC_ARG_ENABLE([fabricd],
 588   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 589 AC_ARG_ENABLE([vrrpd],
 590   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 591 AC_ARG_ENABLE([pathd],
 592   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 593 AC_ARG_ENABLE([bgp-announce],
 594   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 595 AC_ARG_ENABLE([bgp-vnc],
 596   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 597 AC_ARG_ENABLE([bgp-bmp],
 598   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 599 AC_ARG_ENABLE([snmp],
 600   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 601 AC_ARG_ENABLE([config_rollbacks],
 602   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 603 AC_ARG_ENABLE([confd],
 604   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 605 AC_ARG_ENABLE([sysrepo],
 606   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 607 AC_ARG_ENABLE([grpc],
 608   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 609 AC_ARG_ENABLE([zeromq],
 610   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 611 AC_ARG_ENABLE([lttng],
 612   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 613 AC_ARG_ENABLE([usdt],
 614   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 615 AC_ARG_WITH([libpam],
 616   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 617 AC_ARG_ENABLE([ospfapi],
 618   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 619 AC_ARG_ENABLE([ospfclient],
 620   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 621                           (this is the default if --disable-ospfapi is set)]))
 622 AC_ARG_ENABLE([multipath],
 623   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 624 AC_ARG_ENABLE([user],
 625   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 626 AC_ARG_ENABLE([group],
 627   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 628 AC_ARG_ENABLE([vty_group],
 629   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 630 AC_ARG_ENABLE([configfile_mask],
 631   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 632 AC_ARG_ENABLE([logfile_mask],
 633   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 634 AC_ARG_ENABLE([shell_access],
 635   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 636 AC_ARG_ENABLE([realms],
 637   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 638 AC_ARG_ENABLE([rtadv],
 639   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 640 AC_ARG_ENABLE([irdp],
 641   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 642 AC_ARG_ENABLE([capabilities],
 643   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 644 AC_ARG_ENABLE([rusage],
 645   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 646 AC_ARG_ENABLE([gcc_ultra_verbose],
 647   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 648 AC_ARG_ENABLE([backtrace],
 649   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 650 AC_ARG_ENABLE([time-check],
 651   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 652 AC_ARG_ENABLE([cpu-time],
 653   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 654 AC_ARG_ENABLE([pcreposix],
 655   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 656 AC_ARG_ENABLE([fpm],
 657   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 658 AC_ARG_ENABLE([pcep],
 659   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 660 AC_ARG_ENABLE([systemd],
 661   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 662 AC_ARG_ENABLE([werror],
 663   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 664 AC_ARG_ENABLE([cumulus],
 665   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 666 AC_ARG_ENABLE([datacenter],
 667   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 668 AC_ARG_ENABLE([rr-semantics],
 669   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 670 AC_ARG_ENABLE([protobuf],
 671   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 672 AC_ARG_ENABLE([oldvpn_commands],
 673   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 674 AC_ARG_ENABLE([rpki],
 675   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 676 AC_ARG_ENABLE([clippy-only],
 677   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 678 AC_ARG_ENABLE([numeric_version],
 679   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 680 AC_ARG_ENABLE([gcov],
 681   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 682 AC_ARG_ENABLE([clang_coverage],
 683   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 684 AC_ARG_ENABLE([bfdd],
 685   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 686 AC_ARG_ENABLE([address-sanitizer],
 687   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 688 AC_ARG_ENABLE([thread-sanitizer],
 689   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 690 AC_ARG_ENABLE([memory-sanitizer],
 691   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 692 AC_ARG_ENABLE([undefined-sanitizer],
 693   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 694 AC_ARG_WITH([crypto],
 695   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 696 AC_ARG_WITH([frr-format],
 697   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 698
 699 AC_ARG_ENABLE([version-build-config],
 700   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 701
 702 #if openssl, else use the internal
 703 AS_IF([test "$with_crypto" = "openssl"], [
 704 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 705 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 706   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 707 else
 708   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 709 fi
 710 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 711 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 712 )
 713
 714 AS_IF([test "$enable_clippy_only" != "yes"], [
 715 AC_CHECK_HEADERS([json-c/json.h])
 716 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 717 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 718   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 719   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 720       AC_MSG_ERROR([libjson is needed to compile])
 721   fi
 722 fi
 723 ])
 724
 725 AC_ARG_ENABLE([dev_build],
 726     AS_HELP_STRING([--enable-dev-build], [build for development]))
 727
 728 AC_ARG_ENABLE([scripting],
 729     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 730
 731 AC_ARG_ENABLE([netlink-debug],
 732   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 733
 734 if test "$enable_netlink_debug" != "no" ; then
 735   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 736 fi
 737
 738 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 739
 740 if test "$enable_time_check" != "no" ; then
 741   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 742     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 743   else
 744     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 745   fi
 746 fi
 747
 748 case "${enable_cpu_time}" in
 749   "no")
 750   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 751   ;;
 752   "*")
 753   ;;
 754 esac
 755
 756 case "${enable_systemd}" in
 757   "no") ;;
 758   "yes")
 759   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 760   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 761     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 762   else
 763     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 764   fi
 765   ;;
 766   "*") ;;
 767 esac
 768
 769 if test "$enable_rr_semantics" != "no" ; then
 770   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 771 fi
 772
 773 if test "$enable_datacenter" = "yes" ; then
 774   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 775   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 776   DFLT_NAME="datacenter"
 777 else
 778   DFLT_NAME="traditional"
 779 fi
 780
 781 if test "$enable_cumulus" = "yes" ; then
 782   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 783 fi
 784
 785 AC_SUBST([DFLT_NAME])
 786 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 787
 788 if test "$enable_shell_access" = "yes"; then
 789    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 790 fi
 791
 792 #
 793 # Python for clippy
 794 #
 795
 796 AS_IF([test "$host" = "$build"], [
 797   FRR_PYTHON_DEV
 798 ], [
 799   FRR_PYTHON
 800 ])
 801
 802 FRR_PYTHON_MODULES([pytest])
 803
 804 if test "$enable_doc" != "no"; then
 805   FRR_PYTHON_MODULES([sphinx], , [
 806     if test "$enable_doc" = "yes"; then
 807       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 808     fi
 809   ])
 810 fi
 811 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 812 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 813
 814 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 815   PYSPHINX="-m sphinx"
 816 ], [
 817   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 818 ])
 819 AC_SUBST([PYSPHINX])
 820
 821 #
 822 # Logic for old vpn commands support.
 823 #
 824 if test "$enable_oldvpn_commands" = "yes"; then
 825    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 826 fi
 827
 828 #
 829 # End of logic for protobuf support.
 830 #
 831
 832 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 833 if test "$enable_rtadv" != "no"; then
 834   AC_MSG_RESULT([yes])
 835   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 836 else
 837   AC_MSG_RESULT([no])
 838 fi
 839
 840 if test "$enable_user" = "no"; then
 841   enable_user=""
 842 else
 843   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 844     enable_user="frr"
 845   fi
 846   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 847 fi
 848
 849 if test "$enable_group" = "no"; then
 850   enable_group=""
 851 else
 852   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 853     enable_group="frr"
 854   fi
 855   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 856 fi
 857
 858 if test "$enable_vty_group" = "yes" ; then
 859   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 860 elif test "$enable_vty_group" != ""; then
 861   if test "$enable_vty_group" != "no"; then
 862     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 863   fi
 864 fi
 865 AC_SUBST([enable_user])
 866 AC_SUBST([enable_group])
 867 AC_SUBST([enable_vty_group])
 868
 869 enable_configfile_mask=${enable_configfile_mask:-0600}
 870 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 871 AC_SUBST([enable_configfile_mask])
 872
 873 enable_logfile_mask=${enable_logfile_mask:-0600}
 874 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 875
 876 MPATH_NUM=16
 877
 878 case "${enable_multipath}" in
 879   0)
 880     MPATH_NUM=64
 881     ;;
 882   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 883     MPATH_NUM="${enable_multipath}"
 884     ;;
 885   "")
 886     ;;
 887   *)
 888     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 889     ;;
 890 esac
 891
 892 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 893
 894 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 895
 896 dnl --------------------
 897 dnl Enable code coverage
 898 dnl --------------------
 899 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 900
 901 dnl ------------------------------------
 902 dnl Alpine only accepts numeric versions
 903 dnl ------------------------------------
 904 if test "$enable_numeric_version" != "" ; then
 905   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 906   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 907 fi
 908
 909 dnl -----------------------------------
 910 dnl Add extra version string to package
 911 dnl name, string and version fields.
 912 dnl -----------------------------------
 913 if test "$EXTRAVERSION" != "" ; then
 914   VERSION="${VERSION}${EXTRAVERSION}"
 915   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 916   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 917   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 918 fi
 919 AC_SUBST([EXTRAVERSION])
 920
 921 if test "$with_pkg_git_version" = "yes"; then
 922         if test -e "${srcdir}/.git"; then
 923                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 924         else    with_pkg_git_version="no"
 925                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 926         fi
 927 fi
 928 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 929
 930 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 931 if test "$OBJCOPY" != ":"; then
 932   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 933     frr_cv_interp=""
 934     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 935       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 936         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 937       fi
 938       test -f conftest.interp && rm conftest.interp
 939     ])
 940   ])
 941 fi
 942 if test -n "$frr_cv_interp"; then
 943   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 944 fi
 945
 946 dnl -------------------------
 947 dnl Check other header files.
 948 dnl -------------------------
 949 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 950         linux/version.h asm/types.h])
 951
 952 ac_stdatomic_ok=false
 953 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 954 AC_CHECK_HEADER([stdatomic.h],[
 955
 956   AC_MSG_CHECKING([whether _Atomic qualifier works])
 957   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 958 #include <stdatomic.h>
 959 int main(int argc, char **argv) {
 960   _Atomic int i = 0;
 961   return i;
 962 }
 963 ]])], [
 964     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 965     AC_MSG_RESULT([yes])
 966     ac_stdatomic_ok=true
 967   ], [
 968     AC_MSG_RESULT([no])
 969   ])
 970 ])
 971
 972 AS_IF([$ac_stdatomic_ok], [true], [
 973   AC_MSG_CHECKING([for __atomic_* builtins])
 974   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 975 int main(int argc, char **argv) {
 976   volatile int i = 1;
 977   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 978   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 979 }
 980 ]])], [
 981     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 982     AC_MSG_RESULT([yes])
 983   ], [
 984     AC_MSG_RESULT([no])
 985
 986     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 987     AC_MSG_CHECKING([for __sync_* builtins])
 988     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 989 int main(int argc, char **argv) {
 990   volatile int i = 1;
 991   __sync_fetch_and_sub (&i, 1);
 992   return __sync_val_compare_and_swap (&i, 0, 1);
 993 }
 994 ]])], [
 995       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 996       AC_MSG_RESULT([yes])
 997
 998       AC_MSG_CHECKING([for __sync_swap builtin])
 999       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1000 int main(int argc, char **argv) {
1001   volatile int i = 1;
1002   return __sync_swap (&i, 2);
1003 }
1004 ]])], [
1005         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1006         AC_MSG_RESULT([yes])
1007       ], [
1008         AC_MSG_RESULT([no])
1009       ])
1010
1011     ], [
1012       AC_MSG_RESULT([no])
1013       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1014     ])
1015   ])
1016 ])
1017
1018 AC_CHECK_HEADERS([pthread_np.h],,, [
1019 #include <pthread.h>
1020 ])
1021 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
1022
1023 needsync=true
1024
1025 AS_IF([$needsync], [
1026   dnl Linux
1027   AC_MSG_CHECKING([for Linux futex() support])
1028   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1029 #ifndef _GNU_SOURCE
1030 #define _GNU_SOURCE
1031 #endif
1032 #include <unistd.h>
1033 #include <limits.h>
1034 #include <sys/time.h>
1035 #include <sys/syscall.h>
1036 #include <linux/futex.h>
1037
1038 int main(void);
1039 ],
1040 [
1041 {
1042   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1043 }
1044 ])], [
1045     AC_MSG_RESULT([yes])
1046     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1047     needsync=false
1048   ], [
1049     AC_MSG_RESULT([no])
1050   ])
1051 ])
1052
1053 AS_IF([$needsync], [
1054   dnl FreeBSD
1055   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1056   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1057 #include <errno.h>
1058 #include <stdlib.h>
1059 #include <sys/types.h>
1060 #include <sys/umtx.h>
1061 int main(void);
1062 ],
1063 [
1064 {
1065   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1066 }
1067 ])], [
1068     AC_MSG_RESULT([yes])
1069     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1070     needsync=false
1071   ], [
1072     AC_MSG_RESULT([no])
1073   ])
1074 ])
1075
1076 AS_IF([$needsync], [
1077   dnl OpenBSD patch (not upstream at the time of writing this)
1078   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1079   AC_MSG_CHECKING([for OpenBSD futex() support])
1080   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1081 #include <sys/futex.h>
1082 int main(void);
1083 ],
1084 [
1085 {
1086   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1087 }
1088 ])], [
1089     AC_MSG_RESULT([yes])
1090     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1091     needsync=false
1092   ], [
1093     AC_MSG_RESULT([no])
1094   ])
1095 ])
1096
1097 dnl Utility macro to avoid retyping includes all the time
1098 m4_define([FRR_INCLUDES],
1099 [#ifdef SUNOS_5
1100 #define _POSIX_C_SOURCE 200809L
1101 #define __EXTENSIONS__
1102 #endif
1103 #include <stdio.h>
1104 #include <stdlib.h>
1105 #include <stddef.h>
1106 #include <sys/types.h>
1107 /* sys/conf.h depends on param.h on FBSD at least */
1108 #include <sys/param.h>
1109 /* Required for MAXSIG */
1110 #include <signal.h>
1111 #include <sys/socket.h>
1112 #ifdef __APPLE__
1113 # define __APPLE_USE_RFC_3542
1114 #endif
1115 #include <netinet/in.h>
1116 #include <sys/time.h>
1117 #include <time.h>
1118 #include <net/if.h>
1119 ])dnl
1120
1121 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1122 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1123 dnl an additional round for it.
1124
1125 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1126
1127 m4_define([FRR_INCLUDES],
1128 FRR_INCLUDES
1129 [#ifdef HAVE_NET_IF_VAR_H
1130 # include <net/if_var.h>
1131 #endif
1132 ])dnl
1133
1134 AC_CHECK_HEADERS([netinet/in_var.h \
1135         net/if_dl.h net/netopt.h \
1136         inet/nd.h netinet/ip_icmp.h \
1137         sys/sysctl.h sys/sockio.h sys/conf.h],
1138         [], [], [FRR_INCLUDES])
1139
1140 AC_CHECK_HEADERS([ucontext.h], [], [],
1141 [#ifndef __USE_GNU
1142 #define __USE_GNU
1143 #endif /* __USE_GNU */
1144 FRR_INCLUDES
1145 ])
1146
1147 m4_define([UCONTEXT_INCLUDES],
1148 [#include <ucontext.h>])dnl
1149
1150 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1151   [], [], [UCONTEXT_INCLUDES])
1152 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1153   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1154    [], [], [UCONTEXT_INCLUDES])],
1155   [], [UCONTEXT_INCLUDES])
1156 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1157   [], [], [UCONTEXT_INCLUDES])
1158
1159 m4_define([FRR_INCLUDES],
1160 FRR_INCLUDES
1161 [
1162 #include <sys/un.h>
1163 #include <netinet/in_systm.h>
1164 #ifdef HAVE_NETINET_IN_VAR_H
1165 # include <netinet/in_var.h>
1166 #endif
1167 #ifdef HAVE_NET_IF_DL_H
1168 # include <net/if_dl.h>
1169 #endif
1170 #ifdef HAVE_NET_NETOPT_H
1171 # include <net/netopt.h>
1172 #endif
1173 #include <net/route.h>
1174 #ifdef HAVE_INET_ND_H
1175 # include <inet/nd.h>
1176 #endif
1177 #include <arpa/inet.h>
1178 /* Required for IDRP */
1179 #ifdef HAVE_NETINET_IP_ICMP_H
1180 # include <netinet/ip_icmp.h>
1181 #endif
1182 ])dnl
1183
1184 dnl V6 headers are checked below, after we check for v6
1185
1186 is_linux=false
1187
1188 AC_MSG_CHECKING([which operating system interface to use])
1189 case "$host_os" in
1190   sunos* | solaris2*)
1191     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1192     ;;
1193   linux*)
1194     AC_MSG_RESULT([Linux])
1195
1196     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1197     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1198     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1199
1200     dnl Linux has a compilation problem with mixing
1201     dnl netinet/in.h and linux/in6.h they are not
1202     dnl compatible.  There has been discussion on
1203     dnl how to fix it but no real progress on implementation
1204     dnl when they fix it, remove this
1205     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1206
1207     is_linux=true
1208     ;;
1209   openbsd*)
1210     AC_MSG_RESULT([OpenBSD])
1211
1212     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1213     AC_DEFINE([KAME], [1], [KAME IPv6])
1214     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1215     ;;
1216   *)
1217     AC_MSG_RESULT([BSD])
1218
1219     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1220     AC_DEFINE([KAME], [1], [KAME IPv6])
1221     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1222     ;;
1223 esac
1224 AM_CONDITIONAL([LINUX], [${is_linux}])
1225
1226 AC_SYS_LARGEFILE
1227
1228 dnl ------------------------
1229 dnl Integrated REALMS option
1230 dnl ------------------------
1231 if test "$enable_realms" = "yes"; then
1232     case "$host_os" in
1233       linux*)
1234        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1235        ;;
1236       *)
1237        echo "Sorry, only Linux has REALMS support"
1238        exit 1
1239        ;;
1240     esac
1241 fi
1242
1243 dnl -------------------------------
1244 dnl Endian-ness check
1245 dnl -------------------------------
1246 AC_WORDS_BIGENDIAN
1247
1248 dnl ---------------
1249 dnl other functions
1250 dnl ---------------
1251 AC_CHECK_FUNCS([ \
1252         strlcat strlcpy \
1253         getgrouplist \
1254         openat \
1255         unlinkat \
1256         posix_fallocate \
1257         ])
1258
1259 dnl ##########################################################################
1260 dnl LARGE if block spans a lot of "configure"!
1261 if test "$enable_clippy_only" != "yes"; then
1262 dnl ##########################################################################
1263
1264 #
1265 # Logic for protobuf support.
1266 #
1267 PROTO3=false
1268 if test "$enable_protobuf" = "yes"; then
1269   # Check for protoc & protoc-c
1270
1271   # protoc is not required, it's only for a "be nice" helper target
1272   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1273
1274   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1275   if test "$PROTOC_C" = "/bin/false"; then
1276     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1277   fi
1278
1279   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1280     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1281   ])
1282
1283   PROTO3=true
1284   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1285                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1286                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1287                                             [1], [Have Protobuf version 3]),
1288                                   [PROTO3=false],
1289                                   [#include <google/protobuf-c/protobuf-c.h>])],
1290                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1291
1292   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1293 fi
1294
1295
1296 dnl ---------------------
1297 dnl Integrated VTY option
1298 dnl ---------------------
1299 case "${enable_vtysh}" in
1300 "no")
1301   VTYSH="";;
1302 *)
1303   VTYSH="vtysh";
1304   AC_DEFINE([VTYSH], [1], [VTY shell])
1305
1306   prev_libs="$LIBS"
1307   AC_CHECK_LIB([readline], [main], [
1308     LIBREADLINE="-lreadline"
1309   ], [
1310     dnl readline failed - it might be incorrectly linked and missing its
1311     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1312     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1313       LIBREADLINE="$ac_cv_search_tputs"
1314     ], [
1315       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1316     ])
1317
1318     dnl re-try with the lib we found above
1319     unset ac_cv_lib_readline_main
1320     AC_CHECK_LIB([readline], [main], [
1321       LIBREADLINE="-lreadline $LIBREADLINE"
1322     ], [
1323       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1324     ], [$LIBREADLINE])
1325   ], [])
1326   LIBS="$prev_libs"
1327
1328   AC_CHECK_HEADER([readline/history.h])
1329   if test "$ac_cv_header_readline_history_h" = "no"; then
1330     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1331   fi
1332   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1333   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1334     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1335   fi
1336   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1337   if test "$frr_cv_append_history" = "yes"; then
1338     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1339   fi
1340   ;;
1341 esac
1342 AC_SUBST([LIBREADLINE])
1343
1344 dnl ----------
1345 dnl PAM module
1346 dnl
1347 dnl FRR detects the PAM library it is built against by checking for a
1348 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1349 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1350 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1351 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1352 dnl of OpenPAM.
1353 dnl ----------
1354 if test "$with_libpam" = "yes"; then
1355   AC_CHECK_HEADER([security/pam_misc.h],
1356     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1357      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1358      pam_conv_func="misc_conv"
1359     ],
1360     [], FRR_INCLUDES)
1361   AC_CHECK_HEADER([security/openpam.h],
1362     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1363      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1364      pam_conv_func="openpam_ttyconv"
1365     ],
1366     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1367   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1368     AC_MSG_WARN([*** pam support will not be built ***])
1369     with_libpam="no"
1370   fi
1371 fi
1372
1373 if test "$with_libpam" = "yes"; then
1374 dnl took this test from proftpds configure.in and suited to our needs
1375 dnl -------------------------------------------------------------------------
1376 dnl
1377 dnl This next check looks funky due to a linker problem with some versions
1378 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1379 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1380 dnl with RedHat 6.2 and Debian 2.2 or better.
1381 AC_CHECK_LIB([pam], [pam_start],
1382   [AC_CHECK_LIB([pam], [$pam_conv_func],
1383     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1384      LIBPAM="-lpam"],
1385     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1386      LIBPAM="-lpam -lpam_misc"]
1387     )
1388   ],
1389
1390   [AC_CHECK_LIB([pam], [pam_end],
1391     [AC_CHECK_LIB([pam], [$pam_conv_func],
1392       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1393        LIBPAM="-lpam -ldl"],
1394       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1395        LIBPAM="-lpam -ldl -lpam_misc"]
1396      )
1397   ],AC_MSG_WARN([*** pam support will not be built ***]),
1398   [-ldl])
1399   ]
1400 )
1401 fi
1402 AC_SUBST([LIBPAM])
1403
1404 dnl -------------------------------
1405 dnl bgpd needs pow() and hence libm
1406 dnl -------------------------------
1407 TMPLIBS="$LIBS"
1408 LIBS=""
1409 AC_SEARCH_LIBS([pow], [m], [
1410   LIBM="$LIBS"
1411 ], [
1412   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1413 ])
1414 LIBS="$TMPLIBS"
1415 AC_SUBST([LIBM])
1416
1417 AC_CHECK_FUNCS([ppoll], [
1418   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1419 ])
1420 AC_CHECK_FUNCS([pollts], [
1421   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1422 ])
1423
1424 AC_CHECK_HEADER([asm-generic/unistd.h],
1425                 [AC_CHECK_DECL(__NR_setns,
1426                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1427                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1428                                ])
1429                  AC_CHECK_FUNCS([setns])]
1430                )
1431
1432 dnl --------------------------
1433 dnl Determine IS-IS I/O method
1434 dnl --------------------------
1435 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1436 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1437 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1438 AC_CHECK_HEADER([net/bpf.h])
1439 AC_CHECK_HEADER([sys/dlpi.h])
1440 AC_MSG_CHECKING([zebra IS-IS I/O method])
1441
1442 case "$host_os" in
1443   linux*)
1444     AC_MSG_RESULT([pfpacket])
1445     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1446     ;;
1447   *)
1448     if test "$ac_cv_header_net_bpf_h" = "no"; then
1449       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1450         AC_MSG_RESULT([none])
1451         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1452           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1453         fi
1454         AC_MSG_WARN([*** IS-IS support will not be built ***])
1455         enable_isisd="no"
1456         enable_fabricd="no"
1457       else
1458         AC_MSG_RESULT([DLPI])
1459       fi
1460       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1461     else
1462       AC_MSG_RESULT([BPF])
1463       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1464     fi
1465     ;;
1466 esac
1467 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1468
1469 dnl ---------------------------------------------------------------
1470 dnl figure out how to specify an interface in multicast sockets API
1471 dnl ---------------------------------------------------------------
1472 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1473
1474 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1475         #include <sys/socket.h>
1476         #include <netinet/in.h>
1477         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1478         #include <linux/types.h>
1479 ])
1480
1481 m4_define([FRR_INCLUDES],
1482 FRR_INCLUDES
1483 [#ifdef HAVE_LINUX_MROUTE_H
1484 # include <linux/mroute.h>
1485 #endif
1486 ])dnl
1487
1488 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1489         #include <sys/socket.h>
1490         #include <sys/types.h>
1491         #include <netinet/in.h>
1492         #include <net/route.h>
1493 ])
1494
1495 m4_define([FRR_INCLUDES],
1496 FRR_INCLUDES
1497 [#ifdef HAVE_NETINET_IP_MROUTE_H
1498 # include <netinet/ip_mroute.h>
1499 #endif
1500 ])dnl
1501
1502 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1503 AC_TRY_COMPILE([#include <sys/param.h>],
1504 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1505   return (0);
1506 #else
1507   #error No support for BSD struct ip_mreq hack detected
1508 #endif],[AC_MSG_RESULT([yes])
1509 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1510 AC_MSG_RESULT([no]))
1511
1512 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1513 AC_TRY_COMPILE([
1514 #include <sys/types.h>
1515 #include <netinet/in.h>
1516 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1517 ], [AC_MSG_RESULT([yes])
1518 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1519 AC_MSG_RESULT([no]))
1520
1521 dnl ---------------------------------------------------------------
1522 dnl figure out how to check link-state
1523 dnl ---------------------------------------------------------------
1524 AC_CHECK_HEADER([net/if_media.h],
1525   [m4_define([LINK_DETECT_INCLUDES],
1526     FRR_INCLUDES
1527     [#include <net/if_media.h>
1528   ])
1529   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1530     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1531     [], LINK_DETECT_INCLUDES)],
1532   [],
1533   FRR_INCLUDES)
1534
1535 dnl ---------------------------------------------------------------
1536 dnl Additional, newer way to check link-state using ifi_link_state.
1537 dnl Not available in all BSD's when ifmediareq available
1538 dnl ---------------------------------------------------------------
1539 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1540   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1541   [], FRR_INCLUDES)
1542
1543 dnl ------------------------
1544 dnl TCP_MD5SIG socket option
1545 dnl ------------------------
1546
1547 AC_CHECK_HEADER([netinet/tcp.h],
1548    [m4_define([MD5_INCLUDES],
1549       FRR_INCLUDES
1550       [#include <netinet/tcp.h>
1551     ])
1552     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1553    [],
1554    FRR_INCLUDES)
1555 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1556   AC_CHECK_HEADER([linux/tcp.h],
1557        [m4_define([MD5_INCLUDES],
1558           FRR_INCLUDES
1559           [#include <linux/tcp.h>
1560         ])
1561        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1562 fi
1563
1564 AC_CHECK_LIB([crypt], [crypt], [],
1565                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1566 AC_CHECK_LIB([resolv], [res_init])
1567
1568 dnl ---------------------------
1569 dnl check system has PCRE regexp
1570 dnl ---------------------------
1571 if test "$enable_pcreposix" = "yes"; then
1572   AC_CHECK_LIB([pcreposix], [regexec], [], [
1573     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1574   ])
1575 fi
1576 AC_SUBST([HAVE_LIBPCREPOSIX])
1577
1578 dnl ##########################################################################
1579 dnl test "$enable_clippy_only" != "yes"
1580 fi
1581 dnl END OF LARGE if block
1582 dnl ##########################################################################
1583
1584 dnl ------------------
1585 dnl check C-Ares library
1586 dnl ------------------
1587 PKG_CHECK_MODULES([CARES], [libcares], [
1588   c_ares_found=true
1589 ],[
1590   c_ares_found=false
1591 ])
1592 AM_CONDITIONAL([CARES], [$c_ares_found])
1593
1594
1595 dnl ----------------------------------------------------------------------------
1596 dnl figure out if domainname is available in the utsname struct (GNU extension).
1597 dnl ----------------------------------------------------------------------------
1598 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1599
1600 dnl ------------------
1601 dnl IPv6 header checks
1602 dnl ------------------
1603 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1604         netinet6/in6_var.h netinet6/nd6.h], [], [],
1605         FRR_INCLUDES)
1606
1607 m4_define([FRR_INCLUDES],dnl
1608 FRR_INCLUDES
1609 [#ifdef HAVE_NETINET6_IN6_H
1610 #include <netinet6/in6.h>
1611 #endif
1612 #ifdef HAVE_NETINET_IN6_VAR_H
1613 #include <netinet/in6_var.h>
1614 #endif
1615 #include <netinet/icmp6.h>
1616 #ifdef HAVE_NETINET6_IN6_VAR_H
1617 # include <netinet6/in6_var.h>
1618 #endif
1619 #ifdef HAVE_NETINET6_ND6_H
1620 # include <netinet6/nd6.h>
1621 #endif
1622 ])dnl
1623
1624 dnl --------------------
1625 dnl Daemon disable check
1626 dnl --------------------
1627
1628 AS_IF([test "$enable_bgpd" != "no"], [
1629   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1630 ])
1631
1632 AS_IF([test "$enable_ripd" != "no"], [
1633   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1634 ])
1635
1636 AS_IF([test "$enable_ripngd" != "no"], [
1637   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1638 ])
1639
1640 AS_IF([test "$enable_ospfd" != "no"], [
1641   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1642 ])
1643
1644 AS_IF([test "$enable_ospf6d" != "no"], [
1645   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1646 ])
1647
1648 AS_IF([test "$enable_ldpd" != "no"], [
1649   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1650 ])
1651
1652 AS_IF([test "$enable_nhrpd" != "no"], [
1653   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1654 ])
1655
1656 AS_IF([test "$enable_eigrpd" != "no"], [
1657   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1658 ])
1659
1660 AS_IF([test "$enable_babeld" != "no"], [
1661   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1662 ])
1663
1664 AS_IF([test "$enable_isisd" != "no"], [
1665   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1666 ])
1667
1668 AS_IF([test "$enable_pimd" != "no"], [
1669   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1670 ])
1671
1672 AS_IF([test "$enable_pbrd" != "no"], [
1673   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1674 ])
1675
1676 AS_IF([test "$enable_sharpd" = "yes"], [
1677   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1678 ])
1679
1680 AS_IF([test "$enable_staticd" != "no"], [
1681   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1682 ])
1683
1684 AS_IF([test "$enable_fabricd" != "no"], [
1685   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1686 ])
1687
1688 AS_IF([test "$enable_vrrpd" != "no"], [
1689   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1690 ])
1691
1692 if test "$enable_bfdd" = "no"; then
1693   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1694   BFDD=""
1695 else
1696   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1697   BFDD="bfdd"
1698
1699   case $host_os in
1700     linux*)
1701       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1702       ;;
1703
1704     *)
1705       AC_DEFINE([BFD_BSD], [1], [bfdd])
1706       ;;
1707   esac
1708 fi
1709
1710 AS_IF([test "$enable_pathd" != "no"], [
1711   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1712 ])
1713
1714 AS_IF([test "$enable_pcep" != "no"], [
1715   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1716 ])
1717
1718 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1719   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1720 fi
1721
1722 NHRPD=""
1723 case "$host_os" in
1724   linux*)
1725     case "${enable_nhrpd}" in
1726       no)
1727         ;;
1728       yes)
1729         if test "$enable_clippy_only" != "yes"; then
1730         if test "$c_ares_found" != "true" ; then
1731           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1732         fi
1733         fi
1734         NHRPD="nhrpd"
1735         ;;
1736       *)
1737         if test "$c_ares_found" = "true" ; then
1738           NHRPD="nhrpd"
1739         fi
1740         ;;
1741     esac
1742     ;;
1743   *)
1744     if test "$enable_nhrpd" = "yes"; then
1745       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1746     fi
1747     ;;
1748 esac
1749
1750 if test "$enable_watchfrr" = "no";then
1751   WATCHFRR=""
1752 else
1753   WATCHFRR="watchfrr"
1754 fi
1755
1756 OSPFCLIENT=""
1757 if test "$enable_ospfapi" != "no";then
1758     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1759
1760   if test "$enable_ospfclient" != "no";then
1761       OSPFCLIENT="ospfclient"
1762   fi
1763 fi
1764
1765 if test "$enable_bgp_announce" = "no";then
1766   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1767 else
1768   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1769 fi
1770
1771 if test "$enable_bgp_vnc" != "no";then
1772   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1773 fi
1774
1775 bgpd_bmp=false
1776 case "${enable_bmp}" in
1777   no)
1778     ;;
1779   yes)
1780     if test "$c_ares_found" != "true" ; then
1781       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1782     fi
1783     bgpd_bmp=true
1784     ;;
1785   *)
1786     if test "$c_ares_found" = "true" ; then
1787       bgpd_bmp=true
1788     fi
1789     ;;
1790 esac
1791
1792 if test "$enable_version_build_config" != "no";then
1793   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1794 fi
1795
1796 dnl ##########################################################################
1797 dnl LARGE if block
1798 if test "$enable_clippy_only" != "yes"; then
1799 dnl ##########################################################################
1800
1801 dnl ------------------
1802 dnl check Net-SNMP library
1803 dnl ------------------
1804 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1805    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1806    if test "$NETSNMP_CONFIG" = "no"; then
1807       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1808    fi
1809    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1810    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1811    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1812    # among other things we avoid a GPL vs. OpenSSL license conflict here
1813    for removelib in crypto ssl sensors pci wrap; do
1814      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1815    done
1816    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1817    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1818 int main(void);
1819 ],
1820 [
1821 {
1822   return 0;
1823 }
1824 ])], [
1825      AC_MSG_RESULT([no])
1826      AC_MSG_ERROR([--enable-snmp given but not usable])])
1827    case "${enable_snmp}" in
1828      yes)
1829       SNMP_METHOD=agentx
1830       ;;
1831      agentx)
1832       SNMP_METHOD="${enable_snmp}"
1833       ;;
1834      *)
1835       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1836       ;;
1837    esac
1838    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1839    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1840 fi
1841 AC_SUBST([SNMP_LIBS])
1842 AC_SUBST([SNMP_CFLAGS])
1843
1844 dnl ---------------
1845 dnl libyang
1846 dnl ---------------
1847 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1848   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1849 ])
1850 ac_cflags_save="$CFLAGS"
1851 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1852 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1853   AC_MSG_ERROR([m4_normalize([
1854     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1855     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1856   ])
1857 ], [[#include <libyang/libyang.h>]])
1858 CFLAGS="$ac_cflags_save"
1859
1860 dnl ---------------
1861 dnl configuration rollbacks
1862 dnl ---------------
1863 SQLITE3=false
1864 if test "$enable_config_rollbacks" = "yes"; then
1865   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1866     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1867     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1868     SQLITE3=true
1869   ], [
1870     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1871   ])
1872 fi
1873
1874 dnl ---------------
1875 dnl confd
1876 dnl ---------------
1877 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1878    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1879    if test "$CONFD" = "/bin/false"; then
1880       AC_MSG_ERROR([confd was not found on your system.])]
1881    fi
1882    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1883    AC_SUBST([CONFD_CFLAGS])
1884    CONFD_LIBS="-lconfd"
1885    AC_SUBST([CONFD_LIBS])
1886    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1887 fi
1888
1889 dnl ---------------
1890 dnl sysrepo
1891 dnl ---------------
1892 if test "$enable_sysrepo" = "yes"; then
1893   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1894       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1895       SYSREPO=true],
1896       [SYSREPO=false
1897       AC_MSG_ERROR([sysrepo was not found on your system.])]
1898   )
1899 fi
1900
1901 dnl ---------------
1902 dnl gRPC
1903 dnl ---------------
1904 if test "$enable_grpc" = "yes"; then
1905   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1906     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1907     if test "$PROTOC" = "/bin/false"; then
1908       AC_MSG_FAILURE([grpc requested but protoc not found.])
1909     fi
1910
1911     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1912     GRPC=true
1913   ], [
1914     GRPC=false
1915     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1916   ])
1917 fi
1918
1919 dnl -----
1920 dnl LTTng
1921 dnl -----
1922 if test "$enable_lttng" = "yes"; then
1923   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1924     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1925     LTTNG=true
1926   ], [
1927     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1928   ])
1929 fi
1930
1931 dnl ----
1932 dnl USDT
1933 dnl ----
1934 if test "$enable_usdt" = "yes"; then
1935   AC_CHECK_HEADERS([sys/sdt.h], [
1936     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1937     USDT=true
1938   ], [
1939     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1940   ])
1941 fi
1942
1943 dnl ------
1944 dnl ZeroMQ
1945 dnl ------
1946 if test "$enable_zeromq" != "no"; then
1947   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1948     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1949     ZEROMQ=true
1950   ], [
1951     if test "$enable_zeromq" = "yes"; then
1952       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1953     fi
1954   ])
1955 fi
1956
1957 dnl ------------------------------------
1958 dnl Enable RPKI and add librtr to libs
1959 dnl ------------------------------------
1960 if test "$enable_rpki" = "yes"; then
1961   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1962       [RPKI=true],
1963       [RPKI=false
1964       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1965   )
1966 fi
1967
1968 dnl ------------------------------------
1969 dnl pimd is not supported on OpenBSD and MacOS
1970 dnl ------------------------------------
1971 if test "$enable_pimd" != "no"; then
1972 AC_MSG_CHECKING([for pimd OS support])
1973 case "$host_os" in
1974   darwin*)
1975     AC_MSG_RESULT([no])
1976     enable_pimd="no"
1977     ;;
1978   openbsd*)
1979     AC_MSG_RESULT([no])
1980     enable_pimd="no"
1981     ;;
1982   *)
1983     AC_MSG_RESULT([yes])
1984     ;;
1985 esac
1986 fi
1987
1988 dnl -------------------------------------
1989 dnl VRRP is only supported on linux
1990 dnl -------------------------------------
1991 if test "$enable_vrrpd" != "no"; then
1992 AC_MSG_CHECKING([for VRRP OS support])
1993 case "$host_os" in
1994   linux*)
1995     AC_MSG_RESULT([yes])
1996     ;;
1997   *)
1998     AC_MSG_RESULT([no])
1999     enable_vrrpd="no"
2000     ;;
2001 esac
2002 fi
2003
2004 dnl ------------------------------------------
2005 dnl Check whether rtrlib was build with ssh support
2006 dnl ------------------------------------------
2007 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2008 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2009                         [[struct tr_ssh_config config;]])],
2010         [AC_MSG_RESULT([yes])
2011         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2012         AC_MSG_RESULT([no])
2013 )
2014
2015 dnl ---------------
2016 dnl dlopen & dlinfo
2017 dnl ---------------
2018 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2019   AC_MSG_ERROR([unable to find the dlopen()])
2020 ])
2021
2022 AC_CHECK_HEADERS([link.h])
2023
2024 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2025   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2026 #include <stdlib.h>
2027 #ifdef HAVE_LINK_H
2028 #include <link.h>
2029 #endif
2030 #include <dlfcn.h>
2031 ]], [[
2032   char origin[1];
2033   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2034 ]])], [
2035     frr_cv_rtld_di_origin=yes
2036   ], [
2037     frr_cv_rtld_di_origin=no
2038   ])
2039 ])
2040 if test "$frr_cv_rtld_di_origin" = "yes"; then
2041   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2042 fi
2043
2044 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2045   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2046 #include <stdlib.h>
2047 #ifdef HAVE_LINK_H
2048 #include <link.h>
2049 #endif
2050 #include <dlfcn.h>
2051 ]], [[
2052   struct link_map *lm = NULL;
2053   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2054 ]])], [
2055     frr_cv_rtld_di_linkmap=yes
2056   ], [
2057     frr_cv_rtld_di_linkmap=no
2058   ])
2059 ])
2060 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2061   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2062 fi
2063
2064 dnl ##########################################################################
2065 dnl test "$enable_clippy_only" != "yes"
2066 fi
2067 dnl END OF LARGE if block
2068 dnl ##########################################################################
2069
2070 dnl ---------------------------
2071 dnl sockaddr and netinet checks
2072 dnl ---------------------------
2073 AC_CHECK_TYPES([
2074         struct sockaddr_dl,
2075         struct vifctl, struct mfcctl, struct sioc_sg_req,
2076         vifi_t, struct sioc_vif_req, struct igmpmsg,
2077         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2078         struct nd_opt_adv_interval,
2079         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2080         struct nd_opt_rdnss, struct nd_opt_dnssl],
2081         [], [], FRR_INCLUDES)
2082
2083 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2084         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2085         struct sockaddr_dl.sdl_len,
2086         struct if6_aliasreq.ifra_lifetime,
2087         struct nd_opt_adv_interval.nd_opt_ai_type],
2088         [], [], FRR_INCLUDES)
2089
2090 dnl ---------------------------
2091 dnl IRDP/pktinfo/icmphdr checks
2092 dnl ---------------------------
2093
2094 AC_CHECK_TYPES([struct in_pktinfo], [
2095   AC_CHECK_TYPES([struct icmphdr], [
2096     IRDP=true
2097   ], [
2098     IRDP=false
2099   ], [FRR_INCLUDES])
2100 ], [
2101   IRDP=false
2102 ], [FRR_INCLUDES])
2103
2104 case "${enable_irdp}" in
2105 yes)
2106   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2107   ;;
2108 no)
2109   IRDP=false
2110   ;;
2111 esac
2112
2113
2114 dnl -----------------------
2115 dnl checking for IP_PKTINFO
2116 dnl -----------------------
2117 AC_MSG_CHECKING([for IP_PKTINFO])
2118 AC_TRY_COMPILE([#include <netdb.h>], [
2119   int opt = IP_PKTINFO;
2120 ], [
2121   AC_MSG_RESULT([yes])
2122   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2123 ], [
2124   AC_MSG_RESULT([no])
2125 ])
2126
2127 dnl ---------------------------
2128 dnl checking for IP_RECVDSTADDR
2129 dnl ---------------------------
2130 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2131 AC_TRY_COMPILE([#include <netinet/in.h>], [
2132   int opt = IP_RECVDSTADDR;
2133 ], [
2134   AC_MSG_RESULT([yes])
2135   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2136 ], [
2137   AC_MSG_RESULT([no])
2138 ])
2139
2140 dnl ----------------------
2141 dnl checking for IP_RECVIF
2142 dnl ----------------------
2143 AC_MSG_CHECKING([for IP_RECVIF])
2144 AC_TRY_COMPILE([#include <netinet/in.h>], [
2145   int opt = IP_RECVIF;
2146 ], [
2147   AC_MSG_RESULT([yes])
2148   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2149 ], [
2150   AC_MSG_RESULT([no])
2151 ])
2152
2153 dnl ----------------------
2154 dnl checking for SO_BINDANY
2155 dnl ----------------------
2156 AC_MSG_CHECKING([for SO_BINDANY])
2157 AC_TRY_COMPILE([#include <sys/socket.h>], [
2158   int opt = SO_BINDANY;
2159 ], [
2160   AC_MSG_RESULT([yes])
2161   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2162 ], [
2163   AC_MSG_RESULT([no])
2164 ])
2165
2166 dnl ----------------------
2167 dnl checking for IP_FREEBIND
2168 dnl ----------------------
2169 AC_MSG_CHECKING([for IP_FREEBIND])
2170 AC_TRY_COMPILE([#include <netinet/in.h>], [
2171   int opt = IP_FREEBIND;
2172 ], [
2173   AC_MSG_RESULT([yes])
2174   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2175 ], [
2176   AC_MSG_RESULT([no])
2177 ])
2178
2179 dnl --------------------------------------
2180 dnl checking for be32dec existence or not
2181 dnl --------------------------------------
2182 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2183                [#include <sys/endian.h>])
2184
2185 dnl --------------------------------------
2186 dnl checking for clock_time monotonic struct and call
2187 dnl --------------------------------------
2188 AC_CHECK_DECL([CLOCK_MONOTONIC],
2189         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2190          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2191 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2192
2193 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2194   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2195 ])
2196
2197 dnl --------------------------------------
2198 dnl checking for flex and bison
2199 dnl --------------------------------------
2200
2201 AM_PROG_LEX
2202 AC_MSG_CHECKING([version of flex])
2203 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2204 frr_ac_flex_version="${frr_ac_flex_version##* }"
2205 AC_MSG_RESULT([$frr_ac_flex_version])
2206 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2207   LEX="$SHELL $missing_dir/missing flex"
2208   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2209     AC_MSG_WARN([using pregenerated flex output files])
2210   else
2211     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2212   fi
2213   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2214   AC_SUBST([LEXLIB], [''])
2215 ])
2216
2217 AC_PROG_YACC
2218 dnl thanks GNU bison for this b*llshit...
2219 AC_MSG_CHECKING([version of bison])
2220 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2221 frr_ac_bison_version="${frr_ac_bison_version##* }"
2222 frr_ac_bison_missing="false"
2223 case "x${frr_ac_bison_version}x" in
2224   x2.7*)
2225     BISON_OPENBRACE='"'
2226     BISON_CLOSEBRACE='"'
2227     BISON_VERBOSE=''
2228     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2229     ;;
2230   x2.*|x1.*)
2231     AC_MSG_RESULT([$frr_ac_bison_version])
2232     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2233     frr_ac_bison_missing="true"
2234     ;;
2235   x)
2236     AC_MSG_RESULT([none])
2237     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2238     frr_ac_bison_missing="true"
2239     ;;
2240   x3.[012][^0-9]*)
2241     BISON_OPENBRACE='{'
2242     BISON_CLOSEBRACE='}'
2243     BISON_VERBOSE='-Dparse.error=verbose'
2244     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2245     ;;
2246   *)
2247     BISON_OPENBRACE='{'
2248     BISON_CLOSEBRACE='}'
2249     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2250     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2251     ;;
2252 esac
2253 AC_SUBST([BISON_OPENBRACE])
2254 AC_SUBST([BISON_CLOSEBRACE])
2255 AC_SUBST([BISON_VERBOSE])
2256
2257 if $frr_ac_bison_missing; then
2258   YACC="$SHELL $missing_dir/missing bison -y"
2259   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2260     AC_MSG_WARN([using pregenerated bison output files])
2261   else
2262     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2263   fi
2264 fi
2265
2266 dnl -------------------
2267 dnl capabilities checks
2268 dnl -------------------
2269 if test "$enable_capabilities" != "no"; then
2270   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2271   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2272     [AC_MSG_RESULT([yes])
2273      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2274      frr_ac_keepcaps="yes"],
2275      AC_MSG_RESULT([no])
2276   )
2277   if test "$frr_ac_keepcaps" = "yes"; then
2278     AC_CHECK_HEADERS([sys/capability.h])
2279   fi
2280   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2281     AC_CHECK_LIB([cap], [cap_init],
2282       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2283        LIBCAP="-lcap"
2284        frr_ac_lcaps="yes"]
2285     )
2286   fi
2287   if test "$frr_ac_scaps" = "yes" \
2288        -o "$frr_ac_lcaps" = "yes"; then
2289     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2290   fi
2291
2292   case "$host_os" in
2293   linux*)
2294     if test "$enable_clippy_only" != "yes"; then
2295     if test "$frr_ac_lcaps" != "yes"; then
2296       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2297     fi
2298     fi
2299     ;;
2300   esac
2301 else
2302   case "$host_os" in
2303   linux*)
2304     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2305     ;;
2306   esac
2307 fi
2308 AC_SUBST([LIBCAP])
2309
2310 dnl ---------------------------
2311 dnl check for glibc 'backtrace'
2312 dnl ---------------------------
2313 if test "$enable_backtrace" != "no" ; then
2314   backtrace_ok=no
2315   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2316     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2317     backtrace_ok=yes
2318   ], [
2319     true
2320   ])
2321
2322   if test "$backtrace_ok" = "no"; then
2323     AC_CHECK_HEADER([unwind.h], [
2324       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2325         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2326         backtrace_ok=yes
2327       ])
2328     ])
2329   fi
2330
2331   if test "$backtrace_ok" = "no"; then
2332     AC_CHECK_HEADER([execinfo.h], [
2333       AC_SEARCH_LIBS([backtrace], [execinfo], [
2334         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2335         backtrace_ok=yes
2336       ],, [-lm])
2337     ])
2338   fi
2339
2340   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2341     dnl user explicitly requested backtrace but we failed to find support
2342     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2343   fi
2344 fi
2345
2346 dnl -----------------------------------------
2347 dnl check for malloc mallinfo struct and call
2348 dnl this must try and link using LIBS, in
2349 dnl order to check no alternative allocator
2350 dnl has been specified, which might not provide
2351 dnl mallinfo
2352 dnl -----------------------------------------
2353 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2354
2355 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2356   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2357 #ifdef HAVE_MALLOC_H
2358 #include <malloc.h>
2359 #endif
2360 #ifdef HAVE_MALLOC_NP_H
2361 #include <malloc_np.h>
2362 #endif
2363 #ifdef HAVE_MALLOC_MALLOC_H
2364 #include <malloc/malloc.h>
2365 #endif
2366 ]], [[
2367 struct mallinfo ac_x; ac_x = mallinfo ();
2368 ]])], [
2369     frr_cv_mallinfo=yes
2370   ], [
2371     frr_cv_mallinfo=no
2372   ])
2373 ])
2374 if test "$frr_cv_mallinfo" = "yes"; then
2375   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2376 fi
2377
2378 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2379   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2380 #ifdef HAVE_MALLOC_H
2381 #include <malloc.h>
2382 #endif
2383 #ifdef HAVE_MALLOC_NP_H
2384 #include <malloc_np.h>
2385 #endif
2386 #ifdef HAVE_MALLOC_MALLOC_H
2387 #include <malloc/malloc.h>
2388 #endif
2389 ]], [[
2390 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2391 ]])], [
2392     frr_cv_mallinfo2=yes
2393   ], [
2394     frr_cv_mallinfo2=no
2395   ])
2396 ])
2397 if test "$frr_cv_mallinfo2" = "yes"; then
2398   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2399 fi
2400
2401 AC_MSG_CHECKING([whether malloc_usable_size is available])
2402 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2403 #ifdef HAVE_MALLOC_H
2404 #include <malloc.h>
2405 #endif
2406 #ifdef HAVE_MALLOC_MALLOC_H
2407 #include <malloc/malloc.h>
2408 #endif
2409 ]], [[
2410 size_t ac_x; ac_x = malloc_usable_size(NULL);
2411 ]])], [
2412   AC_MSG_RESULT([yes])
2413   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2414 ], [
2415   AC_MSG_RESULT([no])
2416
2417   AC_MSG_CHECKING([whether malloc_size is available])
2418   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2419 #ifdef HAVE_MALLOC_H
2420 #include <malloc.h>
2421 #endif
2422 #ifdef HAVE_MALLOC_MALLOC_H
2423 #include <malloc/malloc.h>
2424 #endif
2425 ]], [[
2426 size_t ac_x; ac_x = malloc_size(NULL);
2427 ]])], [
2428     AC_MSG_RESULT([yes])
2429     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2430   ], [
2431     AC_MSG_RESULT([no])
2432   ])
2433 ])
2434
2435 dnl ----------
2436 dnl configure date
2437 dnl ----------
2438 dev_version=`echo $VERSION | grep dev`
2439 #don't expire deprecated code in non 'dev' branch
2440 if test "$dev_version" = ""; then
2441    CONFDATE=0
2442 else
2443    CONFDATE=`date '+%Y%m%d'`
2444 fi
2445 AC_SUBST([CONFDATE])
2446
2447 dnl ------------------------------
2448 dnl set paths for state directory
2449 dnl ------------------------------
2450 AC_MSG_CHECKING([directory to use for state file])
2451 if test "$prefix" = "NONE"; then
2452   frr_statedir_prefix="";
2453 else
2454   frr_statedir_prefix=${prefix}
2455 fi
2456 if test "$localstatedir" = '${prefix}/var'; then
2457   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2458                         ${frr_statedir_prefix}/var/adm dnl
2459                         ${frr_statedir_prefix}/etc dnl
2460                         /var/run        dnl
2461                         /var/adm        dnl
2462                         /etc            dnl
2463                         /dev/null;
2464   do
2465     test -d $FRR_STATE_DIR && break
2466   done
2467   frr_statedir=$FRR_STATE_DIR
2468 else
2469   frr_statedir=${localstatedir}
2470 fi
2471 if test "$frr_statedir" = "/dev/null"; then
2472     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2473 fi
2474 AC_MSG_RESULT([${frr_statedir}])
2475 AC_SUBST([frr_statedir])
2476
2477 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2478 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2479 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2480 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2481 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2482
2483 dnl autoconf does this, but it does it too late...
2484 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2485 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2486
2487 dnl get the full path, recursing through variables...
2488 vtysh_bin="$bindir/vtysh"
2489 for I in 1 2 3 4 5 6 7 8 9 10; do
2490         eval vtysh_bin="\"$vtysh_bin\""
2491 done
2492 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2493 AC_SUBST([vtysh_bin])
2494
2495 CFG_SYSCONF="$sysconfdir"
2496 CFG_SBIN="$sbindir"
2497 CFG_STATE="$frr_statedir"
2498 CFG_MODULE="$moduledir"
2499 CFG_YANGMODELS="$yangmodelsdir"
2500 CFG_SCRIPT="$scriptdir"
2501 for I in 1 2 3 4 5 6 7 8 9 10; do
2502         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2503         eval CFG_SBIN="\"$CFG_SBIN\""
2504         eval CFG_STATE="\"$CFG_STATE\""
2505         eval CFG_MODULE="\"$CFG_MODULE\""
2506         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2507         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2508 done
2509 AC_SUBST([CFG_SYSCONF])
2510 AC_SUBST([CFG_SBIN])
2511 AC_SUBST([CFG_STATE])
2512 AC_SUBST([CFG_MODULE])
2513 AC_SUBST([CFG_SCRIPT])
2514 AC_SUBST([CFG_YANGMODELS])
2515 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2516 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2517 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2518 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2519
2520 dnl various features
2521 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2522 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2523 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2524 dnl northbound
2525 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2526 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2527 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2528 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2529 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2530 dnl plugins
2531 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2532 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2533 AM_CONDITIONAL([IRDP], [$IRDP])
2534 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2535 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2536 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2537
2538 dnl PCEP plugin
2539 AM_CONDITIONAL([HAVE_PATHD_PCEP], [test "$enable_pcep" = "yes"])
2540 AS_IF([test "$enable_pcep" = "yes"], [
2541   AC_CHECK_LIB([pcep_pcc], [initialize_pcc], [
2542     PATHD_PCEP_LIBS="-lpcep_pcc"
2543   ],[
2544     AC_MSG_ERROR([PCEP library libpcep_pcc not found])
2545   ])
2546   AC_SUBST([PATHD_PCEP_LIBS])
2547 ])
2548
2549 dnl daemons
2550 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2551 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2552 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2553 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2554 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2555 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2556 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2557 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2558 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2559 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2560 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2561 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2562 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2563 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2564 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2565 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2566 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2567 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2568 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2569 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2570 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2571 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2572
2573 AC_CONFIG_FILES([Makefile],[
2574         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2575         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2576 ], [
2577         PYTHON="$PYTHON"
2578         enable_dev_build="$enable_dev_build"
2579 ])
2580
2581 AC_CONFIG_FILES([
2582           config.version
2583           changelog-auto
2584           redhat/frr.spec
2585           alpine/APKBUILD
2586           snapcraft/snapcraft.yaml
2587           lib/version.h
2588           tests/lib/cli/test_cli.refout
2589           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2590           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2591           pkgsrc/eigrpd.sh])
2592
2593 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2594 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2595 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2596 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2597 AC_CONFIG_FILES([tools/frrcommon.sh])
2598 AC_CONFIG_FILES([tools/frr.service])
2599 AC_CONFIG_FILES([tools/frr@.service])
2600
2601 AS_IF([test "$with_pkg_git_version" = "yes"], [
2602     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2603         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2604         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2605                 "${ac_abs_top_srcdir}" \
2606                 > "${dst}.tmp"
2607         test -f "$dst" \
2608                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2609                 && rm "${dst}.tmp" \
2610                 || mv "${dst}.tmp" "${dst}"
2611     ], [
2612         PERL="$PERL"
2613     ])
2614 ])
2615
2616 ## Hack, but working solution to avoid rebuilding of frr.info.
2617 ## It's already in CVS until texinfo 4.7 is more common.
2618 AC_OUTPUT
2619
2620 if test "$enable_rpath" = "yes" ; then
2621         true
2622 else
2623         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2624         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2625         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2626 fi
2627
2628 echo "
2629 FRRouting configuration
2630 ------------------------------
2631 FRR version             : ${PACKAGE_VERSION}
2632 host operating system   : ${host_os}
2633 source code location    : ${srcdir}
2634 compiler                : ${CC}
2635 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2636 make                    : ${MAKE-make}
2637 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2638 state file directory    : ${frr_statedir}
2639 config file directory   : `eval echo \`echo ${sysconfdir}\``
2640 example directory       : `eval echo \`echo ${exampledir}\``
2641 module directory        : ${CFG_MODULE}
2642 script directory        : ${CFG_SCRIPT}
2643 user to run as          : ${enable_user}
2644 group to run as         : ${enable_group}
2645 group for vty sockets   : ${enable_vty_group}
2646 config file mask        : ${enable_configfile_mask}
2647 log file mask           : ${enable_logfile_mask}
2648 zebra protobuf enabled  : ${enable_protobuf:-no}
2649 vici socket path        : ${vici_socket}
2650
2651 The above user and group must have read/write access to the state file
2652 directory and to the config files in the config file directory."
2653
2654 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2655   AC_MSG_WARN([sphinx is missing but required to build documentation])
2656 fi
2657 if test "$frr_py_mod_pytest" = "false"; then
2658   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2659 fi