UefiCpuPkg: Move AsmRelocateApLoopStart from Mpfuncs.nasm to AmdSev.nasm

[mirror_edk2.git] / UefiCpuPkg / PiSmmCpuDxeSmm / Ia32 / MpFuncs.nasm

;------------------------------------------------------------------------------ ;\r
; Copyright (c) 2016, Intel Corporation. All rights reserved.<BR>\r
; SPDX-License-Identifier: BSD-2-Clause-Patent\r
;\r
; Module Name:\r
;\r
;   MpFuncs.nasm\r
;\r
; Abstract:\r
;\r
;   This is the assembly code for Multi-processor S3 support\r
;\r
;-------------------------------------------------------------------------------\r
\r
SECTION .text\r
\r
extern ASM_PFX(InitializeFloatingPointUnits)\r
\r
%define VacantFlag 0x0\r
%define NotVacantFlag 0xff\r
\r
%define LockLocation RendezvousFunnelProcEnd - RendezvousFunnelProcStart\r
%define StackStart LockLocation + 0x4\r
%define StackSize LockLocation + 0x8\r
%define RendezvousProc LockLocation + 0xC\r
%define GdtrProfile LockLocation + 0x10\r
%define IdtrProfile LockLocation + 0x16\r
%define BufferStart LockLocation + 0x1C\r
\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc  procedure follows. All APs execute their procedure. This\r
;procedure serializes all the AP processors through an Init sequence. It must be\r
;noted that APs arrive here very raw...ie: real mode, no stack.\r
;ALSO THIS PROCEDURE IS EXECUTED BY APs ONLY ON 16 BIT MODE. HENCE THIS PROC\r
;IS IN MACHINE CODE.\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc (&WakeUpBuffer,MemAddress);\r
\r
BITS 16\r
global ASM_PFX(RendezvousFunnelProc)\r
ASM_PFX(RendezvousFunnelProc):\r
RendezvousFunnelProcStart:\r
\r
; At this point CS = 0x(vv00) and ip= 0x0.\r
\r
        mov        ax,  cs\r
        mov        ds,  ax\r
        mov        es,  ax\r
        mov        ss,  ax\r
        xor        ax,  ax\r
        mov        fs,  ax\r
        mov        gs,  ax\r
\r
flat32Start:\r
\r
        mov        si, BufferStart\r
        mov        edx,dword [si]          ; EDX is keeping the start address of wakeup buffer\r
\r
        mov        si, GdtrProfile\r
o32     lgdt       [cs:si]\r
\r
        mov        si, IdtrProfile\r
o32     lidt       [cs:si]\r
\r
        xor        ax,  ax\r
        mov        ds,  ax\r
\r
        mov        eax, cr0                    ; Get control register 0\r
        or         eax, 0x000000001            ; Set PE bit (bit #0)\r
        mov        cr0, eax\r
\r
FLAT32_JUMP:\r
\r
a32     jmp   dword 0x20:0x0\r
\r
BITS 32\r
PMODE_ENTRY:                         ; protected mode entry point\r
\r
        mov         ax,  0x8\r
o16     mov         ds,  ax\r
o16     mov         es,  ax\r
o16     mov         fs,  ax\r
o16     mov         gs,  ax\r
o16     mov         ss,  ax           ; Flat mode setup.\r
\r
        mov         esi, edx\r
\r
        mov         edi, esi\r
        add         edi, LockLocation\r
        mov         al,  NotVacantFlag\r
TestLock:\r
        xchg        byte [edi], al\r
        cmp         al, NotVacantFlag\r
        jz          TestLock\r
\r
ProgramStack:\r
\r
        mov         edi, esi\r
        add         edi, StackSize\r
        mov         eax, dword [edi]\r
        mov         edi, esi\r
        add         edi, StackStart\r
        add         eax, dword [edi]\r
        mov         esp, eax\r
        mov         dword [edi], eax\r
\r
Releaselock:\r
\r
        mov         al,  VacantFlag\r
        mov         edi, esi\r
        add         edi, LockLocation\r
        xchg        byte [edi], al\r
\r
        ;\r
        ; Call assembly function to initialize FPU.\r
        ;\r
        mov         ebx, ASM_PFX(InitializeFloatingPointUnits)\r
        call        ebx\r
        ;\r
        ; Call C Function\r
        ;\r
        mov         edi, esi\r
        add         edi, RendezvousProc\r
        mov         eax, dword [edi]\r
\r
        test        eax, eax\r
        jz          GoToSleep\r
        call        eax                           ; Call C function\r
\r
GoToSleep:\r
        cli\r
        hlt\r
        jmp         $-2\r
\r
RendezvousFunnelProcEnd:\r
;-------------------------------------------------------------------------------------\r
;  AsmGetAddressMap (&AddressMap);\r
;-------------------------------------------------------------------------------------\r
global ASM_PFX(AsmGetAddressMap)\r
ASM_PFX(AsmGetAddressMap):\r
\r
        pushad\r
        mov         ebp,esp\r
\r
        mov         ebx, dword [ebp+0x24]\r
        mov         dword [ebx], RendezvousFunnelProcStart\r
        mov         dword [ebx+0x4], PMODE_ENTRY - RendezvousFunnelProcStart\r
        mov         dword [ebx+0x8], FLAT32_JUMP - RendezvousFunnelProcStart\r
        mov         dword [ebx+0xc], RendezvousFunnelProcEnd - RendezvousFunnelProcStart\r
\r
        popad\r
        ret\r
\r