elf_aarch64_efi.lds

   1 OUTPUT_FORMAT("elf64-littleaarch64", "elf64-littleaarch64", "elf64-littleaarch64")
   2 OUTPUT_ARCH(aarch64)
   3 ENTRY(_start)
   4 SECTIONS
   5 {
   6   .text 0x0 : {
   7     _text = .;
   8     *(.text.head)
   9     *(.text)
  10     *(.text.*)
  11     *(.gnu.linkonce.t.*)
  12     *(.srodata)
  13     *(.rodata*)
  14     . = ALIGN(16);
  15     _etext = .;
  16   }
  17   .dynamic  : { *(.dynamic) }
  18   .data :
  19   {
  20    _data = .;
  21    *(.sdata)
  22    *(.data)
  23    *(.data1)
  24    *(.data.*)
  25    *(.got.plt)
  26    *(.got)
  27
  28    /* the EFI loader doesn't seem to like a .bss section, so we stick
  29       it all into .data: */
  30    . = ALIGN(16);
  31    _bss = .;
  32    *(.sbss)
  33    *(.scommon)
  34    *(.dynbss)
  35    *(.bss)
  36    *(COMMON)
  37    . = ALIGN(16);
  38    _bss_end = .;
  39   }
  40
  41   . = ALIGN(4096);
  42   .vendor_cert :
  43   {
  44     *(.vendor_cert)
  45   }
  46   . = ALIGN(4096);
  47
  48   .rela.dyn : { *(.rela.dyn) }
  49   .rela.plt : { *(.rela.plt) }
  50   .rela.got : { *(.rela.got) }
  51   .rela.data : { *(.rela.data) *(.rela.data*) }
  52   _edata = .;
  53   _data_size = . - _data;
  54
  55   . = ALIGN(4096);
  56   .dynsym   : { *(.dynsym) }
  57   . = ALIGN(4096);
  58   .dynstr   : { *(.dynstr) }
  59   . = ALIGN(4096);
  60   /DISCARD/ :
  61   {
  62     *(.rel.reloc)
  63     *(.eh_frame)
  64     *(.note.GNU-stack)
  65   }
  66   .comment 0 : { *(.comment) }
  67 }