MdePkg/Library/BaseMemoryLibOptDxe/X64/CopyMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   CopyMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   CopyMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .code
  25
  26 ;------------------------------------------------------------------------------
  27 ;  VOID *
  28 ;  EFIAPI
  29 ;  InternalMemCopyMem (
  30 ;    IN VOID   *Destination,
  31 ;    IN VOID   *Source,
  32 ;    IN UINTN  Count
  33 ;    );
  34 ;------------------------------------------------------------------------------
  35 InternalMemCopyMem  PROC    USES    rsi rdi
  36     mov     rsi, rdx                    ; rsi <- Source
  37     mov     rdi, rcx                    ; rdi <- Destination
  38     lea     r9, [rsi + r8 - 1]          ; r9 <- Last byte of Source
  39     cmp     rsi, rdi
  40     mov     rax, rdi                    ; rax <- Destination as return value
  41     jae     @F                          ; Copy forward if Source > Destination
  42     cmp     r9, rdi                     ; Overlapped?
  43     jae     @CopyBackward               ; Copy backward if overlapped
  44 @@:
  45     xor     rcx, rcx
  46     sub     rcx, rdi                    ; rcx <- -rdi
  47     and     rcx, 15                     ; rcx + rsi should be 16 bytes aligned
  48     jz      @F                          ; skip if rcx == 0
  49     cmp     rcx, r8
  50     cmova   rcx, r8
  51     sub     r8, rcx
  52     rep     movsb
  53 @@:
  54     mov     rcx, r8
  55     and     r8, 15
  56     shr     rcx, 4                      ; rcx <- # of DQwords to copy
  57     jz      @CopyBytes
  58     movdqa  [rsp + 18h], xmm0           ; save xmm0 on stack
  59 @@:
  60     movdqu  xmm0, [rsi]                 ; rsi may not be 16-byte aligned
  61     movntdq [rdi], xmm0                 ; rdi should be 16-byte aligned
  62     add     rsi, 16
  63     add     rdi, 16
  64     loop    @B
  65     mfence
  66     movdqa  xmm0, [rsp + 18h]           ; restore xmm0
  67     jmp     @CopyBytes                  ; copy remaining bytes
  68 @CopyBackward:
  69     mov     rsi, r9                     ; rsi <- Last byte of Source
  70     lea     rdi, [rdi + r8 - 1]         ; rdi <- Last byte of Destination
  71     std
  72 @CopyBytes:
  73     mov     rcx, r8
  74     rep     movsb
  75     cld
  76     ret
  77 InternalMemCopyMem  ENDP
  78
  79     END