[mirror_edk2.git] / MdeModulePkg / Universal / DebugSupportDxe / Ia32 / AsmFuncs.asm

;/** @file\r
;  Low leve IA32 specific debug support functions.\r
;\r
;  Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
;  This program and the accompanying materials\r
;  are licensed and made available under the terms and conditions of the BSD License\r
;  which accompanies this distribution.  The full text of the license may be found at\r
;  http://opensource.org/licenses/bsd-license.php\r
;\r
;  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
;  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;**/\r
\r
.586p\r
.MODEL          FLAT, C\r
\r
EXCPT32_DIVIDE_ERROR     EQU    0\r
EXCPT32_DEBUG            EQU    1\r
EXCPT32_NMI              EQU    2\r
EXCPT32_BREAKPOINT       EQU    3\r
EXCPT32_OVERFLOW         EQU    4\r
EXCPT32_BOUND            EQU    5\r
EXCPT32_INVALID_OPCODE   EQU    6\r
EXCPT32_DOUBLE_FAULT     EQU    8\r
EXCPT32_INVALID_TSS      EQU   10\r
EXCPT32_SEG_NOT_PRESENT  EQU   11\r
EXCPT32_STACK_FAULT      EQU   12\r
EXCPT32_GP_FAULT         EQU   13\r
EXCPT32_PAGE_FAULT       EQU   14\r
EXCPT32_FP_ERROR         EQU   16\r
EXCPT32_ALIGNMENT_CHECK  EQU   17\r
EXCPT32_MACHINE_CHECK    EQU   18\r
EXCPT32_SIMD             EQU   19\r
\r
FXSTOR_FLAG              EQU   01000000h         ; bit cpuid 24 of feature flags\r
\r
;; The FXSTOR and FXRSTOR commands are used for saving and restoring the x87,\r
;; MMX, SSE, SSE2, etc registers.  The initialization of the debugsupport driver\r
;; MUST check the CPUID feature flags to see that these instructions are available\r
;; and fail to init if they are not.\r
\r
;; fxstor [edi]\r
FXSTOR_EDI               MACRO\r
                         db 0fh, 0aeh, 00000111y ; mod = 00, reg/op = 000, r/m = 111 = [edi]\r
ENDM\r
\r
;; fxrstor [esi]\r
FXRSTOR_ESI              MACRO\r
                         db 0fh, 0aeh, 00001110y ; mod = 00, reg/op = 001, r/m = 110 = [esi]\r
ENDM\r
.DATA\r
\r
public          OrigVector, InterruptEntryStub, StubSize, CommonIdtEntry, FxStorSupport\r
\r
StubSize        dd      InterruptEntryStubEnd - InterruptEntryStub\r
AppEsp          dd      11111111h ; ?\r
DebugEsp        dd      22222222h ; ?\r
ExtraPush       dd      33333333h ; ?\r
ExceptData      dd      44444444h ; ?\r
Eflags          dd      55555555h ; ?\r
OrigVector      dd      66666666h ; ?\r
\r
;; The declarations below define the memory region that will be used for the debug stack.\r
;; The context record will be built by pushing register values onto this stack.\r
;; It is imparitive that alignment be carefully managed, since the FXSTOR and\r
;; FXRSTOR instructions will GP fault if their memory operand is not 16 byte aligned.\r
;;\r
;; The stub will switch stacks from the application stack to the debuger stack\r
;; and pushes the exception number.\r
;;\r
;; Then we building the context record on the stack. Since the stack grows down,\r
;; we push the fields of the context record from the back to the front.  There\r
;; are 132 bytes of stack used prior allocating the 512 bytes of stack to be\r
;; used as the memory buffer for the fxstor instruction. Therefore address of\r
;; the buffer used for the FXSTOR instruction is &Eax - 132 - 512, which\r
;; must be 16 byte aligned.\r
;;\r
;; We carefully locate the stack to make this happen.\r
;;\r
;; For reference, the context structure looks like this:\r
;;      struct {\r
;;        UINT32             ExceptionData;\r
;;        FX_SAVE_STATE_IA32 FxSaveState;    // 512 bytes, must be 16 byte aligned\r
;;        UINT32             Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
;;        UINT32             Cr0, Cr1, Cr2, Cr3, Cr4;\r
;;        UINT32             EFlags;\r
;;        UINT32             Ldtr, Tr;\r
;;        UINT32             Gdtr[2], Idtr[2];\r
;;        UINT32             Eip;\r
;;        UINT32             Gs, Fs, Es, Ds, Cs, Ss;\r
;;        UINT32             Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
;;      } SYSTEM_CONTEXT_IA32;  // 32 bit system context record\r
\r
\r
align           16\r
DebugStackEnd   db      "DbgStkEnd >>>>>>"      ;; 16 byte long string - must be 16 bytes to preserve alignment\r
                dd      1ffdh dup (000000000h)  ;; 32K should be enough stack\r
                                                ;;   This allocation is coocked to insure\r
                                                ;;   that the the buffer for the FXSTORE instruction\r
                                                ;;   will be 16 byte aligned also.\r
                                                ;;\r
