DuetPkg/BootSector/start16.S

   1 #------------------------------------------------------------------------------
   2 #*
   3 #*   Copyright (c) 2006 - 2007, Intel Corporation. All rights reserved.<BR>
   4 #*   This program and the accompanying materials
   5 #*   are licensed and made available under the terms and conditions of the BSD License
   6 #*   which accompanies this distribution.  The full text of the license may be found at
   7 #*   http://opensource.org/licenses/bsd-license.php
   8 #*
   9 #*   THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 #*   WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 #*
  12 #*    start16.asm
  13 #*
  14 #*   Abstract:
  15 #*
  16 #------------------------------------------------------------------------------
  17
  18         #.MODEL small
  19         .stack:
  20         .486p:
  21         .code:
  22
  23 .equ                        FAT_DIRECTORY_ENTRY_SIZE,   0x0020
  24 .equ                        FAT_DIRECTORY_ENTRY_SHIFT,  5
  25 .equ                        BLOCK_SIZE,                 0x0200
  26 .equ                        BLOCK_MASK,                 0x01ff
  27 .equ                        BLOCK_SHIFT,                9
  28
  29         .org 0x00
  30
  31 .global _start
  32 _start:
  33
  34 Ia32Jump:
  35   jmp   BootSectorEntryPoint  # JMP inst    - 3 bytes
  36   nop
  37
  38 OemId:             .ascii  "INTEL   "    # OemId               - 8 bytes
  39
  40 SectorSize:        .word  0              # Sector Size         - 16 bits
  41 SectorsPerCluster: .byte  0              # Sector Per Cluster  - 8 bits
  42 ReservedSectors:   .word  0              # Reserved Sectors    - 16 bits
  43 NoFats:            .byte  0              # Number of FATs      - 8 bits
  44 RootEntries:       .word  0              # Root Entries        - 16 bits
  45 Sectors:           .word  0              # Number of Sectors   - 16 bits
  46 Media:             .byte  0              # Media               - 8 bits  - ignored
  47 SectorsPerFat:     .word  0              # Sectors Per FAT     - 16 bits
  48 SectorsPerTrack:   .word  0              # Sectors Per Track   - 16 bits - ignored
  49 Heads:             .word  0              # Heads               - 16 bits - ignored
  50 HiddenSectors:     .long  0              # Hidden Sectors      - 32 bits - ignored
  51 LargeSectors:      .long  0              # Large Sectors       - 32 bits
  52 PhysicalDrive:     .byte  0              # PhysicalDriveNumber - 8 bits  - ignored
  53 CurrentHead:       .byte  0              # Current Head        - 8 bits
  54 Signature:         .byte  0              # Signature           - 8 bits  - ignored
  55 VolId:             .ascii  "    "        # Volume Serial Number- 4 bytes
  56 FatLabel:          .ascii  "           " # Label               - 11 bytes
  57 SystemId:          .ascii  "FAT16   "    # SystemId            - 8 bytes
  58
  59 BootSectorEntryPoint:
  60         #ASSUME ds:@code
  61         #ASSUME ss:@code
  62       # ds = 1000, es = 2000 + x (size of first cluster >> 4)
  63       # cx = Start Cluster of EfiLdr
  64       # dx = Start Cluster of Efivar.bin
  65
  66 # Re use the BPB data stored in Boot Sector
  67         movw    $0x7c00, %bp
  68
  69         pushw   %cx
  70 # Read Efivar.bin
  71 #       1000:dx    = DirectoryEntry of Efivar.bin -> BS.com has filled already
  72         movw    $0x1900, %ax
  73         movw    %ax, %es
  74         testw   %dx, %dx
  75         jnz     CheckVarStoreSize
  76
  77         movb    $1, %al
  78 NoVarStore:
  79         pushw   %es
  80 # Set the 5th byte start @ 0:19000 to non-zero indicating we should init var store header in DxeIpl
  81         movb    %al, %es:4
  82         jmp     SaveVolumeId
  83
  84 CheckVarStoreSize:
  85         movw    %dx, %di
  86         cmpl    $0x4000, %ds:2(%di)
  87         movb    $2, %al
  88         jne     NoVarStore
  89
  90 LoadVarStore:
  91         movb    $0, %al
  92         movb    %al, %es:4
  93         movw    (%di), %cx
  94 #       ES:DI = 1500:0
  95         xorw    %di, %di
  96         pushw   %es
  97         movw    $0x1500, %ax
  98         movw    %ax, %es
  99         call    ReadFile
 100 SaveVolumeId:
 101         popw    %es
 102         movw    VolId(%bp), %ax
 103         movw    %ax, %es:0                      # Save Volume Id to 0:19000. we will find the correct volume according to this VolumeId
 104         movw    VolId+2(%bp), %ax
 105         movw    %ax, %es:2
 106
 107 # Read Efildr
 108         popw    %cx
 109 #       cx    = Start Cluster of Efildr -> BS.com has filled already
 110 #       ES:DI = 2000:0, first cluster will be read again
 111         xorw    %di, %di                            # di = 0
 112         movw    $0x2000, %ax
 113         movw    %ax, %es
 114         call    ReadFile
 115         movw    %cs, %ax
 116         movw    %ax, %cs:JumpSegment
 117
 118 JumpFarInstruction:
 119         .byte   0xea
 120 JumpOffset:
 121         .word   0x200
 122 JumpSegment:
 123         .word   0x2000
 124
 125
 126
 127 # ****************************************************************************
 128 # ReadFile
 129 #
 130 # Arguments:
 131 #   CX    = Start Cluster of File
 132 #   ES:DI = Buffer to store file content read from disk
 133 #
 134 # Return:
 135 #   (ES << 4 + DI) = end of file content Buffer
 136 #
 137 # ****************************************************************************
 138 ReadFile:
 139 # si      = NumberOfClusters
 140 # cx      = ClusterNumber
 141 # dx      = CachedFatSectorNumber
 142 # ds:0000 = CacheFatSectorBuffer
 143 # es:di   = Buffer to load file
 144 # bx      = NextClusterNumber
 145         pusha
 146         movw    $1, %si                             # NumberOfClusters = 1
 147         pushw   %cx                                 # Push Start Cluster onto stack
 148         movw    $0xfff, %dx                         # CachedFatSectorNumber = 0xfff
 149 FatChainLoop:
 150         movw    %cx, %ax                            # ax = ClusterNumber
 151         andw    $0xfff8, %ax                        # ax = ax & 0xfff8
 152         cmpw    $0xfff8, %ax                        # See if this is the last cluster
 153         je      FoundLastCluster                    # Jump if last cluster found
 154         movw    %cx, %ax                            # ax = ClusterNumber
 155         shlw    %ax                                 # FatOffset = ClusterNumber * 2
 156         pushw   %si                                 # Save si
 157         movw    %ax, %si                            # si = FatOffset
 158         shrw    $BLOCK_SHIFT, %ax                   # ax = FatOffset >> BLOCK_SHIFT
 159         addw    ReservedSectors(%bp), %ax           # ax = FatSectorNumber = ReservedSectors + (FatOffset >> BLOCK_OFFSET)
 160         andw    $BLOCK_MASK, %si                    # si = FatOffset & BLOCK_MASK
 161         cmpw    %dx, %ax                            # Compare FatSectorNumber to CachedFatSectorNumber
 162         je      SkipFatRead
 163         movw    $2, %bx
 164         pushw   %es
 165         pushw   %ds
 166         popw    %es
 167         call    ReadBlocks                          # Read 2 blocks starting at AX storing at ES:DI
 168         popw    %es
 169         movw    %ax, %dx                            # CachedFatSectorNumber = FatSectorNumber
 170 SkipFatRead:
 171         movw    (%si), %bx                          # bx = NextClusterNumber
 172         movw    %cx, %ax                            # ax = ClusterNumber
 173         popw    %si                                 # Restore si
 174         decw    %bx                                 # bx = NextClusterNumber - 1
 175         cmpw    %cx, %bx                            # See if (NextClusterNumber-1)==ClusterNumber
 176         jne     ReadClusters
 177         incw    %bx                                 # bx = NextClusterNumber
 178         incw    %si                                 # NumberOfClusters++
 179         movw    %bx, %cx                            # ClusterNumber = NextClusterNumber
 180         jmp     FatChainLoop
 181 ReadClusters:
 182         incw    %bx
 183         popw    %ax                                 # ax = StartCluster
 184         pushw   %bx                                 # StartCluster = NextClusterNumber
 185         movw    %bx, %cx                            # ClusterNumber = NextClusterNumber
 186         subw    $2, %ax                             # ax = StartCluster - 2
 187         xorb    %bh, %bh
 188         movb    SectorsPerCluster(%bp), %bl         # bx = SectorsPerCluster
 189         mulw    %bx                                 # ax = (StartCluster - 2) * SectorsPerCluster
 190         addw    (%bp), %ax                          # ax = FirstClusterLBA + (StartCluster-2)*SectorsPerCluster
 191         pushw   %ax                                 # save start sector
 192         movw    %si, %ax                            # ax = NumberOfClusters
 193         mulw    %bx                                 # ax = NumberOfClusters * SectorsPerCluster
 194         movw    %ax, %bx                            # bx = Number of Sectors
 195         popw    %ax                                 # ax = Start Sector
 196         call    ReadBlocks
 197         movw    $1, %si                             # NumberOfClusters = 1
 198         jmp     FatChainLoop
 199 FoundLastCluster:
 200         popw    %cx
 201         popa
 202         ret
 203
 204
 205 # ****************************************************************************
 206 # ReadBlocks - Reads a set of blocks from a block device
 207 #
 208 # AX    = Start LBA
 209 # BX    = Number of Blocks to Read
 210 # ES:DI = Buffer to store sectors read from disk
 211 # ****************************************************************************
 212
 213 # cx = Blocks
 214 # bx = NumberOfBlocks
 215 # si = StartLBA
 216
 217 ReadBlocks:
 218         pusha
 219         addl    LBAOffsetForBootSector(%bp), %eax            # Add LBAOffsetForBootSector to Start LBA
 220         addl    HiddenSectors(%bp), %eax            # Add HiddenSectors to Start LBA
 221         movl    %eax, %esi                          # esi = Start LBA
 222         movw    %bx, %cx                            # cx = Number of blocks to read
 223 ReadCylinderLoop:
 224         movw    $0x7bfc, %bp                        # bp = 0x7bfc
 225         movl    %esi, %eax                          # eax = Start LBA
 226         xorl    %edx, %edx                          # edx = 0
 227         movzwl  (%bp), %ebx                         # bx = MaxSector
 228         divl    %ebx                                # ax = StartLBA / MaxSector
 229         incw    %dx                                 # dx = (StartLBA % MaxSector) + 1
 230
 231         movw    (%bp), %bx                          # bx = MaxSector
 232         subw    %dx, %bx                            # bx = MaxSector - Sector
 233         incw    %bx                                 # bx = MaxSector - Sector + 1
 234         cmpw    %bx, %cx                            # Compare (Blocks) to (MaxSector - Sector + 1)
 235         jg      LimitTransfer
 236         movw    %cx, %bx                            # bx = Blocks
 237 LimitTransfer:
 238         pushw   %ax                                 # save ax
 239         movw    %es, %ax                            # ax = es
 240         shrw    $(BLOCK_SHIFT-4), %ax               # ax = Number of blocks into mem system
 241         andw    $0x7f, %ax                          # ax = Number of blocks into current seg
 242         addw    %bx, %ax                            # ax = End Block number of transfer
 243         cmpw    $0x80, %ax                          # See if it crosses a 64K boundry
 244         jle     NotCrossing64KBoundry               # Branch if not crossing 64K boundry
 245         subw    $0x80, %ax                          # ax = Number of blocks past 64K boundry
 246         subw    %ax, %bx                            # Decrease transfer size by block overage
 247 NotCrossing64KBoundry:
 248         popw    %ax                                 # restore ax
 249
 250         pushw   %cx
 251         movb    %dl, %cl                            # cl = (StartLBA % MaxSector) + 1 = Sector
 252         xorw    %dx, %dx                            # dx = 0
 253         divw    2(%bp)                              # ax = ax / (MaxHead + 1) = Cylinder
 254                                                     # dx = ax % (MaxHead + 1) = Head
 255
 256         pushw   %bx                                 # Save number of blocks to transfer
 257         movb    %dl, %dh                            # dh = Head
 258         movw    $0x7c00, %bp                        # bp = 0x7c00
 259         movb    PhysicalDrive(%bp), %dl             # dl = Drive Number
 260         movb    %al, %ch                            # ch = Cylinder
 261         movb    %bl, %al                            # al = Blocks
 262         movb    $2, %ah                             # ah = Function 2
 263         movw    %di, %bx                            # es:bx = Buffer address
 264         int     $0x13
 265         jc      DiskError
 266         popw    %bx
 267         popw    %cx
 268         movzwl  %bx, %ebx
 269         addl    %ebx, %esi                          # StartLBA = StartLBA + NumberOfBlocks
 270         subw    %bx, %cx                            # Blocks = Blocks - NumberOfBlocks
 271         movw    %es, %ax
 272         shlw    $(BLOCK_SHIFT-4), %bx
 273         addw    %bx, %ax
 274         movw    %ax, %es                            # es:di = es:di + NumberOfBlocks*BLOCK_SIZE
 275         cmpw    $0, %cx
 276         jne     ReadCylinderLoop
 277         popa
 278         ret
 279
 280 DiskError:
 281         pushw %cs
 282         popw %ds
 283         leaw ErrorString, %si
 284         movw $7, %cx
 285         jmp  PrintStringAndHalt
 286
 287 PrintStringAndHalt:
 288         movw $0xb800, %ax
 289         movw %ax, %es
 290         movw $160, %di
 291         rep
 292         movsw
 293 Halt:
 294         jmp   Halt
 295
 296 ErrorString:
 297         .byte 'S', 0x0c, 'E', 0x0c, 'r', 0x0c, 'r', 0x0c, 'o', 0x0c, 'r', 0x0c, '!', 0x0c
 298
 299         # .org     0x01fa # Just for passing build.
 300 LBAOffsetForBootSector:
 301         .long   0x0
 302
 303         # .org     0x01fe # Just for passing build.
 304         .word   0xaa55
 305
 306 #******************************************************************************
 307 #******************************************************************************
 308 #******************************************************************************
 309
 310 .equ                 DELAY_PORT,            0x0ed     # Port to use for 1uS delay
 311 .equ                 KBD_CONTROL_PORT,      0x060     # 8042 control port
 312 .equ                 KBD_STATUS_PORT,       0x064     # 8042 status port
 313 .equ                 WRITE_DATA_PORT_CMD,   0x0d1     # 8042 command to write the data port
 314 .equ                 ENABLE_A20_CMD,        0x0df     # 8042 command to enable A20
 315
 316         # .org     0x0200 # Just for passing build.
 317         jmp start
 318 Em64String:
 319         .byte 'E', 0x0c, 'm', 0x0c, '6', 0x0c, '4', 0x0c, 'T', 0x0c, ' ', 0x0c, 'U', 0x0c, 'n', 0x0c, 's', 0x0c, 'u', 0x0c, 'p', 0x0c, 'p', 0x0c, 'o', 0x0c, 'r', 0x0c, 't', 0x0c, 'e', 0x0c, 'd', 0x0c, '!', 0x0c
 320
 321 start:
 322         movw %cs, %ax
 323         movw %ax, %ds
 324         movw %ax, %es
 325         movw %ax, %ss
 326         movw $MyStack, %sp
 327
 328 #        mov ax,0b800h
 329 #        mov es,ax
 330 #        mov byte ptr es:[160],'a'
 331 #        mov ax,cs
 332 #        mov es,ax
 333
 334         movl $0, %ebx
 335         leal MemoryMap, %edi
 336 MemMapLoop:
 337         movl $0xe820, %eax
 338         movl $20, %ecx
 339         movl $0x534d4150, %edx  # 0x534d4150  stands for 'SMAP'
 340         int $0x15
 341         jc  MemMapDone
 342         addl $20, %edi
 343         cmpl $0, %ebx
 344         je  MemMapDone
 345         jmp MemMapLoop
 346 MemMapDone:
 347         leal MemoryMap, %eax
 348         subl %eax, %edi                     # Get the address of the memory map
 349         movl %edi, MemoryMapSize            # Save the size of the memory map
 350
 351         xorl    %ebx, %ebx
 352         movw    %cs, %bx                    # BX=segment
 353         shll    $4, %ebx                    # BX="linear" address of segment base
 354         leal    GDT_BASE(%ebx), %eax        # EAX=PHYSICAL address of gdt
 355         movl    %eax, gdtr + 2              # Put address of gdt into the gdtr
 356         leal    IDT_BASE(%ebx), %eax        # EAX=PHYSICAL address of idt
 357         movl    %eax, idtr + 2              # Put address of idt into the idtr
 358         leal    MemoryMapSize(%ebx), %edx   # Physical base address of the memory map
 359
 360         addl $0x1000, %ebx                  # Source of EFI32
 361         movl %ebx, JUMP+2
 362         addl $0x1000, %ebx
 363         movl %ebx, %esi                     # Source of EFILDR32
 364
 365 #        mov ax,0b800h
 366 #        mov es,ax
 367 #        mov byte ptr es:[162],'b'
 368 #        mov ax,cs
 369 #        mov es,ax
 370
 371 #
 372 # Enable A20 Gate
 373 #
 374
 375         movw $0x2401, %ax                   # Enable A20 Gate
 376         int $0x15
 377         jnc A20GateEnabled                  # Jump if it suceeded
 378
 379 #
 380 # If INT 15 Function 2401 is not supported, then attempt to Enable A20 manually.
 381 #
 382
 383         call    Empty8042InputBuffer        # Empty the Input Buffer on the 8042 controller
 384         jnz     Timeout8042                 # Jump if the 8042 timed out
 385         outw    %ax, $DELAY_PORT            # Delay 1 uS
 386         movb    $WRITE_DATA_PORT_CMD, %al   # 8042 cmd to write output port
 387         outb    %al, $KBD_STATUS_PORT       # Send command to the 8042
 388         call    Empty8042InputBuffer        # Empty the Input Buffer on the 8042 controller
 389         jnz     Timeout8042                 # Jump if the 8042 timed out
 390         movb    $ENABLE_A20_CMD, %al        # gate address bit 20 on
 391         outb    %al, $KBD_CONTROL_PORT      # Send command to thre 8042
 392         call    Empty8042InputBuffer        # Empty the Input Buffer on the 8042 controller
 393         movw    $25, %cx                    # Delay 25 uS for the command to complete on the 8042
 394 Delay25uS:
 395         outw    %ax, $DELAY_PORT            # Delay 1 uS
 396         loop    Delay25uS
 397 Timeout8042:
 398
 399
 400 A20GateEnabled:
 401
 402 #
 403 # DISABLE INTERRUPTS - Entering Protected Mode
 404 #
 405
 406         cli
 407
 408 #        mov ax,0b800h
 409 #        mov es,ax
 410 #        mov byte ptr es:[164],'c'
 411 #        mov ax,cs
 412 #        mov es,ax
 413
 414         .byte   0x66
 415         lgdt    gdtr
 416         .byte   0x66
 417         lidt    idtr
 418
 419         movl    %cr0, %eax
 420         orb     $1, %al
 421         movl    %eax, %cr0
 422
 423         movl $0x008, %eax                   # Flat data descriptor
 424         movl $0x00400000, %ebp              # Destination of EFILDR32
 425         movl $0x00070000, %ebx              # Length of copy
 426
 427 JUMP:
 428 # jmp far 0010:00020000
 429         .byte 0x66
 430         .byte 0xea
 431         .long 0x00020000
 432         .word 0x0010
 433
 434 Empty8042InputBuffer:
 435         movw $0, %cx
 436 Empty8042Loop:
 437         outw    %ax, $DELAY_PORT            # Delay 1us
 438         inb     $KBD_STATUS_PORT, %al       # Read the 8042 Status Port
 439         andb    $0x2, %al                   # Check the Input Buffer Full Flag
 440         loopnz  Empty8042Loop               # Loop until the input buffer is empty or a timout of 65536 uS
 441         ret
 442
 443 ##############################################################################
 444 # data
 445 ##############################################################################
 446
 447         .p2align 1
 448
 449 gdtr:   .word  GDT_END - GDT_BASE - 1       # GDT limit
 450         .long 0                             # (GDT base gets set above)
 451 ##############################################################################
 452 #   global descriptor table (GDT)
 453 ##############################################################################
 454
 455         .p2align 1
 456
 457 GDT_BASE:
 458 # null descriptor
 459 .equ                NULL_SEL, .-GDT_BASE
 460         .word 0         # limit 15:0
 461         .word 0         # base 15:0
 462         .byte 0         # base 23:16
 463         .byte 0         # type
 464         .byte 0         # limit 19:16, flags
 465         .byte 0         # base 31:24
 466
 467 # linear data segment descriptor
 468 .equ            LINEAR_SEL, .-GDT_BASE
 469         .word 0xFFFF    # limit 0xFFFFF
 470         .word 0         # base 0
 471         .byte 0
 472         .byte 0x92      # present, ring 0, data, expand-up, writable
 473         .byte 0xCF              # page-granular, 32-bit
 474         .byte 0
 475
 476 # linear code segment descriptor
 477 .equ            LINEAR_CODE_SEL, .-GDT_BASE
 478         .word 0xFFFF    # limit 0xFFFFF
 479         .word 0         # base 0
 480         .byte 0
 481         .byte 0x9A      # present, ring 0, data, expand-up, writable
 482         .byte 0xCF              # page-granular, 32-bit
 483         .byte 0
 484
 485 # system data segment descriptor
 486 .equ            SYS_DATA_SEL, .-GDT_BASE
 487         .word 0xFFFF    # limit 0xFFFFF
 488         .word 0         # base 0
 489         .byte 0
 490         .byte 0x92      # present, ring 0, data, expand-up, writable
 491         .byte 0xCF              # page-granular, 32-bit
 492         .byte 0
 493
 494 # system code segment descriptor
 495 .equ            SYS_CODE_SEL, .-GDT_BASE
 496         .word 0xFFFF    # limit 0xFFFFF
 497         .word 0         # base 0
 498         .byte 0
 499         .byte 0x9A      # present, ring 0, data, expand-up, writable
 500         .byte 0xCF              # page-granular, 32-bit
 501         .byte 0
 502
 503 # spare segment descriptor
 504 .equ        SPARE3_SEL, .-GDT_BASE
 505         .word 0         # limit 0xFFFFF
 506         .word 0         # base 0
 507         .byte 0
 508         .byte 0         # present, ring 0, data, expand-up, writable
 509         .byte 0         # page-granular, 32-bit
 510         .byte 0
 511
 512 # spare segment descriptor
 513 .equ        SPARE4_SEL, .-GDT_BASE
 514         .word 0         # limit 0xFFFFF
 515         .word 0         # base 0
 516         .byte 0
 517         .byte 0         # present, ring 0, data, expand-up, writable
 518         .byte 0         # page-granular, 32-bit
 519         .byte 0
 520
 521 # spare segment descriptor
 522 .equ        SPARE5_SEL, .-GDT_BASE
 523         .word 0         # limit 0xFFFFF
 524         .word 0         # base 0
 525         .byte 0
 526         .byte 0         # present, ring 0, data, expand-up, writable
 527         .byte 0         # page-granular, 32-bit
 528         .byte 0
 529
 530 GDT_END:
 531
 532         .p2align 1
 533
 534
 535
 536 idtr:   .word IDT_END - IDT_BASE - 1  # IDT limit
 537         .long 0                       # (IDT base gets set above)
 538 ##############################################################################
 539 #   interrupt descriptor table (IDT)
 540 #
 541 #   Note: The hardware IRQ's specified in this table are the normal PC/AT IRQ
 542 #       mappings.  This implementation only uses the system timer and all other
 543 #       IRQs will remain masked.  The descriptors for vectors 33+ are provided
 544 #       for convenience.
 545 ##############################################################################
 546
 547 #idt_tag db "IDT",0
 548         .p2align 1
 549
 550 IDT_BASE:
 551 # divide by zero (INT 0)
 552 .equ                DIV_ZERO_SEL, .-IDT_BASE
 553         .word 0             # offset 15:0
 554         .word SYS_CODE_SEL  # selector 15:0
 555         .byte 0             # 0 for interrupt gate
 556         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 557         .word 0             # offset 31:16
 558
 559 # debug exception (INT 1)
 560 .equ                DEBUG_EXCEPT_SEL, .-IDT_BASE
 561         .word 0             # offset 15:0
 562         .word SYS_CODE_SEL  # selector 15:0
 563         .byte 0             # 0 for interrupt gate
 564         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 565         .word 0             # offset 31:16
 566
 567 # NMI (INT 2)
 568 .equ                NMI_SEL, .-IDT_BASE
 569         .word 0             # offset 15:0
 570         .word SYS_CODE_SEL  # selector 15:0
 571         .byte 0             # 0 for interrupt gate
 572         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 573         .word 0             # offset 31:16
 574
 575 # soft breakpoint (INT 3)
 576 .equ                BREAKPOINT_SEL, .-IDT_BASE
 577         .word 0             # offset 15:0
 578         .word SYS_CODE_SEL  # selector 15:0
 579         .byte 0             # 0 for interrupt gate
 580         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 581         .word 0             # offset 31:16
 582
 583 # overflow (INT 4)
 584 .equ                OVERFLOW_SEL, .-IDT_BASE
 585         .word 0             # offset 15:0
 586         .word SYS_CODE_SEL  # selector 15:0
 587         .byte 0             # 0 for interrupt gate
 588         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 589         .word 0             # offset 31:16
 590
 591 # bounds check (INT 5)
 592 .equ                BOUNDS_CHECK_SEL, .-IDT_BASE
 593         .word 0             # offset 15:0
 594         .word SYS_CODE_SEL  # selector 15:0
 595         .byte 0             # 0 for interrupt gate
 596         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 597         .word 0             # offset 31:16
 598
 599 # invalid opcode (INT 6)
 600 .equ                INVALID_OPCODE_SEL, .-IDT_BASE
 601         .word 0             # offset 15:0
 602         .word SYS_CODE_SEL  # selector 15:0
 603         .byte 0             # 0 for interrupt gate
 604         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 605         .word 0             # offset 31:16
 606
 607 # device not available (INT 7)
 608 .equ                DEV_NOT_AVAIL_SEL, .-IDT_BASE
 609         .word 0             # offset 15:0
 610         .word SYS_CODE_SEL  # selector 15:0
 611         .byte 0             # 0 for interrupt gate
 612         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 613         .word 0             # offset 31:16
 614
 615 # double fault (INT 8)
 616 .equ                DOUBLE_FAULT_SEL, .-IDT_BASE
 617         .word 0             # offset 15:0
 618         .word SYS_CODE_SEL  # selector 15:0
 619         .byte 0             # 0 for interrupt gate
 620         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 621         .word 0             # offset 31:16
 622
 623 # Coprocessor segment overrun - reserved (INT 9)
 624 .equ                RSVD_INTR_SEL1, .-IDT_BASE
 625         .word 0             # offset 15:0
 626         .word SYS_CODE_SEL  # selector 15:0
 627         .byte 0             # 0 for interrupt gate
 628         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 629         .word 0             # offset 31:16
 630
 631 # invalid TSS (INT 0ah)
 632 .equ                INVALID_TSS_SEL, .-IDT_BASE
 633         .word 0             # offset 15:0
 634         .word SYS_CODE_SEL  # selector 15:0
 635         .byte 0             # 0 for interrupt gate
 636         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 637         .word 0             # offset 31:16
 638
 639 # segment not present (INT 0bh)
 640 .equ                SEG_NOT_PRESENT_SEL, .-IDT_BASE
 641         .word 0             # offset 15:0
 642         .word SYS_CODE_SEL  # selector 15:0
 643         .byte 0             # 0 for interrupt gate
 644         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 645         .word 0             # offset 31:16
 646
 647 # stack fault (INT 0ch)
 648 .equ                STACK_FAULT_SEL, .-IDT_BASE
 649         .word 0             # offset 15:0
 650         .word SYS_CODE_SEL  # selector 15:0
 651         .byte 0             # 0 for interrupt gate
 652         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 653         .word 0             # offset 31:16
 654
 655 # general protection (INT 0dh)
 656 .equ                GP_FAULT_SEL, .-IDT_BASE
 657         .word 0             # offset 15:0
 658         .word SYS_CODE_SEL  # selector 15:0
 659         .byte 0             # 0 for interrupt gate
 660         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 661         .word 0             # offset 31:16
 662
 663 # page fault (INT 0eh)
 664 .equ                PAGE_FAULT_SEL, .-IDT_BASE
 665         .word 0             # offset 15:0
 666         .word SYS_CODE_SEL  # selector 15:0
 667         .byte 0             # 0 for interrupt gate
 668         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 669         .word 0             # offset 31:16
 670
 671 # Intel reserved - do not use (INT 0fh)
 672 .equ                RSVD_INTR_SEL2, .-IDT_BASE
 673         .word 0             # offset 15:0
 674         .word SYS_CODE_SEL  # selector 15:0
 675         .byte 0             # 0 for interrupt gate
 676         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 677         .word 0             # offset 31:16
 678
 679 # floating point error (INT 10h)
 680 .equ                FLT_POINT_ERR_SEL, .-IDT_BASE
 681         .word 0             # offset 15:0
 682         .word SYS_CODE_SEL  # selector 15:0
 683         .byte 0             # 0 for interrupt gate
 684         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 685         .word 0             # offset 31:16
 686
 687 # alignment check (INT 11h)
 688 .equ                ALIGNMENT_CHECK_SEL, .-IDT_BASE
 689         .word 0             # offset 15:0
 690         .word SYS_CODE_SEL  # selector 15:0
 691         .byte 0             # 0 for interrupt gate
 692         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 693         .word 0             # offset 31:16
 694
 695 # machine check (INT 12h)
 696 .equ                MACHINE_CHECK_SEL, .-IDT_BASE
 697         .word 0             # offset 15:0
 698         .word SYS_CODE_SEL  # selector 15:0
 699         .byte 0             # 0 for interrupt gate
 700         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 701         .word 0             # offset 31:16
 702
 703 # SIMD floating-point exception (INT 13h)
 704 .equ                SIMD_EXCEPTION_SEL, .-IDT_BASE
 705         .word 0             # offset 15:0
 706         .word SYS_CODE_SEL  # selector 15:0
 707         .byte 0             # 0 for interrupt gate
 708         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 709         .word 0             # offset 31:16
 710
 711 # 85 unspecified descriptors, First 12 of them are reserved, the rest are avail
 712         .fill  85 * 8, 1, 0
 713
 714 # IRQ 0 (System timer) - (INT 68h)
 715 .equ                IRQ0_SEL, .-IDT_BASE
 716         .word 0             # offset 15:0
 717         .word SYS_CODE_SEL  # selector 15:0
 718         .byte 0             # 0 for interrupt gate
 719         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 720         .word 0             # offset 31:16
 721
 722 # IRQ 1 (8042 Keyboard controller) - (INT 69h)
 723 .equ                IRQ1_SEL, .-IDT_BASE
 724         .word 0             # offset 15:0
 725         .word SYS_CODE_SEL  # selector 15:0
 726         .byte 0             # 0 for interrupt gate
 727         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 728         .word 0             # offset 31:16
 729
 730 # Reserved - IRQ 2 redirect (IRQ 2) - DO NOT USE!!! - (INT 6ah)
 731 .equ                IRQ2_SEL, .-IDT_BASE
 732         .word 0             # offset 15:0
 733         .word SYS_CODE_SEL  # selector 15:0
 734         .byte 0             # 0 for interrupt gate
 735         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 736         .word 0             # offset 31:16
 737
 738 # IRQ 3 (COM 2) - (INT 6bh)
 739 .equ                IRQ3_SEL, .-IDT_BASE
 740         .word 0             # offset 15:0
 741         .word SYS_CODE_SEL  # selector 15:0
 742         .byte 0             # 0 for interrupt gate
 743         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 744         .word 0             # offset 31:16
 745
 746 # IRQ 4 (COM 1) - (INT 6ch)
 747 .equ                IRQ4_SEL, .-IDT_BASE
 748         .word 0             # offset 15:0
 749         .word SYS_CODE_SEL  # selector 15:0
 750         .byte 0             # 0 for interrupt gate
 751         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 752         .word 0             # offset 31:16
 753
 754 # IRQ 5 (LPT 2) - (INT 6dh)
 755 .equ                IRQ5_SEL, .-IDT_BASE
 756         .word 0             # offset 15:0
 757         .word SYS_CODE_SEL  # selector 15:0
 758         .byte 0             # 0 for interrupt gate
 759         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 760         .word 0             # offset 31:16
 761
 762 # IRQ 6 (Floppy controller) - (INT 6eh)
 763 .equ                IRQ6_SEL, .-IDT_BASE
 764         .word 0             # offset 15:0
 765         .word SYS_CODE_SEL  # selector 15:0
 766         .byte 0             # 0 for interrupt gate
 767         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 768         .word 0             # offset 31:16
 769
 770 # IRQ 7 (LPT 1) - (INT 6fh)
 771 .equ                IRQ7_SEL, .-IDT_BASE
 772         .word 0             # offset 15:0
 773         .word SYS_CODE_SEL  # selector 15:0
 774         .byte 0             # 0 for interrupt gate
 775         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 776         .word 0             # offset 31:16
 777
 778 # IRQ 8 (RTC Alarm) - (INT 70h)
 779 .equ                IRQ8_SEL, .-IDT_BASE
 780         .word 0             # offset 15:0
 781         .word SYS_CODE_SEL  # selector 15:0
 782         .byte 0             # 0 for interrupt gate
 783         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 784         .word 0             # offset 31:16
 785
 786 # IRQ 9 - (INT 71h)
 787 .equ                IRQ9_SEL, .-IDT_BASE
 788         .word 0             # offset 15:0
 789         .word SYS_CODE_SEL  # selector 15:0
 790         .byte 0             # 0 for interrupt gate
 791         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 792         .word 0             # offset 31:16
 793
 794 # IRQ 10 - (INT 72h)
 795 .equ                 IRQ10_SEL, .-IDT_BASE
 796         .word 0             # offset 15:0
 797         .word SYS_CODE_SEL  # selector 15:0
 798         .byte 0             # 0 for interrupt gate
 799         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 800         .word 0             # offset 31:16
 801
 802 # IRQ 11 - (INT 73h)
 803 .equ                 IRQ11_SEL, .-IDT_BASE
 804         .word 0             # offset 15:0
 805         .word SYS_CODE_SEL  # selector 15:0
 806         .byte 0             # 0 for interrupt gate
 807         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 808         .word 0             # offset 31:16
 809
 810 # IRQ 12 (PS/2 mouse) - (INT 74h)
 811 .equ                 IRQ12_SEL, .-IDT_BASE
 812         .word 0             # offset 15:0
 813         .word SYS_CODE_SEL  # selector 15:0
 814         .byte 0             # 0 for interrupt gate
 815         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 816         .word 0             # offset 31:16
 817
 818 # IRQ 13 (Floating point error) - (INT 75h)
 819 .equ                 IRQ13_SEL, .-IDT_BASE
 820         .word 0             # offset 15:0
 821         .word SYS_CODE_SEL  # selector 15:0
 822         .byte 0             # 0 for interrupt gate
 823         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 824         .word 0             # offset 31:16
 825
 826 # IRQ 14 (Secondary IDE) - (INT 76h)
 827 .equ                 IRQ14_SEL, .-IDT_BASE
 828         .word 0             # offset 15:0
 829         .word SYS_CODE_SEL  # selector 15:0
 830         .byte 0             # 0 for interrupt gate
 831         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 832         .word 0             # offset 31:16
 833
 834 # IRQ 15 (Primary IDE) - (INT 77h)
 835 .equ                 IRQ15_SEL, .-IDT_BASE
 836         .word 0             # offset 15:0
 837         .word SYS_CODE_SEL  # selector 15:0
 838         .byte 0             # 0 for interrupt gate
 839         .byte 0x0e | 0x80  # (10001110)type = 386 interrupt gate, present
 840         .word 0             # offset 31:16
 841
 842 IDT_END:
 843
 844         .p2align 1
 845
 846 MemoryMapSize:  .long 0
 847 MemoryMap:  .long 0,0,0,0,0,0,0,0
 848         .long 0,0,0,0,0,0,0,0
 849         .long 0,0,0,0,0,0,0,0
 850         .long 0,0,0,0,0,0,0,0
 851         .long 0,0,0,0,0,0,0,0
 852         .long 0,0,0,0,0,0,0,0
 853         .long 0,0,0,0,0,0,0,0
 854         .long 0,0,0,0,0,0,0,0
 855         .long 0,0,0,0,0,0,0,0
 856         .long 0,0,0,0,0,0,0,0
 857         .long 0,0,0,0,0,0,0,0
 858         .long 0,0,0,0,0,0,0,0
 859         .long 0,0,0,0,0,0,0,0
 860         .long 0,0,0,0,0,0,0,0
 861         .long 0,0,0,0,0,0,0,0
 862         .long 0,0,0,0,0,0,0,0
 863         .long 0,0,0,0,0,0,0,0
 864         .long 0,0,0,0,0,0,0,0
 865         .long 0,0,0,0,0,0,0,0
 866         .long 0,0,0,0,0,0,0,0
 867         .long 0,0,0,0,0,0,0,0
 868         .long 0,0,0,0,0,0,0,0
 869         .long 0,0,0,0,0,0,0,0
 870         .long 0,0,0,0,0,0,0,0
 871         .long 0,0,0,0,0,0,0,0
 872         .long 0,0,0,0,0,0,0,0
 873         .long 0,0,0,0,0,0,0,0
 874         .long 0,0,0,0,0,0,0,0
 875         .long 0,0,0,0,0,0,0,0
 876         .long 0,0,0,0,0,0,0,0
 877
 878         .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
 879         .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
 880
 881         .org 0x0fe0
 882 MyStack:
 883         # below is the pieces of the IVT that is used to redirect INT 68h - 6fh
 884         #    back to INT 08h - 0fh  when in real mode...  It is 'org'ed to a
 885         #    known low address (20f00) so it can be set up by PlMapIrqToVect in
 886         #    8259.c
 887
 888         int $8
 889         iret
 890
 891         int $9
 892         iret
 893
 894         int $10
 895         iret
 896
 897         int $11
 898         iret
 899
 900         int $12
 901         iret
 902
 903         int $13
 904         iret
 905
 906         int $14
 907         iret
 908
 909         int $15
 910         iret
 911
 912
 913         .org 0x0ffe
 914 BlockSignature:
 915         .word 0xaa55