MdePkg/Library/BaseMemoryLibSse2/Ia32/SetMem32.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2006, Intel Corporation
   4 ; All rights reserved. This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   SetMem32.asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   SetMem32 function
  19 ;
  20 ; Notes:
  21 ;
  22 ;------------------------------------------------------------------------------
  23
  24     .686
  25     .model  flat,C
  26     .xmm
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  VOID *
  31 ;  EFIAPI
  32 ;  InternalMemSetMem32 (
  33 ;    IN VOID   *Buffer,
  34 ;    IN UINTN  Count,
  35 ;    IN UINT32 Value
  36 ;    );
  37 ;------------------------------------------------------------------------------
  38 InternalMemSetMem32 PROC    USES    edi
  39     mov     edx, [esp + 12]
  40     mov     edi, [esp + 8]
  41     xor     ecx, ecx
  42     sub     ecx, edi
  43     and     ecx, 15                     ; ecx + edi aligns on 16-byte boundary
  44     mov     eax, [esp + 16]
  45     jz      @F
  46     shr     ecx, 2
  47     cmp     ecx, edx
  48     cmova   ecx, edx
  49     sub     edx, ecx
  50     rep     stosd
  51 @@:
  52     mov     ecx, edx
  53     and     edx, 3
  54     shr     ecx, 2
  55     jz      @SetDwords
  56     movd    xmm0, eax
  57     pshufd  xmm0, xmm0, 0
  58 @@:
  59     movntdq [edi], xmm0
  60     add     edi, 16
  61     loop    @B
  62     mfence
  63 @SetDwords:
  64     mov     ecx, edx
  65     rep     stosd
  66     mov     eax, [esp + 8]
  67     ret
  68 InternalMemSetMem32 ENDP
  69
  70     END