UefiCpuPkg: Merge StuffRsb.inc files into one in UefiCpuPkg/Include

[mirror_edk2.git] / UefiCpuPkg / Library / SmmCpuFeaturesLib / Ia32 / SmiException.nasm

;------------------------------------------------------------------------------ ;\r
; Copyright (c) 2009 - 2018, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php.\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   SmiException.nasm\r
;\r
; Abstract:\r
;\r
;   Exception handlers used in SM mode\r
;\r
;-------------------------------------------------------------------------------\r
\r
%include "StuffRsbNasm.inc"\r
\r
global  ASM_PFX(gcStmPsd)\r
\r
extern  ASM_PFX(SmmStmExceptionHandler)\r
extern  ASM_PFX(SmmStmSetup)\r
extern  ASM_PFX(SmmStmTeardown)\r
extern  ASM_PFX(gStmXdSupported)\r
extern  ASM_PFX(gStmSmiHandlerIdtr)\r
\r
%define MSR_IA32_MISC_ENABLE 0x1A0\r
%define MSR_EFER      0xc0000080\r
%define MSR_EFER_XD   0x800\r
\r
CODE_SEL          equ 0x08\r
DATA_SEL          equ 0x20\r
TSS_SEL           equ 0x40\r
\r
    SECTION .data\r
\r
ASM_PFX(gcStmPsd):\r
            DB      'TXTPSSIG'\r
            DW      PSD_SIZE\r
            DW      1              ; Version\r
            DD      0              ; LocalApicId\r
            DB      0x05           ; Cr4Pse;Cr4Pae;Intel64Mode;ExecutionDisableOutsideSmrr\r
            DB      0              ; BIOS to STM\r
            DB      0              ; STM to BIOS\r
            DB      0\r
            DW      CODE_SEL\r
            DW      DATA_SEL\r
            DW      DATA_SEL\r
            DW      DATA_SEL\r
            DW      TSS_SEL\r
            DW      0\r
            DQ      0              ; SmmCr3\r
            DD      ASM_PFX(OnStmSetup)\r
            DD      0\r
            DD      ASM_PFX(OnStmTeardown)\r
            DD      0\r
            DQ      0              ; SmmSmiHandlerRip - SMM guest entrypoint\r
            DQ      0              ; SmmSmiHandlerRsp\r
            DQ      0\r
            DD      0\r
            DD      0x80010100     ; RequiredStmSmmRevId\r
            DD      ASM_PFX(OnException)\r
            DD      0\r
            DQ      0              ; ExceptionStack\r
            DW      DATA_SEL\r
            DW      0x01F          ; ExceptionFilter\r
            DD      0\r
            DD      0\r
            DD      0\r
            DQ      0              ; BiosHwResourceRequirementsPtr\r
            DQ      0              ; AcpiRsdp\r
            DB      0              ; PhysicalAddressBits\r
PSD_SIZE  equ $ - ASM_PFX(gcStmPsd)\r
\r
    SECTION .text\r
;------------------------------------------------------------------------------\r
; SMM Exception handlers\r
;------------------------------------------------------------------------------\r
global ASM_PFX(OnException)\r
ASM_PFX(OnException):\r
    mov  ecx, esp\r
    push ecx\r
    call ASM_PFX(SmmStmExceptionHandler)\r
    add  esp, 4\r
\r
    mov  ebx, eax\r
    mov  eax, 4\r
    vmcall\r
    jmp $\r
\r
global ASM_PFX(OnStmSetup)\r
ASM_PFX(OnStmSetup):\r
;\r
; Check XD disable bit\r
;\r
    xor     esi, esi\r
    mov     eax, ASM_PFX(gStmXdSupported)\r
    mov     al, [eax]\r
    cmp     al, 0\r
    jz      @StmXdDone1\r
    mov     ecx, MSR_IA32_MISC_ENABLE\r
    rdmsr\r
    mov     esi, edx                   ; save MSR_IA32_MISC_ENABLE[63-32]\r
    test    edx, BIT2                  ; MSR_IA32_MISC_ENABLE[34]\r
    jz      .51\r
    and     dx, 0xFFFB                 ; clear XD Disable bit if it is set\r
    wrmsr\r
.51:\r
    mov     ecx, MSR_EFER\r
    rdmsr\r
    or      ax, MSR_EFER_XD             ; enable NXE\r
    wrmsr\r
@StmXdDone1:\r
    push    esi\r
\r
  call ASM_PFX(SmmStmSetup)\r
\r
    mov     eax, ASM_PFX(gStmXdSupported)\r
    mov     al, [eax]\r
    cmp     al, 0\r
    jz      .71\r
    pop     edx                       ; get saved MSR_IA32_MISC_ENABLE[63-32]\r
    test    edx, BIT2\r
    jz      .71\r
    mov     ecx, MSR_IA32_MISC_ENABLE\r
    rdmsr\r
    or      dx, BIT2                  ; set XD Disable bit if it was set before entering into SMM\r
    wrmsr\r
\r
.71:\r
    StuffRsb32\r
    rsm\r
\r
global  ASM_PFX(OnStmTeardown)\r
ASM_PFX(OnStmTeardown):\r
;\r
; Check XD disable bit\r
;\r
    xor     esi, esi\r
    mov     eax, ASM_PFX(gStmXdSupported)\r
    mov     al, [eax]\r
    cmp     al, 0\r
    jz      @StmXdDone2\r
    mov     ecx, MSR_IA32_MISC_ENABLE\r
    rdmsr\r
    mov     esi, edx                   ; save MSR_IA32_MISC_ENABLE[63-32]\r
    test    edx, BIT2                  ; MSR_IA32_MISC_ENABLE[34]\r
    jz      .52\r
    and     dx, 0xFFFB                 ; clear XD Disable bit if it is set\r
    wrmsr\r
.52:\r
    mov     ecx, MSR_EFER\r
    rdmsr\r
    or      ax, MSR_EFER_XD             ; enable NXE\r
    wrmsr\r
@StmXdDone2:\r
    push    esi\r
\r
  call ASM_PFX(SmmStmTeardown)\r
\r
    mov     eax, ASM_PFX(gStmXdSupported)\r
    mov     al, [eax]\r
    cmp     al, 0\r
    jz      .72\r
    pop     edx                       ; get saved MSR_IA32_MISC_ENABLE[63-32]\r
    test    edx, BIT2\r
    jz      .72\r
    mov     ecx, MSR_IA32_MISC_ENABLE\r
    rdmsr\r
    or      dx, BIT2                  ; set XD Disable bit if it was set before entering into SMM\r
    wrmsr\r
\r
.72:\r
    StuffRsb32\r
    rsm\r