ExceptionNumber dd      ?                       ;; first entry will be the vector number pushed by the stub\r
\r
DebugStackBegin db      "<<<< DbgStkBegin"      ;; initial debug ESP == DebugStackBegin, set in stub\r
\r
.CODE\r
\r
externdef InterruptDistrubutionHub:near\r
\r
;------------------------------------------------------------------------------\r
; BOOLEAN\r
; FxStorSupport (\r
;   void\r
;   )\r
;\r
; Abstract: Returns TRUE if FxStor instructions are supported\r
;\r
FxStorSupport   PROC    C PUBLIC\r
\r
;\r
; cpuid corrupts ebx which must be preserved per the C calling convention\r
;\r
                push    ebx\r
                mov     eax, 1\r
                cpuid\r
                mov     eax, edx\r
                and     eax, FXSTOR_FLAG\r
                shr     eax, 24\r
                pop     ebx\r
                ret\r
FxStorSupport   ENDP\r
\r
\r
\r
;------------------------------------------------------------------------------\r
; void\r
; Vect2Desc (\r
;   DESCRIPTOR * DestDesc,\r
;   void (*Vector) (void)\r
;   )\r
;\r
; Abstract: Encodes an IDT descriptor with the given physical address\r
;\r
Vect2Desc       PROC    C PUBLIC DestPtr:DWORD, Vector:DWORD\r
\r
                mov     eax, Vector\r
                mov     ecx, DestPtr\r
                mov     word ptr [ecx], ax                  ; write bits 15..0 of offset\r
                mov     dx, cs\r
                mov     word ptr [ecx+2], dx                ; SYS_CODE_SEL from GDT\r
                mov     word ptr [ecx+4], 0e00h OR 8000h    ; type = 386 interrupt gate, present\r
                shr     eax, 16\r
                mov     word ptr [ecx+6], ax                ; write bits 31..16 of offset\r
\r
                ret\r
\r
Vect2Desc       ENDP\r
\r
\r
\r
;------------------------------------------------------------------------------\r
; InterruptEntryStub\r
;\r
; Abstract: This code is not a function, but is a small piece of code that is\r
;               copied and fixed up once for each IDT entry that is hooked.\r
;\r
InterruptEntryStub::\r
                mov     AppEsp, esp                  ; save stack top\r
                mov     esp, offset DebugStackBegin  ; switch to debugger stack\r
                push    0                            ; push vector number - will be modified before installed\r
                db      0e9h                         ; jump rel32\r
                dd      0                            ; fixed up to relative address of CommonIdtEntry\r
InterruptEntryStubEnd:\r
\r
\r
\r
;------------------------------------------------------------------------------\r
; CommonIdtEntry\r
;\r
; Abstract: This code is not a function, but is the common part for all IDT\r
;               vectors.\r
;\r
CommonIdtEntry::\r
;;\r
;; At this point, the stub has saved the current application stack esp into AppEsp\r
;; and switched stacks to the debug stack, where it pushed the vector number\r
;;\r
;; The application stack looks like this:\r
;;\r
;;              ...\r
;;              (last application stack entry)\r
;;              eflags from interrupted task\r
;;              CS from interrupted task\r
;;              EIP from interrupted task\r
;;              Error code <-------------------- Only present for some exeption types\r
;;\r
;;\r
\r
\r
;; The stub switched us to the debug stack and pushed the interrupt number.\r
;;\r
;; Next, construct the context record.  It will be build on the debug stack by\r
;; pushing the registers in the correct order so as to create the context structure\r
;; on the debug stack.  The context record must be built from the end back to the\r
;; beginning because the stack grows down...\r
;\r
;; For reference, the context record looks like this:\r
;;\r
;; typedef\r
;; struct {\r
;;   UINT32             ExceptionData;\r
;;   FX_SAVE_STATE_IA32 FxSaveState;\r
;;   UINT32             Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
;;   UINT32             Cr0, Cr2, Cr3, Cr4;\r
;;   UINT32             EFlags;\r
;;   UINT32             Ldtr, Tr;\r
;;   UINT32             Gdtr[2], Idtr[2];\r
;;   UINT32             Eip;\r
;;   UINT32             Gs, Fs, Es, Ds, Cs, Ss;\r
;;   UINT32             Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
;; } SYSTEM_CONTEXT_IA32;  // 32 bit system context record\r
\r
;; UINT32  Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
                pushad\r
\r
;; Save interrupt state eflags register...\r
                pushfd\r
                pop     eax\r
                mov     dword ptr Eflags, eax\r
