BaseTools/get_vsvars.bat

   1 @REM @file
   2 @REM   Windows batch file to find the Visual Studio set up script
   3 @REM
   4 @REM Copyright (c) 2013-2014, ARM Limited. All rights reserved.
   5
   6 @REM This program and the accompanying materials
   7 @REM are licensed and made available under the terms and conditions of the BSD License
   8 @REM which accompanies this distribution.  The full text of the license may be found at
   9 @REM http://opensource.org/licenses/bsd-license.php
  10 @REM
  11 @REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  12 @REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  13 @REM
  14
  15
  16 @echo off
  17 goto  :main
  18
  19 :set_vsvars
  20 for /f "usebackq tokens=1* delims=: " %%i in (`%*`) do (
  21   if /i "%%i"=="installationPath" call "%%j\VC\Auxiliary\Build\vcvars32.bat"
  22 )
  23 goto :EOF
  24
  25 :read_vsvars
  26 @rem Do nothing if already found, otherwise call vsvars32.bat if there
  27 if defined VCINSTALLDIR goto :EOF
  28   set GET_VSVARS_BAT_CHECK_DIR=%*
  29   set GET_VSVARS_BAT_CHECK_DIR=%GET_VSVARS_BAT_CHECK_DIR:"=%
  30   if exist  "%GET_VSVARS_BAT_CHECK_DIR%\vsvars32.bat"  call "%GET_VSVARS_BAT_CHECK_DIR%\vsvars32.bat"
  31 :vsvars_done
  32 goto :EOF
  33
  34
  35 REM NOTE: This file will find the most recent Visual Studio installation
  36 REM       apparent from the environment.
  37 REM       To use an older version, modify your environment set up.
  38 REM       (Or invoke the relevant vsvars32 file beforehand).
  39
  40 :main
  41 if defined VCINSTALLDIR goto :done
  42   if exist "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"  call :set_vsvars "%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"
  43   if exist "%ProgramFiles%\Microsoft Visual Studio\Installer\vswhere.exe"       call :set_vsvars "%ProgramFiles%\Microsoft Visual Studio\Installer\vswhere.exe"
  44   if defined VS140COMNTOOLS  call :read_vsvars  "%VS140COMNTOOLS%"
  45   if defined VS120COMNTOOLS  call :read_vsvars  "%VS120COMNTOOLS%"
  46   if defined VS110COMNTOOLS  call :read_vsvars  "%VS110COMNTOOLS%"
  47   if defined VS100COMNTOOLS  call :read_vsvars  "%VS100COMNTOOLS%"
  48   if defined VS90COMNTOOLS   call :read_vsvars  "%VS90COMNTOOLS%"
  49   if defined VS80COMNTOOLS   call :read_vsvars  "%VS80COMNTOOLS%"
  50   if defined VS71COMNTOOLS   call :read_vsvars  "%VS71COMNTOOLS%"
  51
  52 :done
  53 set GET_VSVARS_BAT_CHECK_DIR=