Correct parameter UINTN to UINT32. Fix UINTN conver to UINT32

[mirror_edk2.git] / BaseTools / toolsetup.bat

@REM\r
@REM Copyright (c) 2006, Intel Corporation\r
@REM All rights reserved. This program and the accompanying materials\r
@REM are licensed and made available under the terms and conditions of the BSD License\r
@REM which accompanies this distribution.  The full text of the license may be found at\r
@REM http://opensource.org/licenses/bsd-license.php\r
@REM\r
@REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
@REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
@REM\r
\r
@echo off\r
\r
REM ##############################################################\r
REM # You should not have to modify anything below this line\r
REM #\r
\r
if /I "%1"=="-h" goto usage\r
if /I "%1"=="-help" goto usage\r
if /I "%1"=="--help" goto usage\r
if /I "%1"=="/h" goto usage\r
if /I "%1"=="/?" goto usage\r
if /I "%1"=="/help" goto usage\r
\r
if /I "%1"=="Reconfig" (\r
  if NOT "%2"=="" set EDK_TOOLS_PATH=%2\r
) else (\r
  if NOT "%1"=="" set EDK_TOOLS_PATH=%1\r
)\r
\r
REM\r
REM Check the required system environment variables\r
REM\r
\r
:check_vc\r
if defined VCINSTALLDIR goto setup_workspace\r
if defined VS71COMNTOOLS (\r
  call "%VS71COMNTOOLS%\vsvars32.bat"\r
) else (\r
  echo.\r
  echo !!!WARNING!!! Cannot find Visual Studio !!!\r
  echo.\r
)\r
\r
:setup_workspace\r
REM\r
REM check the EDK_TOOLS_PATH\r
REM\r
if not defined EDK_TOOLS_PATH goto no_tools_path\r
if exist %EDK_TOOLS_PATH% goto set_path\r
echo.\r
echo !!!WARNING!!! %EDK_TOOLS_PATH% doesn't exist. %WORKSPACE%\BaseTools will be used !!!\r
echo.\r
\r
:no_tools_path\r
if exist %WORKSPACE%\BaseTools (\r
  set EDK_TOOLS_PATH=%WORKSPACE%\BaseTools\r
) else (\r
  echo.\r
  echo !!!WARNING!!! No tools path found. Please set EDK_TOOLS_PATH !!!\r
  echo.\r
  goto end\r
)\r
\r
:set_path\r
if defined WORKSPACE_TOOLS_PATH goto check_path\r
set PATH=%EDK_TOOLS_PATH%\Bin;%EDK_TOOLS_PATH%\Bin\Win32;%PATH%\r
set WORKSPACE_TOOLS_PATH=%EDK_TOOLS_PATH%\r
goto path_ok\r
\r
:check_path\r
if "%EDK_TOOLS_PATH%"=="%WORKSPACE_TOOLS_PATH%" goto path_ok\r
set PATH=%EDK_TOOLS_PATH%\Bin;%EDK_TOOLS_PATH%\Bin\Win32;%PATH%\r
set WORKSPACE_TOOLS_PATH=%EDK_TOOLS_PATH%\r
echo Resetting the PATH variable to include the EDK_TOOLS_PATH for this WORKSPACE\r
\r
:path_ok\r
echo           PATH = %PATH%\r
echo.\r
echo      WORKSPACE = %WORKSPACE%\r
echo EDK_TOOLS_PATH = %EDK_TOOLS_PATH%\r
echo.\r
\r
REM\r
REM copy *.template to %WORKSPACE%\Conf\r
REM\r
if NOT exist %WORKSPACE%\Conf (\r
  mkdir %WORKSPACE%\Conf\r
) else (\r
  if /I "%1"=="Reconfig" (\r
    echo.\r
    echo  Over-writing the files in the WORKSPACE\Conf directory\r
    echo  using the default template files\r
    echo.\r
  )\r
)\r
if NOT exist %WORKSPACE%\Conf\FrameworkDatabase.db (\r
  echo copying ... FrameworkDatabase.template to %WORKSPACE%\Conf\FrameworkDatabase.db\r
  copy %EDK_TOOLS_PATH%\Conf\FrameworkDatabase.template %WORKSPACE%\Conf\FrameworkDatabase.db > nul\r
) else (\r
  if /I "%1"=="Reconfig" copy /Y %EDK_TOOLS_PATH%\Conf\FrameworkDatabase.template %WORKSPACE%\Conf\FrameworkDatabase.db > nul\r
)\r
if NOT exist %WORKSPACE%\Conf\target.txt (\r
  echo copying ... target.template to %WORKSPACE%\Conf\target.txt\r
  copy %EDK_TOOLS_PATH%\Conf\target.template %WORKSPACE%\Conf\target.txt > nul\r
) else (\r
  if /I "%1"=="Reconfig" copy /Y %EDK_TOOLS_PATH%\Conf\target.template %WORKSPACE%\Conf\target.txt > nul\r
)\r
if NOT exist %WORKSPACE%\Conf\tools_def.txt (\r
  echo copying ... tools_def.template to %WORKSPACE%\Conf\tools_def.txt\r
  copy %EDK_TOOLS_PATH%\Conf\tools_def.template %WORKSPACE%\Conf\tools_def.txt > nul\r
) else (\r
  if /I "%1"=="Reconfig" copy /Y %EDK_TOOLS_PATH%\Conf\tools_def.template %WORKSPACE%\Conf\tools_def.txt > nul\r
)\r
if NOT exist %WORKSPACE%\Conf\build_rule.txt (\r
  echo copying ... build_rule.template to %WORKSPACE%\Conf\build_rule.txt\r
  copy %EDK_TOOLS_PATH%\Conf\build_rule.template %WORKSPACE%\Conf\build_rule.txt > nul\r
) else (\r
  if /I "%1"=="Reconfig" copy /Y %EDK_TOOLS_PATH%\Conf\build_rule.template %WORKSPACE%\Conf\build_rule.txt > nul\r
)\r
\r
REM\r
REM copy XMLSchema to %EDK_TOOLS_PATH%\Conf\XMLSchema\r
REM\r
REM echo copying ... XMLSchema to %EDK_TOOLS_PATH%\Conf\XMLSchema\r
REM xcopy %WORKSPACE%\Conf\XMLSchema %EDK_TOOLS_PATH%\Conf\XMLSchema /S /I /D /F /Q > nul\r
\r
REM\r
REM Done!!!\r
REM\r
goto end\r
\r
:usage\r
echo.\r
echo  "Usage: %0 [/? | /h | /help | -h | -help | --help] [Reconfig] [tools_path]"\r
echo.\r
echo                      tools_path       Tools' path. EDK_TOOLS_PATH will be set to this path.\r
echo.\r
\r
:end\r
@echo on\r
\r