EdkCompatibilityPkg/Foundation/Library/EfiCommonLib/X64/EfiCopyMemRep4.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   EfiCopyMemRep4.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID
  28 ; EfiCommonLibCopyMem (
  29 ;   OUT     VOID                      *Destination,
  30 ;   IN      VOID                      *Source,
  31 ;   IN      UINTN                     Count
  32 ;   );
  33 ;------------------------------------------------------------------------------
  34 EfiCommonLibCopyMem  PROC    USES    rsi rdi
  35     cmp     rdx, rcx                    ; if Source == Destination, do nothing
  36     je      @CopyMemDone
  37     cmp     r8, 0                       ; if Count == 0, do nothing
  38     je      @CopyMemDone
  39     mov     rsi, rdx                    ; rsi <- Source
  40     mov     rdi, rcx                    ; rdi <- Destination
  41     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  42     cmp     rsi, rdi
  43     jae     @F
  44     cmp     r9, rdi
  45     jae     @CopyBackward               ; Copy backward if overlapped
  46 @@:
  47     mov     rcx, r8
  48     and     r8, 3
  49     shr     rcx, 2
  50     rep     movsd                       ; Copy as many Dwords as possible
  51     jmp     @CopyBytes
  52 @CopyBackward:
  53     mov     rsi, r9                     ; rsi <- End of Source
  54     lea     rdi, [rdi + r8 - 1]         ; esi <- End of Destination
  55     std                                 ; set direction flag
  56 @CopyBytes:
  57     mov     rcx, r8
  58     rep     movsb                       ; Copy bytes backward
  59     cld
  60 @CopyMemDone:
  61     ret
  62 EfiCommonLibCopyMem  ENDP
  63
  64     END
  65