]> git.proxmox.com Git - mirror_ubuntu-jammy-kernel.git/blob - include/asm-generic/vmlinux.lds.h
projects / mirror_ubuntu-jammy-kernel.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
UBUNTU: Ubuntu-5.15.0-39.42
[mirror_ubuntu-jammy-kernel.git] / include / asm-generic / vmlinux.lds.h
1 /*
2 * Helper macros to support writing architecture specific
3 * linker scripts.
4 *
5 * A minimal linker scripts has following content:
6 * [This is a sample, architectures may have special requiriements]
7 *
8 * OUTPUT_FORMAT(...)
9 * OUTPUT_ARCH(...)
10 * ENTRY(...)
11 * SECTIONS
12 * {
13 * . = START;
14 * __init_begin = .;
15 * HEAD_TEXT_SECTION
16 * INIT_TEXT_SECTION(PAGE_SIZE)
17 * INIT_DATA_SECTION(...)
18 * PERCPU_SECTION(CACHELINE_SIZE)
19 * __init_end = .;
20 *
21 * _stext = .;
22 * TEXT_SECTION = 0
23 * _etext = .;
24 *
25 * _sdata = .;
26 * RO_DATA(PAGE_SIZE)
27 * RW_DATA(...)
28 * _edata = .;
29 *
30 * EXCEPTION_TABLE(...)
31 *
32 * BSS_SECTION(0, 0, 0)
33 * _end = .;
34 *
35 * STABS_DEBUG
36 * DWARF_DEBUG
37 * ELF_DETAILS
38 *
39 * DISCARDS // must be the last
40 * }
41 *
42 * [__init_begin, __init_end] is the init section that may be freed after init
43 * // __init_begin and __init_end should be page aligned, so that we can
44 * // free the whole .init memory
45 * [_stext, _etext] is the text section
46 * [_sdata, _edata] is the data section
47 *
48 * Some of the included output section have their own set of constants.
49 * Examples are: [__initramfs_start, __initramfs_end] for initramfs and
50 * [__nosave_begin, __nosave_end] for the nosave data
51 */
52
53 #ifndef LOAD_OFFSET
54 #define LOAD_OFFSET 0
55 #endif
56
57 /*
58 * Only some architectures want to have the .notes segment visible in
59 * a separate PT_NOTE ELF Program Header. When this happens, it needs
60 * to be visible in both the kernel text's PT_LOAD and the PT_NOTE
61 * Program Headers. In this case, though, the PT_LOAD needs to be made
62 * the default again so that all the following sections don't also end
63 * up in the PT_NOTE Program Header.
64 */
65 #ifdef EMITS_PT_NOTE
66 #define NOTES_HEADERS :text :note
67 #define NOTES_HEADERS_RESTORE __restore_ph : { *(.__restore_ph) } :text
68 #else
69 #define NOTES_HEADERS
70 #define NOTES_HEADERS_RESTORE
71 #endif
72
73 /*
74 * Some architectures have non-executable read-only exception tables.
75 * They can be added to the RO_DATA segment by specifying their desired
76 * alignment.
77 */
78 #ifdef RO_EXCEPTION_TABLE_ALIGN
79 #define RO_EXCEPTION_TABLE EXCEPTION_TABLE(RO_EXCEPTION_TABLE_ALIGN)
80 #else
81 #define RO_EXCEPTION_TABLE
82 #endif
83
84 /* Align . to a 8 byte boundary equals to maximum function alignment. */
85 #define ALIGN_FUNCTION() . = ALIGN(8)
86
87 /*
88 * LD_DEAD_CODE_DATA_ELIMINATION option enables -fdata-sections, which
89 * generates .data.identifier sections, which need to be pulled in with
90 * .data. We don't want to pull in .data..other sections, which Linux
91 * has defined. Same for text and bss.
92 *
93 * With LTO_CLANG, the linker also splits sections by default, so we need
94 * these macros to combine the sections during the final link.
95 *
96 * RODATA_MAIN is not used because existing code already defines .rodata.x
97 * sections to be brought in with rodata.
98 */
99 #if defined(CONFIG_LD_DEAD_CODE_DATA_ELIMINATION) || defined(CONFIG_LTO_CLANG)
100 #define TEXT_MAIN .text .text.[0-9a-zA-Z_]*
101 #define DATA_MAIN .data .data.[0-9a-zA-Z_]* .data..L* .data..compoundliteral* .data.$__unnamed_* .data.$L*
102 #define SDATA_MAIN .sdata .sdata.[0-9a-zA-Z_]*
103 #define RODATA_MAIN .rodata .rodata.[0-9a-zA-Z_]* .rodata..L*
104 #define BSS_MAIN .bss .bss.[0-9a-zA-Z_]* .bss..compoundliteral*
105 #define SBSS_MAIN .sbss .sbss.[0-9a-zA-Z_]*
106 #else
107 #define TEXT_MAIN .text
108 #define DATA_MAIN .data
109 #define SDATA_MAIN .sdata
110 #define RODATA_MAIN .rodata
111 #define BSS_MAIN .bss
112 #define SBSS_MAIN .sbss
113 #endif
114
115 /*
116 * GCC 4.5 and later have a 32 bytes section alignment for structures.
117 * Except GCC 4.9, that feels the need to align on 64 bytes.
118 */
119 #define STRUCT_ALIGNMENT 32
120 #define STRUCT_ALIGN() . = ALIGN(STRUCT_ALIGNMENT)
121
122 /*
123 * The order of the sched class addresses are important, as they are
124 * used to determine the order of the priority of each sched class in
125 * relation to each other.
126 */
127 #define SCHED_DATA \
128 STRUCT_ALIGN(); \
129 __begin_sched_classes = .; \
130 *(__idle_sched_class) \
131 *(__fair_sched_class) \
132 *(__rt_sched_class) \
133 *(__dl_sched_class) \
134 *(__stop_sched_class) \
135 __end_sched_classes = .;
136
137 /* The actual configuration determine if the init/exit sections
138 * are handled as text/data or they can be discarded (which
139 * often happens at runtime)
140 */
141 #ifdef CONFIG_HOTPLUG_CPU
142 #define CPU_KEEP(sec) *(.cpu##sec)
143 #define CPU_DISCARD(sec)
144 #else
145 #define CPU_KEEP(sec)
146 #define CPU_DISCARD(sec) *(.cpu##sec)
147 #endif
148
149 #if defined(CONFIG_MEMORY_HOTPLUG)
150 #define MEM_KEEP(sec) *(.mem##sec)
151 #define MEM_DISCARD(sec)
152 #else
153 #define MEM_KEEP(sec)
154 #define MEM_DISCARD(sec) *(.mem##sec)
155 #endif
156
157 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
158 /*
159 * The ftrace call sites are logged to a section whose name depends on the
160 * compiler option used. A given kernel image will only use one, AKA
161 * FTRACE_CALLSITE_SECTION. We capture all of them here to avoid header
162 * dependencies for FTRACE_CALLSITE_SECTION's definition.
163 *
164 * Need to also make ftrace_stub_graph point to ftrace_stub
165 * so that the same stub location may have different protocols
166 * and not mess up with C verifiers.
167 */
168 #define MCOUNT_REC() . = ALIGN(8); \
169 __start_mcount_loc = .; \
170 KEEP(*(__mcount_loc)) \
171 KEEP(*(__patchable_function_entries)) \
172 __stop_mcount_loc = .; \
173 ftrace_stub_graph = ftrace_stub;
174 #else
175 # ifdef CONFIG_FUNCTION_TRACER
176 # define MCOUNT_REC() ftrace_stub_graph = ftrace_stub;
177 # else
178 # define MCOUNT_REC()
179 # endif
180 #endif
181
182 #ifdef CONFIG_TRACE_BRANCH_PROFILING
183 #define LIKELY_PROFILE() __start_annotated_branch_profile = .; \
184 KEEP(*(_ftrace_annotated_branch)) \
185 __stop_annotated_branch_profile = .;
186 #else
187 #define LIKELY_PROFILE()
188 #endif
189
190 #ifdef CONFIG_PROFILE_ALL_BRANCHES
191 #define BRANCH_PROFILE() __start_branch_profile = .; \
192 KEEP(*(_ftrace_branch)) \
193 __stop_branch_profile = .;
194 #else
195 #define BRANCH_PROFILE()
196 #endif
197
198 #ifdef CONFIG_KPROBES
199 #define KPROBE_BLACKLIST() . = ALIGN(8); \
200 __start_kprobe_blacklist = .; \
201 KEEP(*(_kprobe_blacklist)) \
202 __stop_kprobe_blacklist = .;
203 #else
204 #define KPROBE_BLACKLIST()
205 #endif
206
207 #ifdef CONFIG_FUNCTION_ERROR_INJECTION
208 #define ERROR_INJECT_WHITELIST() STRUCT_ALIGN(); \
209 __start_error_injection_whitelist = .; \
210 KEEP(*(_error_injection_whitelist)) \
211 __stop_error_injection_whitelist = .;
212 #else
213 #define ERROR_INJECT_WHITELIST()
214 #endif
215
216 #ifdef CONFIG_EVENT_TRACING
217 #define FTRACE_EVENTS() . = ALIGN(8); \
218 __start_ftrace_events = .; \
219 KEEP(*(_ftrace_events)) \
220 __stop_ftrace_events = .; \
221 __start_ftrace_eval_maps = .; \
222 KEEP(*(_ftrace_eval_map)) \
223 __stop_ftrace_eval_maps = .;
224 #else
225 #define FTRACE_EVENTS()
226 #endif
227
228 #ifdef CONFIG_TRACING
229 #define TRACE_PRINTKS() __start___trace_bprintk_fmt = .; \
230 KEEP(*(__trace_printk_fmt)) /* Trace_printk fmt' pointer */ \
231 __stop___trace_bprintk_fmt = .;
232 #define TRACEPOINT_STR() __start___tracepoint_str = .; \
233 KEEP(*(__tracepoint_str)) /* Trace_printk fmt' pointer */ \
234 __stop___tracepoint_str = .;
235 #else
236 #define TRACE_PRINTKS()
237 #define TRACEPOINT_STR()
238 #endif
239
240 #ifdef CONFIG_FTRACE_SYSCALLS
241 #define TRACE_SYSCALLS() . = ALIGN(8); \
242 __start_syscalls_metadata = .; \
243 KEEP(*(__syscalls_metadata)) \
244 __stop_syscalls_metadata = .;
245 #else
246 #define TRACE_SYSCALLS()
247 #endif
248
249 #ifdef CONFIG_BPF_EVENTS
250 #define BPF_RAW_TP() STRUCT_ALIGN(); \
251 __start__bpf_raw_tp = .; \
252 KEEP(*(__bpf_raw_tp_map)) \
253 __stop__bpf_raw_tp = .;
254 #else
255 #define BPF_RAW_TP()
256 #endif
257
258 #ifdef CONFIG_SERIAL_EARLYCON
259 #define EARLYCON_TABLE() . = ALIGN(8); \
260 __earlycon_table = .; \
261 KEEP(*(__earlycon_table)) \
262 __earlycon_table_end = .;
263 #else
264 #define EARLYCON_TABLE()
265 #endif
266
267 #ifdef CONFIG_SECURITY
268 #define LSM_TABLE() . = ALIGN(8); \
269 __start_lsm_info = .; \
270 KEEP(*(.lsm_info.init)) \
271 __end_lsm_info = .;
272 #define EARLY_LSM_TABLE() . = ALIGN(8); \
273 __start_early_lsm_info = .; \
274 KEEP(*(.early_lsm_info.init)) \
275 __end_early_lsm_info = .;
276 #else
277 #define LSM_TABLE()
278 #define EARLY_LSM_TABLE()
279 #endif
280
281 #define ___OF_TABLE(cfg, name) _OF_TABLE_##cfg(name)
282 #define __OF_TABLE(cfg, name) ___OF_TABLE(cfg, name)
283 #define OF_TABLE(cfg, name) __OF_TABLE(IS_ENABLED(cfg), name)
284 #define _OF_TABLE_0(name)
285 #define _OF_TABLE_1(name) \
286 . = ALIGN(8); \
287 __##name##_of_table = .; \
288 KEEP(*(__##name##_of_table)) \
289 KEEP(*(__##name##_of_table_end))
290
291 #define TIMER_OF_TABLES() OF_TABLE(CONFIG_TIMER_OF, timer)
292 #define IRQCHIP_OF_MATCH_TABLE() OF_TABLE(CONFIG_IRQCHIP, irqchip)
293 #define CLK_OF_TABLES() OF_TABLE(CONFIG_COMMON_CLK, clk)
294 #define RESERVEDMEM_OF_TABLES() OF_TABLE(CONFIG_OF_RESERVED_MEM, reservedmem)
295 #define CPU_METHOD_OF_TABLES() OF_TABLE(CONFIG_SMP, cpu_method)
296 #define CPUIDLE_METHOD_OF_TABLES() OF_TABLE(CONFIG_CPU_IDLE, cpuidle_method)
297
298 #ifdef CONFIG_ACPI
299 #define ACPI_PROBE_TABLE(name) \
300 . = ALIGN(8); \
301 __##name##_acpi_probe_table = .; \
302 KEEP(*(__##name##_acpi_probe_table)) \
303 __##name##_acpi_probe_table_end = .;
304 #else
305 #define ACPI_PROBE_TABLE(name)
306 #endif
307
308 #ifdef CONFIG_THERMAL
309 #define THERMAL_TABLE(name) \
310 . = ALIGN(8); \
311 __##name##_thermal_table = .; \
312 KEEP(*(__##name##_thermal_table)) \
313 __##name##_thermal_table_end = .;
314 #else
315 #define THERMAL_TABLE(name)
316 #endif
317
318 #ifdef CONFIG_DTPM
319 #define DTPM_TABLE() \
320 . = ALIGN(8); \
321 __dtpm_table = .; \
322 KEEP(*(__dtpm_table)) \
323 __dtpm_table_end = .;
324 #else
325 #define DTPM_TABLE()
326 #endif
327
328 #define KERNEL_DTB() \
329 STRUCT_ALIGN(); \
330 __dtb_start = .; \
331 KEEP(*(.dtb.init.rodata)) \
332 __dtb_end = .;
333
334 /*
335 * .data section
336 */
337 #define DATA_DATA \
338 *(.xiptext) \
339 *(DATA_MAIN) \
340 *(.ref.data) \
341 *(.data..shared_aligned) /* percpu related */ \
342 MEM_KEEP(init.data*) \
343 MEM_KEEP(exit.data*) \
344 *(.data.unlikely) \
345 __start_once = .; \
346 *(.data.once) \
347 __end_once = .; \
348 STRUCT_ALIGN(); \
349 *(__tracepoints) \
350 /* implement dynamic printk debug */ \
351 . = ALIGN(8); \
352 __start___dyndbg = .; \
353 KEEP(*(__dyndbg)) \
354 __stop___dyndbg = .; \
355 LIKELY_PROFILE() \
356 BRANCH_PROFILE() \
357 TRACE_PRINTKS() \
358 BPF_RAW_TP() \
359 TRACEPOINT_STR()
360
361 /*
362 * Data section helpers
363 */
364 #define NOSAVE_DATA \
365 . = ALIGN(PAGE_SIZE); \
366 __nosave_begin = .; \
367 *(.data..nosave) \
368 . = ALIGN(PAGE_SIZE); \
369 __nosave_end = .;
370
371 #define PAGE_ALIGNED_DATA(page_align) \
372 . = ALIGN(page_align); \
373 *(.data..page_aligned) \
374 . = ALIGN(page_align);
375
376 #define READ_MOSTLY_DATA(align) \
377 . = ALIGN(align); \
378 *(.data..read_mostly) \
379 . = ALIGN(align);
380
381 #define CACHELINE_ALIGNED_DATA(align) \
382 . = ALIGN(align); \
383 *(.data..cacheline_aligned)
384
385 #define INIT_TASK_DATA(align) \
386 . = ALIGN(align); \
387 __start_init_task = .; \
388 init_thread_union = .; \
389 init_stack = .; \
390 KEEP(*(.data..init_task)) \
391 KEEP(*(.data..init_thread_info)) \
392 . = __start_init_task + THREAD_SIZE; \
393 __end_init_task = .;
394
395 #define JUMP_TABLE_DATA \
396 . = ALIGN(8); \
397 __start___jump_table = .; \
398 KEEP(*(__jump_table)) \
399 __stop___jump_table = .;
400
401 #define STATIC_CALL_DATA \
402 . = ALIGN(8); \
403 __start_static_call_sites = .; \
404 KEEP(*(.static_call_sites)) \
405 __stop_static_call_sites = .; \
406 __start_static_call_tramp_key = .; \
407 KEEP(*(.static_call_tramp_key)) \
408 __stop_static_call_tramp_key = .;
409
410 /*
411 * Allow architectures to handle ro_after_init data on their
412 * own by defining an empty RO_AFTER_INIT_DATA.
413 */
414 #ifndef RO_AFTER_INIT_DATA
415 #define RO_AFTER_INIT_DATA \
416 . = ALIGN(8); \
417 __start_ro_after_init = .; \
418 *(.data..ro_after_init) \
419 JUMP_TABLE_DATA \
420 STATIC_CALL_DATA \
421 __end_ro_after_init = .;
422 #endif
423
424 /*
425 * Read only Data
426 */
427 #define RO_DATA(align) \
428 . = ALIGN((align)); \
429 .rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
430 __start_rodata = .; \
431 *(.rodata) *(.rodata.*) \
432 SCHED_DATA \
433 RO_AFTER_INIT_DATA /* Read only after init */ \
434 . = ALIGN(8); \
435 __start___tracepoints_ptrs = .; \
436 KEEP(*(__tracepoints_ptrs)) /* Tracepoints: pointer array */ \
437 __stop___tracepoints_ptrs = .; \
438 *(__tracepoints_strings)/* Tracepoints: strings */ \
439 } \
440 \
441 .rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
442 *(.rodata1) \
443 } \
444 \
445 /* PCI quirks */ \
446 .pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
447 __start_pci_fixups_early = .; \
448 KEEP(*(.pci_fixup_early)) \
449 __end_pci_fixups_early = .; \
450 __start_pci_fixups_header = .; \
451 KEEP(*(.pci_fixup_header)) \
452 __end_pci_fixups_header = .; \
453 __start_pci_fixups_final = .; \
454 KEEP(*(.pci_fixup_final)) \
455 __end_pci_fixups_final = .; \
456 __start_pci_fixups_enable = .; \
457 KEEP(*(.pci_fixup_enable)) \
458 __end_pci_fixups_enable = .; \
459 __start_pci_fixups_resume = .; \
460 KEEP(*(.pci_fixup_resume)) \
461 __end_pci_fixups_resume = .; \
462 __start_pci_fixups_resume_early = .; \
463 KEEP(*(.pci_fixup_resume_early)) \
464 __end_pci_fixups_resume_early = .; \
465 __start_pci_fixups_suspend = .; \
466 KEEP(*(.pci_fixup_suspend)) \
467 __end_pci_fixups_suspend = .; \
468 __start_pci_fixups_suspend_late = .; \
469 KEEP(*(.pci_fixup_suspend_late)) \
470 __end_pci_fixups_suspend_late = .; \
471 } \
472 \
473 /* Built-in firmware blobs */ \
474 .builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) ALIGN(8) { \
475 __start_builtin_fw = .; \
476 KEEP(*(.builtin_fw)) \
477 __end_builtin_fw = .; \
478 } \
479 \
480 TRACEDATA \
481 \
482 PRINTK_INDEX \
483 \
484 /* Kernel symbol table: Normal symbols */ \
485 __ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
486 __start___ksymtab = .; \
487 KEEP(*(SORT(___ksymtab+*))) \
488 __stop___ksymtab = .; \
489 } \
490 \
491 /* Kernel symbol table: GPL-only symbols */ \
492 __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
493 __start___ksymtab_gpl = .; \
494 KEEP(*(SORT(___ksymtab_gpl+*))) \
495 __stop___ksymtab_gpl = .; \
496 } \
497 \
498 /* Kernel symbol table: Normal symbols */ \
499 __kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
500 __start___kcrctab = .; \
501 KEEP(*(SORT(___kcrctab+*))) \
502 __stop___kcrctab = .; \
503 } \
504 \
505 /* Kernel symbol table: GPL-only symbols */ \
506 __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
507 __start___kcrctab_gpl = .; \
508 KEEP(*(SORT(___kcrctab_gpl+*))) \
509 __stop___kcrctab_gpl = .; \
510 } \
511 \
512 /* Kernel symbol table: strings */ \
513 __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
514 *(__ksymtab_strings) \
515 } \
516 \
517 /* __*init sections */ \
518 __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
519 *(.ref.rodata) \
520 MEM_KEEP(init.rodata) \
521 MEM_KEEP(exit.rodata) \
522 } \
523 \
524 /* Built-in module parameters. */ \
525 __param : AT(ADDR(__param) - LOAD_OFFSET) { \
526 __start___param = .; \
527 KEEP(*(__param)) \
528 __stop___param = .; \
529 } \
530 \
531 /* Built-in module versions. */ \
532 __modver : AT(ADDR(__modver) - LOAD_OFFSET) { \
533 __start___modver = .; \
534 KEEP(*(__modver)) \
535 __stop___modver = .; \
536 } \
537 \
538 RO_EXCEPTION_TABLE \
539 NOTES \
540 BTF \
541 \
542 . = ALIGN((align)); \
543 __end_rodata = .;
544
545
546 /*
547 * .text..L.cfi.jumptable.* contain Control-Flow Integrity (CFI)
548 * jump table entries.
549 */
550 #ifdef CONFIG_CFI_CLANG
551 #define TEXT_CFI_JT \
552 . = ALIGN(PMD_SIZE); \
553 __cfi_jt_start = .; \
554 *(.text..L.cfi.jumptable .text..L.cfi.jumptable.*) \
555 . = ALIGN(PMD_SIZE); \
556 __cfi_jt_end = .;
557 #else
558 #define TEXT_CFI_JT
559 #endif
560
561 /*
562 * Non-instrumentable text section
563 */
564 #define NOINSTR_TEXT \
565 ALIGN_FUNCTION(); \
566 __noinstr_text_start = .; \
567 *(.noinstr.text) \
568 __noinstr_text_end = .;
569
570 /*
571 * .text section. Map to function alignment to avoid address changes
572 * during second ld run in second ld pass when generating System.map
573 *
574 * TEXT_MAIN here will match .text.fixup and .text.unlikely if dead
575 * code elimination is enabled, so these sections should be converted
576 * to use ".." first.
577 */
578 #define TEXT_TEXT \
579 ALIGN_FUNCTION(); \
580 *(.text.hot .text.hot.*) \
581 *(TEXT_MAIN .text.fixup) \
582 *(.text.unlikely .text.unlikely.*) \
583 *(.text.unknown .text.unknown.*) \
584 NOINSTR_TEXT \
585 *(.text..refcount) \
586 *(.ref.text) \
587 *(.text.asan.* .text.tsan.*) \
588 TEXT_CFI_JT \
589 MEM_KEEP(init.text*) \
590 MEM_KEEP(exit.text*) \
591
592
593 /* sched.text is aling to function alignment to secure we have same
594 * address even at second ld pass when generating System.map */
595 #define SCHED_TEXT \
596 ALIGN_FUNCTION(); \
597 __sched_text_start = .; \
598 *(.sched.text) \
599 __sched_text_end = .;
600
601 /* spinlock.text is aling to function alignment to secure we have same
602 * address even at second ld pass when generating System.map */
603 #define LOCK_TEXT \
604 ALIGN_FUNCTION(); \
605 __lock_text_start = .; \
606 *(.spinlock.text) \
607 __lock_text_end = .;
608
609 #define CPUIDLE_TEXT \
610 ALIGN_FUNCTION(); \
611 __cpuidle_text_start = .; \
612 *(.cpuidle.text) \
613 __cpuidle_text_end = .;
614
615 #define KPROBES_TEXT \
616 ALIGN_FUNCTION(); \
617 __kprobes_text_start = .; \
618 *(.kprobes.text) \
619 __kprobes_text_end = .;
620
621 #define ENTRY_TEXT \
622 ALIGN_FUNCTION(); \
623 __entry_text_start = .; \
624 *(.entry.text) \
625 __entry_text_end = .;
626
627 #define IRQENTRY_TEXT \
628 ALIGN_FUNCTION(); \
629 __irqentry_text_start = .; \
630 *(.irqentry.text) \
631 __irqentry_text_end = .;
632
633 #define SOFTIRQENTRY_TEXT \
634 ALIGN_FUNCTION(); \
635 __softirqentry_text_start = .; \
636 *(.softirqentry.text) \
637 __softirqentry_text_end = .;
638
639 #define STATIC_CALL_TEXT \
640 ALIGN_FUNCTION(); \
641 __static_call_text_start = .; \
642 *(.static_call.text) \
643 __static_call_text_end = .;
644
645 /* Section used for early init (in .S files) */
646 #define HEAD_TEXT KEEP(*(.head.text))
647
648 #define HEAD_TEXT_SECTION \
649 .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { \
650 HEAD_TEXT \
651 }
652
653 /*
654 * Exception table
655 */
656 #define EXCEPTION_TABLE(align) \
657 . = ALIGN(align); \
658 __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { \
659 __start___ex_table = .; \
660 KEEP(*(__ex_table)) \
661 __stop___ex_table = .; \
662 }
663
664 /*
665 * .BTF
666 */
667 #ifdef CONFIG_DEBUG_INFO_BTF
668 #define BTF \
669 .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) { \
670 __start_BTF = .; \
671 KEEP(*(.BTF)) \
672 __stop_BTF = .; \
673 } \
674 . = ALIGN(4); \
675 .BTF_ids : AT(ADDR(.BTF_ids) - LOAD_OFFSET) { \
676 *(.BTF_ids) \
677 }
678 #else
679 #define BTF
680 #endif
681
682 /*
683 * Init task
684 */
685 #define INIT_TASK_DATA_SECTION(align) \
686 . = ALIGN(align); \
687 .data..init_task : AT(ADDR(.data..init_task) - LOAD_OFFSET) { \
688 INIT_TASK_DATA(align) \
689 }
690
691 #ifdef CONFIG_CONSTRUCTORS
692 #define KERNEL_CTORS() . = ALIGN(8); \
693 __ctors_start = .; \
694 KEEP(*(SORT(.ctors.*))) \
695 KEEP(*(.ctors)) \
696 KEEP(*(SORT(.init_array.*))) \
697 KEEP(*(.init_array)) \
698 __ctors_end = .;
699 #else
700 #define KERNEL_CTORS()
701 #endif
702
703 /* init and exit section handling */
704 #define INIT_DATA \
705 KEEP(*(SORT(___kentry+*))) \
706 *(.init.data init.data.*) \
707 MEM_DISCARD(init.data*) \
708 KERNEL_CTORS() \
709 MCOUNT_REC() \
710 *(.init.rodata .init.rodata.*) \
711 FTRACE_EVENTS() \
712 TRACE_SYSCALLS() \
713 KPROBE_BLACKLIST() \
714 ERROR_INJECT_WHITELIST() \
715 MEM_DISCARD(init.rodata) \
716 CLK_OF_TABLES() \
717 RESERVEDMEM_OF_TABLES() \
718 TIMER_OF_TABLES() \
719 CPU_METHOD_OF_TABLES() \
720 CPUIDLE_METHOD_OF_TABLES() \
721 KERNEL_DTB() \
722 IRQCHIP_OF_MATCH_TABLE() \
723 ACPI_PROBE_TABLE(irqchip) \
724 ACPI_PROBE_TABLE(timer) \
725 THERMAL_TABLE(governor) \
726 DTPM_TABLE() \
727 EARLYCON_TABLE() \
728 LSM_TABLE() \
729 EARLY_LSM_TABLE() \
730 KUNIT_TABLE()
731
732 #define INIT_TEXT \
733 *(.init.text .init.text.*) \
734 *(.text.startup) \
735 MEM_DISCARD(init.text*)
736
737 #define EXIT_DATA \
738 *(.exit.data .exit.data.*) \
739 *(.fini_array .fini_array.*) \
740 *(.dtors .dtors.*) \
741 MEM_DISCARD(exit.data*) \
742 MEM_DISCARD(exit.rodata*)
743
744 #define EXIT_TEXT \
745 *(.exit.text) \
746 *(.text.exit) \
747 MEM_DISCARD(exit.text)
748
749 #define EXIT_CALL \
750 *(.exitcall.exit)
751
752 /*
753 * bss (Block Started by Symbol) - uninitialized data
754 * zeroed during startup
755 */
756 #define SBSS(sbss_align) \
757 . = ALIGN(sbss_align); \
758 .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) { \
759 *(.dynsbss) \
760 *(SBSS_MAIN) \
761 *(.scommon) \
762 }
763
764 /*
765 * Allow archectures to redefine BSS_FIRST_SECTIONS to add extra
766 * sections to the front of bss.
767 */
768 #ifndef BSS_FIRST_SECTIONS
769 #define BSS_FIRST_SECTIONS
770 #endif
771
772 #define BSS(bss_align) \
773 . = ALIGN(bss_align); \
774 .bss : AT(ADDR(.bss) - LOAD_OFFSET) { \
775 BSS_FIRST_SECTIONS \
776 . = ALIGN(PAGE_SIZE); \
777 *(.bss..page_aligned) \
778 . = ALIGN(PAGE_SIZE); \
779 *(.dynbss) \
780 *(BSS_MAIN) \
781 *(COMMON) \
782 }
783
784 /*
785 * DWARF debug sections.
786 * Symbols in the DWARF debugging sections are relative to
787 * the beginning of the section so we begin them at 0.
788 */
789 #define DWARF_DEBUG \
790 /* DWARF 1 */ \
791 .debug 0 : { *(.debug) } \
792 .line 0 : { *(.line) } \
793 /* GNU DWARF 1 extensions */ \
794 .debug_srcinfo 0 : { *(.debug_srcinfo) } \
795 .debug_sfnames 0 : { *(.debug_sfnames) } \
796 /* DWARF 1.1 and DWARF 2 */ \
797 .debug_aranges 0 : { *(.debug_aranges) } \
798 .debug_pubnames 0 : { *(.debug_pubnames) } \
799 /* DWARF 2 */ \
800 .debug_info 0 : { *(.debug_info \
801 .gnu.linkonce.wi.*) } \
802 .debug_abbrev 0 : { *(.debug_abbrev) } \
803 .debug_line 0 : { *(.debug_line) } \
804 .debug_frame 0 : { *(.debug_frame) } \
805 .debug_str 0 : { *(.debug_str) } \
806 .debug_loc 0 : { *(.debug_loc) } \
807 .debug_macinfo 0 : { *(.debug_macinfo) } \
808 .debug_pubtypes 0 : { *(.debug_pubtypes) } \
809 /* DWARF 3 */ \
810 .debug_ranges 0 : { *(.debug_ranges) } \
811 /* SGI/MIPS DWARF 2 extensions */ \
812 .debug_weaknames 0 : { *(.debug_weaknames) } \
813 .debug_funcnames 0 : { *(.debug_funcnames) } \
814 .debug_typenames 0 : { *(.debug_typenames) } \
815 .debug_varnames 0 : { *(.debug_varnames) } \
816 /* GNU DWARF 2 extensions */ \
817 .debug_gnu_pubnames 0 : { *(.debug_gnu_pubnames) } \
818 .debug_gnu_pubtypes 0 : { *(.debug_gnu_pubtypes) } \
819 /* DWARF 4 */ \
820 .debug_types 0 : { *(.debug_types) } \
821 /* DWARF 5 */ \
822 .debug_addr 0 : { *(.debug_addr) } \
823 .debug_line_str 0 : { *(.debug_line_str) } \
824 .debug_loclists 0 : { *(.debug_loclists) } \
825 .debug_macro 0 : { *(.debug_macro) } \
826 .debug_names 0 : { *(.debug_names) } \
827 .debug_rnglists 0 : { *(.debug_rnglists) } \
828 .debug_str_offsets 0 : { *(.debug_str_offsets) }
829
830 /* Stabs debugging sections. */
831 #define STABS_DEBUG \
832 .stab 0 : { *(.stab) } \
833 .stabstr 0 : { *(.stabstr) } \
834 .stab.excl 0 : { *(.stab.excl) } \
835 .stab.exclstr 0 : { *(.stab.exclstr) } \
836 .stab.index 0 : { *(.stab.index) } \
837 .stab.indexstr 0 : { *(.stab.indexstr) }
838
839 /* Required sections not related to debugging. */
840 #define ELF_DETAILS \
841 .comment 0 : { *(.comment) } \
842 .symtab 0 : { *(.symtab) } \
843 .strtab 0 : { *(.strtab) } \
844 .shstrtab 0 : { *(.shstrtab) }
845
846 #ifdef CONFIG_GENERIC_BUG
847 #define BUG_TABLE \
848 . = ALIGN(8); \
849 __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
850 __start___bug_table = .; \
851 KEEP(*(__bug_table)) \
852 __stop___bug_table = .; \
853 }
854 #else
855 #define BUG_TABLE
856 #endif
857
858 #ifdef CONFIG_UNWINDER_ORC
859 #define ORC_UNWIND_TABLE \
860 . = ALIGN(4); \
861 .orc_unwind_ip : AT(ADDR(.orc_unwind_ip) - LOAD_OFFSET) { \
862 __start_orc_unwind_ip = .; \
863 KEEP(*(.orc_unwind_ip)) \
864 __stop_orc_unwind_ip = .; \
865 } \
866 . = ALIGN(2); \
867 .orc_unwind : AT(ADDR(.orc_unwind) - LOAD_OFFSET) { \
868 __start_orc_unwind = .; \
869 KEEP(*(.orc_unwind)) \
870 __stop_orc_unwind = .; \
871 } \
872 . = ALIGN(4); \
873 .orc_lookup : AT(ADDR(.orc_lookup) - LOAD_OFFSET) { \
874 orc_lookup = .; \
875 . += (((SIZEOF(.text) + LOOKUP_BLOCK_SIZE - 1) / \
876 LOOKUP_BLOCK_SIZE) + 1) * 4; \
877 orc_lookup_end = .; \
878 }
879 #else
880 #define ORC_UNWIND_TABLE
881 #endif
882
883 #ifdef CONFIG_PM_TRACE
884 #define TRACEDATA \
885 . = ALIGN(4); \
886 .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
887 __tracedata_start = .; \
888 KEEP(*(.tracedata)) \
889 __tracedata_end = .; \
890 }
891 #else
892 #define TRACEDATA
893 #endif
894
895 #ifdef CONFIG_PRINTK_INDEX
896 #define PRINTK_INDEX \
897 .printk_index : AT(ADDR(.printk_index) - LOAD_OFFSET) { \
898 __start_printk_index = .; \
899 *(.printk_index) \
900 __stop_printk_index = .; \
901 }
902 #else
903 #define PRINTK_INDEX
904 #endif
905
906 #define NOTES \
907 .notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
908 __start_notes = .; \
909 KEEP(*(.note.*)) \
910 __stop_notes = .; \
911 } NOTES_HEADERS \
912 NOTES_HEADERS_RESTORE
913
914 #define INIT_SETUP(initsetup_align) \
915 . = ALIGN(initsetup_align); \
916 __setup_start = .; \
917 KEEP(*(.init.setup)) \
918 __setup_end = .;
919
920 #define INIT_CALLS_LEVEL(level) \
921 __initcall##level##_start = .; \
922 KEEP(*(.initcall##level##.init)) \
923 KEEP(*(.initcall##level##s.init)) \
924
925 #define INIT_CALLS \
926 __initcall_start = .; \
927 KEEP(*(.initcallearly.init)) \
928 INIT_CALLS_LEVEL(0) \
929 INIT_CALLS_LEVEL(1) \
930 INIT_CALLS_LEVEL(2) \
931 INIT_CALLS_LEVEL(3) \
932 INIT_CALLS_LEVEL(4) \
933 INIT_CALLS_LEVEL(5) \
934 INIT_CALLS_LEVEL(rootfs) \
935 INIT_CALLS_LEVEL(6) \
936 INIT_CALLS_LEVEL(7) \
937 __initcall_end = .;
938
939 #define CON_INITCALL \
940 __con_initcall_start = .; \
941 KEEP(*(.con_initcall.init)) \
942 __con_initcall_end = .;
943
944 /* Alignment must be consistent with (kunit_suite *) in include/kunit/test.h */
945 #define KUNIT_TABLE() \
946 . = ALIGN(8); \
947 __kunit_suites_start = .; \
948 KEEP(*(.kunit_test_suites)) \
949 __kunit_suites_end = .;
950
951 #ifdef CONFIG_BLK_DEV_INITRD
952 #define INIT_RAM_FS \
953 . = ALIGN(4); \
954 __initramfs_start = .; \
955 KEEP(*(.init.ramfs)) \
956 . = ALIGN(8); \
957 KEEP(*(.init.ramfs.info))
958 #else
959 #define INIT_RAM_FS
960 #endif
961
962 /*
963 * Memory encryption operates on a page basis. Since we need to clear
964 * the memory encryption mask for this section, it needs to be aligned
965 * on a page boundary and be a page-size multiple in length.
966 *
967 * Note: We use a separate section so that only this section gets
968 * decrypted to avoid exposing more than we wish.
969 */
970 #ifdef CONFIG_AMD_MEM_ENCRYPT
971 #define PERCPU_DECRYPTED_SECTION \
972 . = ALIGN(PAGE_SIZE); \
973 *(.data..decrypted) \
974 *(.data..percpu..decrypted) \
975 . = ALIGN(PAGE_SIZE);
976 #else
977 #define PERCPU_DECRYPTED_SECTION
978 #endif
979
980
981 /*
982 * Default discarded sections.
983 *
984 * Some archs want to discard exit text/data at runtime rather than
985 * link time due to cross-section references such as alt instructions,
986 * bug table, eh_frame, etc. DISCARDS must be the last of output
987 * section definitions so that such archs put those in earlier section
988 * definitions.
989 */
990 #ifdef RUNTIME_DISCARD_EXIT
991 #define EXIT_DISCARDS
992 #else
993 #define EXIT_DISCARDS \
994 EXIT_TEXT \
995 EXIT_DATA
996 #endif
997
998 /*
999 * Clang's -fprofile-arcs, -fsanitize=kernel-address, and
1000 * -fsanitize=thread produce unwanted sections (.eh_frame
1001 * and .init_array.*), but CONFIG_CONSTRUCTORS wants to
1002 * keep any .init_array.* sections.
1003 * https://bugs.llvm.org/show_bug.cgi?id=46478
1004 */
1005 #if defined(CONFIG_GCOV_KERNEL) || defined(CONFIG_KASAN_GENERIC) || defined(CONFIG_KCSAN) || \
1006 defined(CONFIG_CFI_CLANG)
1007 # ifdef CONFIG_CONSTRUCTORS
1008 # define SANITIZER_DISCARDS \
1009 *(.eh_frame)
1010 # else
1011 # define SANITIZER_DISCARDS \
1012 *(.init_array) *(.init_array.*) \
1013 *(.eh_frame)
1014 # endif
1015 #else
1016 # define SANITIZER_DISCARDS
1017 #endif
1018
1019 #define COMMON_DISCARDS \
1020 SANITIZER_DISCARDS \
1021 *(.discard) \
1022 *(.discard.*) \
1023 *(.modinfo) \
1024 /* ld.bfd warns about .gnu.version* even when not emitted */ \
1025 *(.gnu.version*) \
1026
1027 #define DISCARDS \
1028 /DISCARD/ : { \
1029 EXIT_DISCARDS \
1030 EXIT_CALL \
1031 COMMON_DISCARDS \
1032 }
1033
1034 /**
1035 * PERCPU_INPUT - the percpu input sections
1036 * @cacheline: cacheline size
1037 *
1038 * The core percpu section names and core symbols which do not rely
1039 * directly upon load addresses.
1040 *
1041 * @cacheline is used to align subsections to avoid false cacheline
1042 * sharing between subsections for different purposes.
1043 */
1044 #define PERCPU_INPUT(cacheline) \
1045 __per_cpu_start = .; \
1046 *(.data..percpu..first) \
1047 . = ALIGN(PAGE_SIZE); \
1048 *(.data..percpu..page_aligned) \
1049 . = ALIGN(cacheline); \
1050 *(.data..percpu..read_mostly) \
1051 . = ALIGN(cacheline); \
1052 *(.data..percpu) \
1053 *(.data..percpu..shared_aligned) \
1054 PERCPU_DECRYPTED_SECTION \
1055 __per_cpu_end = .;
1056
1057 /**
1058 * PERCPU_VADDR - define output section for percpu area
1059 * @cacheline: cacheline size
1060 * @vaddr: explicit base address (optional)
1061 * @phdr: destination PHDR (optional)
1062 *
1063 * Macro which expands to output section for percpu area.
1064 *
1065 * @cacheline is used to align subsections to avoid false cacheline
1066 * sharing between subsections for different purposes.
1067 *
1068 * If @vaddr is not blank, it specifies explicit base address and all
1069 * percpu symbols will be offset from the given address. If blank,
1070 * @vaddr always equals @laddr + LOAD_OFFSET.
1071 *
1072 * @phdr defines the output PHDR to use if not blank. Be warned that
1073 * output PHDR is sticky. If @phdr is specified, the next output
1074 * section in the linker script will go there too. @phdr should have
1075 * a leading colon.
1076 *
1077 * Note that this macros defines __per_cpu_load as an absolute symbol.
1078 * If there is no need to put the percpu section at a predetermined
1079 * address, use PERCPU_SECTION.
1080 */
1081 #define PERCPU_VADDR(cacheline, vaddr, phdr) \
1082 __per_cpu_load = .; \
1083 .data..percpu vaddr : AT(__per_cpu_load - LOAD_OFFSET) { \
1084 PERCPU_INPUT(cacheline) \
1085 } phdr \
1086 . = __per_cpu_load + SIZEOF(.data..percpu);
1087
1088 /**
1089 * PERCPU_SECTION - define output section for percpu area, simple version
1090 * @cacheline: cacheline size
1091 *
1092 * Align to PAGE_SIZE and outputs output section for percpu area. This
1093 * macro doesn't manipulate @vaddr or @phdr and __per_cpu_load and
1094 * __per_cpu_start will be identical.
1095 *
1096 * This macro is equivalent to ALIGN(PAGE_SIZE); PERCPU_VADDR(@cacheline,,)
1097 * except that __per_cpu_load is defined as a relative symbol against
1098 * .data..percpu which is required for relocatable x86_32 configuration.
1099 */
1100 #define PERCPU_SECTION(cacheline) \
1101 . = ALIGN(PAGE_SIZE); \
1102 .data..percpu : AT(ADDR(.data..percpu) - LOAD_OFFSET) { \
1103 __per_cpu_load = .; \
1104 PERCPU_INPUT(cacheline) \
1105 }
1106
1107
1108 /*
1109 * Definition of the high level *_SECTION macros
1110 * They will fit only a subset of the architectures
1111 */
1112
1113
1114 /*
1115 * Writeable data.
1116 * All sections are combined in a single .data section.
1117 * The sections following CONSTRUCTORS are arranged so their
1118 * typical alignment matches.
1119 * A cacheline is typical/always less than a PAGE_SIZE so
1120 * the sections that has this restriction (or similar)
1121 * is located before the ones requiring PAGE_SIZE alignment.
1122 * NOSAVE_DATA starts and ends with a PAGE_SIZE alignment which
1123 * matches the requirement of PAGE_ALIGNED_DATA.
1124 *
1125 * use 0 as page_align if page_aligned data is not used */
1126 #define RW_DATA(cacheline, pagealigned, inittask) \
1127 . = ALIGN(PAGE_SIZE); \
1128 .data : AT(ADDR(.data) - LOAD_OFFSET) { \
1129 INIT_TASK_DATA(inittask) \
1130 NOSAVE_DATA \
1131 PAGE_ALIGNED_DATA(pagealigned) \
1132 CACHELINE_ALIGNED_DATA(cacheline) \
1133 READ_MOSTLY_DATA(cacheline) \
1134 DATA_DATA \
1135 CONSTRUCTORS \
1136 } \
1137 BUG_TABLE \
1138
1139 #define INIT_TEXT_SECTION(inittext_align) \
1140 . = ALIGN(inittext_align); \
1141 .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { \
1142 _sinittext = .; \
1143 INIT_TEXT \
1144 _einittext = .; \
1145 }
1146
1147 #define INIT_DATA_SECTION(initsetup_align) \
1148 .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { \
1149 INIT_DATA \
1150 INIT_SETUP(initsetup_align) \
1151 INIT_CALLS \
1152 CON_INITCALL \
1153 INIT_RAM_FS \
1154 }
1155
1156 #define BSS_SECTION(sbss_align, bss_align, stop_align) \
1157 . = ALIGN(sbss_align); \
1158 __bss_start = .; \
1159 SBSS(sbss_align) \
1160 BSS(bss_align) \
1161 . = ALIGN(stop_align); \
1162 __bss_stop = .;
Ubuntu Jammy Linux kernel mirror