\r
;; We need to determine if any extra data was pushed by the exception, and if so, save it\r
;; To do this, we check the exception number pushed by the stub, and cache the\r
;; result in a variable since we'll need this again.\r
                .IF     ExceptionNumber == EXCPT32_DOUBLE_FAULT\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_INVALID_TSS\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_SEG_NOT_PRESENT\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_STACK_FAULT\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_GP_FAULT\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_PAGE_FAULT\r
                mov     ExtraPush, 1\r
                .ELSEIF ExceptionNumber == EXCPT32_ALIGNMENT_CHECK\r
                mov     ExtraPush, 1\r
                .ELSE\r
                mov     ExtraPush, 0\r
                .ENDIF\r
\r
;; If there's some extra data, save it also, and modify the saved AppEsp to effectively\r
;; pop this value off the application's stack.\r
                .IF     ExtraPush == 1\r
                mov     eax, AppEsp\r
                mov     ebx, [eax]\r
                mov     ExceptData, ebx\r
                add     eax, 4\r
                mov     AppEsp, eax\r
                .ELSE\r
                mov     ExceptData, 0\r
                .ENDIF\r
\r
;; The "pushad" above pushed the debug stack esp.  Since what we're actually doing\r
;; is building the context record on the debug stack, we need to save the pushed\r
;; debug ESP, and replace it with the application's last stack entry...\r
                mov     eax, [esp + 12]\r
                mov     DebugEsp, eax\r
                mov     eax, AppEsp\r
                add     eax, 12\r
                ; application stack has eflags, cs, & eip, so\r
                ; last actual application stack entry is\r
                ; 12 bytes into the application stack.\r
                mov     [esp + 12], eax\r
\r
;; continue building context record\r
;; UINT32  Gs, Fs, Es, Ds, Cs, Ss;  insure high 16 bits of each is zero\r
                mov     eax, ss\r
                push    eax\r
\r
                ; CS from application is one entry back in application stack\r
                mov     eax, AppEsp\r
                movzx   eax, word ptr [eax + 4]\r
                push    eax\r
\r
                mov     eax, ds\r
                push    eax\r
                mov     eax, es\r
                push    eax\r
                mov     eax, fs\r
                push    eax\r
                mov     eax, gs\r
                push    eax\r
\r
;; UINT32  Eip;\r
                ; Eip from application is on top of application stack\r
                mov     eax, AppEsp\r
                push    dword ptr [eax]\r
\r
;; UINT32  Gdtr[2], Idtr[2];\r
                push    0\r
                push    0\r
                sidt    fword ptr [esp]\r
                push    0\r
                push    0\r
                sgdt    fword ptr [esp]\r
\r
;; UINT32  Ldtr, Tr;\r
                xor     eax, eax\r
                str     ax\r
                push    eax\r
                sldt    ax\r
                push    eax\r
\r
;; UINT32  EFlags;\r
;; Eflags from application is two entries back in application stack\r
                mov     eax, AppEsp\r
                push    dword ptr [eax + 8]\r
\r
;; UINT32  Cr0, Cr1, Cr2, Cr3, Cr4;\r
;; insure FXSAVE/FXRSTOR is enabled in CR4...\r
;; ... while we're at it, make sure DE is also enabled...\r
                mov     eax, cr4\r
                or      eax, 208h\r
                mov     cr4, eax\r
                push    eax\r
                mov     eax, cr3\r
                push    eax\r
                mov     eax, cr2\r
                push    eax\r
                push    0\r
                mov     eax, cr0\r
                push    eax\r
\r
;; UINT32  Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
                mov     eax, dr7\r
                push    eax\r
;; clear Dr7 while executing debugger itself\r
                xor     eax, eax\r
                mov     dr7, eax\r
\r
                mov     eax, dr6\r
                push    eax\r
;; insure all status bits in dr6 are clear...\r
                xor     eax, eax\r
                mov     dr6, eax\r
\r
                mov     eax, dr3\r
                push    eax\r
                mov     eax, dr2\r
                push    eax\r
                mov     eax, dr1\r
                push    eax\r
                mov     eax, dr0\r
                push    eax\r
\r
;; FX_SAVE_STATE_IA32 FxSaveState;\r
                sub     esp, 512\r
                mov     edi, esp\r
                ; IMPORTANT!! The debug stack has been carefully constructed to\r
                ; insure that esp and edi are 16 byte aligned when we get here.\r
                ; They MUST be.  If they are not, a GP fault will occur.\r
                FXSTOR_EDI\r
\r
;; UINT32  ExceptionData;\r
                mov     eax, ExceptData\r
                push    eax\r
\r
; call to C code which will in turn call registered handler\r
; pass in the vector number\r
                mov     eax, esp\r
                push    eax\r
                mov     eax, ExceptionNumber\r
                push    eax\r
                call    InterruptDistrubutionHub\r
                add     esp, 8\r
\r
; restore context...\r
;; UINT32  ExceptionData;\r
                add     esp, 4\r
\r
;; FX_SAVE_STATE_IA32 FxSaveState;\r
                mov     esi, esp\r
                FXRSTOR_ESI\r
                add     esp, 512\r
