EdkCompatibilityPkg/Foundation/Library/EfiCommonLib/x64/EfiSetMemSSE2.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2007, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   SetMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ; VOID
  28 ; EfiCommonLibSetMem (
  29 ;   OUT     VOID                      *Buffer,
  30 ;   IN      UINTN                     Size,
  31 ;   IN      UINT8                     Value
  32 ;   );
  33 ;------------------------------------------------------------------------------
  34 EfiCommonLibSetMem   PROC    USES    rdi
  35     cmp     rdx, 0                      ; if Size == 0, do nothing
  36     je      @SetDone
  37     mov     rdi, rcx                    ; rdi <- Buffer
  38     mov     al, r8b                     ; al <- Value
  39     xor     rcx, rcx
  40     sub     rcx, rdi
  41     and     rcx, 15                     ; rcx + rdi aligns on 16-byte boundary
  42     jz      @F
  43     cmp     rcx, rdx
  44     cmova   rcx, rdx
  45     sub     rdx, rcx
  46     rep     stosb
  47 @@:
  48     mov     rcx, rdx
  49     and     rdx, 15
  50     shr     rcx, 4
  51     jz      @SetBytes
  52     mov     ah, al                      ; ax <- Value repeats twice
  53     movd    xmm0, eax                   ; xmm0[0..16] <- Value repeats twice
  54     pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times
  55     movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times
  56 @@:
  57     movdqa  [rdi], xmm0                 ; rdi should be 16-byte aligned
  58     add     rdi, 16
  59     loop    @B
  60 @SetBytes:
  61     mov     ecx, edx                    ; high 32 bits of rcx are always zero
  62     rep     stosb
  63 @SetDone:
  64     ret
  65 EfiCommonLibSetMem   ENDP
  66
  67     END