configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.6-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 143         vici_socket="$withval"
 144 ], [
 145         vici_socket="/var/run/charon.vici"
 146 ])
 147 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 148
 149 AC_ARG_ENABLE(tcmalloc,
 150         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 151 [case "${enableval}" in
 152   yes) tcmalloc_enabled=true
 153 LIBS="$LIBS -ltcmalloc_minimal"
 154  ;;
 155   no)  tcmalloc_enabled=false ;;
 156   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 157 esac],[tcmalloc_enabled=false])
 158
 159
 160 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 161 dnl flag determination logic.
 162 CFLAGS="${CFLAGS:-}"
 163
 164 dnl --------------------
 165 dnl Check CC and friends
 166 dnl --------------------
 167 dnl note orig_cflags is also used further down
 168 orig_cflags="$CFLAGS"
 169 orig_cxxflags="$CXXFLAGS"
 170 AC_LANG([C])
 171 AC_PROG_CC
 172 AC_PROG_CPP
 173 AC_PROG_CXX
 174 AM_PROG_CC_C_O
 175 dnl remove autoconf default "-g -O2"
 176 CFLAGS="$orig_cflags"
 177 CXXFLAGS="$orig_cxxflags"
 178 AC_PROG_CC_C99
 179 dnl NB: see C11 below
 180
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl it's 2019, sed is sed.
 184 SED=sed
 185 AC_SUBST([SED])
 186
 187 dnl try and enable CFLAGS that are useful for FRR
 188 dnl - specifically, options to control warnings
 189
 190 AC_USE_SYSTEM_EXTENSIONS
 191 AC_DEFUN([AC_C_FLAG], [{
 192     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 193     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 194         AC_LANG_PUSH([C])
 195         ac_c_flag_save="$CFLAGS"
 196         CFLAGS="$CFLAGS $1"
 197         AC_COMPILE_IFELSE(
 198                 [AC_LANG_PROGRAM([[$4]])],
 199                 [
 200                         cachename=yes
 201                 ], [
 202                         cachename=no
 203                 ])
 204         CFLAGS="$ac_c_flag_save"
 205         AC_LANG_POP([C])
 206     ])
 207     if test "$cachename" = "yes"; then
 208         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 209     else
 210         :
 211         $2
 212     fi
 213     m4_popdef([cachename])
 214 }])
 215
 216 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 217         AC_LANG_PUSH([C])
 218         ac_cflags_save="$CFLAGS"
 219         ac_libs_save="$LIBS"
 220         CFLAGS="$CFLAGS $1"
 221         LIBS="$LIBS $2"
 222         AC_LINK_IFELSE(
 223                 [$3],
 224                 [
 225                         CFLAGS="$ac_cflags_save"
 226                         LIBS="$ac_libs_save"
 227                         m4_default([$5], [
 228                                 AC_MSG_RESULT([yes])
 229                         ])
 230                 ], [
 231                         CFLAGS="$ac_cflags_save"
 232                         LIBS="$ac_libs_save"
 233                         m4_default([$4], [
 234                                 AC_MSG_RESULT([no])
 235                         ])
 236                 ])
 237         AC_LANG_POP([C])
 238         }])
 239
 240 dnl ICC won't bail on unknown options without -diag-error 10006
 241 dnl need to do this first so we get useful results for the other options
 242 AC_C_FLAG([-diag-error 10006])
 243
 244 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 245 ac_cc="$CC"
 246 CC="${CC% -std=gnu99}"
 247 CC="${CC% -std=c99}"
 248
 249 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 250
 251 dnl if the user has specified any CFLAGS, override our settings
 252 if test "$enable_gcov" = "yes"; then
 253    if test "$orig_cflags" = ""; then
 254       AC_C_FLAG([-coverage])
 255       AC_C_FLAG([-O0])
 256    fi
 257
 258    LDFLAGS="${LDFLAGS} -lgcov"
 259 fi
 260
 261 if test "$enable_clang_coverage" = "yes"; then
 262    AC_C_FLAG([-fprofile-instr-generate], [
 263      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 264    ])
 265    AC_C_FLAG([-fcoverage-mapping], [
 266      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 267    ])
 268 fi
 269
 270 if test "$enable_dev_build" = "yes"; then
 271    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 272    if test "$orig_cflags" = ""; then
 273       AC_C_FLAG([-g3])
 274       AC_C_FLAG([-O0])
 275    fi
 276    if test "$enable_lua" = "yes"; then
 277       AX_PROG_LUA([5.3])
 278       AX_LUA_HEADERS
 279       AX_LUA_LIBS([
 280          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 281          LIBS="$LIBS $LUA_LIB"
 282       ])
 283    fi
 284 else
 285    if test "$enable_lua" = "yes"; then
 286       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 287    fi
 288    if test "$orig_cflags" = ""; then
 289       AC_C_FLAG([-g])
 290       AC_C_FLAG([-O2])
 291    fi
 292 fi
 293 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 294
 295 dnl always want these CFLAGS
 296 AC_C_FLAG([-fno-omit-frame-pointer])
 297 AC_C_FLAG([-funwind-tables])
 298 AC_C_FLAG([-Wall])
 299 AC_C_FLAG([-Wextra])
 300 AC_C_FLAG([-Wmissing-prototypes])
 301 AC_C_FLAG([-Wmissing-declarations])
 302 AC_C_FLAG([-Wpointer-arith])
 303 AC_C_FLAG([-Wbad-function-cast])
 304 AC_C_FLAG([-Wwrite-strings])
 305 AC_C_FLAG([-Wundef])
 306 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 307   AC_C_FLAG([-Wcast-qual])
 308   AC_C_FLAG([-Wstrict-prototypes])
 309   AC_C_FLAG([-Wmissing-noreturn])
 310   AC_C_FLAG([-Wmissing-format-attribute])
 311   AC_C_FLAG([-Wunreachable-code])
 312   AC_C_FLAG([-Wpacked])
 313   AC_C_FLAG([-Wpadded])
 314   AC_C_FLAG([-Wshadow])
 315 else
 316   AC_C_FLAG([-Wno-unused-result])
 317 fi
 318 AC_C_FLAG([-Wno-unused-parameter])
 319 AC_C_FLAG([-Wno-missing-field-initializers])
 320
 321 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 322 AC_SUBST([CXX_COMPAT_CFLAGS])
 323
 324 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 325 dnl for some reason the string consts get 'promoted' to char *,
 326 dnl triggering a const to non-const conversion warning.
 327 AC_C_FLAG([-diag-disable 3179])
 328
 329 if test "$enable_werror" = "yes" ; then
 330   WERROR="-Werror"
 331 fi
 332 AC_SUBST([WERROR])
 333
 334 SAN_FLAGS=""
 335 if test "$enable_address_sanitizer" = "yes"; then
 336   AC_C_FLAG([-fsanitize=address], [
 337     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 338   ], [
 339     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 340   ])
 341 fi
 342 if test "$enable_thread_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=thread], [
 344     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 347   ])
 348 fi
 349 if test "$enable_memory_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 351     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 354   ])
 355 fi
 356 if test "$enable_undefined_sanitizer" = "yes"; then
 357   AC_C_FLAG([-fsanitize=undefined], [
 358     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 359   ], [
 360     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 361   ])
 362 fi
 363 AC_SUBST([SAN_FLAGS])
 364
 365 dnl frr-format.so
 366 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 367   AC_C_FLAG([-fplugin=${with_frr_format}], [
 368     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 369   ],,[
 370 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 371 #error plugin not loaded
 372 #endif
 373 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 374 #error plugin too old
 375 #endif
 376   ])
 377 elif test "$with_frr_format" = "no"; then
 378   : #nothing
 379 else
 380   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 381     AC_C_FLAG([-fplugin=frr-format],[
 382       if test "$with_frr_format" = "yes"; then
 383         AC_MSG_ERROR([frr-format plugin requested but not found])
 384       fi
 385     ],,[
 386 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 387 #error plugin not loaded
 388 #endif
 389 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 390 #error plugin too old
 391 #endif
 392     ])
 393   ],,[
 394 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 395 #error plugin not loaded
 396 #endif
 397 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 398 #error plugin too old
 399 #endif
 400   ])
 401 fi
 402
 403 dnl ----------
 404 dnl Essentials
 405 dnl ----------
 406
 407 AX_PTHREAD([
 408   CC="$PTHREAD_CC"
 409   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 410   LIBS="$PTHREAD_LIBS $LIBS"
 411 ], [
 412   AC_MSG_FAILURE([This FRR version needs pthreads])
 413 ])
 414
 415 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 416                 [frr_cv_pthread_condattr_setclock=yes],
 417                 [frr_cv_pthread_condattr_setclock=no])
 418 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 419   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 420 fi
 421
 422 dnl --------------
 423 dnl Check programs
 424 dnl --------------
 425 AC_PROG_INSTALL
 426 AC_PROG_LN_S
 427 AC_CHECK_TOOL([AR], [ar])
 428
 429 dnl -------
 430 dnl libtool
 431 dnl -------
 432 AC_ARG_ENABLE([static-bin],
 433   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 434 LT_INIT
 435 _LT_CONFIG_LIBTOOL([
 436   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 437     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 438   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 439   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 440   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 441 ])
 442 if test "$enable_static_bin" = "yes"; then
 443   AC_LDFLAGS="-static"
 444   if test "$enable_static" != "yes"; then
 445     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 446   fi
 447 fi
 448 if test "$enable_shared" != "yes"; then
 449   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 450 fi
 451 AC_SUBST([AC_LDFLAGS])
 452 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 453
 454 dnl $AR and $RANLIB are set by LT_INIT above
 455 AC_MSG_CHECKING([whether $AR supports D option])
 456 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 457   AC_MSG_RESULT([yes])
 458   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 459   ARFLAGS="crD"
 460   AR_FLAGS="crD"
 461 else
 462   AC_MSG_RESULT([no])
 463   ARFLAGS="cru"
 464   AR_FLAGS="cru"
 465 fi
 466 AC_SUBST([ARFLAGS])
 467 AC_SUBST([AR_FLAGS])
 468
 469 AC_MSG_CHECKING([whether $RANLIB supports D option])
 470 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 471   if grep -q -- '-D' conftest.err; then
 472     AC_MSG_RESULT([no])
 473   else
 474     AC_MSG_RESULT([yes])
 475     RANLIB="$RANLIB -D"
 476   fi
 477 else
 478   AC_MSG_RESULT([no])
 479 fi
 480 AC_SUBST([RANLIB])
 481
 482 test -f conftest.err && rm conftest.err
 483 test -f conftest.a && rm conftest.a
 484
 485 dnl ----------------------
 486 dnl Packages configuration
 487 dnl ----------------------
 488 if test -f config.version; then
 489   . ./config.version
 490 elif test -f "${srcdir}/config.version"; then
 491   . "${srcdir}/config.version"
 492 fi
 493 AC_ARG_WITH([pkg-extra-version],
 494   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 495   if test "$withval" = "no"; then
 496     EXTRAVERSION=
 497   else
 498     EXTRAVERSION=$withval
 499   fi
 500 ], [])
 501 AC_ARG_WITH([pkg-git-version],
 502         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 503         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 504 AC_ARG_WITH([clippy],
 505   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 506 AC_ARG_WITH([vtysh_pager],
 507         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 508         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 509 AC_ARG_ENABLE([vtysh],
 510   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 511 AC_ARG_ENABLE([doc],
 512   AS_HELP_STRING([--disable-doc], [do not build docs]))
 513 AC_ARG_ENABLE([doc-html],
 514   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 515 AC_ARG_ENABLE([zebra],
 516   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 517 AC_ARG_ENABLE([bgpd],
 518   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 519 AC_ARG_ENABLE([ripd],
 520   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 521 AC_ARG_ENABLE([ripngd],
 522   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 523 AC_ARG_ENABLE([ospfd],
 524   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 525 AC_ARG_ENABLE([ospf6d],
 526   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 527 AC_ARG_ENABLE([ldpd],
 528   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 529 AC_ARG_ENABLE([nhrpd],
 530   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 531 AC_ARG_ENABLE([eigrpd],
 532   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 533 AC_ARG_ENABLE([babeld],
 534   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 535 AC_ARG_ENABLE([watchfrr],
 536   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 537 AC_ARG_ENABLE([isisd],
 538   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 539 AC_ARG_ENABLE([pimd],
 540   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 541 AC_ARG_ENABLE([pbrd],
 542   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 543 AC_ARG_ENABLE([sharpd],
 544   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 545 AC_ARG_ENABLE([staticd],
 546   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 547 AC_ARG_ENABLE([fabricd],
 548   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 549 AC_ARG_ENABLE([vrrpd],
 550   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 551 AC_ARG_ENABLE([bgp-announce],
 552   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 553 AC_ARG_ENABLE([bgp-vnc],
 554   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 555 AC_ARG_ENABLE([bgp-bmp],
 556   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 557 AC_ARG_ENABLE([snmp],
 558   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 559 AC_ARG_ENABLE([config_rollbacks],
 560   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 561 AC_ARG_ENABLE([confd],
 562   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 563 AC_ARG_ENABLE([sysrepo],
 564   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 565 AC_ARG_ENABLE([grpc],
 566   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 567 AC_ARG_ENABLE([zeromq],
 568   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 569 AC_ARG_WITH([libpam],
 570   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 571 AC_ARG_ENABLE([ospfapi],
 572   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 573 AC_ARG_ENABLE([ospfclient],
 574   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 575                           (this is the default if --disable-ospfapi is set)]))
 576 AC_ARG_ENABLE([multipath],
 577   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 578 AC_ARG_ENABLE([user],
 579   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 580 AC_ARG_ENABLE([group],
 581   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 582 AC_ARG_ENABLE([vty_group],
 583   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 584 AC_ARG_ENABLE([configfile_mask],
 585   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 586 AC_ARG_ENABLE([logfile_mask],
 587   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 588 AC_ARG_ENABLE([shell_access],
 589   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 590 AC_ARG_ENABLE([realms],
 591   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 592 AC_ARG_ENABLE([rtadv],
 593   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 594 AC_ARG_ENABLE([irdp],
 595   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 596 AC_ARG_ENABLE([capabilities],
 597   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 598 AC_ARG_ENABLE([rusage],
 599   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 600 AC_ARG_ENABLE([gcc_ultra_verbose],
 601   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 602 AC_ARG_ENABLE([backtrace],
 603   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 604 AC_ARG_ENABLE([time-check],
 605   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 606 AC_ARG_ENABLE([cpu-time],
 607   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 608 AC_ARG_ENABLE([pcreposix],
 609   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 610 AC_ARG_ENABLE([fpm],
 611   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 612 AC_ARG_ENABLE([systemd],
 613   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 614 AC_ARG_ENABLE([werror],
 615   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 616 AC_ARG_ENABLE([cumulus],
 617   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 618 AC_ARG_ENABLE([datacenter],
 619   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 620 AC_ARG_ENABLE([rr-semantics],
 621   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 622 AC_ARG_ENABLE([protobuf],
 623   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 624 AC_ARG_ENABLE([oldvpn_commands],
 625   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 626 AC_ARG_ENABLE([rpki],
 627   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 628 AC_ARG_ENABLE([clippy-only],
 629   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 630 AC_ARG_ENABLE([numeric_version],
 631   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 632 AC_ARG_ENABLE([gcov],
 633   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 634 AC_ARG_ENABLE([clang_coverage],
 635   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 636 AC_ARG_ENABLE([bfdd],
 637   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 638 AC_ARG_ENABLE([address-sanitizer],
 639   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 640 AC_ARG_ENABLE([thread-sanitizer],
 641   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 642 AC_ARG_ENABLE([memory-sanitizer],
 643   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 644 AC_ARG_ENABLE([undefined-sanitizer],
 645   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 646 AC_ARG_WITH([crypto],
 647   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 648 AC_ARG_WITH([frr-format],
 649   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 650
 651 AC_ARG_ENABLE([version-build-config],
 652   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 653
 654 #if openssl, else use the internal
 655 AS_IF([test "$with_crypto" = "openssl"], [
 656 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 657 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 658   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 659 else
 660   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 661 fi
 662 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 663 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 664 )
 665
 666 AS_IF([test "$enable_clippy_only" != "yes"], [
 667 AC_CHECK_HEADERS([json-c/json.h])
 668 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 669 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 670   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 671   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 672       AC_MSG_ERROR([libjson is needed to compile])
 673   fi
 674 fi
 675 ])
 676
 677 AC_ARG_ENABLE([dev_build],
 678     AS_HELP_STRING([--enable-dev-build], [build for development]))
 679
 680 AC_ARG_ENABLE([lua],
 681     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 682
 683 if test "$enable_time_check" != "no" ; then
 684   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 685     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 686   else
 687     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 688   fi
 689 fi
 690
 691 case "${enable_cpu_time}" in
 692   "no")
 693   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 694   ;;
 695   "*")
 696   ;;
 697 esac
 698
 699 case "${enable_systemd}" in
 700   "no") ;;
 701   "yes")
 702   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 703   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 704     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 705   else
 706     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 707   fi
 708   ;;
 709   "*") ;;
 710 esac
 711
 712 if test "$enable_rr_semantics" != "no" ; then
 713   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 714 fi
 715
 716 if test "$enable_datacenter" = "yes" ; then
 717   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 718   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 719   DFLT_NAME="datacenter"
 720 else
 721   DFLT_NAME="traditional"
 722 fi
 723
 724 if test "$enable_cumulus" = "yes" ; then
 725   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 726 fi
 727
 728 AC_SUBST([DFLT_NAME])
 729 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 730
 731 if test "$enable_shell_access" = "yes"; then
 732    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 733 fi
 734
 735 #
 736 # Python for clippy
 737 #
 738
 739 AS_IF([test "$host" = "$build"], [
 740   FRR_PYTHON_DEV
 741 ], [
 742   FRR_PYTHON
 743 ])
 744
 745 FRR_PYTHON_MODULES([pytest])
 746
 747 if test "$enable_doc" != "no"; then
 748   FRR_PYTHON_MODULES([sphinx], , [
 749     if test "$enable_doc" = "yes"; then
 750       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 751     fi
 752   ])
 753 fi
 754 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 755 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 756
 757 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 758   PYSPHINX="-m sphinx"
 759 ], [
 760   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 761 ])
 762 AC_SUBST([PYSPHINX])
 763
 764 #
 765 # Logic for old vpn commands support.
 766 #
 767 if test "$enable_oldvpn_commands" = "yes"; then
 768    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 769 fi
 770
 771 #
 772 # End of logic for protobuf support.
 773 #
 774
 775 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 776 if test "$enable_rtadv" != "no"; then
 777   AC_MSG_RESULT([yes])
 778   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 779 else
 780   AC_MSG_RESULT([no])
 781 fi
 782
 783 if test "$enable_user" = "no"; then
 784   enable_user=""
 785 else
 786   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 787     enable_user="frr"
 788   fi
 789   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 790 fi
 791
 792 if test "$enable_group" = "no"; then
 793   enable_group=""
 794 else
 795   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 796     enable_group="frr"
 797   fi
 798   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 799 fi
 800
 801 if test "$enable_vty_group" = "yes" ; then
 802   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 803 elif test "$enable_vty_group" != ""; then
 804   if test "$enable_vty_group" != "no"; then
 805     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 806   fi
 807 fi
 808 AC_SUBST([enable_user])
 809 AC_SUBST([enable_group])
 810 AC_SUBST([enable_vty_group])
 811
 812 enable_configfile_mask=${enable_configfile_mask:-0600}
 813 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 814 AC_SUBST([enable_configfile_mask])
 815
 816 enable_logfile_mask=${enable_logfile_mask:-0600}
 817 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 818
 819 MPATH_NUM=16
 820
 821 case "${enable_multipath}" in
 822   0)
 823     MPATH_NUM=64
 824     ;;
 825   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 826     MPATH_NUM="${enable_multipath}"
 827     ;;
 828   "")
 829     ;;
 830   *)
 831     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 832     ;;
 833 esac
 834
 835 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 836
 837 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 838
 839 dnl --------------------
 840 dnl Enable code coverage
 841 dnl --------------------
 842 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 843
 844 dnl ------------------------------------
 845 dnl Alpine only accepts numeric versions
 846 dnl ------------------------------------
 847 if test "$enable_numeric_version" != "" ; then
 848   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 849   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 850 fi
 851
 852 dnl -----------------------------------
 853 dnl Add extra version string to package
 854 dnl name, string and version fields.
 855 dnl -----------------------------------
 856 if test "$EXTRAVERSION" != "" ; then
 857   VERSION="${VERSION}${EXTRAVERSION}"
 858   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 859   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 860   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 861 fi
 862 AC_SUBST([EXTRAVERSION])
 863
 864 if test "$with_pkg_git_version" = "yes"; then
 865         if test -e "${srcdir}/.git"; then
 866                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 867         else    with_pkg_git_version="no"
 868                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 869         fi
 870 fi
 871 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 872
 873 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 874 if test "$OBJCOPY" != ":"; then
 875   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 876     frr_cv_interp=""
 877     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 878       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 879         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 880       fi
 881       test -f conftest.interp && rm conftest.interp
 882     ])
 883   ])
 884 fi
 885 if test -n "$frr_cv_interp"; then
 886   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 887 fi
 888
 889 dnl -------------------------
 890 dnl Check other header files.
 891 dnl -------------------------
 892 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 893         linux/version.h asm/types.h])
 894
 895 ac_stdatomic_ok=false
 896 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 897 AC_CHECK_HEADER([stdatomic.h],[
 898
 899   AC_MSG_CHECKING([whether _Atomic qualifier works])
 900   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 901 #include <stdatomic.h>
 902 int main(int argc, char **argv) {
 903   _Atomic int i = 0;
 904   return i;
 905 }
 906 ]])], [
 907     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 908     AC_MSG_RESULT([yes])
 909     ac_stdatomic_ok=true
 910   ], [
 911     AC_MSG_RESULT([no])
 912   ])
 913 ])
 914
 915 AS_IF([$ac_stdatomic_ok], [true], [
 916   AC_MSG_CHECKING([for __atomic_* builtins])
 917   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 918 int main(int argc, char **argv) {
 919   volatile int i = 1;
 920   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 921   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 922 }
 923 ]])], [
 924     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 925     AC_MSG_RESULT([yes])
 926   ], [
 927     AC_MSG_RESULT([no])
 928
 929     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 930     AC_MSG_CHECKING([for __sync_* builtins])
 931     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 932 int main(int argc, char **argv) {
 933   volatile int i = 1;
 934   __sync_fetch_and_sub (&i, 1);
 935   return __sync_val_compare_and_swap (&i, 0, 1);
 936 }
 937 ]])], [
 938       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 939       AC_MSG_RESULT([yes])
 940
 941       AC_MSG_CHECKING([for __sync_swap builtin])
 942       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 943 int main(int argc, char **argv) {
 944   volatile int i = 1;
 945   return __sync_swap (&i, 2);
 946 }
 947 ]])], [
 948         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 949         AC_MSG_RESULT([yes])
 950       ], [
 951         AC_MSG_RESULT([no])
 952       ])
 953
 954     ], [
 955       AC_MSG_RESULT([no])
 956       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 957     ])
 958   ])
 959 ])
 960
 961 AC_CHECK_HEADERS([pthread_np.h],,, [
 962 #include <pthread.h>
 963 ])
 964 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 965
 966 needsync=true
 967
 968 AS_IF([$needsync], [
 969   dnl Linux
 970   AC_MSG_CHECKING([for Linux futex() support])
 971   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 972 #ifndef _GNU_SOURCE
 973 #define _GNU_SOURCE
 974 #endif
 975 #include <unistd.h>
 976 #include <limits.h>
 977 #include <sys/time.h>
 978 #include <sys/syscall.h>
 979 #include <linux/futex.h>
 980
 981 int main(void);
 982 ],
 983 [
 984 {
 985   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 986 }
 987 ])], [
 988     AC_MSG_RESULT([yes])
 989     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 990     needsync=false
 991   ], [
 992     AC_MSG_RESULT([no])
 993   ])
 994 ])
 995
 996 AS_IF([$needsync], [
 997   dnl FreeBSD
 998   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 999   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1000 #include <errno.h>
1001 #include <stdlib.h>
1002 #include <sys/types.h>
1003 #include <sys/umtx.h>
1004 int main(void);
1005 ],
1006 [
1007 {
1008   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1009 }
1010 ])], [
1011     AC_MSG_RESULT([yes])
1012     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1013     needsync=false
1014   ], [
1015     AC_MSG_RESULT([no])
1016   ])
1017 ])
1018
1019 AS_IF([$needsync], [
1020   dnl OpenBSD patch (not upstream at the time of writing this)
1021   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1022   AC_MSG_CHECKING([for OpenBSD futex() support])
1023   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1024 #include <sys/futex.h>
1025 int main(void);
1026 ],
1027 [
1028 {
1029   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1030 }
1031 ])], [
1032     AC_MSG_RESULT([yes])
1033     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1034     needsync=false
1035   ], [
1036     AC_MSG_RESULT([no])
1037   ])
1038 ])
1039
1040 dnl Utility macro to avoid retyping includes all the time
1041 m4_define([FRR_INCLUDES],
1042 [#ifdef SUNOS_5
1043 #define _POSIX_C_SOURCE 200809L
1044 #define __EXTENSIONS__
1045 #endif
1046 #include <stdio.h>
1047 #include <stdlib.h>
1048 #include <stddef.h>
1049 #include <sys/types.h>
1050 /* sys/conf.h depends on param.h on FBSD at least */
1051 #include <sys/param.h>
1052 /* Required for MAXSIG */
1053 #include <signal.h>
1054 #include <sys/socket.h>
1055 #ifdef __APPLE__
1056 # define __APPLE_USE_RFC_3542
1057 #endif
1058 #include <netinet/in.h>
1059 #include <sys/time.h>
1060 #include <time.h>
1061 #include <net/if.h>
1062 ])dnl
1063
1064 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1065 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1066 dnl an additional round for it.
1067
1068 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1069
1070 m4_define([FRR_INCLUDES],
1071 FRR_INCLUDES
1072 [#ifdef HAVE_NET_IF_VAR_H
1073 # include <net/if_var.h>
1074 #endif
1075 ])dnl
1076
1077 AC_CHECK_HEADERS([netinet/in_var.h \
1078         net/if_dl.h net/netopt.h \
1079         inet/nd.h netinet/ip_icmp.h \
1080         sys/sysctl.h sys/sockio.h sys/conf.h],
1081         [], [], [FRR_INCLUDES])
1082
1083 AC_CHECK_HEADERS([ucontext.h], [], [],
1084 [#ifndef __USE_GNU
1085 #define __USE_GNU
1086 #endif /* __USE_GNU */
1087 FRR_INCLUDES
1088 ])
1089
1090 m4_define([UCONTEXT_INCLUDES],
1091 [#include <ucontext.h>])dnl
1092
1093 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1094   [], [], [UCONTEXT_INCLUDES])
1095 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1096   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1097    [], [], [UCONTEXT_INCLUDES])],
1098   [], [UCONTEXT_INCLUDES])
1099 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1100   [], [], [UCONTEXT_INCLUDES])
1101
1102 m4_define([FRR_INCLUDES],
1103 FRR_INCLUDES
1104 [
1105 #include <sys/un.h>
1106 #include <netinet/in_systm.h>
1107 #ifdef HAVE_NETINET_IN_VAR_H
1108 # include <netinet/in_var.h>
1109 #endif
1110 #ifdef HAVE_NET_IF_DL_H
1111 # include <net/if_dl.h>
1112 #endif
1113 #ifdef HAVE_NET_NETOPT_H
1114 # include <net/netopt.h>
1115 #endif
1116 #include <net/route.h>
1117 #ifdef HAVE_INET_ND_H
1118 # include <inet/nd.h>
1119 #endif
1120 #include <arpa/inet.h>
1121 /* Required for IDRP */
1122 #ifdef HAVE_NETINET_IP_ICMP_H
1123 # include <netinet/ip_icmp.h>
1124 #endif
1125 ])dnl
1126
1127 dnl V6 headers are checked below, after we check for v6
1128
1129 is_linux=false
1130
1131 AC_MSG_CHECKING([which operating system interface to use])
1132 case "$host_os" in
1133   sunos* | solaris2*)
1134     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1135     ;;
1136   linux*)
1137     AC_MSG_RESULT([Linux])
1138
1139     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1140     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1141     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1142
1143     dnl Linux has a compilation problem with mixing
1144     dnl netinet/in.h and linux/in6.h they are not
1145     dnl compatible.  There has been discussion on
1146     dnl how to fix it but no real progress on implementation
1147     dnl when they fix it, remove this
1148     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1149
1150     is_linux=true
1151     ;;
1152   openbsd*)
1153     AC_MSG_RESULT([OpenBSD])
1154
1155     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1156     AC_DEFINE([KAME], [1], [KAME IPv6])
1157     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1158     ;;
1159   *)
1160     AC_MSG_RESULT([BSD])
1161
1162     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1163     AC_DEFINE([KAME], [1], [KAME IPv6])
1164     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1165     ;;
1166 esac
1167 AM_CONDITIONAL([LINUX], [${is_linux}])
1168
1169 AC_SYS_LARGEFILE
1170
1171 dnl ------------------------
1172 dnl Integrated REALMS option
1173 dnl ------------------------
1174 if test "$enable_realms" = "yes"; then
1175     case "$host_os" in
1176       linux*)
1177        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1178        ;;
1179       *)
1180        echo "Sorry, only Linux has REALMS support"
1181        exit 1
1182        ;;
1183     esac
1184 fi
1185
1186 dnl -------------------------------
1187 dnl Endian-ness check
1188 dnl -------------------------------
1189 AC_WORDS_BIGENDIAN
1190
1191 dnl ---------------
1192 dnl other functions
1193 dnl ---------------
1194 AC_CHECK_FUNCS([ \
1195         strlcat strlcpy \
1196         getgrouplist \
1197         openat \
1198         unlinkat \
1199         posix_fallocate \
1200         ])
1201
1202 dnl ##########################################################################
1203 dnl LARGE if block spans a lot of "configure"!
1204 if test "$enable_clippy_only" != "yes"; then
1205 dnl ##########################################################################
1206
1207 #
1208 # Logic for protobuf support.
1209 #
1210 PROTO3=false
1211 if test "$enable_protobuf" = "yes"; then
1212   # Check for protoc & protoc-c
1213
1214   # protoc is not required, it's only for a "be nice" helper target
1215   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1216
1217   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1218   if test "$PROTOC_C" = "/bin/false"; then
1219     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1220   fi
1221
1222   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1223     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1224   ])
1225
1226   PROTO3=true
1227   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1228                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1229                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1230                                             [1], [Have Protobuf version 3]),
1231                                   [PROTO3=false],
1232                                   [#include <google/protobuf-c/protobuf-c.h>])],
1233                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1234
1235   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1236 fi
1237
1238
1239 dnl ---------------------
1240 dnl Integrated VTY option
1241 dnl ---------------------
1242 case "${enable_vtysh}" in
1243 "no")
1244   VTYSH="";;
1245 *)
1246   VTYSH="vtysh";
1247   AC_DEFINE([VTYSH], [1], [VTY shell])
1248
1249   prev_libs="$LIBS"
1250   AC_CHECK_LIB([readline], [main], [
1251     LIBREADLINE="-lreadline"
1252   ], [
1253     dnl readline failed - it might be incorrectly linked and missing its
1254     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1255     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1256       LIBREADLINE="$ac_cv_search_tputs"
1257     ], [
1258       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1259     ])
1260
1261     dnl re-try with the lib we found above
1262     unset ac_cv_lib_readline_main
1263     AC_CHECK_LIB([readline], [main], [
1264       LIBREADLINE="-lreadline $LIBREADLINE"
1265     ], [
1266       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1267     ], [$LIBREADLINE])
1268   ], [])
1269   LIBS="$prev_libs"
1270
1271   AC_CHECK_HEADER([readline/history.h])
1272   if test "$ac_cv_header_readline_history_h" = "no"; then
1273     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1274   fi
1275   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1276   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1277     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1278   fi
1279   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1280   if test "$frr_cv_append_history" = "yes"; then
1281     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1282   fi
1283   ;;
1284 esac
1285 AC_SUBST([LIBREADLINE])
1286
1287 dnl ----------
1288 dnl PAM module
1289 dnl
1290 dnl FRR detects the PAM library it is built against by checking for a
1291 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1292 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1293 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1294 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1295 dnl of OpenPAM.
1296 dnl ----------
1297 if test "$with_libpam" = "yes"; then
1298   AC_CHECK_HEADER([security/pam_misc.h],
1299     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1300      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1301      pam_conv_func="misc_conv"
1302     ],
1303     [], FRR_INCLUDES)
1304   AC_CHECK_HEADER([security/openpam.h],
1305     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1306      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1307      pam_conv_func="openpam_ttyconv"
1308     ],
1309     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1310   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1311     AC_MSG_WARN([*** pam support will not be built ***])
1312     with_libpam="no"
1313   fi
1314 fi
1315
1316 if test "$with_libpam" = "yes"; then
1317 dnl took this test from proftpds configure.in and suited to our needs
1318 dnl -------------------------------------------------------------------------
1319 dnl
1320 dnl This next check looks funky due to a linker problem with some versions
1321 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1322 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1323 dnl with RedHat 6.2 and Debian 2.2 or better.
1324 AC_CHECK_LIB([pam], [pam_start],
1325   [AC_CHECK_LIB([pam], [$pam_conv_func],
1326     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1327      LIBPAM="-lpam"],
1328     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1329      LIBPAM="-lpam -lpam_misc"]
1330     )
1331   ],
1332
1333   [AC_CHECK_LIB([pam], [pam_end],
1334     [AC_CHECK_LIB([pam], [$pam_conv_func],
1335       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1336        LIBPAM="-lpam -ldl"],
1337       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1338        LIBPAM="-lpam -ldl -lpam_misc"]
1339      )
1340   ],AC_MSG_WARN([*** pam support will not be built ***]),
1341   [-ldl])
1342   ]
1343 )
1344 fi
1345 AC_SUBST([LIBPAM])
1346
1347 dnl -------------------------------
1348 dnl bgpd needs pow() and hence libm
1349 dnl -------------------------------
1350 TMPLIBS="$LIBS"
1351 LIBS=""
1352 AC_SEARCH_LIBS([pow], [m], [
1353   LIBM="$LIBS"
1354 ], [
1355   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1356 ])
1357 LIBS="$TMPLIBS"
1358 AC_SUBST([LIBM])
1359
1360 AC_CHECK_FUNCS([ppoll], [
1361   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1362 ])
1363 AC_CHECK_FUNCS([pollts], [
1364   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1365 ])
1366
1367 AC_CHECK_HEADER([asm-generic/unistd.h],
1368                 [AC_CHECK_DECL(__NR_setns,
1369                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1370                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1371                                ])
1372                  AC_CHECK_FUNCS([setns])]
1373                )
1374
1375 dnl --------------------------
1376 dnl Determine IS-IS I/O method
1377 dnl --------------------------
1378 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1379 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1380 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1381 AC_CHECK_HEADER([net/bpf.h])
1382 AC_CHECK_HEADER([sys/dlpi.h])
1383 AC_MSG_CHECKING([zebra IS-IS I/O method])
1384
1385 case "$host_os" in
1386   linux*)
1387     AC_MSG_RESULT([pfpacket])
1388     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1389     ;;
1390   *)
1391     if test "$ac_cv_header_net_bpf_h" = "no"; then
1392       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1393         AC_MSG_RESULT([none])
1394         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1395           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1396         fi
1397         AC_MSG_WARN([*** IS-IS support will not be built ***])
1398         enable_isisd="no"
1399         enable_fabricd="no"
1400       else
1401         AC_MSG_RESULT([DLPI])
1402       fi
1403       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1404     else
1405       AC_MSG_RESULT([BPF])
1406       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1407     fi
1408     ;;
1409 esac
1410 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1411
1412 dnl ---------------------------------------------------------------
1413 dnl figure out how to specify an interface in multicast sockets API
1414 dnl ---------------------------------------------------------------
1415 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1416
1417 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1418         #include <sys/socket.h>
1419         #include <netinet/in.h>
1420         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1421         #include <linux/types.h>
1422 ])
1423
1424 m4_define([FRR_INCLUDES],
1425 FRR_INCLUDES
1426 [#ifdef HAVE_LINUX_MROUTE_H
1427 # include <linux/mroute.h>
1428 #endif
1429 ])dnl
1430
1431 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1432         #include <sys/socket.h>
1433         #include <sys/types.h>
1434         #include <netinet/in.h>
1435         #include <net/route.h>
1436 ])
1437
1438 m4_define([FRR_INCLUDES],
1439 FRR_INCLUDES
1440 [#ifdef HAVE_NETINET_IP_MROUTE_H
1441 # include <netinet/ip_mroute.h>
1442 #endif
1443 ])dnl
1444
1445 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1446 AC_TRY_COMPILE([#include <sys/param.h>],
1447 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1448   return (0);
1449 #else
1450   #error No support for BSD struct ip_mreq hack detected
1451 #endif],[AC_MSG_RESULT([yes])
1452 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1453 AC_MSG_RESULT([no]))
1454
1455 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1456 AC_TRY_COMPILE([
1457 #include <sys/types.h>
1458 #include <netinet/in.h>
1459 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1460 ], [AC_MSG_RESULT([yes])
1461 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1462 AC_MSG_RESULT([no]))
1463
1464 dnl ---------------------------------------------------------------
1465 dnl figure out how to check link-state
1466 dnl ---------------------------------------------------------------
1467 AC_CHECK_HEADER([net/if_media.h],
1468   [m4_define([LINK_DETECT_INCLUDES],
1469     FRR_INCLUDES
1470     [#include <net/if_media.h>
1471   ])
1472   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1473     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1474     [], LINK_DETECT_INCLUDES)],
1475   [],
1476   FRR_INCLUDES)
1477
1478 dnl ---------------------------------------------------------------
1479 dnl Additional, newer way to check link-state using ifi_link_state.
1480 dnl Not available in all BSD's when ifmediareq available
1481 dnl ---------------------------------------------------------------
1482 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1483   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1484   [], FRR_INCLUDES)
1485
1486 dnl ------------------------
1487 dnl TCP_MD5SIG socket option
1488 dnl ------------------------
1489
1490 AC_CHECK_HEADER([netinet/tcp.h],
1491    [m4_define([MD5_INCLUDES],
1492       FRR_INCLUDES
1493       [#include <netinet/tcp.h>
1494     ])
1495     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1496    [],
1497    FRR_INCLUDES)
1498 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1499   AC_CHECK_HEADER([linux/tcp.h],
1500        [m4_define([MD5_INCLUDES],
1501           FRR_INCLUDES
1502           [#include <linux/tcp.h>
1503         ])
1504        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1505 fi
1506
1507 AC_CHECK_LIB([crypt], [crypt], [],
1508                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1509 AC_CHECK_LIB([resolv], [res_init])
1510
1511 dnl ---------------------------
1512 dnl check system has PCRE regexp
1513 dnl ---------------------------
1514 if test "$enable_pcreposix" = "yes"; then
1515   AC_CHECK_LIB([pcreposix], [regexec], [], [
1516     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1517   ])
1518 fi
1519 AC_SUBST([HAVE_LIBPCREPOSIX])
1520
1521 dnl ##########################################################################
1522 dnl test "$enable_clippy_only" != "yes"
1523 fi
1524 dnl END OF LARGE if block
1525 dnl ##########################################################################
1526
1527 dnl ------------------
1528 dnl check C-Ares library
1529 dnl ------------------
1530 PKG_CHECK_MODULES([CARES], [libcares], [
1531   c_ares_found=true
1532 ],[
1533   c_ares_found=false
1534 ])
1535 AM_CONDITIONAL([CARES], [$c_ares_found])
1536
1537
1538 dnl ----------------------------------------------------------------------------
1539 dnl figure out if domainname is available in the utsname struct (GNU extension).
1540 dnl ----------------------------------------------------------------------------
1541 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1542
1543 dnl ------------------
1544 dnl IPv6 header checks
1545 dnl ------------------
1546 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1547         netinet6/in6_var.h netinet6/nd6.h], [], [],
1548         FRR_INCLUDES)
1549
1550 m4_define([FRR_INCLUDES],dnl
1551 FRR_INCLUDES
1552 [#ifdef HAVE_NETINET6_IN6_H
1553 #include <netinet6/in6.h>
1554 #endif
1555 #ifdef HAVE_NETINET_IN6_VAR_H
1556 #include <netinet/in6_var.h>
1557 #endif
1558 #include <netinet/icmp6.h>
1559 #ifdef HAVE_NETINET6_IN6_VAR_H
1560 # include <netinet6/in6_var.h>
1561 #endif
1562 #ifdef HAVE_NETINET6_ND6_H
1563 # include <netinet6/nd6.h>
1564 #endif
1565 ])dnl
1566
1567 dnl --------------------
1568 dnl Daemon disable check
1569 dnl --------------------
1570
1571 AS_IF([test "$enable_bgpd" != "no"], [
1572   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1573 ])
1574
1575 AS_IF([test "$enable_ripd" != "no"], [
1576   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1577 ])
1578
1579 AS_IF([test "$enable_ripngd" != "no"], [
1580   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1581 ])
1582
1583 AS_IF([test "$enable_ospfd" != "no"], [
1584   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1585 ])
1586
1587 AS_IF([test "$enable_ospf6d" != "no"], [
1588   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1589 ])
1590
1591 AS_IF([test "$enable_ldpd" != "no"], [
1592   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1593 ])
1594
1595 AS_IF([test "$enable_nhrpd" != "no"], [
1596   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1597 ])
1598
1599 AS_IF([test "$enable_eigrpd" != "no"], [
1600   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1601 ])
1602
1603 AS_IF([test "$enable_babeld" != "no"], [
1604   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1605 ])
1606
1607 AS_IF([test "$enable_isisd" != "no"], [
1608   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1609 ])
1610
1611 AS_IF([test "$enable_pimd" != "no"], [
1612   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1613 ])
1614
1615 AS_IF([test "$enable_pbrd" != "no"], [
1616   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1617 ])
1618
1619 AS_IF([test "$enable_sharpd" = "yes"], [
1620   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1621 ])
1622
1623 AS_IF([test "$enable_staticd" != "no"], [
1624   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1625 ])
1626
1627 AS_IF([test "$enable_fabricd" != "no"], [
1628   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1629 ])
1630
1631 AS_IF([test "$enable_vrrpd" != "no"], [
1632   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1633 ])
1634
1635 if test "$enable_bfdd" = "no"; then
1636   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1637   BFDD=""
1638 else
1639   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1640   BFDD="bfdd"
1641
1642   case $host_os in
1643     linux*)
1644       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1645       ;;
1646
1647     *)
1648       AC_DEFINE([BFD_BSD], [1], [bfdd])
1649       ;;
1650   esac
1651 fi
1652
1653 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1654   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1655 fi
1656
1657 NHRPD=""
1658 case "$host_os" in
1659   linux*)
1660     case "${enable_nhrpd}" in
1661       no)
1662         ;;
1663       yes)
1664         if test "$enable_clippy_only" != "yes"; then
1665         if test "$c_ares_found" != "true" ; then
1666           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1667         fi
1668         fi
1669         NHRPD="nhrpd"
1670         ;;
1671       *)
1672         if test "$c_ares_found" = "true" ; then
1673           NHRPD="nhrpd"
1674         fi
1675         ;;
1676     esac
1677     ;;
1678   *)
1679     if test "$enable_nhrpd" = "yes"; then
1680       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1681     fi
1682     ;;
1683 esac
1684
1685 if test "$enable_watchfrr" = "no";then
1686   WATCHFRR=""
1687 else
1688   WATCHFRR="watchfrr"
1689 fi
1690
1691 OSPFCLIENT=""
1692 if test "$enable_ospfapi" != "no";then
1693     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1694
1695   if test "$enable_ospfclient" != "no";then
1696       OSPFCLIENT="ospfclient"
1697   fi
1698 fi
1699
1700 if test "$enable_bgp_announce" = "no";then
1701   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1702 else
1703   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1704 fi
1705
1706 if test "$enable_bgp_vnc" != "no";then
1707   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1708 fi
1709
1710 bgpd_bmp=false
1711 case "${enable_bmp}" in
1712   no)
1713     ;;
1714   yes)
1715     if test "$c_ares_found" != "true" ; then
1716       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1717     fi
1718     bgpd_bmp=true
1719     ;;
1720   *)
1721     if test "$c_ares_found" = "true" ; then
1722       bgpd_bmp=true
1723     fi
1724     ;;
1725 esac
1726
1727 if test "$enable_version_build_config" != "no";then
1728   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1729 fi
1730
1731 dnl ##########################################################################
1732 dnl LARGE if block
1733 if test "$enable_clippy_only" != "yes"; then
1734 dnl ##########################################################################
1735
1736 dnl ------------------
1737 dnl check Net-SNMP library
1738 dnl ------------------
1739 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1740    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1741    if test "$NETSNMP_CONFIG" = "no"; then
1742       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1743    fi
1744    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1745    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1746    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1747    # among other things we avoid a GPL vs. OpenSSL license conflict here
1748    for removelib in crypto ssl sensors pci wrap; do
1749      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1750    done
1751    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1752    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1753 int main(void);
1754 ],
1755 [
1756 {
1757   return 0;
1758 }
1759 ])], [
1760      AC_MSG_RESULT([no])
1761      AC_MSG_ERROR([--enable-snmp given but not usable])])
1762    case "${enable_snmp}" in
1763      yes)
1764       SNMP_METHOD=agentx
1765       ;;
1766      agentx)
1767       SNMP_METHOD="${enable_snmp}"
1768       ;;
1769      *)
1770       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1771       ;;
1772    esac
1773    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1774    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1775 fi
1776 AC_SUBST([SNMP_LIBS])
1777 AC_SUBST([SNMP_CFLAGS])
1778
1779 dnl ---------------
1780 dnl libyang
1781 dnl ---------------
1782 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1783   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1784 ])
1785 ac_cflags_save="$CFLAGS"
1786 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1787 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1788   AC_MSG_ERROR([m4_normalize([
1789     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1790     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1791   ])
1792 ], [[#include <libyang/libyang.h>]])
1793 CFLAGS="$ac_cflags_save"
1794
1795 dnl ---------------
1796 dnl configuration rollbacks
1797 dnl ---------------
1798 SQLITE3=false
1799 if test "$enable_config_rollbacks" = "yes"; then
1800   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1801     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1802     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1803     SQLITE3=true
1804   ], [
1805     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1806   ])
1807 fi
1808
1809 dnl ---------------
1810 dnl confd
1811 dnl ---------------
1812 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1813    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1814    if test "$CONFD" = "/bin/false"; then
1815       AC_MSG_ERROR([confd was not found on your system.])]
1816    fi
1817    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1818    AC_SUBST([CONFD_CFLAGS])
1819    CONFD_LIBS="-lconfd"
1820    AC_SUBST([CONFD_LIBS])
1821    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1822 fi
1823
1824 dnl ---------------
1825 dnl sysrepo
1826 dnl ---------------
1827 if test "$enable_sysrepo" = "yes"; then
1828   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1829       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1830       SYSREPO=true],
1831       [SYSREPO=false
1832       AC_MSG_ERROR([sysrepo was not found on your system.])]
1833   )
1834 fi
1835
1836 dnl ---------------
1837 dnl gRPC
1838 dnl ---------------
1839 if test "$enable_grpc" = "yes"; then
1840   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1841     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1842     if test "$PROTOC" = "/bin/false"; then
1843       AC_MSG_FAILURE([grpc requested but protoc not found.])
1844     fi
1845
1846     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1847     GRPC=true
1848   ], [
1849     GRPC=false
1850     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1851   ])
1852 fi
1853
1854 dnl ------
1855 dnl ZeroMQ
1856 dnl ------
1857 if test "$enable_zeromq" != "no"; then
1858   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1859     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1860     ZEROMQ=true
1861   ], [
1862     if test "$enable_zeromq" = "yes"; then
1863       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1864     fi
1865   ])
1866 fi
1867
1868 dnl ------------------------------------
1869 dnl Enable RPKI and add librtr to libs
1870 dnl ------------------------------------
1871 if test "$enable_rpki" = "yes"; then
1872   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1873       [RPKI=true],
1874       [RPKI=false
1875       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1876   )
1877 fi
1878
1879 dnl ------------------------------------
1880 dnl pimd is not supported on OpenBSD and MacOS
1881 dnl ------------------------------------
1882 if test "$enable_pimd" != "no"; then
1883 AC_MSG_CHECKING([for pimd OS support])
1884 case "$host_os" in
1885   darwin*)
1886     AC_MSG_RESULT([no])
1887     enable_pimd="no"
1888     ;;
1889   openbsd*)
1890     AC_MSG_RESULT([no])
1891     enable_pimd="no"
1892     ;;
1893   *)
1894     AC_MSG_RESULT([yes])
1895     ;;
1896 esac
1897 fi
1898
1899 dnl -------------------------------------
1900 dnl VRRP is only supported on linux
1901 dnl -------------------------------------
1902 if test "$enable_vrrpd" != "no"; then
1903 AC_MSG_CHECKING([for VRRP OS support])
1904 case "$host_os" in
1905   linux*)
1906     AC_MSG_RESULT([yes])
1907     ;;
1908   *)
1909     AC_MSG_RESULT([no])
1910     enable_vrrpd="no"
1911     ;;
1912 esac
1913 fi
1914
1915 dnl ------------------------------------------
1916 dnl Check whether rtrlib was build with ssh support
1917 dnl ------------------------------------------
1918 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1919 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1920                         [[struct tr_ssh_config config;]])],
1921         [AC_MSG_RESULT([yes])
1922         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1923         AC_MSG_RESULT([no])
1924 )
1925
1926 dnl ---------------
1927 dnl dlopen & dlinfo
1928 dnl ---------------
1929 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1930   AC_MSG_ERROR([unable to find the dlopen()])
1931 ])
1932
1933 AC_CHECK_HEADERS([link.h])
1934
1935 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1936   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1937 #include <stdlib.h>
1938 #ifdef HAVE_LINK_H
1939 #include <link.h>
1940 #endif
1941 #include <dlfcn.h>
1942 ]], [[
1943   char origin[1];
1944   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1945 ]])], [
1946     frr_cv_rtld_di_origin=yes
1947   ], [
1948     frr_cv_rtld_di_origin=no
1949   ])
1950 ])
1951 if test "$frr_cv_rtld_di_origin" = "yes"; then
1952   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1953 fi
1954
1955 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1956   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1957 #include <stdlib.h>
1958 #ifdef HAVE_LINK_H
1959 #include <link.h>
1960 #endif
1961 #include <dlfcn.h>
1962 ]], [[
1963   struct link_map *lm = NULL;
1964   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1965 ]])], [
1966     frr_cv_rtld_di_linkmap=yes
1967   ], [
1968     frr_cv_rtld_di_linkmap=no
1969   ])
1970 ])
1971 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
1972   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1973 fi
1974
1975 dnl ##########################################################################
1976 dnl test "$enable_clippy_only" != "yes"
1977 fi
1978 dnl END OF LARGE if block
1979 dnl ##########################################################################
1980
1981 dnl ---------------------------
1982 dnl sockaddr and netinet checks
1983 dnl ---------------------------
1984 AC_CHECK_TYPES([
1985         struct sockaddr_dl,
1986         struct vifctl, struct mfcctl, struct sioc_sg_req,
1987         vifi_t, struct sioc_vif_req, struct igmpmsg,
1988         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1989         struct nd_opt_adv_interval,
1990         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1991         struct nd_opt_rdnss, struct nd_opt_dnssl],
1992         [], [], FRR_INCLUDES)
1993
1994 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1995         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1996         struct sockaddr_dl.sdl_len,
1997         struct if6_aliasreq.ifra_lifetime,
1998         struct nd_opt_adv_interval.nd_opt_ai_type],
1999         [], [], FRR_INCLUDES)
2000
2001 dnl ---------------------------
2002 dnl IRDP/pktinfo/icmphdr checks
2003 dnl ---------------------------
2004
2005 AC_CHECK_TYPES([struct in_pktinfo], [
2006   AC_CHECK_TYPES([struct icmphdr], [
2007     IRDP=true
2008   ], [
2009     IRDP=false
2010   ], [FRR_INCLUDES])
2011 ], [
2012   IRDP=false
2013 ], [FRR_INCLUDES])
2014
2015 case "${enable_irdp}" in
2016 yes)
2017   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2018   ;;
2019 no)
2020   IRDP=false
2021   ;;
2022 esac
2023
2024
2025 dnl -----------------------
2026 dnl checking for IP_PKTINFO
2027 dnl -----------------------
2028 AC_MSG_CHECKING([for IP_PKTINFO])
2029 AC_TRY_COMPILE([#include <netdb.h>], [
2030   int opt = IP_PKTINFO;
2031 ], [
2032   AC_MSG_RESULT([yes])
2033   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2034 ], [
2035   AC_MSG_RESULT([no])
2036 ])
2037
2038 dnl ---------------------------
2039 dnl checking for IP_RECVDSTADDR
2040 dnl ---------------------------
2041 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2042 AC_TRY_COMPILE([#include <netinet/in.h>], [
2043   int opt = IP_RECVDSTADDR;
2044 ], [
2045   AC_MSG_RESULT([yes])
2046   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2047 ], [
2048   AC_MSG_RESULT([no])
2049 ])
2050
2051 dnl ----------------------
2052 dnl checking for IP_RECVIF
2053 dnl ----------------------
2054 AC_MSG_CHECKING([for IP_RECVIF])
2055 AC_TRY_COMPILE([#include <netinet/in.h>], [
2056   int opt = IP_RECVIF;
2057 ], [
2058   AC_MSG_RESULT([yes])
2059   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2060 ], [
2061   AC_MSG_RESULT([no])
2062 ])
2063
2064 dnl ----------------------
2065 dnl checking for SO_BINDANY
2066 dnl ----------------------
2067 AC_MSG_CHECKING([for SO_BINDANY])
2068 AC_TRY_COMPILE([#include <sys/socket.h>], [
2069   int opt = SO_BINDANY;
2070 ], [
2071   AC_MSG_RESULT([yes])
2072   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2073 ], [
2074   AC_MSG_RESULT([no])
2075 ])
2076
2077 dnl ----------------------
2078 dnl checking for IP_FREEBIND
2079 dnl ----------------------
2080 AC_MSG_CHECKING([for IP_FREEBIND])
2081 AC_TRY_COMPILE([#include <netinet/in.h>], [
2082   int opt = IP_FREEBIND;
2083 ], [
2084   AC_MSG_RESULT([yes])
2085   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2086 ], [
2087   AC_MSG_RESULT([no])
2088 ])
2089
2090 dnl --------------------------------------
2091 dnl checking for be32dec existence or not
2092 dnl --------------------------------------
2093 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2094                [#include <sys/endian.h>])
2095
2096 dnl --------------------------------------
2097 dnl checking for clock_time monotonic struct and call
2098 dnl --------------------------------------
2099 AC_CHECK_DECL([CLOCK_MONOTONIC],
2100         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2101          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2102 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2103
2104 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2105   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2106 ])
2107
2108 dnl --------------------------------------
2109 dnl checking for flex and bison
2110 dnl --------------------------------------
2111
2112 AM_PROG_LEX
2113 AC_MSG_CHECKING([version of flex])
2114 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2115 frr_ac_flex_version="${frr_ac_flex_version##* }"
2116 AC_MSG_RESULT([$frr_ac_flex_version])
2117 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2118   LEX="$SHELL $missing_dir/missing flex"
2119   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2120     AC_MSG_WARN([using pregenerated flex output files])
2121   else
2122     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2123   fi
2124   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2125   AC_SUBST([LEXLIB], [''])
2126 ])
2127
2128 AC_PROG_YACC
2129 dnl thanks GNU bison for this b*llshit...
2130 AC_MSG_CHECKING([version of bison])
2131 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2132 frr_ac_bison_version="${frr_ac_bison_version##* }"
2133 frr_ac_bison_missing="false"
2134 case "x${frr_ac_bison_version}x" in
2135   x2.7*)
2136     BISON_OPENBRACE='"'
2137     BISON_CLOSEBRACE='"'
2138     BISON_VERBOSE=''
2139     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2140     ;;
2141   x2.*|x1.*)
2142     AC_MSG_RESULT([$frr_ac_bison_version])
2143     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2144     frr_ac_bison_missing="true"
2145     ;;
2146   x)
2147     AC_MSG_RESULT([none])
2148     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2149     frr_ac_bison_missing="true"
2150     ;;
2151   x3.[012][^0-9]*)
2152     BISON_OPENBRACE='{'
2153     BISON_CLOSEBRACE='}'
2154     BISON_VERBOSE='-Dparse.error=verbose'
2155     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2156     ;;
2157   *)
2158     BISON_OPENBRACE='{'
2159     BISON_CLOSEBRACE='}'
2160     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2161     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2162     ;;
2163 esac
2164 AC_SUBST([BISON_OPENBRACE])
2165 AC_SUBST([BISON_CLOSEBRACE])
2166 AC_SUBST([BISON_VERBOSE])
2167
2168 if $frr_ac_bison_missing; then
2169   YACC="$SHELL $missing_dir/missing bison -y"
2170   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2171     AC_MSG_WARN([using pregenerated bison output files])
2172   else
2173     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2174   fi
2175 fi
2176
2177 dnl -------------------
2178 dnl capabilities checks
2179 dnl -------------------
2180 if test "$enable_capabilities" != "no"; then
2181   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2182   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2183     [AC_MSG_RESULT([yes])
2184      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2185      frr_ac_keepcaps="yes"],
2186      AC_MSG_RESULT([no])
2187   )
2188   if test "$frr_ac_keepcaps" = "yes"; then
2189     AC_CHECK_HEADERS([sys/capability.h])
2190   fi
2191   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2192     AC_CHECK_LIB([cap], [cap_init],
2193       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2194        LIBCAP="-lcap"
2195        frr_ac_lcaps="yes"]
2196     )
2197   fi
2198   if test "$frr_ac_scaps" = "yes" \
2199        -o "$frr_ac_lcaps" = "yes"; then
2200     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2201   fi
2202
2203   case "$host_os" in
2204   linux*)
2205     if test "$enable_clippy_only" != "yes"; then
2206     if test "$frr_ac_lcaps" != "yes"; then
2207       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2208     fi
2209     fi
2210     ;;
2211   esac
2212 else
2213   case "$host_os" in
2214   linux*)
2215     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2216     ;;
2217   esac
2218 fi
2219 AC_SUBST([LIBCAP])
2220
2221 dnl ---------------------------
2222 dnl check for glibc 'backtrace'
2223 dnl ---------------------------
2224 if test "$enable_backtrace" != "no" ; then
2225   backtrace_ok=no
2226   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2227     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2228     backtrace_ok=yes
2229   ], [
2230     true
2231   ])
2232
2233   if test "$backtrace_ok" = "no"; then
2234     AC_CHECK_HEADER([unwind.h], [
2235       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2236         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2237         backtrace_ok=yes
2238       ])
2239     ])
2240   fi
2241
2242   if test "$backtrace_ok" = "no"; then
2243     AC_CHECK_HEADER([execinfo.h], [
2244       AC_SEARCH_LIBS([backtrace], [execinfo], [
2245         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2246         backtrace_ok=yes
2247       ],, [-lm])
2248     ])
2249   fi
2250
2251   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2252     dnl user explicitly requested backtrace but we failed to find support
2253     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2254   fi
2255 fi
2256
2257 dnl -----------------------------------------
2258 dnl check for malloc mallinfo struct and call
2259 dnl this must try and link using LIBS, in
2260 dnl order to check no alternative allocator
2261 dnl has been specified, which might not provide
2262 dnl mallinfo
2263 dnl -----------------------------------------
2264 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2265
2266 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2267   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2268 #ifdef HAVE_MALLOC_H
2269 #include <malloc.h>
2270 #endif
2271 #ifdef HAVE_MALLOC_NP_H
2272 #include <malloc_np.h>
2273 #endif
2274 #ifdef HAVE_MALLOC_MALLOC_H
2275 #include <malloc/malloc.h>
2276 #endif
2277 ]], [[
2278 struct mallinfo ac_x; ac_x = mallinfo ();
2279 ]])], [
2280     frr_cv_mallinfo=yes
2281   ], [
2282     frr_cv_mallinfo=no
2283   ])
2284 ])
2285 if test "$frr_cv_mallinfo" = "yes"; then
2286   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2287 fi
2288
2289 AC_MSG_CHECKING([whether malloc_usable_size is available])
2290 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2291 #ifdef HAVE_MALLOC_H
2292 #include <malloc.h>
2293 #endif
2294 #ifdef HAVE_MALLOC_MALLOC_H
2295 #include <malloc/malloc.h>
2296 #endif
2297 ]], [[
2298 size_t ac_x; ac_x = malloc_usable_size(NULL);
2299 ]])], [
2300   AC_MSG_RESULT([yes])
2301   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2302 ], [
2303   AC_MSG_RESULT([no])
2304
2305   AC_MSG_CHECKING([whether malloc_size is available])
2306   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2307 #ifdef HAVE_MALLOC_H
2308 #include <malloc.h>
2309 #endif
2310 #ifdef HAVE_MALLOC_MALLOC_H
2311 #include <malloc/malloc.h>
2312 #endif
2313 ]], [[
2314 size_t ac_x; ac_x = malloc_size(NULL);
2315 ]])], [
2316     AC_MSG_RESULT([yes])
2317     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2318   ], [
2319     AC_MSG_RESULT([no])
2320   ])
2321 ])
2322
2323 dnl ----------
2324 dnl configure date
2325 dnl ----------
2326 dev_version=`echo $VERSION | grep dev`
2327 #don't expire deprecated code in non 'dev' branch
2328 if test "$dev_version" = ""; then
2329    CONFDATE=0
2330 else
2331    CONFDATE=`date '+%Y%m%d'`
2332 fi
2333 AC_SUBST([CONFDATE])
2334
2335 dnl ------------------------------
2336 dnl set paths for state directory
2337 dnl ------------------------------
2338 AC_MSG_CHECKING([directory to use for state file])
2339 if test "$prefix" = "NONE"; then
2340   frr_statedir_prefix="";
2341 else
2342   frr_statedir_prefix=${prefix}
2343 fi
2344 if test "$localstatedir" = '${prefix}/var'; then
2345   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2346                         ${frr_statedir_prefix}/var/adm dnl
2347                         ${frr_statedir_prefix}/etc dnl
2348                         /var/run        dnl
2349                         /var/adm        dnl
2350                         /etc            dnl
2351                         /dev/null;
2352   do
2353     test -d $FRR_STATE_DIR && break
2354   done
2355   frr_statedir=$FRR_STATE_DIR
2356 else
2357   frr_statedir=${localstatedir}
2358 fi
2359 if test "$frr_statedir" = "/dev/null"; then
2360     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2361 fi
2362 AC_MSG_RESULT([${frr_statedir}])
2363 AC_SUBST([frr_statedir])
2364
2365 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2366 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2367 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2368 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2369 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2370
2371 dnl autoconf does this, but it does it too late...
2372 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2373 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2374
2375 dnl get the full path, recursing through variables...
2376 vtysh_bin="$bindir/vtysh"
2377 for I in 1 2 3 4 5 6 7 8 9 10; do
2378         eval vtysh_bin="\"$vtysh_bin\""
2379 done
2380 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2381 AC_SUBST([vtysh_bin])
2382
2383 CFG_SYSCONF="$sysconfdir"
2384 CFG_SBIN="$sbindir"
2385 CFG_STATE="$frr_statedir"
2386 CFG_MODULE="$moduledir"
2387 CFG_YANGMODELS="$yangmodelsdir"
2388 for I in 1 2 3 4 5 6 7 8 9 10; do
2389         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2390         eval CFG_SBIN="\"$CFG_SBIN\""
2391         eval CFG_STATE="\"$CFG_STATE\""
2392         eval CFG_MODULE="\"$CFG_MODULE\""
2393         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2394 done
2395 AC_SUBST([CFG_SYSCONF])
2396 AC_SUBST([CFG_SBIN])
2397 AC_SUBST([CFG_STATE])
2398 AC_SUBST([CFG_MODULE])
2399 AC_SUBST([CFG_YANGMODELS])
2400 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2401 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2402 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2403
2404 dnl various features
2405 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2406 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2407 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2408 dnl northbound
2409 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2410 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2411 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2412 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2413 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2414 dnl plugins
2415 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2416 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2417 AM_CONDITIONAL([IRDP], [$IRDP])
2418 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2419 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2420 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2421 dnl daemons
2422 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2423 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2424 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2425 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2426 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2427 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2428 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2429 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2430 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2431 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2432 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2433 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2434 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2435 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2436 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2437 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2438 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2439 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2440 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2441 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2442 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2443
2444 AC_CONFIG_FILES([Makefile],[
2445         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2446         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2447 ], [
2448         PYTHON="$PYTHON"
2449         enable_dev_build="$enable_dev_build"
2450 ])
2451
2452 AC_CONFIG_FILES([
2453           config.version
2454           changelog-auto
2455           redhat/frr.spec
2456           alpine/APKBUILD
2457           snapcraft/snapcraft.yaml
2458           lib/version.h
2459           tests/lib/cli/test_cli.refout
2460           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2461           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2462           pkgsrc/eigrpd.sh])
2463
2464 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2465 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2466 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2467 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2468 AC_CONFIG_FILES([tools/frrcommon.sh])
2469
2470 AC_CONFIG_COMMANDS([lib/route_types.h], [
2471         dst="${ac_abs_top_builddir}/lib/route_types.h"
2472         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2473                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2474                 > "${dst}.tmp"
2475         test -f "$dst" \
2476                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2477                 && rm "${dst}.tmp" \
2478                 || mv "${dst}.tmp" "${dst}"
2479 ], [
2480         PERL="$PERL"
2481 ])
2482
2483 AS_IF([test "$with_pkg_git_version" = "yes"], [
2484     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2485         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2486         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2487                 "${ac_abs_top_srcdir}" \
2488                 > "${dst}.tmp"
2489         test -f "$dst" \
2490                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2491                 && rm "${dst}.tmp" \
2492                 || mv "${dst}.tmp" "${dst}"
2493     ], [
2494         PERL="$PERL"
2495     ])
2496 ])
2497
2498 ## Hack, but working solution to avoid rebuilding of frr.info.
2499 ## It's already in CVS until texinfo 4.7 is more common.
2500 AC_OUTPUT
2501
2502 echo "
2503 FRRouting configuration
2504 ------------------------------
2505 FRR version             : ${PACKAGE_VERSION}
2506 host operating system   : ${host_os}
2507 source code location    : ${srcdir}
2508 compiler                : ${CC}
2509 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2510 make                    : ${MAKE-make}
2511 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2512 state file directory    : ${frr_statedir}
2513 config file directory   : `eval echo \`echo ${sysconfdir}\``
2514 example directory       : `eval echo \`echo ${exampledir}\``
2515 module directory        : ${CFG_MODULE}
2516 user to run as          : ${enable_user}
2517 group to run as         : ${enable_group}
2518 group for vty sockets   : ${enable_vty_group}
2519 config file mask        : ${enable_configfile_mask}
2520 log file mask           : ${enable_logfile_mask}
2521 zebra protobuf enabled  : ${enable_protobuf:-no}
2522 vici socket path        : ${vici_socket}
2523
2524 The above user and group must have read/write access to the state file
2525 directory and to the config files in the config file directory."
2526
2527 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2528   AC_MSG_WARN([sphinx is missing but required to build documentation])
2529 fi
2530 if test "$frr_py_mod_pytest" = "false"; then
2531   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2532 fi