BeagleBoardPkg/Sec/Arm/ModuleEntryPoint.asm

   1 //------------------------------------------------------------------------------
   2 //
   3 // Copyright (c) 2008-2009 Apple Inc. All rights reserved.
   4 //
   5 // All rights reserved. This program and the accompanying materials
   6 // are licensed and made available under the terms and conditions of the BSD License
   7 // which accompanies this distribution.  The full text of the license may be found at
   8 // http://opensource.org/licenses/bsd-license.php
   9 //
  10 // THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 // WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 //
  13 //------------------------------------------------------------------------------
  14
  15 #include <AsmMacroIoLib.h>
  16 #include <Library/PcdLib.h>
  17 #include <AutoGen.h>
  18   INCLUDE AsmMacroIoLib.inc
  19
  20   IMPORT  CEntryPoint
  21   EXPORT  _ModuleEntryPoint
  22
  23   PRESERVE8
  24   AREA    ModuleEntryPoint, CODE, READONLY
  25
  26
  27 _ModuleEntryPoint
  28
  29   //Disable L2 cache
  30   mrc     p15, 0, r0, c1, c0, 1   // read Auxiliary Control Register
  31   bic     r0, r0, #0x00000002     // disable L2 cache
  32   mcr     p15, 0, r0, c1, c0, 1   // store Auxiliary Control Register
  33
  34   //Enable Strict alignment checking & Instruction cache
  35   mrc     p15, 0, r0, c1, c0, 0
  36   bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
  37   bic     r0, r0, #0x00000005     /* clear bits 0, 2 (---- -C-M) */
  38   orr     r0, r0, #0x00000002     /* set bit 1 (A) Align */
  39   orr     r0, r0, #0x00001000     /* set bit 12 (I) enable I-Cache */
  40   mcr     p15, 0, r0, c1, c0, 0
  41
  42   // Set CPU vectors to start of DRAM
  43   LoadConstantToReg (FixedPcdGet32(PcdCpuVectorBaseAddress) ,r0) // Get vector base
  44   mcr     p15, 0, r0, c12, c0, 0
  45   isb                               // Sync changes to control registers
  46
  47   // Fill vector table with branchs to current pc (jmp $)
  48   ldr     r1, ShouldNeverGetHere
  49   movs    r2, #0
  50 FillVectors
  51   str     r1, [r0, r2]
  52   adds    r2, r2, #4
  53   cmp     r2, #32
  54   bne     FillVectors
  55
  56   /* before we call C code, lets setup the stack pointer in internal RAM */
  57 stack_pointer_setup
  58
  59   //
  60   // Set stack based on PCD values. Need to do it this way to make C code work
  61   // when it runs from FLASH.
  62   //
  63   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackBase) ,r2)    // stack base arg2
  64   LoadConstantToReg (FixedPcdGet32(PcdPrePiStackSize) ,r3)    // stack size arg3
  65   add     r4, r2, r3
  66
  67   //Enter SVC mode and set up SVC stack pointer
  68   mov     r5,#0x13|0x80|0x40
  69   msr     CPSR_c,r5
  70   mov     r13,r4
  71
  72   // Call C entry point
  73   LoadConstantToReg (FixedPcdGet32(PcdMemorySize) ,r1)    // memory size arg1
  74   LoadConstantToReg (FixedPcdGet32(PcdMemoryBase) ,r0)    // memory start arg0
  75   blx     CEntryPoint                                     // Assume C code is thumb
  76
  77 ShouldNeverGetHere
  78   /* _CEntryPoint should never return */
  79   b       ShouldNeverGetHere
  80
  81   END
  82