EdkCompatibilityPkg/Foundation/Library/CompilerStub/X64/memcpySSE2.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   memcpy function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID *
  28 ; memcpy (
  29 ;   OUT     VOID                      *DestinationBuffer,
  30 ;   IN      CONST VOID                *SourceBuffer,
  31 ;   IN      UINTN                     Length
  32 ;   );
  33 ;------------------------------------------------------------------------------
  34 memcpy  PROC    USES    rsi rdi
  35     mov     rax, rcx                    ; rax <- Destination as return value
  36     cmp     rdx, rcx                    ; if Source == Destination, do nothing
  37     je      @CopyMemDone
  38     cmp     r8, 0                       ; if Count == 0, do nothing
  39     je      @CopyMemDone
  40     mov     rsi, rdx                    ; rsi <- Source
  41     mov     rdi, rcx                    ; rdi <- Destination
  42     lea     r9, [rsi + r8 - 1]          ; r9 <- Last byte of Source
  43     cmp     rsi, rdi
  44     jae     @F                          ; Copy forward if Source > Destination
  45     cmp     r9, rdi                     ; Overlapped?
  46     jae     @CopyBackward               ; Copy backward if overlapped
  47 @@:
  48     xor     rcx, rcx
  49     sub     rcx, rdi                    ; rcx <- -rdi
  50     and     rcx, 15                     ; rcx + rsi should be 16 bytes aligned
  51     jz      @F                          ; skip if rcx == 0
  52     cmp     rcx, r8
  53     cmova   rcx, r8
  54     sub     r8, rcx
  55     rep     movsb
  56 @@:
  57     mov     rcx, r8
  58     and     r8, 15
  59     shr     rcx, 4                      ; rcx <- # of DQwords to copy
  60     jz      @CopyBytes
  61 @@:
  62     movdqu  xmm0, [rsi]                 ; rsi may not be 16-byte aligned
  63     movdqa  [rdi], xmm0                 ; rdi should be 16-byte aligned
  64     add     rsi, 16
  65     add     rdi, 16
  66     loop    @B
  67     jmp     @CopyBytes                  ; copy remaining bytes
  68 @CopyBackward:
  69     mov     rsi, r9                     ; rsi <- Last byte of Source
  70     lea     rdi, [rdi + r8 - 1]         ; rdi <- Last byte of Destination
  71     std
  72 @CopyBytes:
  73     mov     rcx, r8
  74     rep     movsb
  75     cld
  76 @CopyMemDone:
  77     ret
  78 memcpy  ENDP
  79
  80     END