MdePkg/Library/BaseLib/Ipf/CpuFlushTlb.s

   1 /// @file
   2 ///   CpuFlushTlb() function for Itanium-based architecture.
   3 ///
   4 /// Copyright (c) 2006, Intel Corporation
   5 /// All rights reserved. This program and the accompanying materials
   6 /// are licensed and made available under the terms and conditions of the BSD License
   7 /// which accompanies this distribution.  The full text of the license may be found at
   8 /// http://opensource.org/licenses/bsd-license.php
   9 ///
  10 /// THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 /// WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 ///
  13 /// Module Name:  CpuFlushTlb.s
  14 ///
  15 ///
  16
  17 .auto
  18 .text
  19
  20 .globl PalCallStatic
  21 .type   PalCallStatic, @function
  22
  23 .proc   CpuFlushTlb
  24 .type   CpuFlushTlb, @function
  25 CpuFlushTlb::
  26         alloc               loc0 = ar.pfs, 0, 3, 5, 0
  27         mov                 out0 = 0
  28         mov                 out1 = 6
  29         mov                 out2 = 0
  30         mov                 out3 = 0
  31         mov                 loc1 = b0
  32         mov                 out4 = 0
  33         brl.call.sptk       b0  = PalCallStatic
  34         mov                 loc2 = psr              // save PSR
  35         mov                 ar.pfs = loc0
  36         extr.u              r14 = r10, 32, 32       // r14 <- count1
  37         rsm                 1 << 14                 // Disable interrupts
  38         extr.u              r15 = r11, 32, 32       // r15 <- stride1
  39         extr.u              r10 = r10, 0, 32        // r10 <- count2
  40         add                 r10 = -1, r10
  41         extr.u              r11 = r11, 0, 32        // r11 <- stride2
  42         br.cond.sptk        LoopPredicate
  43 LoopOuter:
  44         mov                 ar.lc = r10             // LC <- count2
  45         mov                 ar.ec = r0              // EC <- 0
  46 Loop:
  47         ptc.e               r9
  48         add                 r9 = r11, r9            // r9 += stride2
  49         br.ctop.sptk        Loop
  50         add                 r9 = r15, r9            // r9 += stride1
  51 LoopPredicate:
  52         cmp.ne              p6 = r0, r14            // count1 == 0?
  53         add                 r14 = -1, r14
  54 (p6)    br.cond.sptk        LoopOuter
  55         mov                 psr.l = loc2
  56         mov                 b0  = loc1
  57         br.ret.sptk.many    b0
  58 .endp