MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   SetMem function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .686
  25     .model  flat,C
  26     .xmm
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  VOID *
  31 ;  EFIAPI
  32 ;  InternalMemSetMem (
  33 ;    IN VOID   *Buffer,
  34 ;    IN UINTN  Count,
  35 ;    IN UINT8  Value
  36 ;    );
  37 ;------------------------------------------------------------------------------
  38 InternalMemSetMem   PROC    USES    edi
  39     mov     edx, [esp + 12]             ; edx <- Count
  40     mov     edi, [esp + 8]              ; edi <- Buffer
  41     mov     al, [esp + 16]              ; al <- Value
  42     xor     ecx, ecx
  43     sub     ecx, edi
  44     and     ecx, 15                     ; ecx + edi aligns on 16-byte boundary
  45     jz      @F
  46     cmp     ecx, edx
  47     cmova   ecx, edx
  48     sub     edx, ecx
  49     rep     stosb
  50 @@:
  51     mov     ecx, edx
  52     and     edx, 15
  53     shr     ecx, 4                      ; ecx <- # of DQwords to set
  54     jz      @SetBytes
  55     mov     ah, al                      ; ax <- Value | (Value << 8)
  56     add     esp, -16
  57     movdqu  [esp], xmm0                 ; save xmm0
  58     movd    xmm0, eax
  59     pshuflw xmm0, xmm0, 0               ; xmm0[0..63] <- Value repeats 8 times
  60     movlhps xmm0, xmm0                  ; xmm0 <- Value repeats 16 times
  61 @@:
  62     movntdq [edi], xmm0                 ; edi should be 16-byte aligned
  63     add     edi, 16
  64     loop    @B
  65     mfence
  66     movdqu  xmm0, [esp]                 ; restore xmm0
  67     add     esp, 16                     ; stack cleanup
  68 @SetBytes:
  69     mov     ecx, edx
  70     rep     stosb
  71     mov     eax, [esp + 8]              ; eax <- Buffer as return value
  72     ret
  73 InternalMemSetMem   ENDP
  74
  75     END