MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   SetMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .686
  25     .model  flat,C
  26     .xmm
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  VOID *
  31 ;  _mem_SetMem (
  32 ;    IN VOID   *Buffer,
  33 ;    IN UINTN  Count,
  34 ;    IN UINT8  Value
  35 ;    )
  36 ;------------------------------------------------------------------------------
  37 InternalMemSetMem   PROC    USES    edi
  38     mov     edx, [esp + 12]             ; edx <- Count
  39     mov     edi, [esp + 8]              ; edi <- Buffer
  40     mov     al, [esp + 16]              ; al <- Value
  41     xor     ecx, ecx
  42     sub     ecx, edi
  43     and     ecx, 15                     ; ecx + edi aligns on 16-byte boundary
  44     jz      @F
  45     cmp     ecx, edx
  46     cmova   ecx, edx
  47     sub     edx, ecx
  48     rep     stosb
  49 @@:
  50     mov     ecx, edx
  51     and     edx, 15
  52     shr     ecx, 4                      ; ecx <- # of DQwords to set
  53     jz      @SetBytes
  54     mov     ah, al                      ; ax <- Value | (Value << 8)
  55     add     esp, -16
  56     movdqu  [esp], xmm0                 ; save xmm0
  57     movd    xmm0, eax
  58     pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times
  59     movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times
  60 @@:
  61     movntdq [edi], xmm0                 ; edi should be 16-byte aligned
  62     add     edi, 16
  63     loop    @B
  64     mfence
  65     movdqu  xmm0, [esp]                 ; restore xmm0
  66     add     esp, 16                     ; stack cleanup
  67 @SetBytes:
  68     mov     ecx, edx
  69     rep     stosb
  70     mov     eax, [esp + 8]              ; eax <- Buffer as return value
  71     ret
  72 InternalMemSetMem   ENDP
  73
  74     END