Rename two files to follow the file naming convention.

[mirror_edk2.git] / UefiCpuPkg / ResetVector / Vtf0 / SerialDebug.asm

;------------------------------------------------------------------------------\r
; @file\r
; Serial port debug support macros\r
;\r
; Copyright (c) 2008 - 2009, Intel Corporation. All rights reserved.<BR>\r
; This program and the accompanying materials\r
; are licensed and made available under the terms and conditions of the BSD License\r
; which accompanies this distribution.  The full text of the license may be found at\r
; http://opensource.org/licenses/bsd-license.php\r
;\r
; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
;\r
;------------------------------------------------------------------------------\r
\r
;//---------------------------------------------\r
;// UART Register Offsets\r
;//---------------------------------------------\r
%define BAUD_LOW_OFFSET         0x00\r
%define BAUD_HIGH_OFFSET        0x01\r
%define IER_OFFSET              0x01\r
%define LCR_SHADOW_OFFSET       0x01\r
%define FCR_SHADOW_OFFSET       0x02\r
%define IR_CONTROL_OFFSET       0x02\r
%define FCR_OFFSET              0x02\r
%define EIR_OFFSET              0x02\r
%define BSR_OFFSET              0x03\r
%define LCR_OFFSET              0x03\r
%define MCR_OFFSET              0x04\r
%define LSR_OFFSET              0x05\r
%define MSR_OFFSET              0x06\r
\r
;//---------------------------------------------\r
;// UART Register Bit Defines\r
;//---------------------------------------------\r
%define LSR_TXRDY               0x20\r
%define LSR_RXDA                0x01\r
%define DLAB                    0x01\r
\r
; UINT16  gComBase = 0x3f8;\r
; UINTN   gBps = 115200;\r
; UINT8   gData = 8;\r
; UINT8   gStop = 1;\r
; UINT8   gParity = 0;\r
; UINT8   gBreakSet = 0;\r
\r
%define DEFAULT_COM_BASE 0x3f8\r
%define DEFAULT_BPS 115200\r
%define DEFAULT_DATA 8\r
%define DEFAULT_STOP 1\r
%define DEFAULT_PARITY 0\r
%define DEFAULT_BREAK_SET 0\r
\r
%define SERIAL_DEFAULT_LCR ( \\r
     (DEFAULT_BREAK_SET << 6) | \\r
     (DEFAULT_PARITY << 3) | \\r
     (DEFAULT_STOP << 2) | \\r
     (DEFAULT_DATA - 5) \\r
    )\r
\r
%define SERIAL_PORT_IO_BASE_ADDRESS DEFAULT_COM_BASE\r
\r
%macro  inFromSerialPort 1\r
    mov     dx, (SERIAL_PORT_IO_BASE_ADDRESS + %1)\r
    in      al, dx\r
%endmacro\r
\r
%macro  waitForSerialTxReady 0\r
\r
%%waitingForTx:\r
    inFromSerialPort LSR_OFFSET\r
    test    al, LSR_TXRDY\r
    jz      %%waitingForTx\r
\r
%endmacro\r
\r
%macro  outToSerialPort 2\r
    mov     dx, (SERIAL_PORT_IO_BASE_ADDRESS + %1)\r
    mov     al, %2\r
    out     dx, al\r
%endmacro\r
\r
%macro  debugShowCharacter 1\r
    waitForSerialTxReady\r
    outToSerialPort 0, %1\r
%endmacro\r
\r
%macro  debugShowHexDigit 1\r
  %if (%1 < 0xa)\r
    debugShowCharacter BYTE ('0' + (%1))\r
  %else\r
    debugShowCharacter BYTE ('a' + ((%1) - 0xa))\r
  %endif\r
%endmacro\r
\r
%macro  debugNewline 0\r
    debugShowCharacter `\r`\r
    debugShowCharacter `\n`\r
%endmacro\r
\r
%macro  debugShowPostCode 1\r
    debugShowHexDigit (((%1) >> 4) & 0xf)\r
    debugShowHexDigit ((%1) & 0xf)\r
    debugNewline\r
%endmacro\r
\r
BITS    16\r
\r
%macro  debugInitialize 0\r
	jmp	real16InitDebug\r
real16InitDebugReturn:\r
%endmacro\r
\r
real16InitDebug:\r
    ;\r
    ; Set communications format\r
    ;\r
    outToSerialPort LCR_OFFSET, ((DLAB << 7) | SERIAL_DEFAULT_LCR)\r
\r
    ;\r
    ; Configure baud rate\r
    ;\r
    outToSerialPort BAUD_HIGH_OFFSET, ((115200 / DEFAULT_BPS) >> 8)\r
    outToSerialPort BAUD_LOW_OFFSET, ((115200 / DEFAULT_BPS) & 0xff)\r
\r
    ;\r
    ; Switch back to bank 0\r
    ;\r
    outToSerialPort LCR_OFFSET, SERIAL_DEFAULT_LCR\r
\r
    jmp     real16InitDebugReturn\r
\r