IntelFsp2WrapperPkg: Update gFspWrapperTokenSpaceGuid to gIntelFsp2WrapperTokenSpaceGuid.

[mirror_edk2.git] / edksetup.bat

@REM @file\r
@REM   Windows batch file to setup a WORKSPACE environment\r
@REM\r
@REM Copyright (c) 2006 - 2016, Intel Corporation. All rights reserved.<BR>\r
@REM This program and the accompanying materials\r
@REM are licensed and made available under the terms and conditions of the BSD License\r
@REM which accompanies this distribution.  The full text of the license may be found at\r
@REM http://opensource.org/licenses/bsd-license.php\r
@REM\r
@REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
@REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
@REM\r
\r
@REM set CYGWIN_HOME=C:\cygwin\r
\r
@REM usage: \r
@REM   edksetup.bat [--nt32] [AntBuild] [Rebuild] [ForceRebuild] [Reconfig]\r
@REM if the argument, skip is present, only the paths and the\r
@REM test and set of environment settings are performed. \r
\r
@REM ##############################################################\r
@REM # You should not have to modify anything below this line\r
@REM #\r
\r
@echo off\r
\r
@REM\r
@REM Set the WORKSPACE to the current working directory\r
@REM\r
pushd .\r
cd %~dp0\r
\r
if not defined WORKSPACE (\r
  goto SetWorkSpace\r
)\r
\r
if %WORKSPACE% == %CD% (\r
  @REM Workspace is not changed.\r
  goto ParseArgs\r
)\r
\r
:SetWorkSpace\r
@REM set new workspace\r
@REM clear EFI_SOURCE and EDK_SOURCE for the new workspace\r
if not defined WORKSPACE (\r
  set WORKSPACE=%CD%\r
  set EFI_SOURCE=\r
  set EDK_SOURCE=\r
)\r
\r
:ParseArgs\r
if /I "%1"=="-h" goto Usage\r
if /I "%1"=="-help" goto Usage\r
if /I "%1"=="--help" goto Usage\r
if /I "%1"=="/h" goto Usage\r
if /I "%1"=="/?" goto Usage\r
if /I "%1"=="/help" goto Usage\r
\r
if /I not "%1"=="--nt32" goto no_nt32\r
\r
@REM Flag, --nt32 is set\r
@REM The Nt32 Emluation Platform requires Microsoft Libraries\r
@REM and headers to interface with Windows.\r
\r
if not defined VCINSTALLDIR (\r
  if defined VS140COMNTOOLS (\r
    call "%VS140COMNTOOLS%\vsvars32.bat"\r
  ) else (\r
    if defined VS120COMNTOOLS (\r
      call "%VS120COMNTOOLS%\vsvars32.bat"\r
    ) else (	\r
      if defined VS110COMNTOOLS (\r
        call "%VS110COMNTOOLS%\vsvars32.bat"\r
      ) else (\r
        if defined VS100COMNTOOLS (\r
          call "%VS100COMNTOOLS%\vsvars32.bat"\r
        ) else (\r
          if defined VS90COMNTOOLS (\r
            call "%VS90COMNTOOLS%\vsvars32.bat"\r
          ) else (\r
            if defined VS80COMNTOOLS (\r
              call "%VS80COMNTOOLS%\vsvars32.bat"\r
            ) else (\r
              if defined VS71COMNTOOLS (\r
                call "%VS71COMNTOOLS%\vsvars32.bat"\r
              ) else (\r
                echo.\r
                echo !!! WARNING !!! Cannot find Visual Studio !!!\r
                echo.\r
              )\r
            )\r
          )\r
        )\r
      )\r
    )\r
  )\r
)\r
shift\r
\r
:no_nt32\r
\r
if /I "%1"=="NewBuild" shift\r
if not defined EDK_TOOLS_PATH (\r
  if exist %WORKSPACE%\BaseTools (\r
    set EDK_TOOLS_PATH=%WORKSPACE%\BaseTools\r
  ) else (\r
    if defined PACKAGES_PATH (\r
      for %%i IN (%PACKAGES_PATH%) DO (\r
        if exist %%~fi\BaseTools (\r
          set EDK_TOOLS_PATH=%%~fi\BaseTools\r
          goto checkBaseTools\r
        )\r
      )\r
    ) else (\r
      echo.\r
      echo !!! ERROR !!! Cannot find BaseTools !!!\r
      echo. \r
      goto BadBaseTools\r
    )\r
  )\r
)\r
if exist %EDK_TOOLS_PATH%\Source set BASE_TOOLS_PATH=%EDK_TOOLS_PATH%\r
\r
:checkBaseTools\r
IF NOT EXIST "%EDK_TOOLS_PATH%\toolsetup.bat" goto BadBaseTools\r
call %EDK_TOOLS_PATH%\toolsetup.bat %*\r
if /I "%1"=="Reconfig" shift\r
goto check_cygwin\r
\r
:BadBaseTools\r
  @REM\r
  REM Need the BaseTools Package in order to build\r
  @REM\r
  @echo.\r
  @echo !!! ERROR !!! The BaseTools Package was not found !!!\r
  @echo.\r
  @echo Set the system environment variable, EDK_TOOLS_PATH to the BaseTools,\r
  @echo For example,\r
  @echo   set EDK_TOOLS_PATH=C:\MyTools\BaseTools\r
  @echo The setup script, toolsetup.bat must reside in this folder.\r
  @echo.\r
  goto end\r
\r
:check_cygwin\r
if defined CYGWIN_HOME (\r
  if not exist "%CYGWIN_HOME%" (\r
    @echo.\r
    @echo !!! WARNING !!! CYGWIN_HOME not found, gcc build may not be used !!!\r
    @echo.\r
  )\r
) else (\r
  if exist c:\cygwin (\r
    set CYGWIN_HOME=c:\cygwin\r
  ) else (\r
    @echo.\r
    @echo !!! WARNING !!! No CYGWIN_HOME set, gcc build may not be used !!!\r
    @echo.\r
  )\r
)\r
\r
:cygwin_done\r
if "%1"=="" goto end\r
\r
:Usage\r
  @echo.\r
  @echo  Usage: "%0 [-h | -help | --help | /h | /help | /?] [--nt32] [Reconfig]"\r
  @echo         --nt32         Call vsvars32.bat for NT32 platform build.\r
  @echo.\r
  @echo         Reconfig       Reinstall target.txt, tools_def.txt and build_rule.txt.\r
  @echo.\r
  @echo  Note that target.template, tools_def.template and build_rules.template\r
  @echo  will only be copied to target.txt, tools_def.txt and build_rule.txt\r
  @echo  respectively if they do not exist. Use option [Reconfig] to force the copy.\r
  @echo.\r
  goto end\r
\r
:end\r
  popd\r
\r