UefiCpuPkg/PiSmmCpuDxeSmm: patch "gSmbase" with PatchInstructionX86()

[mirror_edk2.git] / UefiCpuPkg / PiSmmCpuDxeSmm / X64 / MpFuncs.nasm

;------------------------------------------------------------------------------ ;\r
; Copyright (c) 2016 - 2018, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php.\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
; Module Name:\r
;\r
;   MpFuncs.nasm\r
;\r
; Abstract:\r
;\r
;   This is the assembly code for Multi-processor S3 support\r
;\r
;-------------------------------------------------------------------------------\r
\r
%define VacantFlag 0x0\r
%define NotVacantFlag 0xff\r
\r
%define LockLocation RendezvousFunnelProcEnd - RendezvousFunnelProcStart\r
%define StackStartAddressLocation LockLocation + 0x8\r
%define StackSizeLocation LockLocation + 0x10\r
%define CProcedureLocation LockLocation + 0x18\r
%define GdtrLocation LockLocation + 0x20\r
%define IdtrLocation LockLocation + 0x2A\r
%define BufferStartLocation LockLocation + 0x34\r
%define Cr3OffsetLocation LockLocation + 0x38\r
%define InitializeFloatingPointUnitsAddress LockLocation + 0x3C\r
\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc  procedure follows. All APs execute their procedure. This\r
;procedure serializes all the AP processors through an Init sequence. It must be\r
;noted that APs arrive here very raw...ie: real mode, no stack.\r
;ALSO THIS PROCEDURE IS EXECUTED BY APs ONLY ON 16 BIT MODE. HENCE THIS PROC\r
;IS IN MACHINE CODE.\r
;-------------------------------------------------------------------------------------\r
;RendezvousFunnelProc (&WakeUpBuffer,MemAddress);\r
\r
;text      SEGMENT\r
DEFAULT REL\r
SECTION .text\r
\r
BITS 16\r
global ASM_PFX(RendezvousFunnelProc)\r
ASM_PFX(RendezvousFunnelProc):\r
RendezvousFunnelProcStart:\r
\r
; At this point CS = 0x(vv00) and ip= 0x0.\r
\r
        mov        ax,  cs\r
        mov        ds,  ax\r
        mov        es,  ax\r
        mov        ss,  ax\r
        xor        ax,  ax\r
        mov        fs,  ax\r
        mov        gs,  ax\r
\r
flat32Start:\r
\r
        mov        si, BufferStartLocation\r
        mov        edx,dword [si]          ; EDX is keeping the start address of wakeup buffer\r
\r
        mov        si, Cr3OffsetLocation\r
        mov        ecx,dword [si]          ; ECX is keeping the value of CR3\r
\r
        mov        si, GdtrLocation\r
o32     lgdt       [cs:si]\r
\r
        mov        si, IdtrLocation\r
o32     lidt       [cs:si]\r
\r
        xor        ax,  ax\r
        mov        ds,  ax\r
\r
        mov        eax, cr0                    ; Get control register 0\r
        or         eax, 0x000000001            ; Set PE bit (bit #0)\r
        mov        cr0, eax\r
\r
FLAT32_JUMP:\r
\r
a32     jmp   dword 0x20:0x0\r
\r
BITS 32\r
PMODE_ENTRY:                         ; protected mode entry point\r
\r
        mov        ax,  0x18\r
o16     mov        ds,  ax\r
o16     mov        es,  ax\r
o16     mov        fs,  ax\r
o16     mov        gs,  ax\r
o16     mov        ss,  ax                     ; Flat mode setup.\r
\r
        mov        eax, cr4\r
        bts        eax, 5\r
        mov        cr4, eax\r
\r
        mov        cr3, ecx\r
\r
        mov        esi, edx                    ; Save wakeup buffer address\r
\r
        mov        ecx, 0xc0000080             ; EFER MSR number.\r
        rdmsr                                  ; Read EFER.\r
        bts        eax, 8                      ; Set LME=1.\r
        wrmsr                                  ; Write EFER.\r
\r
        mov        eax, cr0                    ; Read CR0.\r
        bts        eax, 31                     ; Set PG=1.\r
        mov        cr0, eax                    ; Write CR0.\r
\r
LONG_JUMP:\r
\r
a16     jmp   dword 0x38:0x0\r
\r
BITS 64\r
LongModeStart:\r
\r
        mov         ax,  0x30\r
o16     mov         ds,  ax\r
o16     mov         es,  ax\r
o16     mov         ss,  ax\r
\r
        mov  edi, esi\r
        add  edi, LockLocation\r
        mov  al,  NotVacantFlag\r
TestLock:\r
        xchg byte [edi], al\r
        cmp  al, NotVacantFlag\r
        jz   TestLock\r
\r
ProgramStack:\r
\r
        mov  edi, esi\r
        add  edi, StackSizeLocation\r
        mov  rax, qword [edi]\r
        mov  edi, esi\r
        add  edi, StackStartAddressLocation\r
        add  rax, qword [edi]\r
        mov  rsp, rax\r
        mov  qword [edi], rax\r
\r
Releaselock:\r
\r
        mov  al,  VacantFlag\r
        mov  edi, esi\r
        add  edi, LockLocation\r
        xchg byte [edi], al\r
\r
        ;\r
        ; Call assembly function to initialize FPU.\r
        ;\r
        mov         rax, qword [esi + InitializeFloatingPointUnitsAddress]\r
        sub         rsp, 0x20\r
        call        rax\r
        add         rsp, 0x20\r
\r
        ;\r
        ; Call C Function\r
        ;\r
        mov         edi, esi\r
        add         edi, CProcedureLocation\r
        mov         rax, qword [edi]\r
\r
        test        rax, rax\r
        jz          GoToSleep\r
\r
        sub         rsp, 0x20\r
        call        rax\r
        add         rsp, 0x20\r
\r
GoToSleep:\r
        cli\r
        hlt\r
        jmp         $-2\r
\r
RendezvousFunnelProcEnd:\r
\r
;-------------------------------------------------------------------------------------\r
;  AsmGetAddressMap (&AddressMap);\r
;-------------------------------------------------------------------------------------\r
; comments here for definition of address map\r
global ASM_PFX(AsmGetAddressMap)\r
ASM_PFX(AsmGetAddressMap):\r
        lea         rax, [RendezvousFunnelProcStart]\r
        mov         qword [rcx], rax\r
        mov         qword [rcx+0x8], PMODE_ENTRY - RendezvousFunnelProcStart\r
        mov         qword [rcx+0x10], FLAT32_JUMP - RendezvousFunnelProcStart\r
        mov         qword [rcx+0x18], RendezvousFunnelProcEnd - RendezvousFunnelProcStart\r
        mov         qword [rcx+0x20], LongModeStart - RendezvousFunnelProcStart\r
        mov         qword [rcx+0x28], LONG_JUMP - RendezvousFunnelProcStart\r
        ret\r
\r