SecurityPkg/RandomNumberGenerator/RngDxe/X64/AsmRdRand.asm

   1 ;------------------------------------------------------------------------------
   2 ;
   3 ; Copyright (c) 2013, Intel Corporation. All rights reserved.<BR>
   4 ; This program and the accompanying materials
   5 ; are licensed and made available under the terms and conditions of the BSD License
   6 ; which accompanies this distribution.  The full text of the license may be found at
   7 ; http://opensource.org/licenses/bsd-license.php.
   8 ;
   9 ; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  10 ; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  11 ;
  12 ; Module Name:
  13 ;
  14 ;   AsmRdRand.Asm
  15 ;
  16 ; Abstract:
  17 ;
  18 ;   Implementation for 16-, 32-, and 64-bit invocations of RDRAND instruction under 64bit platform.
  19 ;
  20 ; Notes:
  21 ;
  22 ;   Visual Studio coding practices do not use inline asm since multiple compilers and
  23 ;   architectures are supported assembler not recognizing rdrand instruction so using DB's.
  24 ;
  25 ;------------------------------------------------------------------------------
  26
  27     .code
  28
  29 ;------------------------------------------------------------------------------
  30 ;  Generate a 16 bit random number
  31 ;  Return TRUE if Rand generated successfully, or FALSE if not
  32 ;
  33 ;  BOOLEAN EFIAPI RdRand16Step (UINT16 *Rand);   RCX
  34 ;------------------------------------------------------------------------------
  35 RdRand16Step  PROC
  36     ; rdrand   ax                  ; generate a 16 bit RN into ax, CF=1 if RN generated ok, otherwise CF=0
  37     db     0fh, 0c7h, 0f0h         ; rdrand r16:  "0f c7 /6  ModRM:r/m(w)"
  38     jb     rn16_ok                 ; jmp if CF=1
  39     xor    rax, rax                ; reg=0 if CF=0
  40     ret                            ; return with failure status
  41 rn16_ok:
  42     mov    [rcx], ax
  43     mov    rax, 1
  44     ret
  45 RdRand16Step ENDP
  46
  47 ;------------------------------------------------------------------------------
  48 ;  Generate a 32 bit random number
  49 ;    Return TRUE if Rand generated successfully, or FALSE if not
  50 ;
  51 ;  BOOLEAN EFIAPI RdRand32Step (UINT32 *Rand);   RCX
  52 ;------------------------------------------------------------------------------
  53 RdRand32Step  PROC
  54     ; rdrand   eax                 ; generate a 32 bit RN into eax, CF=1 if RN generated ok, otherwise CF=0
  55     db     0fh, 0c7h, 0f0h         ; rdrand r32:  "0f c7 /6  ModRM:r/m(w)"
  56     jb     rn32_ok                 ; jmp if CF=1
  57     xor    rax, rax                ; reg=0 if CF=0
  58     ret                            ; return with failure status
  59 rn32_ok:
  60     mov    [rcx], eax
  61     mov    rax,  1
  62     ret
  63 RdRand32Step ENDP
  64
  65 ;------------------------------------------------------------------------------
  66 ;  Generate a 64 bit random number
  67 ;    Return TRUE if RN generated successfully, or FALSE if not
  68 ;
  69 ;  BOOLEAN EFIAPI RdRand64Step (UINT64 *Random);   RCX
  70 ;------------------------------------------------------------------------------
  71 RdRand64Step  PROC
  72     ; rdrand   rax                 ; generate a 64 bit RN into rax, CF=1 if RN generated ok, otherwise CF=0
  73     db     048h, 0fh, 0c7h, 0f0h   ; rdrand r64: "REX.W + 0F C7 /6 ModRM:r/m(w)"
  74     jb     rn64_ok                 ; jmp if CF=1
  75     xor    rax, rax                ; reg=0 if CF=0
  76     ret                            ; return with failure status
  77 rn64_ok:
  78     mov    [rcx], rax
  79     mov    rax, 1
  80     ret
  81 RdRand64Step ENDP
  82
  83     END