UefiCpuPkg: Add PiSmmCpuDxeSmm module X64 files

[mirror_edk2.git] / UefiCpuPkg / PiSmmCpuDxeSmm / X64 / SmmInit.S

#------------------------------------------------------------------------------\r
#\r
# Copyright (c) 2009 - 2015, Intel Corporation. All rights reserved.<BR>\r
# This program and the accompanying materials\r
# are licensed and made available under the terms and conditions of the BSD License\r
# which accompanies this distribution.  The full text of the license may be found at\r
# http://opensource.org/licenses/bsd-license.php.\r
#\r
# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
#\r
# Module Name:\r
#\r
#   SmmInit.S\r
#\r
# Abstract:\r
#\r
#   Functions for relocating SMBASE's for all processors\r
#\r
#------------------------------------------------------------------------------\r
\r
ASM_GLOBAL   ASM_PFX(gSmmCr0)\r
ASM_GLOBAL   ASM_PFX(gSmmCr3)\r
ASM_GLOBAL   ASM_PFX(gSmmCr4)\r
ASM_GLOBAL   ASM_PFX(gSmmJmpAddr)\r
ASM_GLOBAL   ASM_PFX(gcSmmInitTemplate)\r
ASM_GLOBAL   ASM_PFX(gcSmmInitSize)\r
ASM_GLOBAL   ASM_PFX(mRebasedFlagAddr32)\r
ASM_GLOBAL   ASM_PFX(SmmRelocationSemaphoreComplete)\r
ASM_GLOBAL   ASM_PFX(SmmRelocationSemaphoreComplete32)\r
ASM_GLOBAL   ASM_PFX(mSmmRelocationOriginalAddressPtr32)\r
ASM_GLOBAL   ASM_PFX(gSmmInitStack)\r
ASM_GLOBAL   ASM_PFX(gcSmiInitGdtr)\r
\r
\r
    .text\r
\r
ASM_PFX(gcSmiInitGdtr):\r
            .word      0\r
            .quad      0\r
\r
SmmStartup:\r
    .byte 0x66,0xb8                     # mov eax, imm32\r
ASM_PFX(gSmmCr3):    .space     4\r
    movq    %rax, %cr3\r
    .byte 0x66,0x2e\r
    lgdt    (ASM_PFX(gcSmiInitGdtr) - SmmStartup)(%ebp)\r
    .byte 0x66,0xb8                     # mov eax, imm32\r
ASM_PFX(gSmmCr4):    .space     4\r
    orb     $2, %ah                     # enable XMM registers access\r
    movq    %rax, %cr4\r
    .byte 0x66\r
    movl    $0xc0000080,%ecx            # IA32_EFER MSR\r
    rdmsr\r
    orb     $1,%ah                      # set LME bit\r
    wrmsr\r
    .byte 0x66,0xb8                     # mov eax, imm32\r
ASM_PFX(gSmmCr0):    .space     4\r
    movq    %rax, %cr0\r
    .byte 0x66,0xea                     # far jmp to long mode\r
ASM_PFX(gSmmJmpAddr): .quad      LongMode\r
LongMode:                               # long-mode starts here\r
    .byte 0x48,0xbc                     # mov rsp, imm64\r
ASM_PFX(gSmmInitStack):  .space  8\r
    andw  $0xfff0, %sp                  # make sure RSP is 16-byte aligned\r
    #\r
    # Accoring to X64 calling convention, XMM0~5 are volatile, we need to save\r
    # them before calling C-function.\r
    #\r
    subq     $0x60, %rsp\r
    movdqa   %xmm0, 0x0(%rsp)\r
    movdqa   %xmm1, 0x10(%rsp)\r
    movdqa   %xmm2, 0x20(%rsp)\r
    movdqa   %xmm3, 0x30(%rsp)\r
    movdqa   %xmm4, 0x40(%rsp)\r
    movdqa   %xmm5, 0x50(%rsp)\r
\r
\r
    addq  $-0x20, %rsp\r
    call  ASM_PFX(SmmInitHandler)\r
    addq  $0x20, %rsp\r
    #\r
    # Restore XMM0~5 after calling C-function.\r
    #\r
    movdqa  0x0(%rsp), %xmm0\r
    movdqa  0x10(%rsp), %xmm1\r
    movdqa  0x20(%rsp), %xmm2\r
    movdqa  0x30(%rsp), %xmm3\r
    movdqa  0x40(%rsp), %xmm4\r
    movdqa  0x50(%rsp), %xmm5\r
\r
    rsm\r
\r
ASM_PFX(gcSmmInitTemplate):\r
\r
_SmmInitTemplate:\r
    .byte 0x66,0x2e,0x8b,0x2e           # mov ebp, cs:[@F]\r
    .word L1 - _SmmInitTemplate + 0x8000\r
    .byte 0x66, 0x81, 0xed, 0, 0, 3, 0  # sub ebp, 0x30000\r
    jmp     *%bp                        # jmp ebp actually\r
L1:\r
    .quad      SmmStartup\r
\r
ASM_PFX(gcSmmInitSize):   .word  . - ASM_PFX(gcSmmInitTemplate)\r
\r
ASM_PFX(SmmRelocationSemaphoreComplete):\r
    # Create a simple stack frame to store RAX and the original RSM location\r
    pushq   %rax  # Used to store return address\r
    pushq   %rax\r
\r
    # Load the original RSM location onto stack\r
    movabsq $ASM_PFX(mSmmRelocationOriginalAddress), %rax\r
    movq    (%rax), %rax\r
    movq    %rax, 0x08(%rsp)\r
\r
    # Update rebase flag\r
    movabsq $ASM_PFX(mRebasedFlag), %rax\r
    movq    (%rax), %rax\r
    movb    $1, (%rax)\r
\r
    #restore RAX and return to original RSM location\r
    popq    %rax\r
    retq\r
\r
#\r
# Semaphore code running in 32-bit mode\r
#\r
ASM_PFX(SmmRelocationSemaphoreComplete32):\r
    #\r
    # movb $1, ()\r
    #\r
    .byte   0xc6, 0x05\r
ASM_PFX(mRebasedFlagAddr32):\r
    .long   0\r
    .byte   1\r
    #\r
    # jmpd ()\r
    #\r
    .byte   0xff, 0x25\r
ASM_PFX(mSmmRelocationOriginalAddressPtr32):\r
    .long   0\r