EdkCompatibilityPkg/Foundation/Library/EdkIIGlueLib/Library/BaseMemoryLib/Ia32/CopyMem.S

   1 #------------------------------------------------------------------------------
   2 #
   3 # Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
   4 # This program and the accompanying materials
   5 # are licensed and made available under the terms and conditions of the BSD License
   6 # which accompanies this distribution.  The full text of the license may be found at
   7 # http://opensource.org/licenses/bsd-license.php
   8 #
   9 # THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 #
  12 # Module Name:
  13 #
  14 #   CopyMem.Asm
  15 #
  16 # Abstract:
  17 #
  18 #   CopyMem function
  19 #
  20 # Notes:
  21 #
  22 #------------------------------------------------------------------------------
  23 #include <EdkIIGlueBase.h>
  24 .globl ASM_PFX(InternalMemCopyMem)
  25
  26 #------------------------------------------------------------------------------
  27 #  VOID *
  28 #  EFIAPI
  29 #  InternalMemCopyMem (
  30 #    IN VOID   *Destination,
  31 #    IN VOID   *Source,
  32 #    IN UINTN  Count
  33 #    );
  34 #------------------------------------------------------------------------------
  35 ASM_PFX(InternalMemCopyMem):
  36     push    %esi
  37     push    %edi
  38     movl    16(%esp), %esi              # esi <- Source
  39     movl    12(%esp), %edi              # edi <- Destination
  40     movl    20(%esp), %edx              # edx <- Count
  41     leal    -1(%esi, %edx), %eax        # eax <- End of Source
  42     cmpl    %edi, %esi
  43     jae     L0
  44     cmpl    %edi, %eax
  45     jae     L_CopyBackward              # Copy backward if overlapped
  46 L0:
  47     movl    %edx, %ecx
  48     andl    $3, %edx
  49     shrl    $2, %ecx
  50     rep
  51     movsl                               # Copy as many Dwords as possible
  52     jmp     L_CopyBytes
  53 L_CopyBackward:
  54     movl    %eax, %esi                  # esi <- End of Source
  55     leal    -1(%edi, %edx), %edi        # edi <- End of Destination
  56     std
  57 L_CopyBytes:
  58     movl    %edx, %ecx
  59     rep
  60     movsb                               # Copy bytes backward
  61     cld
  62     movl    12(%esp), %eax              # eax <- Destination as return value
  63     pop     %edi
  64     pop     %esi
  65     ret