edksetup.bat

   1 @REM @file
   2 @REM   Windows batch file to setup a WORKSPACE environment
   3 @REM
   4 @REM Copyright (c) 2006 - 2008, Intel Corporation
   5 @REM All rights reserved. This program and the accompanying materials
   6 @REM are licensed and made available under the terms and conditions of the BSD License
   7 @REM which accompanies this distribution.  The full text of the license may be found at
   8 @REM http://opensource.org/licenses/bsd-license.php
   9 @REM
  10 @REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 @REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 @REM
  13
  14 @REM set CYGWIN_HOME=C:\cygwin
  15
  16 @REM usage:
  17 @REM   edksetup.bat [--nt32] [AntBuild] [Rebuild] [ForceRebuild] [Reconfig]
  18 @REM if the argument, skip is present, only the paths and the
  19 @REM test and set of environment settings are performed.
  20
  21 @REM ##############################################################
  22 @REM # You should not have to modify anything below this line
  23 @REM #
  24
  25 @echo off
  26
  27 @REM
  28 @REM Set the WORKSPACE to the current working directory
  29 @REM
  30 pushd .
  31 cd %~dp0
  32
  33 if defined WORKSPACE (
  34   if %WORKSPACE% == %CD% (
  35     @REM workspace is not changed.
  36     @goto ParseArgs
  37   )
  38 )
  39
  40 @REM set new workspace
  41 @REM clear EFI_SOURCE and EDK_SOURCE for the new workspace
  42 set WORKSPACE=%CD%
  43 set EFI_SOURCE=
  44 set EDK_SOURCE=
  45
  46 :ParseArgs
  47 @if /I "%1"=="-h" goto Usage
  48 @if /I "%1"=="-help" goto Usage
  49 @if /I "%1"=="--help" goto Usage
  50 @if /I "%1"=="/h" goto Usage
  51 @if /I "%1"=="/?" goto Usage
  52 @if /I "%1"=="/help" goto Usage
  53
  54 @if /I not "%1"=="--nt32" goto no_nt32
  55
  56 @REM Flag, --nt32 is set
  57 @REM The Nt32 Emluation Platform requires Microsoft Libraries
  58 @REM and headers to interface with Windows.
  59
  60 if not defined VCINSTALLDIR (
  61   if defined VS71COMNTOOLS (
  62     call "%VS71COMNTOOLS%\vsvars32.bat"
  63   ) else (
  64     if defined VS80COMNTOOLS (
  65       call "%VS80COMNTOOLS%\vsvars32.bat"
  66     ) else (
  67       if defined VS90COMNTOOLS (
  68         call "%VS90COMNTOOLS%\vsvars32.bat"
  69       ) else (
  70         echo.
  71         echo !!! WARNING !!! Cannot find Visual Studio !!!
  72         echo.
  73       )
  74     )
  75   )
  76 )
  77 shift
  78
  79 :no_nt32
  80 @if /I "%1"=="NewBuild" shift
  81 @if not defined EDK_TOOLS_PATH set EDK_TOOLS_PATH=%WORKSPACE%\BaseTools
  82 @IF NOT EXIST "%EDK_TOOLS_PATH%\toolsetup.bat" goto BadBaseTools
  83 @call %EDK_TOOLS_PATH%\toolsetup.bat %*
  84 @if /I "%1"=="Reconfig" shift
  85 @goto check_cygwin
  86
  87 :BadBaseTools
  88   @REM
  89   @REM Need the BaseTools Package in order to build
  90   @REM
  91   echo.
  92   echo !!! ERROR !!! The BaseTools Package was not found !!!
  93   echo.
  94   echo Set the system environment variable, EDK_TOOLS_PATH to the BaseTools,
  95   echo For example,
  96   echo   set EDK_TOOLS_PATH=C:\MyTools\BaseTools
  97   echo The setup script, toolsetup.bat must reside in this folder.
  98   echo.
  99   @goto end
 100
 101 :check_cygwin
 102   @if exist c:\cygwin (
 103     @set CYGWIN_HOME=c:\cygwin
 104   ) else (
 105     @echo.
 106     @echo !!! WARNING !!! No CYGWIN_HOME set, gcc build may not be used !!!
 107     @echo.
 108   )
 109
 110 @if NOT "%1"=="" goto Usage
 111 @goto end
 112
 113 :Usage
 114   @echo.
 115   @echo  Usage: "%0 [-h | -help | --help | /h | /help | /?] [--nt32] [Reconfig]"
 116   @echo         --nt32         Call vsvars32.bat for NT32 platform build.
 117   @echo.
 118   @echo         Reconfig       Reinstall target.txt, tools_def.txt and build_rule.txt.
 119   @echo.
 120   @echo  Note that target.template, tools_def.template and build_rules.template
 121   @echo  will be only copied to target.txt, tools_def.txt and build_rule.txt
 122   @echo  respectively if they do not exist. Using option [Reconfig] to force the copy.
 123   @echo.
 124   @goto end
 125
 126 :end
 127   @popd
 128   @echo on
 129