Fix capitalization issues
[mirror_edk2.git] / MdePkg / Library / BaseMemoryLibSse2 / Ia32 / SetMem16.asm
1 ;------------------------------------------------------------------------------
2 ;
3 ; Copyright (c) 2006, Intel Corporation
4 ; All rights reserved. This program and the accompanying materials
5 ; are licensed and made available under the terms and conditions of the BSD License
6 ; which accompanies this distribution. The full text of the license may be found at
7 ; http://opensource.org/licenses/bsd-license.php
8 ;
9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
11 ;
12 ; Module Name:
13 ;
14 ; SetMem16.asm
15 ;
16 ; Abstract:
17 ;
18 ; SetMem16 function
19 ;
20 ; Notes:
21 ;
22 ;------------------------------------------------------------------------------
23
24 .686
25 .model flat,C
26 .xmm
27 .code
28
29 ;------------------------------------------------------------------------------
30 ; VOID *
31 ; _mem_SetMem16 (
32 ; IN VOID *Buffer,
33 ; IN UINTN Count,
34 ; IN UINT16 Value
35 ; )
36 ;------------------------------------------------------------------------------
37 InternalMemSetMem16 PROC USES edi
38 mov edx, [esp + 12]
39 mov edi, [esp + 8]
40 xor ecx, ecx
41 sub ecx, edi
42 and ecx, 15 ; ecx + edi aligns on 16-byte boundary
43 mov eax, [esp + 16]
44 jz @F
45 shr ecx, 1
46 cmp ecx, edx
47 cmova ecx, edx
48 sub edx, ecx
49 rep stosw
50 @@:
51 mov ecx, edx
52 and edx, 7
53 shr ecx, 3
54 jz @SetWords
55 movd xmm0, eax
56 pshuflw xmm0, xmm0, 0
57 movlhps xmm0, xmm0
58 @@:
59 movntdq [edi], xmm0 ; edi should be 16-byte aligned
60 add edi, 16
61 loop @B
62 mfence
63 @SetWords:
64 mov ecx, edx
65 rep stosw
66 mov eax, [esp + 8]
67 ret
68 InternalMemSetMem16 ENDP
69
70 END