ArmPlatformPkg/PrePi/Arm/ModuleEntryPoint.S

   1 //
   2 //  Copyright (c) 2011-2013, ARM Limited. All rights reserved.
   3 //
   4 //  This program and the accompanying materials
   5 //  are licensed and made available under the terms and conditions of the BSD License
   6 //  which accompanies this distribution.  The full text of the license may be found at
   7 //  http://opensource.org/licenses/bsd-license.php
   8 //
   9 //  THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 //  WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 //
  12 //
  13
  14 #include <AsmMacroIoLib.h>
  15 #include <Base.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18
  19 #include <Chipset/ArmV7.h>
  20
  21 .text
  22 .align 3
  23
  24 GCC_ASM_IMPORT(CEntryPoint)
  25 GCC_ASM_IMPORT(ArmReadMpidr)
  26 GCC_ASM_IMPORT(ArmPlatformStackSet)
  27 GCC_ASM_EXPORT(_ModuleEntryPoint)
  28
  29 StartupAddr: .word    CEntryPoint
  30
  31
  32 ASM_PFX(_ModuleEntryPoint):
  33   // Get ID of this CPU in Multicore system
  34   bl    ASM_PFX(ArmReadMpidr)
  35   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCoreMask), r1)
  36   and   r6, r0, r1
  37
  38 _SetSVCMode:
  39   // Enter SVC mode, Disable FIQ and IRQ
  40   mov     r1, #(CPSR_MODE_SVC | CPSR_IRQ | CPSR_FIQ)
  41   msr     CPSR_c, r1
  42
  43 // Check if we can install the stack at the top of the System Memory or if we need
  44 // to install the stacks at the bottom of the Firmware Device (case the FD is located
  45 // at the top of the DRAM)
  46 _SetupStackPosition:
  47   // Compute Top of System Memory
  48   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryBase), r1)
  49   LoadConstantToReg (FixedPcdGet32(PcdSystemMemorySize), r2)
  50   sub   r2, r2, #1
  51   add   r1, r1, r2      // r1 = SystemMemoryTop = PcdSystemMemoryBase + PcdSystemMemorySize
  52
  53   // Calculate Top of the Firmware Device
  54   LoadConstantToReg (FixedPcdGet32(PcdFdBaseAddress), r2)
  55   LoadConstantToReg (FixedPcdGet32(PcdFdSize), r3)
  56   sub   r3, r3, #1
  57   add   r3, r3, r2      // r3 = FdTop = PcdFdBaseAddress + PcdFdSize
  58
  59   // UEFI Memory Size (stacks are allocated in this region)
  60   LoadConstantToReg (FixedPcdGet32(PcdSystemMemoryUefiRegionSize), r4)
  61
  62   //
  63   // Reserve the memory for the UEFI region (contain stacks on its top)
  64   //
  65
  66   // Calculate how much space there is between the top of the Firmware and the Top of the System Memory
  67   subs  r0, r1, r3      // r0 = SystemMemoryTop - FdTop
  68   bmi   _SetupStack     // Jump if negative (FdTop > SystemMemoryTop). Case when the PrePi is in XIP memory outside of the DRAM
  69   cmp   r0, r4
  70   bge   _SetupStack
  71
  72   // Case the top of stacks is the FdBaseAddress
  73   mov   r1, r2
  74
  75 _SetupStack:
  76   // r1 contains the top of the stack (and the UEFI Memory)
  77
  78   // Because the 'push' instruction is equivalent to 'stmdb' (decrement before), we need to increment
  79   // one to the top of the stack. We check if incrementing one does not overflow (case of DRAM at the
  80   // top of the memory space)
  81   adds  r7, r1, #1
  82   bcs   _SetupOverflowStack
  83
  84 _SetupAlignedStack:
  85   mov   r1, r7
  86   b     _GetBaseUefiMemory
  87
  88 _SetupOverflowStack:
  89   // Case memory at the top of the address space. Ensure the top of the stack is EFI_PAGE_SIZE
  90   // aligned (4KB)
  91   LoadConstantToReg (EFI_PAGE_MASK, r7)
  92   and   r7, r7, r1
  93   sub   r1, r1, r7
  94
  95 _GetBaseUefiMemory:
  96   // Calculate the Base of the UEFI Memory
  97   sub   r7, r1, r4
  98
  99 _GetStackBase:
 100   // r1 = The top of the Mpcore Stacks
 101   // Stack for the primary core = PrimaryCoreStack
 102   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 103   sub   r8, r1, r2
 104
 105   // Stack for the secondary core = Number of Cores - 1
 106   LoadConstantToReg (FixedPcdGet32(PcdCoreCount), r0)
 107   sub   r0, r0, #1
 108   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r1)
 109   mul   r1, r1, r0
 110   sub   r8, r8, r1
 111
 112   // r8 = The base of the MpCore Stacks (primary stack & secondary stacks)
 113   mov   r0, r8
 114   mov   r1, r6
 115   //ArmPlatformStackSet(StackBase, MpId, PrimaryStackSize, SecondaryStackSize)
 116   LoadConstantToReg (FixedPcdGet32(PcdCPUCorePrimaryStackSize), r2)
 117   LoadConstantToReg (FixedPcdGet32(PcdCPUCoreSecondaryStackSize), r3)
 118   bl    ASM_PFX(ArmPlatformStackSet)
 119
 120   // Is it the Primary Core ?
 121   LoadConstantToReg (FixedPcdGet32(PcdArmPrimaryCore), r4)
 122   cmp   r6, r4
 123   bne   _PrepareArguments
 124
 125 _ReserveGlobalVariable:
 126   LoadConstantToReg (FixedPcdGet32(PcdPeiGlobalVariableSize), r0)
 127   // InitializePrimaryStack($GlobalVariableSize, $Tmp1)
 128   InitializePrimaryStack(r0, r1)
 129
 130 _PrepareArguments:
 131   mov   r0, r6
 132   mov   r1, r7
 133   mov   r2, r8
 134   mov   r3, sp
 135
 136   // Move sec startup address into a data register
 137   // Ensure we're jumping to FV version of the code (not boot remapped alias)
 138   ldr   r4, StartupAddr
 139
 140   // Jump to PrePiCore C code
 141   //    r0 = MpId
 142   //    r1 = UefiMemoryBase
 143   //    r2 = StacksBase
 144   //    r3 = GlobalVariableBase
 145   blx   r4
 146
 147 _NeverReturn:
 148   b _NeverReturn
 149