722df882deb79fe4a309c8dd5004e31306833782
[mirror_edk2.git] / edksetup.bat
1 @REM
2 @REM Copyright (c) 2006, Intel Corporation
3 @REM All rights reserved. This program and the accompanying materials
4 @REM are licensed and made available under the terms and conditions of the BSD License
5 @REM which accompanies this distribution. The full text of the license may be found at
6 @REM http://opensource.org/licenses/bsd-license.php
7 @REM
8 @REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
9 @REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
10 @REM
11
12 @REM set following environment in this file or in command shell
13 @REM set JAVA_HOME=C:\Java\jdk1.5.0_04
14 @REM set ANT_HOME=C:\ANT
15 @REM set XMLBEANS_HOME=C:\xmlbeans
16 @REM set CYGWIN_HOME=C:\cygwin
17
18 @REM usage: edksetup.bat [skip]
19 @REM if the argument, skip is present, only the paths and the
20 @REM test and set of environment settings are performed.
21
22 @REM ##############################################################
23 @REM # You should not have to modify anything below this line
24 @REM #
25
26 @echo off
27
28 @REM
29 @REM Check the required system environment variables
30 @REM
31
32 :check_vc
33 if defined VCINSTALLDIR goto check_cygwin
34 if defined VS71COMNTOOLS (
35 call "%VS71COMNTOOLS%vsvars32.bat"
36 ) else (
37 echo.
38 echo !!! WARNING !!!! Cannot find Visual Studio !!!
39 echo.
40 )
41
42 :check_cygwin
43 if defined CYGWIN_HOME goto check_java
44 if exist c:\cygwin (
45 set CYGWIN_HOME=c:\cygwin
46 ) else (
47 echo.
48 echo !!! WARNING !!!! Not set CYGWIN_HOME, gcc build may not be used !!!
49 echo.
50 )
51
52 :check_java
53 if "%JAVA_HOME%"=="" goto no_jdk
54
55 :check_ant
56 if "%ANT_HOME%"=="" goto no_ant
57 if not exist %ANT_HOME%\lib\ant-contrib.jar goto no_antcontrib
58
59 :check_xmlbeans
60 if "%XMLBEANS_HOME%"=="" goto no_xmlbeans
61 if not exist %XMLBEANS_HOME%\lib\saxon8.jar goto no_saxon8
62
63 @REM
64 @REM Set the WORKSPACE to the current working directory
65 @REM
66 set WORKSPACE=%CD%
67
68 set FRAMEWORK_TOOLS_PATH=%WORKSPACE%\Tools\bin
69
70 if defined WORKSPACE_TOOLS_PATH goto check_path
71 set PATH=%FRAMEWORK_TOOLS_PATH%;%JAVA_HOME%\bin;%ANT_HOME%\bin;%XMLBEANS_HOME%\bin;%PATH%
72 set WORKSPACE_TOOLS_PATH=%FRAMEWORK_TOOLS_PATH%
73 echo Setting the PATH variable to include the Framework_Tools_Path for this WORKSPACE
74 goto path_ok
75
76 :check_path
77 if "%FRAMEWORK_TOOLS_PATH%"=="%WORKSPACE_TOOLS_PATH%" goto path_ok
78 set PATH=%FRAMEWORK_TOOLS_PATH%;%PATH%
79 set WORKSPACE_PATH=%WORKSPACE%
80 echo Resetting the PATH variable to include the Framework_Tools_Path for this WORKSPACE
81
82 :path_ok
83
84 if "%1"=="skip" goto skipbuild
85
86 echo.
87 echo WORKSPACE: %WORKSPACE%
88 echo JAVA_HOME: %JAVA_HOME%
89 echo ANT_HOME: %ANT_HOME%
90 echo XMLBEANS_HOME: %XMLBEANS_HOME%
91 echo CYGWIN_HOME: %CYGWIN_HOME%
92 echo PATH: %PATH%
93 echo.
94
95 @REM
96 @REM Start to build the Framework Tools
97 @REM
98
99
100 echo.
101 echo Building the Framework Tools
102 echo.
103
104 @REM
105 @REM We are going to create the SurfaceArea.jar file first so that the other
106 @REM Java Programs can use it.
107 @REM It needs the XMLBEANS libraries in order to compile.
108 @REM
109 set CLASSPATH=.;%XMLBEANS_HOME%\lib\jsr173_1.0_api.jar;%XMLBEANS_HOME%\lib\xbean.jar
110 set CLASSPATH=%CLASSPATH%;%XMLBEANS_HOME%\lib\xbean_xpath.jar;%XMLBEANS_HOME%\lib\xmlpublic.jar
111 set CLASSPATH=%CLASSPATH%;%XMLBEANS_HOME%\lib\saxon8.jar;%XMLBEANS_HOME%\lib\resolver.jar
112
113 call ant -f %WORKSPACE%\Tools\build.xml SurfaceArea
114
115 @REM
116 @REM Now we can make the other Java Programs
117 @REM All of the remaining Java Programs require the SurfaceArea library to compile
118 @REM
119 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\%Tools\Jars\SurfaceArea.jar
120
121
122 call ant -f %WORKSPACE%\Tools\build.xml JavaCode
123
124 @REM
125 @REM We have all of the Java Programs and add-in classes created, so we can start
126 @REM using the cpp-tasks to create our tools
127 @REM
128 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\Tools\Jars\Common.jar
129 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\Tools\Jars\GenBuild.jar
130 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\Tools\Jars\cpptasks.jar;%WORKSPACE%\Tools\Jars\frameworktasks.jar
131
132 call ant -f %WORKSPACE%\Tools\build.xml C_Code
133
134 @REM
135 @REM Done!!!
136 @REM
137 goto end
138
139 :no_jdk
140 echo.
141 echo !!! Please install Java, and set JAVA_HOME !!!
142 echo.
143 goto end
144
145 :no_ant
146 echo.
147 echo !!! Please install Apache Ant, and set ANT_HOME !!!
148 echo.
149 goto end
150
151 :no_antcontrib
152 echo.
153 echo !!! Please install Ant-contrib to ANT_HOME !!!
154 echo.
155 goto end
156
157 :no_xmlbeans
158 echo.
159 echo !!! Please install XML Beans, and set XMLBEANS_HOME !!!
160 echo.
161 goto end
162
163 :no_saxon8
164 echo.
165 echo !!! Please copy saxon8.jar file to XMLBEANS_HOME\lib !!!
166 echo.
167 goto end
168
169 :skipbuild
170 @REM
171 @REM This just sets up the CLASSPATH, the rest of the environment should have been set already.
172 @REM
173 echo.
174 echo WORKSPACE: %WORKSPACE%
175 echo JAVA_HOME: %JAVA_HOME%
176 echo ANT_HOME: %ANT_HOME%
177 echo XMLBEANS_HOME: %XMLBEANS_HOME%
178 echo CYGWIN_HOME: %CYGWIN_HOME%
179 echo PATH: %PATH%
180 echo.
181 set CLASSPATH=%XMLBEANS_HOME%\lib\jsr173_1.0_api.jar;%XMLBEANS_HOME%\lib\xbean.jar
182 set CLASSPATH=%CLASSPATH%;%XMLBEANS_HOME%\lib\xbean_xpath.jar;%XMLBEANS_HOME%\lib\xmlpublic.jar
183 set CLASSPATH=%CLASSPATH%;%XMLBEANS_HOME%\lib\saxon8.jar;%XMLBEANS_HOME%\lib\resolver.jar
184 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\Tools\Jars\SurfaceArea.jar;%WORKSPACE%\Tools\Jars\GenBuild.jar
185 set CLASSPATH=%CLASSPATH%;%WORKSPACE%\Tools\Jars\cpptasks.jar;%WORKSPACE%\Tools\Jars\frameworktasks.jar
186 goto end
187
188 :end
189 @echo on
190