\r
;; UINT32  Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
                pop     eax\r
                mov     dr0, eax\r
                pop     eax\r
                mov     dr1, eax\r
                pop     eax\r
                mov     dr2, eax\r
                pop     eax\r
                mov     dr3, eax\r
;; skip restore of dr6.  We cleared dr6 during the context save.\r
                add     esp, 4\r
                pop     eax\r
                mov     dr7, eax\r
\r
;; UINT32  Cr0, Cr1, Cr2, Cr3, Cr4;\r
                pop     eax\r
                mov     cr0, eax\r
                add     esp, 4\r
                pop     eax\r
                mov     cr2, eax\r
                pop     eax\r
                mov     cr3, eax\r
                pop     eax\r
                mov     cr4, eax\r
\r
;; UINT32  EFlags;\r
                mov     eax, AppEsp\r
                pop     dword ptr [eax + 8]\r
\r
;; UINT32  Ldtr, Tr;\r
;; UINT32  Gdtr[2], Idtr[2];\r
;; Best not let anyone mess with these particular registers...\r
                add     esp, 24\r
\r
;; UINT32  Eip;\r
                pop     dword ptr [eax]\r
\r
;; UINT32  SegGs, SegFs, SegEs, SegDs, SegCs, SegSs;\r
;; NOTE - modified segment registers could hang the debugger...  We\r
;;        could attempt to insulate ourselves against this possibility,\r
;;        but that poses risks as well.\r
;;\r
\r
                pop     gs\r
                pop     fs\r
                pop     es\r
                pop     ds\r
                pop     [eax + 4]\r
                pop     ss\r
\r
;; The next stuff to restore is the general purpose registers that were pushed\r
;; using the "pushad" instruction.\r
;;\r
;; The value of ESP as stored in the context record is the application ESP\r
;; including the 3 entries on the application stack caused by the exception\r
;; itself. It may have been modified by the debug agent, so we need to\r
;; determine if we need to relocate the application stack.\r
\r
                mov     ebx, [esp + 12]  ; move the potentially modified AppEsp into ebx\r
                mov     eax, AppEsp\r
                add     eax, 12\r
                cmp     ebx, eax\r
                je      NoAppStackMove\r
\r
                mov     eax, AppEsp\r
                mov     ecx, [eax]       ; EIP\r
                mov     [ebx], ecx\r
\r
                mov     ecx, [eax + 4]   ; CS\r
                mov     [ebx + 4], ecx\r
\r
                mov     ecx, [eax + 8]   ; EFLAGS\r
                mov     [ebx + 8], ecx\r
\r
                mov     eax, ebx         ; modify the saved AppEsp to the new AppEsp\r
                mov     AppEsp, eax\r
NoAppStackMove:\r
                mov     eax, DebugEsp    ; restore the DebugEsp on the debug stack\r
                                         ; so our "popad" will not cause a stack switch\r
                mov     [esp + 12], eax\r
\r
                cmp     ExceptionNumber, 068h\r
                jne     NoChain\r
\r
Chain:\r
\r
;; Restore eflags so when we chain, the flags will be exactly as if we were never here.\r
;; We gin up the stack to do an iretd so we can get ALL the flags.\r
                mov     eax, AppEsp\r
                mov     ebx, [eax + 8]\r
                and     ebx, NOT 300h ; special handling for IF and TF\r
                push    ebx\r
                push    cs\r
                push    PhonyIretd\r
                iretd\r
PhonyIretd:\r
\r
;; UINT32  Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
                popad\r
\r
;; Switch back to application stack\r
                mov     esp, AppEsp\r
\r
;; Jump to original handler\r
                jmp     OrigVector\r
\r
NoChain:\r
;; UINT32  Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
                popad\r
\r
;; Switch back to application stack\r
                mov     esp, AppEsp\r
\r
;; We're outa here...\r
                iretd\r
END\r
\r
\r
\r
Commit	Line	Data
7b414b4e	1	;/** @file\r
	2	; Low leve IA32 specific debug support functions.\r
	3	;\r
e5eed7d3 HT	4	; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
e5eed7d3 HT	5	; This program and the accompanying materials\r
7b414b4e	6	; are licensed and made available under the terms and conditions of the BSD License\r
	7	; which accompanies this distribution. The full text of the license may be found at\r
	8	; http://opensource.org/licenses/bsd-license.php\r
	9	;\r
	10	; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
	11	; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
	12	;\r
	13	;**/\r
