MdeModulePkg/UfsPciHcDxe: Fix EBC build error

[mirror_edk2.git] / ArmPlatformPkg / ArmVirtualizationPkg / Library / ArmXenRelocatablePlatformLib / AARCH64 / RelocatableVirtHelper.S

#\r
#  Copyright (c) 2011-2013, ARM Limited. All rights reserved.\r
#\r
#  This program and the accompanying materials\r
#  are licensed and made available under the terms and conditions of the BSD License\r
#  which accompanies this distribution.  The full text of the license may be found at\r
#  http://opensource.org/licenses/bsd-license.php\r
#\r
#  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
#  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
#\r
\r
#include <AsmMacroIoLibV8.h>\r
#include <Base.h>\r
#include <Library/ArmLib.h>\r
#include <Library/PcdLib.h>\r
#include <AutoGen.h>\r
\r
.text\r
.align 2\r
\r
GCC_ASM_EXPORT(ArmPlatformPeiBootAction)\r
GCC_ASM_EXPORT(ArmPlatformIsPrimaryCore)\r
GCC_ASM_EXPORT(ArmPlatformGetPrimaryCoreMpId)\r
GCC_ASM_EXPORT(ArmPlatformGetCorePosition)\r
GCC_ASM_EXPORT(ArmGetPhysAddrTop)\r
\r
GCC_ASM_IMPORT(_gPcd_FixedAtBuild_PcdArmPrimaryCore)\r
GCC_ASM_IMPORT(_gPcd_FixedAtBuild_PcdArmPrimaryCoreMask)\r
GCC_ASM_IMPORT(_gPcd_FixedAtBuild_PcdCoreCount)\r
\r
.LFdtMagic:\r
  .byte   0xd0, 0x0d, 0xfe, 0xed\r
\r
.LArm64LinuxMagic:\r
  .byte   0x41, 0x52, 0x4d, 0x64\r
\r
// VOID\r
// ArmPlatformPeiBootAction (\r
//   VOID   *DeviceTreeBaseAddress,   // passed by loader in x0\r
//   VOID   *ImageBase                // passed by FDF trampoline in x1\r
//   );\r
ASM_PFX(ArmPlatformPeiBootAction):\r
  mov   x29, x30            // preserve LR\r
\r
  //\r
  // If we are booting from RAM using the Linux kernel boot protocol, x0 will\r
  // point to the DTB image in memory. Otherwise, we are just coming out of\r
  // reset, and x0 will be 0. Check also the FDT magic.\r
  //\r
  cbz   x0, .Lout\r
  ldr   w8, .LFdtMagic\r
  ldr   w9, [x0]\r
  cmp   w8, w9\r
  bne   .Lout\r
\r
  //\r
  // The base of the runtime image has been preserved in x1. Check whether\r
  // the expected magic number can be found in the header.\r
  //\r
  ldr   w8, .LArm64LinuxMagic\r
  ldr   w9, [x1, #0x38]\r
  cmp   w8, w9\r
  bne   .Lout\r
\r
  //\r
  //\r
  // OK, so far so good. We have confirmed that we likely have a DTB and are\r
  // booting via the arm64 Linux boot protocol. Update the base-of-image PCD\r
  // to the actual relocated value, and add the shift of PcdFdBaseAddress to\r
  // PcdFvBaseAddress as well\r
  //\r
  adr   x8, PcdGet64 (PcdFdBaseAddress)\r
  adr   x9, PcdGet64 (PcdFvBaseAddress)\r
  ldr   x6, [x8]\r
  ldr   x7, [x9]\r
  sub   x7, x7, x6\r
  add   x7, x7, x1\r
  str   x1, [x8]\r
  str   x7, [x9]\r
\r
  //\r
  // Copy the DTB to the slack space right after the 64 byte arm64/Linux style\r
  // image header at the base of this image (defined in the FDF), and record the\r
  // pointer in PcdDeviceTreeInitialBaseAddress.\r
  //\r
  adr   x8, PcdGet64 (PcdDeviceTreeInitialBaseAddress)\r
  add   x1, x1, #0x40\r
  str   x1, [x8]\r
\r
  ldr   w8, [x0, #4]          // get DTB size (BE)\r
  mov   x9, x1\r
  rev   w8, w8\r
  add   x8, x8, x0\r
0:ldp   x6, x7, [x0], #16\r
  stp   x6, x7, [x9], #16\r
  cmp   x0, x8\r
  blt   0b\r
\r
  //\r
  // Discover the memory size and offset from the DTB, and record in the\r
  // respective PCDs\r
  //\r
  mov   x0, x1\r
  bl    find_memnode    // returns (size, base) size in (x0, x1)\r
  cbz   x0, .Lout\r
\r
  adr   x8, PcdGet64 (PcdSystemMemorySize)\r
  adr   x9, PcdGet64 (PcdSystemMemoryBase)\r
  str   x0, [x8]\r
  str   x1, [x9]\r
\r
.Lout:\r
  ret    x29\r
\r
//UINTN\r
//ArmPlatformGetPrimaryCoreMpId (\r
//  VOID\r
//  );\r
ASM_PFX(ArmPlatformGetPrimaryCoreMpId):\r
  LoadConstantToReg (_gPcd_FixedAtBuild_PcdArmPrimaryCore, x0)\r
  ldrh   w0, [x0]\r
  ret\r
\r
//UINTN\r
//ArmPlatformIsPrimaryCore (\r
//  IN UINTN MpId\r
//  );\r
ASM_PFX(ArmPlatformIsPrimaryCore):\r
  mov   x0, #1\r
  ret\r
\r
//UINTN\r
//ArmPlatformGetCorePosition (\r
//  IN UINTN MpId\r
//  );\r
// With this function: CorePos = (ClusterId * 4) + CoreId\r
ASM_PFX(ArmPlatformGetCorePosition):\r
  and   x1, x0, #ARM_CORE_MASK\r
  and   x0, x0, #ARM_CLUSTER_MASK\r
  add   x0, x1, x0, LSR #6\r
  ret\r
\r
//EFI_PHYSICAL_ADDRESS\r
//GetPhysAddrTop (\r
//  VOID\r
//  );\r
ASM_PFX(ArmGetPhysAddrTop):\r
  mrs   x0, id_aa64mmfr0_el1\r
  adr   x1, .LPARanges\r
  and   x0, x0, #7\r
  ldrb  w1, [x1, x0]\r
  mov   x0, #1\r
  lsl   x0, x0, x1\r
  ret\r
\r
//\r
// Bits 0..2 of the AA64MFR0_EL1 system register encode the size of the\r
// physical address space support on this CPU:\r
// 0 == 32 bits, 1 == 36 bits, etc etc\r
// 6 and 7 are reserved\r
//\r
.LPARanges:\r
  .byte 32, 36, 40, 42, 44, 48, -1, -1\r
\r
ASM_FUNCTION_REMOVE_IF_UNREFERENCED\r