EdkCompatibilityPkg/Foundation/Library/EfiCommonLib/x64/EfiCopyMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID *
  28 ; EFIAPI
  29 ; EfiCommonLibCopyMem (
  30 ;   OUT     VOID                      *Destination,
  31 ;   IN      VOID                      *Source,
  32 ;   IN      UINTN                     Count
  33 ;   );
  34 ;------------------------------------------------------------------------------
  35 EfiCommonLibCopyMem  PROC    USES    rsi rdi
  36     cmp     rdx, rcx                    ; if Source == Destination, do nothing
  37     je      @CopyMemDone
  38     cmp     r8, 0                       ; if Count == 0, do nothing
  39     je      @CopyMemDone
  40     mov     rsi, rdx                    ; rsi <- Source
  41     mov     rdi, rcx                    ; rdi <- Destination
  42     lea     r9, [rsi + r8 - 1]          ; r9 <- End of Source
  43     cmp     rsi, rdi
  44     mov     rax, rdi                    ; rax <- Destination as return value
  45     jae     @F
  46     cmp     r9, rdi
  47     jae     @CopyBackward               ; Copy backward if overlapped
  48 @@:
  49     mov     rcx, r8
  50     and     r8, 7
  51     shr     rcx, 3                      ; rcx <- # of Qwords to copy
  52     jz      @CopyBytes
  53     DB      49h, 0fh, 7eh, 0c2h         ; movd r10, mm0 (Save mm0 in r10)
  54 @@:
  55     DB      0fh, 6fh, 06h               ; movd mm0, [rsi]
  56     DB      48h, 0fh, 7eh, 07h          ; movd [rdi], mm0
  57     add     rsi, 8
  58     add     rdi, 8
  59     loop    @B
  60     DB      49h, 0fh, 6eh, 0c2h         ; movd mm0, r10 (Restore mm0)
  61     jmp     @CopyBytes
  62 @CopyBackward:
  63     mov     rsi, r9                     ; rsi <- End of Source
  64     lea     rdi, [rdi + r8 - 1]         ; rdi <- End of Destination
  65     std                                 ; set direction flag
  66 @CopyBytes:
  67     mov     rcx, r8
  68     rep     movsb                       ; Copy bytes backward
  69     cld
  70 @CopyMemDone:
  71     ret
  72 EfiCommonLibCopyMem  ENDP
  73
  74     END