c1f23d63	14	\r
	15	.586p\r
	16	.MODEL FLAT, C\r
	17	\r
	18	EXCPT32_DIVIDE_ERROR EQU 0\r
	19	EXCPT32_DEBUG EQU 1\r
	20	EXCPT32_NMI EQU 2\r
	21	EXCPT32_BREAKPOINT EQU 3\r
	22	EXCPT32_OVERFLOW EQU 4\r
	23	EXCPT32_BOUND EQU 5\r
	24	EXCPT32_INVALID_OPCODE EQU 6\r
	25	EXCPT32_DOUBLE_FAULT EQU 8\r
	26	EXCPT32_INVALID_TSS EQU 10\r
	27	EXCPT32_SEG_NOT_PRESENT EQU 11\r
	28	EXCPT32_STACK_FAULT EQU 12\r
	29	EXCPT32_GP_FAULT EQU 13\r
	30	EXCPT32_PAGE_FAULT EQU 14\r
	31	EXCPT32_FP_ERROR EQU 16\r
	32	EXCPT32_ALIGNMENT_CHECK EQU 17\r
	33	EXCPT32_MACHINE_CHECK EQU 18\r
	34	EXCPT32_SIMD EQU 19\r
	35	\r
	36	FXSTOR_FLAG EQU 01000000h ; bit cpuid 24 of feature flags\r
	37	\r
	38	;; The FXSTOR and FXRSTOR commands are used for saving and restoring the x87,\r
	39	;; MMX, SSE, SSE2, etc registers. The initialization of the debugsupport driver\r
	40	;; MUST check the CPUID feature flags to see that these instructions are available\r
	41	;; and fail to init if they are not.\r
	42	\r
	43	;; fxstor [edi]\r
	44	FXSTOR_EDI MACRO\r
	45	db 0fh, 0aeh, 00000111y ; mod = 00, reg/op = 000, r/m = 111 = [edi]\r
	46	ENDM\r
	47	\r
	48	;; fxrstor [esi]\r
	49	FXRSTOR_ESI MACRO\r
	50	db 0fh, 0aeh, 00001110y ; mod = 00, reg/op = 001, r/m = 110 = [esi]\r
	51	ENDM\r
	52	.DATA\r
	53	\r
	54	public OrigVector, InterruptEntryStub, StubSize, CommonIdtEntry, FxStorSupport\r
	55	\r
	56	StubSize dd InterruptEntryStubEnd - InterruptEntryStub\r
	57	AppEsp dd 11111111h ; ?\r
	58	DebugEsp dd 22222222h ; ?\r
	59	ExtraPush dd 33333333h ; ?\r
	60	ExceptData dd 44444444h ; ?\r
	61	Eflags dd 55555555h ; ?\r
	62	OrigVector dd 66666666h ; ?\r
	63	\r
	64	;; The declarations below define the memory region that will be used for the debug stack.\r
	65	;; The context record will be built by pushing register values onto this stack.\r
	66	;; It is imparitive that alignment be carefully managed, since the FXSTOR and\r
	67	;; FXRSTOR instructions will GP fault if their memory operand is not 16 byte aligned.\r
	68	;;\r
	69	;; The stub will switch stacks from the application stack to the debuger stack\r
	70	;; and pushes the exception number.\r
	71	;;\r
	72	;; Then we building the context record on the stack. Since the stack grows down,\r
	73	;; we push the fields of the context record from the back to the front. There\r
	74	;; are 132 bytes of stack used prior allocating the 512 bytes of stack to be\r
	75	;; used as the memory buffer for the fxstor instruction. Therefore address of\r
	76	;; the buffer used for the FXSTOR instruction is &Eax - 132 - 512, which\r
	77	;; must be 16 byte aligned.\r
78	;;\r
79	;; We carefully locate the stack to make this happen.\r
80	;;\r
81	;; For reference, the context structure looks like this:\r
82	;; struct {\r
83	;; UINT32 ExceptionData;\r
84	;; FX_SAVE_STATE_IA32 FxSaveState; // 512 bytes, must be 16 byte aligned\r
85	;; UINT32 Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
86	;; UINT32 Cr0, Cr1, Cr2, Cr3, Cr4;\r
87	;; UINT32 EFlags;\r
88	;; UINT32 Ldtr, Tr;\r
89	;; UINT32 Gdtr[2], Idtr[2];\r
90	;; UINT32 Eip;\r
91	;; UINT32 Gs, Fs, Es, Ds, Cs, Ss;\r
92	;; UINT32 Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
93	;; } SYSTEM_CONTEXT_IA32; // 32 bit system context record\r
94	\r
95	\r
96	align 16\r
97	DebugStackEnd db "DbgStkEnd >>>>>>" ;; 16 byte long string - must be 16 bytes to preserve alignment\r
98	dd 1ffdh dup (000000000h) ;; 32K should be enough stack\r
7b414b4e	99	;; This allocation is coocked to insure\r
c1f23d63	100	;; that the the buffer for the FXSTORE instruction\r
	101	;; will be 16 byte aligned also.\r
	102	;;\r
	103	ExceptionNumber dd ? ;; first entry will be the vector number pushed by the stub\r
	104	\r
	105	DebugStackBegin db "<<<< DbgStkBegin" ;; initial debug ESP == DebugStackBegin, set in stub\r
	106	\r
	107	.CODE\r
	108	\r
	109	externdef InterruptDistrubutionHub:near\r
	110	\r
	111	;------------------------------------------------------------------------------\r
	112	; BOOLEAN\r
	113	; FxStorSupport (\r
	114	; void\r
	115	; )\r
	116	;\r
	117	; Abstract: Returns TRUE if FxStor instructions are supported\r
	118	;\r
	119	FxStorSupport PROC C PUBLIC\r
	120	\r
	121	;\r
	122	; cpuid corrupts ebx which must be preserved per the C calling convention\r
	123	;\r
	124	push ebx\r
	125	mov eax, 1\r
	126	cpuid\r
	127	mov eax, edx\r
	128	and eax, FXSTOR_FLAG\r
	129	shr eax, 24\r
	130	pop ebx\r
	131	ret\r
	132	FxStorSupport ENDP\r
	133	\r
	134	\r
