Initial import.

[mirror_edk2.git] / MdePkg / Library / BaseLib / ia32 / Thunk16.asm

;------------------------------------------------------------------------------\r
;\r
; Copyright (c) 2006, Intel Corporation\r
; All rights reserved. This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   Thunk.asm\r
;\r
; Abstract:\r
;\r
;   Real mode thunk\r
;\r
;------------------------------------------------------------------------------\r
\r
    .686p\r
    .model  flat,C\r
\r
    .data\r
\r
NullSegSel      DQ      0\r
_16BitCsSel     LABEL   QWORD\r
                DW      -1\r
                DW      0\r
                DB      0\r
                DB      9bh\r
                DB      8fh             ; 16-bit segment\r
                DB      0\r
_16BitDsSel     LABEL   QWORD\r
                DW      -1\r
                DW      0\r
                DB      0\r
                DB      93h\r
                DB      8fh             ; 16-bit segment\r
                DB      0\r
GdtEnd          LABEL   QWORD\r
\r
    .const\r
\r
_16Gdtr         LABEL   FWORD\r
                DW      offset GdtEnd - offset NullSegSel - 1\r
                DD      offset NullSegSel\r
\r
_16Idtr         FWORD   (1 SHL 10) - 1\r
\r
    .code\r
\r
IA32_REGS   STRUC   4t\r
_EDI        DD      ?\r
_ESI        DD      ?\r
_EBP        DD      ?\r
_ESP        DD      ?\r
_EBX        DD      ?\r
_EDX        DD      ?\r
_ECX        DD      ?\r
_EAX        DD      ?\r
_DS         DW      ?\r
_ES         DW      ?\r
_FS         DW      ?\r
_GS         DW      ?\r
_EFLAGS     DD      ?\r
_EIP        DD      ?\r
_CS         DW      ?\r
_SS         DW      ?\r
IA32_REGS   ENDS\r
\r
InternalAsmThunk16  PROC    USES    ebp ebx esi edi ds  es  fs  gs\r
    mov     esi, [esp + 36]             ; esi <- RegSet\r
    push    sizeof (IA32_REGS)\r
    pop     ecx\r
    movzx   edx, (IA32_REGS ptr [esi])._SS\r
    mov     edi, (IA32_REGS ptr [esi])._ESP\r
    sub     edi, ecx                    ; reserve space on realmode stack\r
    push    edi                         ; save stack offset\r
    imul    eax, edx, 16                ; eax <- edx * 16\r
    add     edi, eax                    ; edi <- linear address of 16-bit stack\r
    rep     movsb                       ; copy RegSet\r
    mov     esi, edx                    ; esi <- 16-bit stack segment\r
    pop     ebx                         ; ebx <- 16-bit stack offset\r
    mov     edi, [esp + 40]             ; edi <- realmode patch\r
    push    cs                          ; save CS segment selector\r
    push    offset @BackToThunk         ; offset to back from real mode\r
    mov     eax, offset @16Return\r
    stosd\r
    xor     eax, eax\r
    stosw                               ; set CS base to 0\r
    mov     eax, esp\r
    stosd\r
    mov     eax, ss\r
    stosd\r
    mov     eax, cr0\r
    mov     ecx, eax                    ; ecx <- CR0\r
    and     ecx, 7ffffffeh              ; clear PE, PG bits\r
    stosd\r
    mov     eax, cr4\r
    mov     ebp, eax\r
    and     ebp, 300h                   ; clear all but PCE and OSFXSR bits\r
    stosd\r
    sidt    fword ptr [esp + 44]        ; use parameter space to save IDTR\r
    sgdt    fword ptr [edi]\r
    lidt    _16Idtr\r
    push    10h\r
    pop     eax\r
    push    8\r
    push    offset @16Start\r
    lgdt    _16Gdtr\r
    retf\r
@16Start:                               ; 16-bit starts here\r
    mov     ss, eax                     ; set SS to be a 16-bit segment\r
    mov     cr0, ecx\r
    mov     cr4, ebp\r
    mov     ss, esi                     ; set up 16-bit stack\r
    mov     sp, bx                      ; mov esp, ebx actually\r
    popaw                               ; popad actually\r
    pop     ds\r
    pop     es\r
    pop     fs\r
    pop     gs\r
    add     sp, 4                       ; skip _EFLAGS\r
    DB      66h\r
    retf                                ; transfer control to 16-bit code\r
@16Return:\r
    pushf                               ; pushfd actually\r
    push    gs\r
    push    fs\r
    push    es\r
    push    ds\r
    pushaw                              ; pushad actually\r
    DB      67h, 66h\r
    lds     esi, fword ptr (IA32_REGS ptr [esp])._EIP\r
    DB      67h, 66h\r
    mov     eax, [esi + 12]\r
    mov     cr4, eax                    ; restore CR4\r
    DB      67h, 66h\r
    lgdt    fword ptr [esi + 16]\r
    DB      67h, 66h\r
    mov     eax, [esi + 8]\r
    mov     cr0, eax                    ; restore CR0\r
    xor     ax, ax                      ; xor eax, eax actually\r
    mov     eax, ss\r
    DB      67h\r
    mov     dword ptr (IA32_REGS ptr [esp])._SS, eax\r
    shl     ax, 4                       ; shl eax, 4 actually\r
    add     ax, sp                      ; add eax, esp actually\r
    add     sp, sizeof (IA32_REGS)      ; add esp, sizeof (IA32_REGS)\r
    DB      67h, 66h\r
    mov     dword ptr (IA32_REGS ptr [esp - sizeof (IA32_REGS)])._ESP, esp\r
    DB      67h, 66h\r
    lss     esp, fword ptr [esi]        ; restore protected mode stack\r
    DB      66h\r
    retf                                ; go back to protected mode\r
@BackToThunk:\r
    lidt    fword ptr [esp + 36]        ; restore protected mode IDTR\r
    ret\r
InternalAsmThunk16  ENDP\r
\r
    END\r