EdkCompatibilityPkg/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/EnablePaging64.asm

   1 ; Copyright (c) 2004, Intel Corporation
   2 ; All rights reserved. This program and the accompanying materials
   3 ; are licensed and made available under the terms and conditions of the BSD License
   4 ; which accompanies this distribution.  The full text of the license may be found at
   5 ; http://opensource.org/licenses/bsd-license.php
   6 ;
   7 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
   8 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
   9 ;
  10 ; Module Name:
  11 ;
  12 ;   EnablePaging64.Asm
  13 ;
  14 ; Abstract:
  15 ;
  16 ;   AsmEnablePaging64 function
  17 ;
  18 ; Notes:
  19 ;
  20 ;------------------------------------------------------------------------------
  21
  22     .686p
  23     .model  flat,C
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID
  28 ; EFIAPI
  29 ; InternalX86EnablePaging64 (
  30 ;   IN      UINT16                    Cs,
  31 ;   IN      UINT64                    EntryPoint,
  32 ;   IN      UINT64                    Context1,  OPTIONAL
  33 ;   IN      UINT64                    Context2,  OPTIONAL
  34 ;   IN      UINT64                    NewStack
  35 ;   );
  36 ;------------------------------------------------------------------------------
  37 InternalX86EnablePaging64 PROC
  38     cli
  39     mov     [esp], @F                   ; offset for far retf, seg is the 1st arg
  40     mov     eax, cr4
  41     or      al, (1 SHL 5)
  42     mov     cr4, eax                    ; enable PAE
  43     mov     ecx, 0c0000080h
  44     rdmsr
  45     or      ah, 1                       ; set LME
  46     wrmsr
  47     mov     eax, cr0
  48     bts     eax, 31                     ; set PG
  49     mov     cr0, eax                    ; enable paging
  50     retf                                ; topmost 2 dwords hold the address
  51 @@:                                     ; long mode starts here
  52     DB      67h, 48h                    ; 32-bit address size, 64-bit operand size
  53     mov     ebx, [esp]                  ; mov rbx, [esp]
  54     DB      67h, 48h
  55     mov     ecx, [esp + 8]              ; mov rcx, [esp + 8]
  56     DB      67h, 48h
  57     mov     edx, [esp + 10h]            ; mov rdx, [esp + 10h]
  58     DB      67h, 48h
  59     mov     esp, [esp + 18h]            ; mov rsp, [esp + 18h]
  60     DB      48h
  61     add     esp, -20h                   ; add rsp, -20h
  62     call    ebx                         ; call rbx
  63     hlt                                 ; no one should get here
  64 InternalX86EnablePaging64 ENDP
  65
  66     END