c1f23d63	135	\r
c1f23d63	136	;------------------------------------------------------------------------------\r
	137	; void\r
	138	; Vect2Desc (\r
	139	; DESCRIPTOR * DestDesc,\r
	140	; void (*Vector) (void)\r
	141	; )\r
	142	;\r
	143	; Abstract: Encodes an IDT descriptor with the given physical address\r
	144	;\r
	145	Vect2Desc PROC C PUBLIC DestPtr:DWORD, Vector:DWORD\r
	146	\r
	147	mov eax, Vector\r
	148	mov ecx, DestPtr\r
	149	mov word ptr [ecx], ax ; write bits 15..0 of offset\r
	150	mov dx, cs\r
	151	mov word ptr [ecx+2], dx ; SYS_CODE_SEL from GDT\r
	152	mov word ptr [ecx+4], 0e00h OR 8000h ; type = 386 interrupt gate, present\r
	153	shr eax, 16\r
	154	mov word ptr [ecx+6], ax ; write bits 31..16 of offset\r
	155	\r
	156	ret\r
	157	\r
	158	Vect2Desc ENDP\r
	159	\r
	160	\r
	161	\r
	162	;------------------------------------------------------------------------------\r
	163	; InterruptEntryStub\r
	164	;\r
	165	; Abstract: This code is not a function, but is a small piece of code that is\r
	166	; copied and fixed up once for each IDT entry that is hooked.\r
	167	;\r
	168	InterruptEntryStub::\r
	169	mov AppEsp, esp ; save stack top\r
	170	mov esp, offset DebugStackBegin ; switch to debugger stack\r
	171	push 0 ; push vector number - will be modified before installed\r
	172	db 0e9h ; jump rel32\r
	173	dd 0 ; fixed up to relative address of CommonIdtEntry\r
	174	InterruptEntryStubEnd:\r
	175	\r
	176	\r
	177	\r
	178	;------------------------------------------------------------------------------\r
	179	; CommonIdtEntry\r
	180	;\r
	181	; Abstract: This code is not a function, but is the common part for all IDT\r
	182	; vectors.\r
	183	;\r
	184	CommonIdtEntry::\r
	185	;;\r
	186	;; At this point, the stub has saved the current application stack esp into AppEsp\r
	187	;; and switched stacks to the debug stack, where it pushed the vector number\r
	188	;;\r
	189	;; The application stack looks like this:\r
	190	;;\r
	191	;; ...\r
	192	;; (last application stack entry)\r
	193	;; eflags from interrupted task\r
	194	;; CS from interrupted task\r
	195	;; EIP from interrupted task\r
	196	;; Error code <-------------------- Only present for some exeption types\r
	197	;;\r
	198	;;\r
	199	\r
