EdkCompatibilityPkg/Foundation/Library/CompilerStub/x64/memcpy.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   memcpy function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID *
  28 ; memcpy (
  29 ;   OUT     VOID                      *DestinationBuffer,
  30 ;   IN      CONST VOID                *SourceBuffer,
  31 ;   IN      UINTN                     Length
  32 ;   );
  33 ;------------------------------------------------------------------------------
  34 memcpy  PROC    USES    rsi rdi
  35     mov     rax, rcx                    ; rax <- Destination as return value
  36     cmp     rdx, rcx                    ; if Source == Destination, do nothing
  37     je      @CopyMemDone
  38     cmp     r8, 0                       ; if Count == 0, do nothing
  39     je      @CopyMemDone
  40     mov     rsi, rdx                    ; rsi <- Source
  41     mov     rdi, rcx                    ; rdi <- Destination
  42     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  43     cmp     rsi, rdi
  44     jae     @F
  45     cmp     r9, rdi
  46     jae     @CopyBackward               ; Copy backward if overlapped
  47 @@:
  48     mov     rcx, r8
  49     and     r8, 7
  50     shr     rcx, 3                      ; rcx <- # of Qwords to copy
  51     jz      @CopyBytes
  52     DB      49h, 0fh, 7eh, 0c2h         ; movd r10, mm0 (Save mm0 in r10)
  53 @@:
  54     DB      0fh, 6fh, 06h               ; movd mm0, [rsi]
  55     DB      48h, 0fh, 7eh, 07h          ; movd [rdi], mm0
  56     add     rsi, 8
  57     add     rdi, 8
  58     loop    @B
  59     DB      49h, 0fh, 6eh, 0c2h         ; movd mm0, r10 (Restore mm0)
  60     jmp     @CopyBytes
  61 @CopyBackward:
  62     mov     rsi, r9                     ; rsi <- End of Source
  63     lea     rdi, [rdi + r8 - 1]         ; rdi <- End of Destination
  64     std                                 ; set direction flag
  65 @CopyBytes:
  66     mov     rcx, r8
  67     rep     movsb                       ; Copy bytes backward
  68     cld
  69 @CopyMemDone:
  70     ret
  71 memcpy  ENDP
  72
  73     END