configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 ## $Id$
   9 AC_PREREQ(2.53)
  10
  11 AC_INIT(Quagga, 0.99.16, [http://bugzilla.quagga.net])
  12 AC_CONFIG_SRCDIR(lib/zebra.h)
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 dnl -----------------------------------
  16 dnl Get hostname and other information.
  17 dnl -----------------------------------
  18 AC_CANONICAL_BUILD()
  19 AC_CANONICAL_HOST()
  20 AC_CANONICAL_TARGET()
  21
  22 AM_INIT_AUTOMAKE(1.6)
  23 AM_CONFIG_HEADER(config.h)
  24
  25 AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  26 if test "x$GAWK" = "xnot-in-PATH" ; then
  27         AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  28 BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  29 fi
  30 AC_ARG_VAR([GAWK],[GNU AWK])
  31
  32 dnl default is to match previous behavior
  33 exampledir=${sysconfdir}
  34 AC_ARG_ENABLE([exampledir],
  35           AC_HELP_STRING([--enable-exampledir],
  36                          [specify alternate directory for examples]),
  37                          exampledir="$enableval",)
  38 dnl XXX add --exampledir to autoconf standard directory list somehow
  39 AC_SUBST(exampledir)
  40
  41 dnl default is to match previous behavior
  42 pkgsrcrcdir=""
  43 pkgsrcdir=""
  44 AC_ARG_ENABLE([pkgsrcrcdir],
  45           AC_HELP_STRING([--enable-pkgsrcrcdir],
  46                          [specify directory for rc.d scripts]),
  47                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  48 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  49 AC_SUBST(pkgsrcdir)
  50 AC_SUBST(pkgsrcrcdir)
  51
  52 dnl ------------
  53 dnl Check CFLAGS
  54 dnl ------------
  55 AC_ARG_WITH(cflags,
  56 [  --with-cflags           Set CFLAGS for use in compilation.])
  57 if test "x$with_cflags" != "x" ; then
  58   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  59 elif test -n "$CFLAGS" ; then
  60   cflags_specified=yes ;
  61 fi
  62
  63 dnl --------------------
  64 dnl Check CC and friends
  65 dnl --------------------
  66 AC_LANG([C])
  67 AC_PROG_CC
  68 AC_PROG_CPP
  69 AM_PROG_CC_C_O
  70 AC_PROG_EGREP
  71
  72 dnl autoconf 2.59 appears not to support AC_PROG_SED
  73 dnl AC_PROG_SED
  74 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  75
  76 dnl ------------------------------------------------------------------
  77 dnl Intel compiler check. Although Intel tries really hard to make icc
  78 dnl look like gcc, there are some differences. It's very verbose with
  79 dnl -Wall and it doesn't support the individual -W options.
  80 dnl ------------------------------------------------------------------
  81 if test "x${GCC}" = "xyes" ; then
  82   COMPILER="GCC"
  83   AC_MSG_CHECKING([whether we are using the Intel compiler])
  84   AC_EGREP_CPP([^__INTEL_COMPILER], [__INTEL_COMPILER],
  85       [AC_MSG_RESULT([no])],
  86       [COMPILER="ICC"
  87        AC_MSG_RESULT([yes])]
  88   )
  89 else
  90   AC_MSG_CHECKING([whether we are using SunPro compiler])
  91   AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  92       [AC_MSG_RESULT([no])],
  93       [COMPILER="SUNPRO"
  94        AC_MSG_RESULT([yes])]
  95   )
  96 fi
  97
  98 dnl ---------------------------------------------
  99 dnl If CLFAGS doesn\'t exist set default value
 100 dnl AC_PROG_CC will have set minimal default
 101 dnl already, eg "-O2 -g" for gcc, "-g" for others
 102 dnl (Wall is gcc specific... have to make sure
 103 dnl  gcc is being used before setting it)
 104 dnl
 105 dnl Intel icc 8.0 also sets __GNUC__,
 106 dnl but doesn't support all these fancy -W options.
 107 dnl Intel compiler warnings we ignore:
 108 dnl 279: controlling expression is constant.
 109 dnl 869: parameter "xxx" was never referenced - to avoid massive warnings
 110 dnl      about "self", "vty", "argc" and "argv" never referenced in DEFUN
 111 dnl      macro.
 112 dnl 981: operands are evaluated in unspecified order.
 113 dnl
 114 dnl Sun Studio 10 / SunPro 5.7 is also supported,
 115 dnl so lets set some sane CFLAGS for it.
 116 dnl ---------------------------------------------
 117
 118 AC_MSG_CHECKING([whether to set a default CFLAGS])
 119 if test "x${cflags_specified}" = "x" ; then
 120   case ${COMPILER} in
 121     "ICC")
 122         CFLAGS="-Os -g -Wall -wd 279,869,981"
 123         AC_MSG_RESULT([Intel default])
 124         ;;
 125     "GCC")
 126         CFLAGS="-Os -fno-omit-frame-pointer -g -std=gnu99 -Wall"
 127         CFLAGS="${CFLAGS} -Wsign-compare -Wpointer-arith"
 128         CFLAGS="${CFLAGS} -Wbad-function-cast -Wwrite-strings"
 129         CFLAGS="${CFLAGS} -Wmissing-prototypes -Wmissing-declarations"
 130         CFLAGS="${CFLAGS} -Wchar-subscripts -Wcast-qual"
 131         # TODO: conditionally addd -Wpacked if handled
 132         AC_MSG_RESULT([gcc default])
 133         ;;
 134     "SUNPRO")
 135         CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
 136         AC_MSG_RESULT([SunPro default])
 137         ;;
 138     *)
 139         AC_MSG_RESULT([unknown compiler])
 140         ;;
 141   esac
 142 else
 143   AC_MSG_RESULT([CFLAGS supplied by user])
 144 fi
 145
 146 dnl --------------
 147 dnl Check programs
 148 dnl --------------
 149 AC_PROG_INSTALL
 150 AC_PROG_LN_S
 151 AC_PROG_MAKE_SET
 152 AC_CHECK_TOOL(AR, ar)
 153
 154 dnl ---------------------------
 155 dnl We, perhaps unfortunately,
 156 dnl depend on GNU Make specific
 157 dnl constructs.
 158 dnl Give the user a warning if
 159 dnl not GNU Make.
 160 dnl ---------------------------
 161 AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
 162         [quagga_cv_gnu_make=no
 163          if ${MAKE-make} --version 2>/dev/null | \
 164                 grep '^GNU Make ' >/dev/null ; then
 165                 quagga_cv_gnu_make=yes;
 166          fi
 167         ]
 168 )
 169
 170 dnl -----------------
 171 dnl System extensions
 172 dnl -----------------
 173 AC_GNU_SOURCE
 174
 175 dnl -------
 176 dnl libtool
 177 dnl -------
 178 AC_PROG_LIBTOOL
 179
 180 dnl ----------------------
 181 dnl Packages configuration
 182 dnl ----------------------
 183 AC_ARG_ENABLE(vtysh,
 184 [  --enable-vtysh          include integrated vty shell for Quagga])
 185 AC_ARG_ENABLE(ipv6,
 186 [  --disable-ipv6          turn off IPv6 related features and daemons])
 187 AC_ARG_ENABLE(doc,
 188 [  --disable-doc           do not build docs])
 189 AC_ARG_ENABLE(zebra,
 190 [  --disable-zebra         do not build zebra daemon])
 191 AC_ARG_ENABLE(bgpd,
 192 [  --disable-bgpd          do not build bgpd])
 193 AC_ARG_ENABLE(ripd,
 194 [  --disable-ripd          do not build ripd])
 195 AC_ARG_ENABLE(ripngd,
 196 [  --disable-ripngd        do not build ripngd])
 197 AC_ARG_ENABLE(ospfd,
 198 [  --disable-ospfd         do not build ospfd])
 199 AC_ARG_ENABLE(ospf6d,
 200 [  --disable-ospf6d        do not build ospf6d])
 201 AC_ARG_ENABLE(watchquagga,
 202 [  --disable-watchquagga   do not build watchquagga])
 203 AC_ARG_ENABLE(isisd,
 204 [  --enable-isisd          build isisd])
 205 AC_ARG_ENABLE(solaris,
 206 [  --enable-solaris          build solaris])
 207 AC_ARG_ENABLE(bgp-announce,
 208 [  --disable-bgp-announce, turn off BGP route announcement])
 209 AC_ARG_ENABLE(netlink,
 210 [  --enable-netlink        force to use Linux netlink interface])
 211 AC_ARG_ENABLE(broken-aliases,
 212 [  --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
 213 AC_ARG_WITH(crypto,
 214 [  --without-crypto        do not use libcrypto in SNMP])
 215 AC_ARG_ENABLE(snmp,
 216 [  --enable-snmp           enable SNMP support])
 217 AC_ARG_WITH(libpam,
 218 [  --with-libpam           use libpam for PAM support in vtysh])
 219 AC_ARG_ENABLE(tcp-zebra,
 220 [  --enable-tcp-zebra      enable TCP/IP socket connection between zebra and protocol daemon])
 221 AC_ARG_ENABLE(opaque-lsa,
 222 [  --enable-opaque-lsa     enable OSPF Opaque-LSA with OSPFAPI support (RFC2370)])
 223 AC_ARG_ENABLE(ospfapi,
 224 [  --disable-ospfapi       do not build OSPFAPI to access the OSPF LSA Database,
 225                           (this is the default if --enable-opaque-lsa is not set)])
 226 AC_ARG_ENABLE(ospfclient,
 227 [  --disable-ospfclient    do not build OSPFAPI client for OSPFAPI,
 228                           (this is the default if --disable-ospfapi is set)])
 229 AC_ARG_ENABLE(ospf-te,
 230 [  --enable-ospf-te        enable Traffic Engineering Extension to OSPF])
 231 AC_ARG_ENABLE(multipath,
 232 [  --enable-multipath=ARG  enable multipath function, ARG must be digit])
 233 AC_ARG_ENABLE(user,
 234   AC_HELP_STRING([--enable-user=user], [user to run Quagga suite as (default quagga)]))
 235 AC_ARG_ENABLE(group,
 236   AC_HELP_STRING([--enable-group=group], [group to run Quagga suite as (default quagga)]))
 237 AC_ARG_ENABLE(vty_group,
 238 [  --enable-vty-group=ARG  set vty sockets to have specified group as owner])
 239 AC_ARG_ENABLE(configfile_mask,
 240 [  --enable-configfile-mask=ARG  set mask for config files])
 241 AC_ARG_ENABLE(logfile_mask,
 242 [  --enable-logfile-mask=ARG     set mask for log files])
 243
 244 AC_ARG_ENABLE(rtadv,
 245 [  --disable-rtadv               disable IPV6 router advertisement feature])
 246 AC_ARG_ENABLE(irdp,
 247 [  --enable-irdp                 enable IRDP server support in zebra])
 248 AC_ARG_ENABLE(isis_topology,
 249 [  --enable-isis-topology        enable IS-IS topology generator])
 250 AC_ARG_ENABLE(capabilities,
 251 [  --disable-capabilities        disable using POSIX capabilities])
 252 AC_ARG_ENABLE(gcc_ultra_verbose,
 253 [  --enable-gcc-ultra-verbose    enable ultra verbose GCC warnings])
 254 AC_ARG_ENABLE(linux24_tcp_md5,
 255 [  --enable-linux24-tcp-md5  enable support for old, Linux-2.4 RFC2385 patch])
 256 AC_ARG_ENABLE(gcc-rdynamic,
 257 [  --enable-gcc-rdynamic   enable gcc linking with -rdynamic for better backtraces])
 258 AC_ARG_ENABLE(time-check,
 259 [  --disable-time-check          disable slow thread warning messages])
 260 AC_ARG_ENABLE(pcreposix,
 261 [  --enable-pcreposix          enable using PCRE Posix libs for regex functions])
 262
 263 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 264   CFLAGS="${CFLAGS} -W -Wcast-qual -Wstrict-prototypes"
 265   CFLAGS="${CFLAGS} -Wmissing-declarations -Wmissing-noreturn"
 266   CFLAGS="${CFLAGS} -Wmissing-format-attribute -Wunreachable-code"
 267   CFLAGS="${CFLAGS} -Wpacked -Wpadded"
 268 fi
 269
 270 if test x"${enable_gcc_rdynamic}" = x"yes" ; then
 271   LDFLAGS="${LDFLAGS} -rdynamic"
 272 fi
 273
 274 if test x"${enable_time_check}" != x"no" ; then
 275   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 276     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 277   else
 278     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 279   fi
 280 fi
 281
 282 if test "${enable_broken_aliases}" = "yes"; then
 283   if test "${enable_netlink}" = "yes"
 284   then
 285     AC_MSG_FAILURE([Sorry you can not use netlink with broken aliases])
 286   fi
 287   AC_DEFINE(HAVE_BROKEN_ALIASES,,Broken Alias)
 288   enable_netlink=no
 289 fi
 290
 291 if test "${enable_tcp_zebra}" = "yes"; then
 292   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 293 fi
 294
 295 if test "${enable_opaque_lsa}" = "yes"; then
 296   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 297 fi
 298
 299 if test "${enable_ospf_te}" = "yes"; then
 300   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 301   AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
 302 fi
 303
 304 if test "${enable_linux24_tcp_md5}" = "yes"; then
 305   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 306 fi
 307
 308 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 309 if test "${enable_rtadv}" != "no"; then
 310   AC_MSG_RESULT(yes)
 311   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 312 else
 313   AC_MSG_RESULT(no)
 314 fi
 315
 316 if test "${enable_irdp}" = "yes"; then
 317   AC_DEFINE(HAVE_IRDP,, IRDP )
 318 fi
 319
 320 if test "${enable_isisd}" = "yes" && test "${enable_isis_topology}" = yes; then
 321   AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
 322   ISIS_TOPOLOGY_INCLUDES="-I./topology"
 323   ISIS_TOPOLOGY_DIR="topology"
 324   ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
 325 fi
 326
 327 AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
 328 AC_SUBST(ISIS_TOPOLOGY_DIR)
 329 AC_SUBST(ISIS_TOPOLOGY_LIB)
 330
 331 if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
 332   enable_user="quagga"
 333 elif test "${enable_user}" = "no"; then
 334   enable_user="root"
 335 fi
 336
 337 if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
 338   enable_group="quagga"
 339 elif test "${enable_group}" = "no"; then
 340   enable_group="root"
 341 fi
 342
 343 if test x"${enable_vty_group}" = x"yes" ; then
 344   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 345 elif test x"${enable_vty_group}" != x""; then
 346   if test x"${enable_vty_group}" != x"no"; then
 347     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 348   fi
 349 fi
 350 AC_SUBST([enable_user])
 351 AC_SUBST([enable_group])
 352 AC_SUBST([enable_vty_group])
 353 AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 354 AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 355
 356 enable_configfile_mask=${enable_configfile_mask:-0600}
 357 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 358
 359 enable_logfile_mask=${enable_logfile_mask:-0600}
 360 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 361
 362 MULTIPATH_NUM=1
 363
 364 case "${enable_multipath}" in
 365   [[0-9]|[1-9][0-9]])
 366     MULTIPATH_NUM="${enable_multipath}"
 367     ;;
 368   "")
 369     ;;
 370   *)
 371     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 372     ;;
 373 esac
 374
 375 AC_SUBST(MULTIPATH_NUM)
 376
 377 dnl ------------------------------------
 378 dnl Check C keywords and standard  types
 379 dnl ------------------------------------
 380 AC_C_CONST
 381 AC_C_INLINE
 382 AC_C_RESTRICT
 383 AC_C_VOLATILE
 384 AC_HEADER_STDC
 385 AC_HEADER_TIME
 386 AC_HEADER_SYS_WAIT
 387 dnl AC_TYPE_PID_T
 388 AC_TYPE_UID_T
 389 AC_TYPE_MODE_T
 390 AC_TYPE_SIZE_T
 391 AC_TYPE_SIGNAL
 392 AC_STRUCT_TM
 393
 394 dnl -------------------------
 395 dnl Check other header files.
 396 dnl -------------------------
 397 AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
 398         sys/types.h linux/version.h netdb.h asm/types.h \
 399         sys/param.h limits.h signal.h libutil.h \
 400         sys/socket.h netinet/in.h time.h sys/time.h])
 401
 402 dnl Utility macro to avoid retyping includes all the time
 403 m4_define([QUAGGA_INCLUDES],
 404 [#ifdef SUNOS_5
 405 #define _XPG4_2
 406 #define __EXTENSIONS__
 407 #endif
 408 #include <stdio.h>
 409 #if STDC_HEADERS
 410 # include <stdlib.h>
 411 # include <stddef.h>
 412 #else
 413 # if HAVE_STDLIB_H
 414 #  include <stdlib.h>
 415 # endif
 416 #endif
 417 #if HAVE_SYS_TYPES_H
 418 # include <sys/types.h>
 419 #endif
 420 /* sys/conf.h depends on param.h on FBSD at least */
 421 #if HAVE_SYS_PARAM_H
 422 # include <sys/param.h>
 423 #endif
 424 /* Required for MAXSIG */
 425 #if HAVE_SIGNAL_H
 426 # include <signal.h>
 427 #endif
 428 #if HAVE_SYS_SOCKET_H
 429 # include <sys/socket.h>
 430 #endif
 431 #if HAVE_NETINET_IN_H
 432 # include <netinet/in.h>
 433 #endif
 434 #ifdef TIME_WITH_SYS_TIME
 435 # include <sys/time.h>
 436 # include <time.h>
 437 #else
 438 # ifdef HAVE_SYS_TIME_H
 439 #  include <sys/time.h>
 440 # else
 441 #  include <time.h>
 442 # endif
 443 #endif /* TIME_WITH_SYS_TIME */
 444 ])dnl
 445
 446 AC_CHECK_HEADERS([sys/un.h net/if.h netinet/in_systm.h netinet/in_var.h \
 447         net/if_dl.h net/if_var.h net/netopt.h net/route.h \
 448         inet/nd.h arpa/inet.h netinet/ip_icmp.h \
 449         fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
 450         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 451         [], [], QUAGGA_INCLUDES)
 452
 453 AC_CHECK_HEADERS([ucontext.h], [], [],
 454 [#ifndef __USE_GNU
 455 #define __USE_GNU
 456 #endif /* __USE_GNU */
 457 QUAGGA_INCLUDES
 458 ])
 459
 460 m4_define([QUAGGA_INCLUDES],
 461 QUAGGA_INCLUDES
 462 [#if HAVE_NET_IF_H
 463 # include <net/if.h>
 464 #endif
 465 #if HAVE_SYS_UN_H
 466 # include <sys/un.h>
 467 #endif
 468 #if HAVE_NETINET_IN_SYSTM_H
 469 # include <netinet/in_systm.h>
 470 #endif
 471 #if HAVE_NETINET_IN_VAR_H
 472 # include <netinet/in_var.h>
 473 #endif
 474 #if HAVE_NET_IF_DL_H
 475 # include <net/if_dl.h>
 476 #endif
 477 #if HAVE_NET_IF_VAR_H
 478 # include <net/if_var.h>
 479 #endif
 480 #if HAVE_NET_NETOPT_H
 481 # include <net/netopt.h>
 482 #endif
 483 #if HAVE_NET_ROUTE_H
 484 # include <net/route.h>
 485 #endif
 486 #if HAVE_INET_ND_H
 487 # include <inet/nd.h>
 488 #endif
 489 #if HAVE_ARPA_INET_H
 490 # include <arpa/inet.h>
 491 #endif
 492 /* Required for IDRP */
 493 #if HAVE_NETINET_IP_ICMP_H
 494 # include <netinet/ip_icmp.h>
 495 #endif
 496 ])dnl
 497
 498 dnl V6 headers are checked below, after we check for v6
 499
 500 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 501 case "$host" in
 502   [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
 503       opsys=sol2-6
 504       AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
 505       AC_DEFINE(SUNOS_5, 1, SunOS 5)
 506       AC_CHECK_LIB(xnet, main)
 507       CURSES=-lcurses
 508   ;;
 509   [*-sunos5.[8-9]] \
 510   | [*-sunos5.1[0-9]] \
 511   | [*-sunos5.1[0-9].[0-9]] \
 512   | [*-solaris2.[8-9]] \
 513   | [*-solaris2.1[0-9]] \
 514   | [*-solaris2.1[0-9].[0-9]])
 515       opsys=sol8
 516       AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
 517       AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 518       AC_CHECK_LIB(socket, main)
 519       AC_CHECK_LIB(nsl, main)
 520       AC_CHECK_LIB(umem, main)
 521       AC_CHECK_FUNCS([printstack],
 522         [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 523          AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 524         ])
 525       CURSES=-lcurses
 526   ;;
 527   *-sunos5* | *-solaris2*)
 528       AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
 529       AC_CHECK_LIB(socket, main)
 530       AC_CHECK_LIB(nsl, main)
 531       CURSES=-lcurses
 532   ;;
 533   *-linux*)
 534       opsys=gnu-linux
 535       AC_DEFINE(GNU_LINUX,,GNU Linux)
 536   ;;
 537   *-nec-sysv4*)
 538       AC_CHECK_LIB(nsl, gethostbyname)
 539       AC_CHECK_LIB(socket, socket)
 540   ;;
 541   *-openbsd*)
 542       opsys=openbsd
 543       AC_DEFINE(OPEN_BSD,,OpenBSD)
 544   ;;
 545   *-bsdi*)
 546       opsys=bsdi
 547       OTHER_METHOD="mtu_kvm.o"
 548       AC_CHECK_LIB(kvm, main)
 549   ;;
 550   *-irix6.5)
 551       opsys=irix
 552       AC_DEFINE(IRIX_65,,IRIX 6.5)
 553   ;;
 554 esac
 555
 556 AC_SYS_LARGEFILE
 557
 558 dnl ---------------------
 559 dnl Integrated VTY option
 560 dnl ---------------------
 561 case "${enable_vtysh}" in
 562   "yes") VTYSH="vtysh";
 563          AC_DEFINE(VTYSH,,VTY shell)
 564          AC_PATH_PROG(PERL, perl)
 565 dnl      Vtysh uses libreadline, which looks for termcap functions at
 566 dnl      configure time.  We follow readlines search order.
 567 dnl      The required procedures are in libtermcap on NetBSD, in
 568 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 569          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 570            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 571              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 572                [AC_CHECK_LIB(ncurses, tputs,
 573                              LIBREADLINE="$LIBREADLINE -lncurses")]
 574               )]
 575             )]
 576           )
 577          AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
 578                       "$LIBREADLINE")
 579          if test $ac_cv_lib_readline_main = no; then
 580            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 581          fi
 582          AC_CHECK_HEADER(readline/history.h)
 583          if test $ac_cv_header_readline_history_h = no;then
 584            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 585          fi
 586          AC_CHECK_LIB(readline, rl_completion_matches,
 587                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 588          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 589            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 590          fi
 591          ;;
 592   "no" ) VTYSH="";;
 593   *    ) ;;
 594 esac
 595 AC_SUBST(LIBREADLINE)
 596
 597 dnl ----------
 598 dnl PAM module
 599 dnl ----------
 600 if test "$with_libpam" = "yes"; then
 601   AC_CHECK_HEADER([security/pam_misc.h],
 602     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 603      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 604      pam_conv_func="misc_conv"
 605     ],
 606     [], QUAGGA_INCLUDES)
 607   AC_CHECK_HEADER([security/openpam.h],
 608     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 609      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 610      pam_conv_func="openpam_ttyconv"
 611     ],
 612     [], QUAGGA_INCLUDES)
 613   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 614     AC_MSG_WARN([*** pam support will not be built ***])
 615     with_libpam="no"
 616   fi
 617 fi
 618
 619 if test "$with_libpam" = "yes"; then
 620 dnl took this test from proftpds configure.in and suited to our needs
 621 dnl -------------------------------------------------------------------------
 622 dnl
 623 dnl This next check looks funky due to a linker problem with some versions
 624 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 625 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 626 dnl with RedHat 6.2 and Debian 2.2 or better.
 627 AC_CHECK_LIB(pam, pam_start,
 628   [AC_CHECK_LIB(pam, $pam_conv_func,
 629     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 630      LIBPAM="-lpam"],
 631     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 632      LIBPAM="-lpam -lpam_misc"]
 633     )
 634   ],
 635
 636   [AC_CHECK_LIB(pam, pam_end,
 637     [AC_CHECK_LIB(pam, $pam_conv_func,
 638       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 639        LIBPAM="-lpam -ldl"],
 640       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 641        LIBPAM="-lpam -ldl -lpam_misc"]
 642      )
 643   ],AC_MSG_WARN([*** pam support will not be built ***]),
 644   [-ldl])
 645   ]
 646 )
 647 fi
 648 AC_SUBST(LIBPAM)
 649
 650 dnl -------------------------------
 651 dnl Endian-ness check
 652 dnl -------------------------------
 653 AC_WORDS_BIGENDIAN
 654
 655 dnl -------------------------------
 656 dnl check the size in byte of the C
 657 dnl -------------------------------
 658 dnl AC_CHECK_SIZEOF(char)
 659 dnl AC_CHECK_SIZEOF(int)
 660 dnl AC_CHECK_SIZEOF(short)
 661 dnl AC_CHECK_SIZEOF(long)
 662
 663 dnl ----------------------------
 664 dnl check existance of functions
 665 dnl ----------------------------
 666 AC_FUNC_CHOWN
 667 AC_FUNC_FNMATCH
 668 AC_FUNC_FORK
 669 AC_FUNC_MALLOC
 670 AC_FUNC_MEMCMP
 671 AC_FUNC_MKTIME
 672 AC_FUNC_STRFTIME
 673 AC_FUNC_REALLOC
 674 AC_FUNC_STAT
 675 AC_FUNC_SELECT_ARGTYPES
 676 AC_FUNC_STRFTIME
 677 dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
 678 dnl can lead to strange side effects.  So we just check for strnlen
 679 dnl directly, see below.
 680 dnl AC_FUNC_STRNLENdnl
 681 AC_FUNC_VPRINTF
 682
 683 dnl -------------------------------
 684 dnl bgpd needs pow() and hence libm
 685 dnl -------------------------------
 686 TMPLIBS="$LIBS"
 687 AC_CHECK_HEADER([math.h],
 688   [AC_CHECK_LIB([m], [pow],
 689     [LIBM="-lm"
 690      LIBS="$LIBS $LIBM"
 691      AC_DEFINE(HAVE_LIBM,, Have libm)
 692      AC_CHECK_FUNCS(pow,[],[LIBM=""])
 693     ])
 694 ])
 695 if test x"$LIBM" = x ; then
 696   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
 697 fi
 698 LIBS="$TMPLIBS"
 699 AC_SUBST(LIBM)
 700
 701 dnl ---------------
 702 dnl other functions
 703 dnl ---------------
 704 AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
 705         inet_ntoa inet_aton strnlen \
 706         memchr memmove memset select socket \
 707         strcasecmp strchr strcspn strdup strerror \
 708         strncasecmp strndup strrchr strspn strstr \
 709         strtol strtoul strlcat strlcpy \
 710         daemon snprintf vsnprintf \
 711         if_nametoindex if_indextoname getifaddrs \
 712         uname fcntl])
 713
 714 AC_CHECK_FUNCS(setproctitle, ,
 715   [AC_CHECK_LIB(util, setproctitle,
 716      [LIBS="$LIBS -lutil"
 717       AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
 718      ]
 719    )
 720   ]
 721 )
 722
 723 dnl ------------------------------------
 724 dnl Determine routing get and set method
 725 dnl ------------------------------------
 726 AC_MSG_CHECKING(zebra between kernel interface method)
 727 if test x"$opsys" = x"gnu-linux"; then
 728   if test "${enable_netlink}" = "yes";then
 729     AC_MSG_RESULT(netlink)
 730     RT_METHOD=rt_netlink.o
 731     AC_DEFINE(HAVE_NETLINK,,netlink)
 732     netlink=yes
 733   elif test "${enable_netlink}" = "no"; then
 734     AC_MSG_RESULT(ioctl)
 735     RT_METHOD=rt_ioctl.o
 736     netlink=no
 737   else
 738     AC_MSG_RESULT(netlink)
 739     RT_METHOD=rt_netlink.o
 740     AC_DEFINE(HAVE_NETLINK,,netlink)
 741     netlink=yes
 742   fi
 743 elif test x"$opsys" = x"sol2-6";then
 744   AC_MSG_RESULT(Route socket)
 745   KERNEL_METHOD="kernel_socket.o"
 746   RT_METHOD="rt_socket.o"
 747 elif test x"$opsys" = x"sol8";then
 748   AC_MSG_RESULT(Route socket)
 749   KERNEL_METHOD="kernel_socket.o"
 750   RT_METHOD="rt_socket.o"
 751 elif test "$opsys" = "irix" ; then
 752   AC_MSG_RESULT(Route socket)
 753   KERNEL_METHOD="kernel_socket.o"
 754   RT_METHOD="rt_socket.o"
 755 else
 756   AC_TRY_RUN([#include <errno.h>
 757 #include <sys/types.h>
 758 #include <sys/socket.h>
 759
 760 main ()
 761 {
 762   int ac_sock;
 763
 764   ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
 765   if (ac_sock < 0 && errno == EINVAL)
 766     exit (1);
 767   exit (0);
 768 }],
 769   [KERNEL_METHOD=kernel_socket.o
 770    RT_METHOD=rt_socket.o
 771    AC_MSG_RESULT(socket)],
 772   [RT_METHOD=rt_ioctl.o
 773    AC_MSG_RESULT(ioctl)],
 774   [KERNEL_METHOD=kernel_socket.o
 775    RT_METHOD=rt_socket.o
 776    AC_MSG_RESULT(socket)])
 777 fi
 778 AC_SUBST(RT_METHOD)
 779 AC_SUBST(KERNEL_METHOD)
 780 AC_SUBST(OTHER_METHOD)
 781
 782 dnl --------------------------
 783 dnl Determine IS-IS I/O method
 784 dnl --------------------------
 785 AC_CHECK_HEADER(net/bpf.h)
 786 AC_CHECK_HEADER(sys/dlpi.h)
 787 AC_MSG_CHECKING(zebra IS-IS I/O method)
 788 if test x"$opsys" = x"gnu-linux"; then
 789   AC_MSG_RESULT(pfpacket)
 790   ISIS_METHOD=isis_pfpacket.o
 791 elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
 792   AC_MSG_RESULT(DLPI)
 793   ISIS_METHOD="isis_dlpi.o"
 794 else
 795   if test $ac_cv_header_net_bpf_h = no; then
 796     if test $ac_cv_header_sys_dlpi_h = no; then
 797       AC_MSG_RESULT(none)
 798       AC_MSG_WARN([*** IS-IS support will not be built ***])
 799       ISISD=""
 800     else
 801       AC_MSG_RESULT(DLPI)
 802     fi
 803     ISIS_METHOD="isis_dlpi.o"
 804   else
 805     AC_MSG_RESULT(BPF)
 806     ISIS_METHOD="isis_bpf.o"
 807   fi
 808 fi
 809 AC_SUBST(ISIS_METHOD)
 810
 811 dnl ------------------------------------
 812 dnl check for broken CMSG_FIRSTHDR macro
 813 dnl ------------------------------------
 814 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
 815 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 816 #ifdef SUNOS_5
 817 #define _XPG4_2
 818 #define __EXTENSIONS__
 819 #endif
 820 #ifdef HAVE_STDLIB_H
 821 # include <stdlib.h>
 822 #endif
 823 #ifdef HAVE_SYS_TYPES_H
 824 #include <sys/types.h>
 825 #endif
 826 #ifdef HAVE_SYS_SOCKET_H
 827 #include <sys/socket.h>
 828 #endif
 829
 830 main()
 831 {
 832   struct msghdr msg;
 833   char buf[4];
 834
 835   msg.msg_control = buf;
 836   msg.msg_controllen = 0;
 837
 838   if (CMSG_FIRSTHDR(&msg) != NULL)
 839     exit(0);
 840   exit (1);
 841 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
 842 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 843
 844 dnl ------------------------------
 845 dnl check kernel route read method
 846 dnl ------------------------------
 847 AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
 848 [if test "x$netlink" = xyes; then
 849   quagga_cv_rtread_method="netlink"
 850 else
 851 for quagga_cv_rtread_method in /proc/net/route /dev/ip /dev/null;
 852 do
 853   test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
 854 done
 855 case $quagga_cv_rtread_method in
 856   "/proc/net/route") quagga_cv_rtread_method="proc";;
 857   "/dev/ip")
 858                      case "$host" in
 859                        *-freebsd*)    quagga_cv_rtread_method="sysctl";;
 860                        *)             quagga_cv_rtread_method="getmsg";;
 861                      esac;;
 862         *)
 863                      quagga_cv_rtread_method="sysctl";;
 864 esac
 865 fi])
 866 RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
 867 AC_SUBST(RTREAD_METHOD)
 868
 869 dnl -----------------------------
 870 dnl check interface lookup method
 871 dnl -----------------------------
 872 IOCTL_METHOD=ioctl.o
 873 AC_MSG_CHECKING(interface looking up method)
 874 if test "$netlink" = yes; then
 875   AC_MSG_RESULT(netlink)
 876   IF_METHOD=if_netlink.o
 877 elif test "$opsys" = "sol2-6";then
 878   AC_MSG_RESULT(Solaris GIF)
 879   IF_METHOD=if_ioctl.o
 880 elif test "$opsys" = "sol8";then
 881   AC_MSG_RESULT(Solaris GLIF)
 882   IF_METHOD=if_ioctl_solaris.o
 883   IOCTL_METHOD=ioctl_solaris.o
 884 elif test "$opsys" = "irix" ; then
 885   AC_MSG_RESULT(IRIX)
 886   IF_METHOD=if_ioctl.o
 887 elif test "$opsys" = "openbsd";then
 888   AC_MSG_RESULT(openbsd)
 889   IF_METHOD=if_ioctl.o
 890 elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 891   AC_MSG_RESULT(sysctl)
 892     IF_METHOD=if_sysctl.o
 893     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 894 else
 895     AC_MSG_RESULT(ioctl)
 896     IF_METHOD=if_ioctl.o
 897 fi
 898 AC_SUBST(IF_METHOD)
 899 AC_SUBST(IOCTL_METHOD)
 900
 901 dnl ---------------------------------------------------------------
 902 dnl figure out how to specify an interface in multicast sockets API
 903 dnl ---------------------------------------------------------------
 904 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
 905
 906 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
 907 AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
 908 #include <sys/param.h>
 909 #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000)
 910   return (0);
 911 #else
 912   #error No support for BSD struct ip_mreq hack detected
 913 #endif],[AC_MSG_RESULT(yes)
 914 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
 915 AC_MSG_RESULT(no))
 916
 917 dnl ---------------------------------------------------------------
 918 dnl figure out how to check link-state
 919 dnl ---------------------------------------------------------------
 920 AC_CHECK_HEADER([net/if.h],
 921   [AC_CHECK_HEADER( [net/if_media.h],
 922     [m4_define([LINK_DETECT_INCLUDES],
 923       QUAGGA_INCLUDES
 924       [#include <net/if_media.h>
 925     ])
 926     AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
 927       AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
 928       [], LINK_DETECT_INCLUDES)],
 929     [],
 930     QUAGGA_INCLUDES)],
 931   [], QUAGGA_INCLUDES )
 932
 933 dnl ------------------------
 934 dnl TCP_MD5SIG socket option
 935 dnl ------------------------
 936
 937 AC_CHECK_HEADER([netinet/tcp.h],
 938    [m4_define([MD5_INCLUDES],
 939       QUAGGA_INCLUDES
 940       [#include <netinet/tcp.h>
 941     ])
 942     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
 943    [],
 944    QUAGGA_INCLUDES)
 945 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
 946   AC_CHECK_HEADER([linux/tcp.h],
 947        [m4_define([MD5_INCLUDES],
 948           QUAGGA_INCLUDES
 949           [#include <linux/tcp.h>
 950         ])
 951        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
 952 fi
 953
 954 dnl -----------------------
 955 dnl check proc file system.
 956 dnl -----------------------
 957 if test "$netlink" != yes; then
 958   if test -r /proc/net/dev; then
 959     AC_DEFINE(HAVE_PROC_NET_DEV,,/proc/net/dev)
 960     IF_PROC=if_proc.o
 961   fi
 962   if test -r /proc/net/if_inet6; then
 963     AC_DEFINE(HAVE_PROC_NET_IF_INET6,,/proc/net/if_inet6)
 964     IF_PROC=if_proc.o
 965   fi
 966 fi
 967 AC_SUBST(IF_PROC)
 968
 969 dnl -----------------------------
 970 dnl check ipforward detect method
 971 dnl -----------------------------
 972 AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
 973 [for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
 974 do
 975   test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
 976 done
 977 case $quagga_cv_ipforward_method in
 978   "/proc/net/snmp")  quagga_cv_ipforward_method="proc";;
 979   "/dev/ip")
 980                      case "$host" in
 981                        *-nec-sysv4*)  quagga_cv_ipforward_method="ews";;
 982                        *-freebsd*)    quagga_cv_ipforward_method="sysctl";;
 983                        *)             quagga_cv_ipforward_method="solaris";;
 984                      esac;;
 985   *)                 quagga_cv_ipforward_method="sysctl";;
 986 esac])
 987 IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
 988 AC_SUBST(IPFORWARD)
 989
 990 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
 991
 992 dnl ----------
 993 dnl IPv6 check
 994 dnl ----------
 995 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
 996 if test "${enable_ipv6}" = "no"; then
 997   AC_MSG_RESULT(disabled)
 998 else
 999 dnl ----------