200	\r
201	;; The stub switched us to the debug stack and pushed the interrupt number.\r
202	;;\r
203	;; Next, construct the context record. It will be build on the debug stack by\r
204	;; pushing the registers in the correct order so as to create the context structure\r
205	;; on the debug stack. The context record must be built from the end back to the\r
206	;; beginning because the stack grows down...\r
207	;\r
208	;; For reference, the context record looks like this:\r
209	;;\r
210	;; typedef\r
211	;; struct {\r
212	;; UINT32 ExceptionData;\r
213	;; FX_SAVE_STATE_IA32 FxSaveState;\r
214	;; UINT32 Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
215	;; UINT32 Cr0, Cr2, Cr3, Cr4;\r
216	;; UINT32 EFlags;\r
217	;; UINT32 Ldtr, Tr;\r
218	;; UINT32 Gdtr[2], Idtr[2];\r
219	;; UINT32 Eip;\r
220	;; UINT32 Gs, Fs, Es, Ds, Cs, Ss;\r
221	;; UINT32 Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
222	;; } SYSTEM_CONTEXT_IA32; // 32 bit system context record\r
223	\r
224	;; UINT32 Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
225	pushad\r
226	\r
227	;; Save interrupt state eflags register...\r
228	pushfd\r
229	pop eax\r
230	mov dword ptr Eflags, eax\r
231	\r
232	;; We need to determine if any extra data was pushed by the exception, and if so, save it\r
233	;; To do this, we check the exception number pushed by the stub, and cache the\r
234	;; result in a variable since we'll need this again.\r
235	.IF ExceptionNumber == EXCPT32_DOUBLE_FAULT\r
236	mov ExtraPush, 1\r
237	.ELSEIF ExceptionNumber == EXCPT32_INVALID_TSS\r
238	mov ExtraPush, 1\r
239	.ELSEIF ExceptionNumber == EXCPT32_SEG_NOT_PRESENT\r
240	mov ExtraPush, 1\r
241	.ELSEIF ExceptionNumber == EXCPT32_STACK_FAULT\r
242	mov ExtraPush, 1\r
243	.ELSEIF ExceptionNumber == EXCPT32_GP_FAULT\r
244	mov ExtraPush, 1\r
245	.ELSEIF ExceptionNumber == EXCPT32_PAGE_FAULT\r
246	mov ExtraPush, 1\r
247	.ELSEIF ExceptionNumber == EXCPT32_ALIGNMENT_CHECK\r
248	mov ExtraPush, 1\r
249	.ELSE\r
250	mov ExtraPush, 0\r
251	.ENDIF\r
252	\r
253	;; If there's some extra data, save it also, and modify the saved AppEsp to effectively\r
254	;; pop this value off the application's stack.\r
255	.IF ExtraPush == 1\r
256	mov eax, AppEsp\r
257	mov ebx, [eax]\r
258	mov ExceptData, ebx\r
259	add eax, 4\r
260	mov AppEsp, eax\r
261	.ELSE\r
262	mov ExceptData, 0\r
263	.ENDIF\r
264	\r
265	;; The "pushad" above pushed the debug stack esp. Since what we're actually doing\r
266	;; is building the context record on the debug stack, we need to save the pushed\r
267	;; debug ESP, and replace it with the application's last stack entry...\r
268	mov eax, [esp + 12]\r
269	mov DebugEsp, eax\r
270	mov eax, AppEsp\r
271	add eax, 12\r
272	; application stack has eflags, cs, & eip, so\r
273	; last actual application stack entry is\r
274	; 12 bytes into the application stack.\r
275	mov [esp + 12], eax\r
276	\r
277	;; continue building context record\r
278	;; UINT32 Gs, Fs, Es, Ds, Cs, Ss; insure high 16 bits of each is zero\r
279	mov eax, ss\r
280	push eax\r
281	\r
282	; CS from application is one entry back in application stack\r
283	mov eax, AppEsp\r
284	movzx eax, word ptr [eax + 4]\r
285	push eax\r
286	\r
287	mov eax, ds\r
288	push eax\r
289	mov eax, es\r
290	push eax\r
291	mov eax, fs\r
292	push eax\r
293	mov eax, gs\r
294	push eax\r
295	\r
296	;; UINT32 Eip;\r
297	; Eip from application is on top of application stack\r
298	mov eax, AppEsp\r
299	push dword ptr [eax]\r
300	\r
301	;; UINT32 Gdtr[2], Idtr[2];\r
302	push 0\r
303	push 0\r
304	sidt fword ptr [esp]\r
305	push 0\r
306	push 0\r
307	sgdt fword ptr [esp]\r
308	\r
309	;; UINT32 Ldtr, Tr;\r
310	xor eax, eax\r
311	str ax\r
312	push eax\r
313	sldt ax\r
314	push eax\r
315	\r
316	;; UINT32 EFlags;\r
317	;; Eflags from application is two entries back in application stack\r
318	mov eax, AppEsp\r
319	push dword ptr [eax + 8]\r
320	\r
321	;; UINT32 Cr0, Cr1, Cr2, Cr3, Cr4;\r
322	;; insure FXSAVE/FXRSTOR is enabled in CR4...\r
323	;; ... while we're at it, make sure DE is also enabled...\r
324	mov eax, cr4\r
325	or eax, 208h\r
326	mov cr4, eax\r
327	push eax\r
328	mov eax, cr3\r
329	push eax\r
330	mov eax, cr2\r
331	push eax\r
332	push 0\r
333	mov eax, cr0\r
334	push eax\r
335	\r
336	;; UINT32 Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
337	mov eax, dr7\r
338	push eax\r
339	;; clear Dr7 while executing debugger itself\r
340	xor eax, eax\r
341	mov dr7, eax\r
342	\r
343	mov eax, dr6\r
344	push eax\r
345	;; insure all status bits in dr6 are clear...\r
346	xor eax, eax\r
347	mov dr6, eax\r
348	\r
349	mov eax, dr3\r
350	push eax\r
351	mov eax, dr2\r
352	push eax\r
353	mov eax, dr1\r
354	push eax\r
355	mov eax, dr0\r
356	push eax\r
357	\r
358	;; FX_SAVE_STATE_IA32 FxSaveState;\r
359	sub esp, 512\r
360	mov edi, esp\r
361	; IMPORTANT!! The debug stack has been carefully constructed to\r
362	; insure that esp and edi are 16 byte aligned when we get here.\r
363	; They MUST be. If they are not, a GP fault will occur.\r
364	FXSTOR_EDI\r
365	\r
366	;; UINT32 ExceptionData;\r
367	mov eax, ExceptData\r
368	push eax\r
369	\r
370	; call to C code which will in turn call registered handler\r
371	; pass in the vector number\r
372	mov eax, esp\r
373	push eax\r
374	mov eax, ExceptionNumber\r
375	push eax\r
376	call InterruptDistrubutionHub\r
377	add esp, 8\r
378	\r
379	; restore context...\r
380	;; UINT32 ExceptionData;\r
381	add esp, 4\r
382	\r
383	;; FX_SAVE_STATE_IA32 FxSaveState;\r
384	mov esi, esp\r
385	FXRSTOR_ESI\r
386	add esp, 512\r
387	\r
388	;; UINT32 Dr0, Dr1, Dr2, Dr3, Dr6, Dr7;\r
389	pop eax\r
390	mov dr0, eax\r
391	pop eax\r
392	mov dr1, eax\r
393	pop eax\r
394	mov dr2, eax\r
395	pop eax\r
396	mov dr3, eax\r
397	;; skip restore of dr6. We cleared dr6 during the context save.\r
398	add esp, 4\r
399	pop eax\r
400	mov dr7, eax\r
401	\r
402	;; UINT32 Cr0, Cr1, Cr2, Cr3, Cr4;\r
403	pop eax\r
404	mov cr0, eax\r
405	add esp, 4\r
406	pop eax\r
407	mov cr2, eax\r
408	pop eax\r
409	mov cr3, eax\r
410	pop eax\r
411	mov cr4, eax\r
412	\r
413	;; UINT32 EFlags;\r
414	mov eax, AppEsp\r
415	pop dword ptr [eax + 8]\r
416	\r
417	;; UINT32 Ldtr, Tr;\r
418	;; UINT32 Gdtr[2], Idtr[2];\r
419	;; Best not let anyone mess with these particular registers...\r
420	add esp, 24\r
421	\r
422	;; UINT32 Eip;\r
423	pop dword ptr [eax]\r
424	\r
425	;; UINT32 SegGs, SegFs, SegEs, SegDs, SegCs, SegSs;\r
426	;; NOTE - modified segment registers could hang the debugger... We\r
427	;; could attempt to insulate ourselves against this possibility,\r
428	;; but that poses risks as well.\r
429	;;\r
430	\r
431	pop gs\r
432	pop fs\r
433	pop es\r
434	pop ds\r
435	pop [eax + 4]\r
436	pop ss\r
437	\r
438	;; The next stuff to restore is the general purpose registers that were pushed\r
439	;; using the "pushad" instruction.\r
440	;;\r
441	;; The value of ESP as stored in the context record is the application ESP\r
442	;; including the 3 entries on the application stack caused by the exception\r
443	;; itself. It may have been modified by the debug agent, so we need to\r
444	;; determine if we need to relocate the application stack.\r
445	\r
446	mov ebx, [esp + 12] ; move the potentially modified AppEsp into ebx\r
447	mov eax, AppEsp\r
448	add eax, 12\r
449	cmp ebx, eax\r
450	je NoAppStackMove\r
451	\r
452	mov eax, AppEsp\r
453	mov ecx, [eax] ; EIP\r
454	mov [ebx], ecx\r
455	\r
456	mov ecx, [eax + 4] ; CS\r
457	mov [ebx + 4], ecx\r
458	\r
459	mov ecx, [eax + 8] ; EFLAGS\r
460	mov [ebx + 8], ecx\r
461	\r
462	mov eax, ebx ; modify the saved AppEsp to the new AppEsp\r
463	mov AppEsp, eax\r
464	NoAppStackMove:\r
465	mov eax, DebugEsp ; restore the DebugEsp on the debug stack\r
466	; so our "popad" will not cause a stack switch\r
467	mov [esp + 12], eax\r
468	\r
469	cmp ExceptionNumber, 068h\r
470	jne NoChain\r
471	\r
472	Chain:\r
473	\r
474	;; Restore eflags so when we chain, the flags will be exactly as if we were never here.\r
475	;; We gin up the stack to do an iretd so we can get ALL the flags.\r
476	mov eax, AppEsp\r
477	mov ebx, [eax + 8]\r
478	and ebx, NOT 300h ; special handling for IF and TF\r
479	push ebx\r
480	push cs\r
481	push PhonyIretd\r
482	iretd\r
483	PhonyIretd:\r
484	\r
485	;; UINT32 Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
486	popad\r
487	\r
488	;; Switch back to application stack\r
489	mov esp, AppEsp\r
490	\r
491	;; Jump to original handler\r
492	jmp OrigVector\r
493	\r
494	NoChain:\r
495	;; UINT32 Edi, Esi, Ebp, Esp, Ebx, Edx, Ecx, Eax;\r
496	popad\r
497	\r
498	;; Switch back to application stack\r
499	mov esp, AppEsp\r
500	\r
501	;; We're outa here...\r
502	iretd\r
503	END\r
504	\r
505	\r
506	\r