1000 dnl INRIA IPv6
1001 dnl ----------
1002   if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
1003     zebra_cv_ipv6=yes
1004     AC_DEFINE(HAVE_IPV6,1,INRIA IPv6)
1005     AC_DEFINE(INRIA_IPV6,1,INRIA IPv6)
1006     RIPNGD="ripngd"
1007     OSPF6D="ospf6d"
1008     LIB_IPV6=""
1009     AC_MSG_RESULT(INRIA IPv6)
1010 dnl ---------
1011 dnl KAME IPv6
1012 dnl ---------
1013   elif grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1014     zebra_cv_ipv6=yes
1015     AC_DEFINE(HAVE_IPV6,1,KAME IPv6)
1016     AC_DEFINE(KAME,1,KAME IPv6)
1017     RIPNGD="ripngd"
1018     OSPF6D="ospf6d"
1019     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
1020       LIB_IPV6="-L/usr/local/v6/lib -linet6"
1021     fi
1022     AC_MSG_RESULT(KAME)
1023 dnl -------------------------
1024 dnl MUSICA IPv6
1025 dnl  default host check
1026 dnl  It is not used by Kheops
1027 dnl -------------------------
1028   elif grep MUSICA /usr/include6/netinet6/in6.h >/dev/null 2>&1; then
1029     zebra_cv_ipv6=yes
1030     AC_DEFINE(HAVE_IPV6,1,Musicia IPv6)
1031     AC_DEFINE(MUSICA,1,Musica IPv6 stack)
1032     AC_DEFINE(KAME,1,KAME IPv6 stack)
1033     RIPNGD="ripngd"
1034     OSPF6D="ospf6d"
1035     if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
1036       LIB_IPV6="-L/usr/local/v6/lib -linet6"
1037     fi
1038     AC_MSG_RESULT(MUSICA)
1039 dnl ---------
1040 dnl NRL check
1041 dnl ---------
1042   elif grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1043     zebra_cv_ipv6=yes
1044     AC_DEFINE(HAVE_IPV6,1,NRL IPv6)
1045     AC_DEFINE(NRL,1,NRL)
1046     RIPNGD="ripngd"
1047     OSPF6D="ospf6d"
1048     if test x"$opsys" = x"bsdi";then
1049       AC_DEFINE(BSDI_NRL,,BSDI)
1050       AC_MSG_RESULT(BSDI_NRL)
1051     else
1052       AC_MSG_RESULT(NRL)
1053     fi
1054 dnl ------------------------------------
1055 dnl Solaris 9, 10 and potentially higher
1056 dnl ------------------------------------
1057   elif test x"$opsys" = x"sol8"; then
1058     zebra_cv_ipv6=yes;
1059     AC_DEFINE(HAVE_IPV6, 1, IPv6)
1060     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1061     RIPNGD="ripngd"
1062     OSPF6D="ospf6d"
1063     AC_MSG_RESULT(Solaris IPv6)
1064 dnl ----------
1065 dnl Linux IPv6
1066 dnl ----------
1067   elif test "${enable_ipv6}" = "yes"; then
1068     AC_EGREP_CPP(yes, [
1069       #include <linux/version.h>
1070       /* 2.1.128 or later */
1071       #if LINUX_VERSION_CODE >= 0x020180
1072       yes
1073       #endif],
1074       [zebra_cv_ipv6=yes
1075        zebra_cv_linux_ipv6=yes
1076        AC_MSG_RESULT(Linux IPv6)])
1077   else
1078     if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
1079      then
1080       zebra_cv_ipv6=yes
1081       zebra_cv_linux_ipv6=yes
1082       AC_MSG_RESULT(Linux IPv6)
1083     fi
1084   fi
1085
1086   if test "$zebra_cv_linux_ipv6" = "yes";then
1087     AC_MSG_CHECKING(whether libc has IPv6 support)
1088     AC_TRY_LINK([#include <netinet/in.h>
1089     ],[ int a; a = (int) in6addr_any.s6_addr[0]; if (a != 12345) return a; ],
1090     [AC_MSG_RESULT(yes)
1091       zebra_cv_ipv6=yes
1092       zebra_cv_linux_ipv6=yes],
1093     [AC_MSG_RESULT(no)
1094       zebra_cv_ipv6=no
1095       zebra_cv_linux_ipv6=no])
1096   fi
1097
1098   if test "$zebra_cv_linux_ipv6" = "yes";then
1099     AC_MSG_CHECKING(for GNU libc >= 2.1)
1100     AC_DEFINE(HAVE_IPV6,1,Linux IPv6)
1101     AC_EGREP_CPP(yes, [
1102 #include <features.h>
1103 #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
1104   yes
1105 #endif],
1106       [glibc=yes
1107        AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1108        AC_MSG_RESULT(yes)],
1109       AC_MSG_RESULT(no)
1110     )
1111     RIPNGD="ripngd"
1112     OSPF6D="ospf6d"
1113     if test "$glibc" != "yes"; then
1114       INCLUDES="-I/usr/inet6/include"
1115       if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
1116          LIB_IPV6="-L/usr/inet6/lib -linet6"
1117       fi
1118     fi
1119   fi
1120
1121 dnl -----------------------
1122 dnl Set IPv6 related values
1123 dnl -----------------------
1124   LIBS="$LIB_IPV6 $LIBS"
1125   AC_SUBST(LIB_IPV6)
1126
1127   if test x"$RIPNGD" = x""; then
1128     AC_MSG_RESULT(IPv4 only)
1129   fi
1130 fi
1131
1132 dnl ------------------
1133 dnl IPv6 header checks
1134 dnl ------------------
1135 if test "x${zebra_cv_ipv6}" = "xyes"; then
1136 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
1137         netinet6/in6_var.h netinet6/nd6.h], [], [],
1138         QUAGGA_INCLUDES)
1139 fi
1140
1141 m4_define([QUAGGA_INCLUDES],dnl
1142 QUAGGA_INCLUDES
1143 [#if HAVE_NETINET6_IN6_H
1144 #include <netinet6/in6.h>
1145 #endif
1146 #if HAVE_NETINET_IN6_VAR_H
1147 #include <netinet/in6_var.h>
1148 #endif
1149 #if HAVE_NETINET_ICMP6_H
1150 # include <netinet/icmp6.h>
1151 #endif
1152 #if HAVE_NETINET6_IN6_VAR_H
1153 # include <netinet6/in6_var.h>
1154 #endif
1155 #if HAVE_NETINET6_ND6_H
1156 # include <netinet6/nd6.h>
1157 #endif
1158 ])dnl
1159
1160 dnl disable doc check
1161 if test "${enable_doc}" = "no";then
1162   DOC=""
1163 else
1164   DOC="doc"
1165 fi
1166
1167 dnl --------------------
1168 dnl Daemon disable check
1169 dnl --------------------
1170 if test "${enable_zebra}" = "no";then
1171   ZEBRA=""
1172 else
1173   ZEBRA="zebra"
1174 fi
1175
1176 if test "${enable_bgpd}" = "no";then
1177   BGPD=""
1178 else
1179   BGPD="bgpd"
1180 fi
1181
1182 if test "${enable_ripd}" = "no";then
1183   RIPD=""
1184 else
1185   RIPD="ripd"
1186 fi
1187
1188 if test "${enable_ospfd}" = "no";then
1189   OSPFD=""
1190 else
1191   OSPFD="ospfd"
1192 fi
1193
1194 if test "${enable_watchquagga}" = "no";then
1195   WATCHQUAGGA=""
1196 else
1197   WATCHQUAGGA="watchquagga"
1198 fi
1199
1200 OSPFCLIENT=""
1201 if test "${enable_opaque_lsa}" = "yes"; then
1202   if test "${enable_ospfapi}" != "no";then
1203     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1204
1205     if test "${enable_ospfclient}" != "no";then
1206       OSPFCLIENT="ospfclient"
1207     fi
1208   fi
1209
1210 fi
1211
1212 case "${enable_ripngd}" in
1213   "yes") RIPNGD="ripngd";;
1214   "no" ) RIPNGD="";;
1215   *    ) ;;
1216 esac
1217
1218 case "${enable_ospf6d}" in
1219   "yes") OSPF6D="ospf6d";;
1220   "no" ) OSPF6D="";;
1221   *    ) ;;
1222 esac
1223
1224 case "${enable_isisd}" in
1225   "yes") ISISD="isisd";;
1226   "no" ) ISISD="";;
1227   *    ) ;;
1228 esac
1229
1230 # XXX Perhaps auto-enable on Solaris, but that's messy for cross builds.
1231 case "${enable_solaris}" in
1232   "yes") SOLARIS="solaris";;
1233   "no" ) SOLARIS="";;
1234   *    ) ;;
1235 esac
1236
1237 if test "${enable_bgp_announce}" = "no";then
1238   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1239 else
1240   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1241 fi
1242
1243 AC_SUBST(DOC)
1244 AC_SUBST(ZEBRA)
1245 AC_SUBST(BGPD)
1246 AC_SUBST(RIPD)
1247 AC_SUBST(RIPNGD)
1248 AC_SUBST(OSPFD)
1249 AC_SUBST(OSPF6D)
1250 AC_SUBST(WATCHQUAGGA)
1251 AC_SUBST(ISISD)
1252 AC_SUBST(SOLARIS)
1253 AC_SUBST(VTYSH)
1254 AC_SUBST(INCLUDES)
1255 AC_SUBST(CURSES)
1256 AC_SUBST(OSPFCLIENT)
1257 AC_SUBST(OSPFAPI)
1258 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
1259 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
1260 AC_CHECK_LIB(crypt, crypt)
1261 AC_CHECK_LIB(resolv, res_init)
1262
1263 dnl ---------------------------------------------------
1264 dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
1265 dnl ---------------------------------------------------
1266 AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP,,__inet_ntop))
1267 AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON,,__inet_pton))
1268 AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON,,__inet_aton))
1269
1270 dnl ---------------------------
1271 dnl check system has PCRE regexp
1272 dnl ---------------------------
1273 if test "x$enable_pcreposix" = "xyes"; then
1274   AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
1275   AC_MSG_WARN([*** falling back to other regex library ***]) ])
1276 fi
1277
1278 if test "x$enable_pcreposix" != "xyes"; then
1279 dnl ---------------------------
1280 dnl check system has GNU regexp
1281 dnl ---------------------------
1282 AC_MSG_CHECKING(whether system has GNU regex)
1283 AC_CHECK_LIB(c, regexec,
1284 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
1285  LIB_REGEX=""],
1286 [LIB_REGEX="regex.o"])
1287 fi
1288 AC_SUBST(HAVE_LIBPCREPOSIX)
1289 AC_SUBST(LIB_REGEX)
1290
1291 dnl ------------------
1292 dnl check Net-SNMP library
1293 dnl ------------------
1294 if test "${enable_snmp}" = "yes"; then
1295     if test "$with_crypto" != "no"; then
1296         LIBS="${LIBS} -lcrypto";
1297     fi
1298     AC_CHECK_LIB(netsnmp, asn_parse_int,
1299         [AC_DEFINE(HAVE_NETSNMP,,Net SNMP)
1300          AC_DEFINE(HAVE_SNMP,,SNMP)
1301          LIBS="${LIBS} -lnetsnmp"],
1302         [AC_MSG_ERROR([--enable-snmp given, but cannot find support for SNMP])])
1303
1304     AC_CHECK_HEADER([net-snmp/net-snmp-config.h],
1305         [],
1306         [AC_MSG_ERROR([--enable-snmp given, but cannot find net-snmp-config.h])],
1307         QUAGGA_INCLUDES)
1308     AC_SUBST(SNMP_INCLUDES)
1309 fi
1310
1311 dnl ---------------------------
1312 dnl sockaddr and netinet checks
1313 dnl ---------------------------
1314 AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
1315         struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
1316         socklen_t,
1317         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1318         struct nd_opt_adv_interval, struct rt_addrinfo,
1319         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1320         [], [], QUAGGA_INCLUDES)
1321
1322 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1323         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1324         struct sockaddr_in6.sin6_scope_id,
1325         struct if6_aliasreq.ifra_lifetime,
1326         struct nd_opt_adv_interval.nd_opt_ai_type],
1327         [], [], QUAGGA_INCLUDES)
1328
1329 dnl ---------------------------
1330 dnl IRDP/pktinfo/icmphdr checks
1331 dnl ---------------------------
1332 AC_CHECK_TYPES([struct in_pktinfo],
1333  [AC_CHECK_TYPES([struct icmphdr],
1334    [if test "${enable_irdp}" != "no"; then
1335       AC_DEFINE(HAVE_IRDP,, IRDP)
1336     fi],
1337    [if test "${enable_irdp}" = "yes"; then
1338       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1339     fi], [QUAGGA_INCLUDES])],
1340  [if test "${enable_irdp}" = "yes"; then
1341     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1342   fi], [QUAGGA_INCLUDES])
1343
1344 dnl --------------------------------------
1345 dnl checking for getrusage struct and call
1346 dnl --------------------------------------
1347 AC_MSG_CHECKING(whether getrusage is available)
1348 AC_TRY_COMPILE([#include <sys/resource.h>
1349 ],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
1350 [AC_MSG_RESULT(yes)
1351  AC_DEFINE(HAVE_RUSAGE,,rusage)],
1352  AC_MSG_RESULT(no))
1353
1354 dnl --------------------------------------
1355 dnl checking for clock_time monotonic struct and call
1356 dnl --------------------------------------
1357 AC_CHECK_DECL(CLOCK_MONOTONIC,
1358         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1359          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1360 ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
1361
1362 dnl -------------------
1363 dnl capabilities checks
1364 dnl -------------------
1365 if test "${enable_capabilities}" != "no"; then
1366   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1367   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1368     [AC_MSG_RESULT(yes)
1369      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1370      quagga_ac_keepcaps="yes"],
1371      AC_MSG_RESULT(no)
1372   )
1373   if test x"${quagga_ac_keepcaps}" = x"yes"; then
1374     AC_CHECK_HEADERS(sys/capability.h)
1375   fi
1376   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1377     AC_CHECK_LIB(cap, cap_init,
1378       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1379        LIBCAP="-lcap"
1380        quagga_ac_lcaps="yes"]
1381     )
1382   else
1383     AC_CHECK_HEADERS(priv.h,
1384      [AC_MSG_CHECKING(Solaris style privileges are available)
1385       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1386           [AC_MSG_RESULT(yes)
1387            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1388            quagga_ac_scaps="yes"],
1389            AC_MSG_RESULT(no)
1390       )
1391      ]
1392    )
1393   fi
1394   if test x"${quagga_ac_scaps}" = x"yes" \
1395        -o x"${quagga_ac_lcaps}" = x"yes"; then
1396     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1397   fi
1398 fi
1399 AC_SUBST(LIBCAP)
1400
1401 dnl ---------------------------
1402 dnl check for glibc 'backtrace'
1403 dnl ---------------------------
1404 if test "${glibc}" = "yes"; then
1405    AC_CHECK_HEADER([execinfo.h],
1406     [AC_CHECK_FUNC([backtrace],
1407         [AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1408          AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1409         ])
1410     ])
1411 fi
1412
1413 dnl -----------------------------------------
1414 dnl check for malloc mallinfo struct and call
1415 dnl this must try and link using LIBS, in
1416 dnl order to check no alternative allocator
1417 dnl has been specified, which might not provide
1418 dnl mallinfo, e.g. such as Umem on Solaris.
1419 dnl -----------------------------------------
1420 AC_CHECK_HEADER([malloc.h],
1421  [AC_MSG_CHECKING(whether mallinfo is available)
1422   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1423                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1424       [AC_MSG_RESULT(yes)
1425        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1426        AC_MSG_RESULT(no)
1427   )
1428  ], [], QUAGGA_INCLUDES)
1429
1430 dnl ----------
1431 dnl configure date
1432 dnl ----------
1433 CONFDATE=`date '+%Y%m%d'`
1434 AC_SUBST(CONFDATE)
1435
1436 dnl Conditionally enable PIE support for GNU toolchains.
1437 AC_ARG_ENABLE(pie, AS_HELP_STRING([--disable-pie], [Do not build tools as a Position Independent Executables]))
1438 if test "$enable_pie" != "no"; then
1439   AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
1440     save_CFLAGS=$CFLAGS
1441     save_LDFLAGS=$LDFLAGS
1442     CFLAGS="$CFLAGS -fPIE"
1443     LDFLAGS="$LDFLAGS -pie"
1444     AC_LINK_IFELSE([AC_LANG_SOURCE([[static int foo[30000]; int main () { return 0; }]])],
1445       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no]
1446     )
1447     CFLAGS=$save_CFLAGS
1448     LDFLAGS=$save_LDFLAGS
1449   ])
1450   if test "$ap_cv_cc_pie" = "yes"; then
1451     PICFLAGS="-fPIE"
1452     PILDFLAGS="-pie"
1453   fi
1454 fi
1455
1456 AC_SUBST(PICFLAGS)
1457 AC_SUBST(PILDFLAGS)
1458
1459 dnl ------------------------------
1460 dnl set paths for state directory
1461 dnl ------------------------------
1462 AC_MSG_CHECKING(directory to use for state file)
1463 if test "${prefix}" = "NONE"; then
1464   quagga_statedir_prefix="";
1465 else
1466   quagga_statedir_prefix=${prefix}
1467 fi
1468 if test "${localstatedir}" = '${prefix}/var'; then
1469   for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
1470                         ${quagga_statedir_prefix}/var/adm dnl
1471                         ${quagga_statedir_prefix}/etc dnl
1472                         /var/run        dnl
1473                         /var/adm        dnl
1474                         /etc            dnl
1475                         /dev/null;
1476   do
1477     test -d $QUAGGA_STATE_DIR && break
1478   done
1479   quagga_statedir=$QUAGGA_STATE_DIR
1480 else
1481   quagga_statedir=${localstatedir}
1482 fi
1483 if test $quagga_statedir = "/dev/null"; then
1484     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1485 fi
1486 AC_MSG_RESULT(${quagga_statedir})
1487 AC_SUBST(quagga_statedir)
1488
1489 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
1490 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
1491 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
1492 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
1493 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
1494 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
1495 AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
1496 AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
1497 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
1498 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
1499 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
1500 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
1501 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
1502 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
1503 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
1504 AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
1505 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
1506
1507 dnl -------------------------------
1508 dnl Quagga sources should always be
1509 dnl current wrt interfaces. Dont
1510 dnl allow deprecated interfaces to
1511 dnl be exposed.
1512 dnl -------------------------------
1513 AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
1514
1515 dnl ---------------------------
1516 dnl Check htonl works correctly
1517 dnl ---------------------------
1518 AC_MSG_CHECKING(for working htonl)
1519 AC_CACHE_VAL(ac_cv_htonl_works,
1520  [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
1521                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1522  ]
1523 )
1524 AC_MSG_RESULT($ac_cv_htonl_works)
1525
1526 AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
1527           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
1528           ospf6d/Makefile isisd/Makefile vtysh/Makefile doc/Makefile
1529           ospfclient/Makefile tests/Makefile m4/Makefile redhat/Makefile
1530           pkgsrc/Makefile
1531           redhat/quagga.spec
1532           lib/version.h
1533           doc/defines.texi
1534           isisd/topology/Makefile
1535           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1536           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
1537 AC_CONFIG_FILES([solaris/Makefile])
1538
1539 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1540 ## Hack, but working solution to avoid rebuilding of quagga.info.
1541 ## It's already in CVS until texinfo 4.7 is more common.
1542 AC_OUTPUT
1543
1544 echo "
1545 Quagga configuration
1546 --------------------
1547 quagga version          : ${PACKAGE_VERSION}
1548 host operating system  : ${host_os}
1549 source code location    : ${srcdir}
1550 compiler                : ${CC}
1551 compiler flags          : ${CFLAGS}
1552 make                    : ${MAKE-make}
1553 includes                : ${INCLUDES} ${SNMP_INCLUDES}
1554 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1555 state file directory    : ${quagga_statedir}
1556 config file directory   : `eval echo \`echo ${sysconfdir}\``
1557 example directory       : `eval echo \`echo ${exampledir}\``
1558 user to run as          : ${enable_user}
1559 group to run as         : ${enable_group}
1560 group for vty sockets   : ${enable_vty_group}
1561 config file mask        : ${enable_configfile_mask}
1562 log file mask           : ${enable_logfile_mask}
1563
1564 The above user and group must have read/write access to the state file
1565 directory and to the config files in the config file directory."
1566
1567 if test x"$quagga_cv_gnu_make" = x"no"; then echo "
1568 Warning: The ${MAKE-make} programme detected, either in your path or
1569 via the MAKE variable, is not GNU Make. GNU make may be installed as
1570 gmake on some systems. and is required to complete a build of Quagga
1571 " > /dev/stderr
1572 fi